| 1 | MODULE step |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE step *** |
|---|
| 4 | !! Time-stepping : manager of the ocean, tracer and ice time stepping |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1991-03 (G. Madec) Original code |
|---|
| 7 | !! - ! 1991-11 (G. Madec) |
|---|
| 8 | !! - ! 1992-06 (M. Imbard) add a first output record |
|---|
| 9 | !! - ! 1996-04 (G. Madec) introduction of dynspg |
|---|
| 10 | !! - ! 1996-04 (M.A. Foujols) introduction of passive tracer |
|---|
| 11 | !! 8.0 ! 1997-06 (G. Madec) new architecture of call |
|---|
| 12 | !! 8.2 ! 1997-06 (G. Madec, M. Imbard, G. Roullet) free surface |
|---|
| 13 | !! - ! 1999-02 (G. Madec, N. Grima) hpg implicit |
|---|
| 14 | !! - ! 2000-07 (J-M Molines, M. Imbard) Open Bondary Conditions |
|---|
| 15 | !! NEMO 1.0 ! 2002-06 (G. Madec) free form, suppress macro-tasking |
|---|
| 16 | !! - ! 2004-08 (C. Talandier) New trends organization |
|---|
| 17 | !! - ! 2005-01 (C. Ethe) Add the KPP closure scheme |
|---|
| 18 | !! - ! 2005-11 (G. Madec) Reorganisation of tra and dyn calls |
|---|
| 19 | !! - ! 2006-01 (L. Debreu, C. Mazauric) Agrif implementation |
|---|
| 20 | !! - ! 2006-07 (S. Masson) restart using iom |
|---|
| 21 | !! 3.2 ! 2009-02 (G. Madec, R. Benshila) reintroduicing z*-coordinate |
|---|
| 22 | !! - ! 2009-06 (S. Masson, G. Madec) TKE restart compatible with key_cpl |
|---|
| 23 | !!---------------------------------------------------------------------- |
|---|
| 24 | |
|---|
| 25 | !!---------------------------------------------------------------------- |
|---|
| 26 | !! stp : OPA system time-stepping |
|---|
| 27 | !!---------------------------------------------------------------------- |
|---|
| 28 | USE oce ! ocean dynamics and tracers variables |
|---|
| 29 | USE dom_oce ! ocean space and time domain variables |
|---|
| 30 | USE zdf_oce ! ocean vertical physics variables |
|---|
| 31 | USE ldftra_oce ! ocean tracer - trends |
|---|
| 32 | USE ldfdyn_oce ! ocean dynamics - trends |
|---|
| 33 | USE in_out_manager ! I/O manager |
|---|
| 34 | USE iom ! |
|---|
| 35 | USE lbclnk |
|---|
| 36 | |
|---|
| 37 | USE daymod ! calendar (day routine) |
|---|
| 38 | |
|---|
| 39 | USE dtatem ! ocean temperature data (dta_tem routine) |
|---|
| 40 | USE dtasal ! ocean salinity data (dta_sal routine) |
|---|
| 41 | USE sbcmod ! surface boundary condition (sbc routine) |
|---|
| 42 | USE sbcrnf ! surface boundary condition: runoff variables |
|---|
| 43 | USE sbccpl ! surface boundary condition: coupled formulation (call send at end of step) |
|---|
| 44 | USE cpl_oasis3, ONLY : lk_cpl |
|---|
| 45 | |
|---|
| 46 | #if defined key_top |
|---|
| 47 | USE trcstp ! passive tracer time-stepping (trc_stp routine) |
|---|
| 48 | #endif |
|---|
| 49 | |
|---|
| 50 | USE traqsr ! solar radiation penetration (tra_qsr routine) |
|---|
| 51 | USE trasbc ! surface boundary condition (tra_sbc routine) |
|---|
| 52 | USE trabbc ! bottom boundary condition (tra_bbc routine) |
|---|
| 53 | USE trabbl ! bottom boundary layer (tra_bbl routine) |
|---|
| 54 | USE tradmp ! internal damping (tra_dmp routine) |
|---|
| 55 | USE traadv ! advection scheme control (tra_adv_ctl routine) |
|---|
| 56 | USE traldf ! lateral mixing (tra_ldf routine) |
|---|
| 57 | USE cla ! cross land advection (tra_cla routine) |
|---|
| 58 | ! zdfkpp ! KPP non-local tracer fluxes (tra_kpp routine) |
|---|
| 59 | USE trazdf ! vertical mixing (tra_zdf routine) |
|---|
| 60 | USE tranxt ! time-stepping (tra_nxt routine) |
|---|
| 61 | USE tranpc ! non-penetrative convection (tra_npc routine) |
|---|
| 62 | |
|---|
| 63 | USE eosbn2 ! equation of state (eos_bn2 routine) |
|---|
| 64 | |
|---|
| 65 | USE dynadv ! advection (dyn_adv routine) |
|---|
| 66 | USE dynbfr ! Bottom friction terms (dyn_bfr routine) |
|---|
| 67 | USE dynvor ! vorticity term (dyn_vor routine) |
|---|
| 68 | USE dynhpg ! hydrostatic pressure grad. (dyn_hpg routine) |
|---|
| 69 | USE dynldf ! lateral momentum diffusion (dyn_ldf routine) |
|---|
| 70 | USE dynzdf ! vertical diffusion (dyn_zdf routine) |
|---|
| 71 | USE dynspg_oce ! surface pressure gradient (dyn_spg routine) |
|---|
| 72 | USE dynspg ! surface pressure gradient (dyn_spg routine) |
|---|
| 73 | USE dynnxt ! time-stepping (dyn_nxt routine) |
|---|
| 74 | |
|---|
| 75 | USE obc_par ! open boundary condition variables |
|---|
| 76 | USE obcdta ! open boundary condition data (obc_dta routine) |
|---|
| 77 | USE obcrst ! open boundary cond. restart (obc_rst routine) |
|---|
| 78 | USE obcrad ! open boundary cond. radiation (obc_rad routine) |
|---|
| 79 | |
|---|
| 80 | USE bdy_par ! unstructured open boundary data variables |
|---|
| 81 | USE bdydta ! unstructured open boundary data (bdy_dta routine) |
|---|
| 82 | |
|---|
| 83 | USE sshwzv ! vertical velocity and ssh (ssh_wzv routine) |
|---|
| 84 | |
|---|
| 85 | USE ldfslp ! iso-neutral slopes (ldf_slp routine) |
|---|
| 86 | USE ldfeiv ! eddy induced velocity coef. (ldf_eiv routine) |
|---|
| 87 | |
|---|
| 88 | USE zdftmx ! tide-induced vertical mixing (zdf_tmx routine) |
|---|
| 89 | USE zdfbfr ! bottom friction (zdf_bfr routine) |
|---|
| 90 | USE zdftke_old ! old TKE vertical mixing (zdf_tke_old routine) |
|---|
| 91 | USE zdftke ! TKE vertical mixing (zdf_tke routine) |
|---|
| 92 | USE zdfkpp ! KPP vertical mixing (zdf_kpp routine) |
|---|
| 93 | USE zdfddm ! double diffusion mixing (zdf_ddm routine) |
|---|
| 94 | USE zdfevd ! enhanced vertical diffusion (zdf_evd routine) |
|---|
| 95 | USE zdfric ! Richardson vertical mixing (zdf_ric routine) |
|---|
| 96 | USE zdfmxl ! Mixed-layer depth (zdf_mxl routine) |
|---|
| 97 | |
|---|
| 98 | USE zpshde ! partial step: hor. derivative (zps_hde routine) |
|---|
| 99 | |
|---|
| 100 | USE diawri ! Standard run outputs (dia_wri routine) |
|---|
| 101 | USE trdicp ! Ocean momentum/tracers trends (trd_wri routine) |
|---|
| 102 | USE trdmld ! mixed-layer trends (trd_mld routine) |
|---|
| 103 | USE trdmld_rst ! restart for mixed-layer trends |
|---|
| 104 | USE trdmod_oce ! ocean momentum/tracers trends |
|---|
| 105 | USE trdvor ! vorticity budget (trd_vor routine) |
|---|
| 106 | USE diagap ! hor. mean model-data gap (dia_gap routine) |
|---|
| 107 | USE diahdy ! dynamic height (dia_hdy routine) |
|---|
| 108 | USE diaptr ! poleward transports (dia_ptr routine) |
|---|
| 109 | USE diaar5 ! AR5 diagnosics (dia_ar5 routine) |
|---|
| 110 | USE diahth ! thermocline depth (dia_hth routine) |
|---|
| 111 | USE diafwb ! freshwater budget (dia_fwb routine) |
|---|
| 112 | USE flo_oce ! floats variables |
|---|
| 113 | USE floats ! floats computation (flo_stp routine) |
|---|
| 114 | |
|---|
| 115 | USE stpctl ! time stepping control (stp_ctl routine) |
|---|
| 116 | USE restart ! ocean restart (rst_wri routine) |
|---|
| 117 | USE prtctl ! Print control (prt_ctl routine) |
|---|
| 118 | |
|---|
| 119 | #if defined key_agrif |
|---|
| 120 | USE agrif_opa_sponge ! Momemtum and tracers sponges |
|---|
| 121 | #endif |
|---|
| 122 | |
|---|
| 123 | IMPLICIT NONE |
|---|
| 124 | PRIVATE |
|---|
| 125 | |
|---|
| 126 | PUBLIC stp ! called by opa.F90 |
|---|
| 127 | |
|---|
| 128 | !! * Substitutions |
|---|
| 129 | # include "domzgr_substitute.h90" |
|---|
| 130 | # include "zdfddm_substitute.h90" |
|---|
| 131 | !!---------------------------------------------------------------------- |
|---|
| 132 | !! NEMO/OPA 3.2 , LOCEAN-IPSL (2009) |
|---|
| 133 | !! $Id$ |
|---|
| 134 | !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt) |
|---|
| 135 | !!---------------------------------------------------------------------- |
|---|
| 136 | |
|---|
| 137 | CONTAINS |
|---|
| 138 | |
|---|
| 139 | #if defined key_agrif |
|---|
| 140 | SUBROUTINE stp( ) |
|---|
| 141 | INTEGER :: kstp ! ocean time-step index |
|---|
| 142 | #else |
|---|
| 143 | SUBROUTINE stp( kstp ) |
|---|
| 144 | INTEGER, INTENT(in) :: kstp ! ocean time-step index |
|---|
| 145 | #endif |
|---|
| 146 | !!---------------------------------------------------------------------- |
|---|
| 147 | !! *** ROUTINE stp *** |
|---|
| 148 | !! |
|---|
| 149 | !! ** Purpose : - Time stepping of OPA (momentum and active tracer eqs.) |
|---|
| 150 | !! - Time stepping of LIM (dynamic and thermodynamic eqs.) |
|---|
| 151 | !! - Tme stepping of TRC (passive tracer eqs.) |
|---|
| 152 | !! |
|---|
| 153 | !! ** Method : -1- Update forcings and data |
|---|
| 154 | !! -2- Update ocean physics |
|---|
| 155 | !! -3- Compute the t and s trends |
|---|
| 156 | !! -4- Update t and s |
|---|
| 157 | !! -5- Compute the momentum trends |
|---|
| 158 | !! -6- Update the horizontal velocity |
|---|
| 159 | !! -7- Compute the diagnostics variables (rd,N2, div,cur,w) |
|---|
| 160 | !! -8- Outputs and diagnostics |
|---|
| 161 | !!---------------------------------------------------------------------- |
|---|
| 162 | INTEGER :: jk ! dummy loop indice |
|---|
| 163 | INTEGER :: indic ! error indicator if < 0 |
|---|
| 164 | !! --------------------------------------------------------------------- |
|---|
| 165 | |
|---|
| 166 | #if defined key_agrif |
|---|
| 167 | kstp = nit000 + Agrif_Nb_Step() |
|---|
| 168 | ! IF ( Agrif_Root() .and. lwp) Write(*,*) '---' |
|---|
| 169 | ! IF (lwp) Write(*,*) 'Grid Number',Agrif_Fixed(),' time step ',kstp |
|---|
| 170 | #endif |
|---|
| 171 | indic = 1 ! reset to no error condition |
|---|
| 172 | |
|---|
| 173 | IF( kstp /= nit000 ) CALL day( kstp ) ! Calendar (day was already called at nit000 in day_init) |
|---|
| 174 | |
|---|
| 175 | CALL iom_setkt( kstp ) ! say to iom that we are at time step kstp |
|---|
| 176 | |
|---|
| 177 | CALL rst_opn( kstp ) ! Open the restart file |
|---|
| 178 | |
|---|
| 179 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 180 | ! Update data, open boundaries, surface boundary condition (including sea-ice) |
|---|
| 181 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 182 | IF( lk_dtatem ) CALL dta_tem( kstp ) ! update 3D temperature data |
|---|
| 183 | IF( lk_dtasal ) CALL dta_sal( kstp ) ! update 3D salinity data |
|---|
| 184 | CALL sbc ( kstp ) ! Sea Boundary Condition (including sea-ice) |
|---|
| 185 | IF( lk_obc ) CALL obc_dta( kstp ) ! update dynamic and tracer data at open boundaries |
|---|
| 186 | IF( lk_obc ) CALL obc_rad( kstp ) ! compute phase velocities at open boundaries |
|---|
| 187 | IF( lk_bdy ) CALL bdy_dta( kstp ) ! update dynamic and tracer data at unstructured open boundary |
|---|
| 188 | |
|---|
| 189 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 190 | ! Ocean dynamics : ssh, wn, hdiv, rot ! |
|---|
| 191 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 192 | CALL ssh_wzv( kstp ) ! after ssh & vertical velocity |
|---|
| 193 | |
|---|
| 194 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 195 | ! Ocean physics update (ua, va, ta, sa used as workspace) |
|---|
| 196 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 197 | CALL bn2( tb, sb, rn2b ) ! before Brunt-Vaisala frequency |
|---|
| 198 | CALL bn2( tn, sn, rn2 ) ! now Brunt-Vaisala frequency |
|---|
| 199 | ! |
|---|
| 200 | ! VERTICAL PHYSICS |
|---|
| 201 | CALL zdf_bfr( kstp ) ! bottom friction |
|---|
| 202 | ! ! Vertical eddy viscosity and diffusivity coefficients |
|---|
| 203 | IF( lk_zdfric ) CALL zdf_ric ( kstp ) ! Richardson number dependent Kz |
|---|
| 204 | IF( lk_zdftke_old ) CALL zdf_tke_old( kstp ) ! TKE closure scheme for Kz (old scheme) |
|---|
| 205 | IF( lk_zdftke ) CALL zdf_tke ( kstp ) ! TKE closure scheme for Kz |
|---|
| 206 | IF( lk_zdfkpp ) CALL zdf_kpp ( kstp ) ! KPP closure scheme for Kz |
|---|
| 207 | IF( lk_zdfcst ) THEN ! Constant Kz (reset avt, avm[uv] to the background value) |
|---|
| 208 | avt (:,:,:) = rn_avt0 * tmask(:,:,:) |
|---|
| 209 | avmu(:,:,:) = rn_avm0 * umask(:,:,:) |
|---|
| 210 | avmv(:,:,:) = rn_avm0 * vmask(:,:,:) |
|---|
| 211 | ENDIF |
|---|
| 212 | IF( ln_rnf_mouth ) THEN ! increase diffusivity at rivers mouths |
|---|
| 213 | DO jk = 2, nkrnf ; avt(:,:,jk) = avt(:,:,jk) + 2.e0 * rn_avt_rnf * rnfmsk(:,:) * tmask(:,:,jk) ; END DO |
|---|
| 214 | ENDIF |
|---|
| 215 | IF( ln_zdfevd ) CALL zdf_evd( kstp ) ! enhanced vertical eddy diffusivity |
|---|
| 216 | |
|---|
| 217 | IF( lk_zdftmx ) CALL zdf_tmx( kstp ) ! tidal vertical mixing |
|---|
| 218 | |
|---|
| 219 | IF( lk_zdfddm .AND. .NOT. lk_zdfkpp ) & |
|---|
| 220 | & CALL zdf_ddm( kstp ) ! double diffusive mixing |
|---|
| 221 | CALL zdf_mxl( kstp ) ! mixed layer depth |
|---|
| 222 | |
|---|
| 223 | ! write tke information in the restart file |
|---|
| 224 | IF( lrst_oce .AND. lk_zdftke ) CALL tke_rst( kstp, 'WRITE' ) |
|---|
| 225 | ! |
|---|
| 226 | ! LATERAL PHYSICS |
|---|
| 227 | ! |
|---|
| 228 | IF( lk_ldfslp ) THEN ! slope of lateral mixing |
|---|
| 229 | CALL eos( tb, sb, rhd ) ! before in situ density |
|---|
| 230 | IF( ln_zps ) CALL zps_hde( kstp, tb, sb, rhd, & ! Partial steps: before horizontal gradient |
|---|
| 231 | & gtu, gsu, gru, & ! of t, s, rd at the last ocean level |
|---|
| 232 | & gtv, gsv, grv ) |
|---|
| 233 | CALL ldf_slp( kstp, rhd, rn2b ) ! before slope of the lateral mixing |
|---|
| 234 | ENDIF |
|---|
| 235 | #if defined key_traldf_c2d |
|---|
| 236 | IF( lk_traldf_eiv ) CALL ldf_eiv( kstp ) ! eddy induced velocity coefficient |
|---|
| 237 | # endif |
|---|
| 238 | |
|---|
| 239 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 240 | ! diagnostics and outputs (ua, va, ta, sa used as workspace) |
|---|
| 241 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 242 | IF( lk_floats ) CALL flo_stp( kstp ) ! drifting Floats |
|---|
| 243 | IF( lk_diahth ) CALL dia_hth( kstp ) ! Thermocline depth (20 degres isotherm depth) |
|---|
| 244 | IF( lk_diagap ) CALL dia_gap( kstp ) ! basin averaged diagnostics |
|---|
| 245 | IF( lk_diahdy ) CALL dia_hdy( kstp ) ! dynamical heigh diagnostics |
|---|
| 246 | IF( lk_diafwb ) CALL dia_fwb( kstp ) ! Fresh water budget diagnostics |
|---|
| 247 | IF( ln_diaptr ) CALL dia_ptr( kstp ) ! Poleward TRansports diagnostics |
|---|
| 248 | IF( lk_diaar5 ) CALL dia_ar5( kstp ) ! ar5 diag |
|---|
| 249 | CALL dia_wri( kstp ) ! ocean model: outputs |
|---|
| 250 | |
|---|
| 251 | #if defined key_top |
|---|
| 252 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 253 | ! Passive Tracer Model |
|---|
| 254 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 255 | CALL trc_stp( kstp ) ! time-stepping |
|---|
| 256 | #endif |
|---|
| 257 | |
|---|
| 258 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 259 | ! Active tracers (ua, va used as workspace) |
|---|
| 260 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 261 | ta(:,:,:) = 0.e0 ! set tracer trends to zero |
|---|
| 262 | sa(:,:,:) = 0.e0 |
|---|
| 263 | |
|---|
| 264 | CALL tra_sbc ( kstp ) ! surface boundary condition |
|---|
| 265 | IF( ln_traqsr ) CALL tra_qsr ( kstp ) ! penetrative solar radiation qsr |
|---|
| 266 | IF( lk_trabbc ) CALL tra_bbc ( kstp ) ! bottom heat flux |
|---|
| 267 | IF( lk_trabbl_dif ) CALL tra_bbl_dif( kstp ) ! diffusive bottom boundary layer scheme |
|---|
| 268 | IF( lk_trabbl_adv ) CALL tra_bbl_adv( kstp ) ! advective (and/or diffusive) bottom boundary layer scheme |
|---|
| 269 | IF( lk_tradmp ) CALL tra_dmp ( kstp ) ! internal damping trends |
|---|
| 270 | CALL tra_adv ( kstp ) ! horizontal & vertical advection |
|---|
| 271 | IF( n_cla == 1 ) CALL tra_cla ( kstp ) ! Cross Land Advection (Update Hor. advection) |
|---|
| 272 | IF( lk_zdfkpp ) CALL tra_kpp ( kstp ) ! KPP non-local tracer fluxes |
|---|
| 273 | CALL tra_ldf ( kstp ) ! lateral mixing |
|---|
| 274 | #if defined key_agrif |
|---|
| 275 | IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_tra ! tracers sponge |
|---|
| 276 | #endif |
|---|
| 277 | CALL tra_zdf ( kstp ) ! vertical mixing and after tracer fields |
|---|
| 278 | |
|---|
| 279 | IF( ln_dynhpg_imp ) THEN ! semi-implicit hpg (time stepping then eos) |
|---|
| 280 | IF( ln_zdfnpc ) CALL tra_npc ( kstp ) ! update after fields by non-penetrative convection |
|---|
| 281 | CALL tra_nxt ( kstp ) ! tracer fields at next time step |
|---|
| 282 | CALL eos( ta, sa, rhd, rhop ) ! Time-filtered in situ density for hpg computation |
|---|
| 283 | IF( ln_zps ) CALL zps_hde( kstp, ta, sa, rhd, & ! Partial steps: time filtered hor. derivative |
|---|
| 284 | & gtu, gsu, gru, & ! of t, s, rd at the bottom ocean level |
|---|
| 285 | & gtv, gsv, grv ) |
|---|
| 286 | |
|---|
| 287 | ELSE ! centered hpg (eos then time stepping) |
|---|
| 288 | CALL eos( tn, sn, rhd, rhop ) ! now in situ density for hpg computation |
|---|
| 289 | IF( ln_zps ) CALL zps_hde( kstp, tn, sn, rhd, & ! Partial steps: now horizontal derivative |
|---|
| 290 | & gtu, gsu, gru, & ! of t, s, rd at the bottom ocean level |
|---|
| 291 | & gtv, gsv, grv ) |
|---|
| 292 | IF( ln_zdfnpc ) CALL tra_npc ( kstp ) ! update after fields by non-penetrative convection |
|---|
| 293 | CALL tra_nxt ( kstp ) ! tracer fields at next time step |
|---|
| 294 | ENDIF |
|---|
| 295 | |
|---|
| 296 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 297 | ! Dynamics (ta, sa used as workspace) |
|---|
| 298 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 299 | ua(:,:,:) = 0.e0 ! set dynamics trends to zero |
|---|
| 300 | va(:,:,:) = 0.e0 |
|---|
| 301 | |
|---|
| 302 | CALL dyn_adv( kstp ) ! advection (vector or flux form) |
|---|
| 303 | CALL dyn_vor( kstp ) ! vorticity term including Coriolis |
|---|
| 304 | CALL dyn_ldf( kstp ) ! lateral mixing |
|---|
| 305 | #if defined key_agrif |
|---|
| 306 | IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_dyn ! momemtum sponge |
|---|
| 307 | #endif |
|---|
| 308 | CALL dyn_hpg( kstp ) ! horizontal gradient of Hydrostatic pressure |
|---|
| 309 | CALL dyn_bfr( kstp ) ! bottom friction |
|---|
| 310 | CALL dyn_zdf( kstp ) ! vertical diffusion |
|---|
| 311 | indic=0 |
|---|
| 312 | CALL dyn_spg( kstp, indic ) ! surface pressure gradient |
|---|
| 313 | CALL dyn_nxt( kstp ) ! lateral velocity at next time step |
|---|
| 314 | |
|---|
| 315 | CALL ssh_nxt( kstp ) ! sea surface height at next time step |
|---|
| 316 | |
|---|
| 317 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 318 | ! Control and restarts |
|---|
| 319 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 320 | CALL stp_ctl( kstp, indic ) |
|---|
| 321 | IF( indic < 0 ) THEN |
|---|
| 322 | CALL ctl_stop( 'step: indic < 0' ) |
|---|
| 323 | CALL dia_wri_state( 'output.abort', kstp ) |
|---|
| 324 | ENDIF |
|---|
| 325 | IF( kstp == nit000 ) CALL iom_close( numror ) ! close input ocean restart file |
|---|
| 326 | IF( lrst_oce ) CALL rst_write ( kstp ) ! write output ocean restart file |
|---|
| 327 | IF( lk_obc ) CALL obc_rst_write( kstp ) ! write open boundary restart file |
|---|
| 328 | |
|---|
| 329 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 330 | ! Trends (ua, va, ta, sa used as workspace) |
|---|
| 331 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 332 | IF( nstop == 0 ) THEN |
|---|
| 333 | IF( lk_trddyn ) CALL trd_dwr( kstp ) ! trends: dynamics |
|---|
| 334 | IF( lk_trdtra ) CALL trd_twr( kstp ) ! trends: active tracers |
|---|
| 335 | IF( lk_trdmld ) CALL trd_mld( kstp ) ! trends: Mixed-layer |
|---|
| 336 | IF( lk_trdvor ) CALL trd_vor( kstp ) ! trends: vorticity budget |
|---|
| 337 | ENDIF |
|---|
| 338 | |
|---|
| 339 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 340 | ! Coupled mode |
|---|
| 341 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 342 | IF( lk_cpl ) CALL sbc_cpl_snd( kstp ) ! coupled mode : field exchanges |
|---|
| 343 | ! |
|---|
| 344 | ! |
|---|
| 345 | END SUBROUTINE stp |
|---|
| 346 | |
|---|
| 347 | !!====================================================================== |
|---|
| 348 | END MODULE step |
|---|
