source: trunk/NEMO/TOP_SRC/PISCES/p4zche.F90 @ 935

Last change on this file since 935 was 935, checked in by cetlod, 13 years ago

adding modules for PISCES SMS model, see ticket 141

  • Property svn:executable set to *
File size: 14.7 KB
Line 
1MODULE p4zche
2   !!======================================================================
3   !!                         ***  MODULE p4zche  ***
4   !! TOP :   PISCES Sea water chemistry computed following OCMIP protocol
5   !!======================================================================
6   !! History :    -   !  1988     (E. Maier-Reimer)  Original code
7   !!              -   !  1998     (O. Aumont)  addition
8   !!              -   !  1999     (C. Le Quere)  modification
9   !!             1.0  !  2004     (O. Aumont)  modification
10   !!              -   !  2006     (R. Gangsto)  modification
11   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
12   !!----------------------------------------------------------------------
13#if defined key_pisces
14   !!----------------------------------------------------------------------
15   !!   'key_pisces'                                       PISCES bio-model
16   !!----------------------------------------------------------------------
17   !!   p4z_che        :  Sea water chemistry computed following OCMIP protocol
18   !!----------------------------------------------------------------------
19   USE oce_trc         !
20   USE trp_trc         !
21   USE sms             !
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   p4z_che    ! called in p4zprg.F90
27
28   !! * Shared module variables
29   REAL(wp), PUBLIC, DIMENSION(jpi,jpj,jpk) ::   &   !:
30      sio3eq, fekeq           !: chemistry of Fe and Si
31
32   REAL(wp), PUBLIC, DIMENSION(jpi,jpj,2)   ::   &   !:
33      chemc                   !: Solubilities of O2 and CO2
34
35   !! * Module variables
36
37   REAL(wp) :: &
38      salchl = 1./1.80655 ! conversion factor for salinity --> chlorinity (Wooster et al. 1969)
39
40   REAL(wp) :: &            ! coeff. for apparent solubility equilibrium
41      akcc1 = -171.9065 , &    ! Millero et al. 1995 from Mucci 1983
42      akcc2 = -0.077993 , & 
43      akcc3 = 2839.319  , & 
44      akcc4 = 71.595    , & 
45      akcc5 = -0.77712  , & 
46      akcc6 = 0.0028426 , & 
47      akcc7 = 178.34    , & 
48      akcc8 = -0.07711  , & 
49      akcc9 = 0.0041249
50
51   REAL(wp) :: &             ! universal gas constants
52      rgas = 83.143, &
53      oxyco = 1./22.4144
54
55   REAL(wp) :: &             ! borat constants
56      bor1 = 0.00023, &
57      bor2 = 1./10.82
58
59   REAL(wp) :: &              !
60      ca0 = -162.8301  , &
61      ca1 = 218.2968   , &
62      ca2 = 90.9241    , &
63      ca3 = -1.47696   , &
64      ca4 = 0.025695   , &
65      ca5 = -0.025225  , &
66      ca6 = 0.0049867
67
68   REAL(wp) :: &              ! coeff. for 1. dissoc. of carbonic acid (Edmond and Gieskes, 1970)   
69      c10 = -3670.7   , &
70      c11 = 62.008    , &
71      c12 = -9.7944   , &
72      c13 = 0.0118    , &
73      c14 = -0.000116
74
75   REAL(wp) :: &              ! coeff. for 2. dissoc. of carbonic acid (Millero, 1995)   
76      c20 = -1394.7   , &
77      c21 = -4.777    , &
78      c22 = 0.0184    , &
79      c23 = -0.000118
80
81   REAL(wp) :: &             ! constants for calculate concentrations
82      st1  = 0.14     , &    ! for sulfate (Morris & Riley 1966)
83      st2  = 1./96.062, &
84      ks0  = 141.328  , &
85      ks1  = -4276.1  , &
86      ks2  = -23.093  , &
87      ks3  = -13856.  , &
88      ks4  = 324.57   , &
89      ks5  = -47.986  , &
90      ks6  = 35474.   , &
91      ks7  = -771.54  , &
92      ks8  = 114.723  , &
93      ks9  = -2698.   , &
94      ks10 = 1776.    , &
95      ks11 = 1.       , &
96      ks12 = -0.001005 
97
98   REAL(wp) :: &             ! constants for calculate concentrations
99      ft1  = 0.000067   , &  ! fluorides (Dickson & Riley 1979 )
100      ft2  = 1./18.9984 , &
101      kf0  = -12.641    , &
102      kf1  = 1590.2     , &
103      kf2  = 1.525      , &
104      kf3  = 1.0        , &
105      kf4  =-0.001005
106
107
108   REAL(wp) :: &              ! coeff. for 1. dissoc. of boric acid (Dickson and Goyet, 1994)
109      cb0  = -8966.90, &
110      cb1  = -2890.53, &
111      cb2  = -77.942 , &
112      cb3  = 1.728   , &
113      cb4  = -0.0996 , &
114      cb5  = 148.0248, &
115      cb6  = 137.1942, &
116      cb7  = 1.62142 , &
117      cb8  = -24.4344, &
118      cb9  = -25.085 , &
119      cb10 = -0.2474 , &
120      cb11 = 0.053105
121
122   REAL(wp) :: &             ! coeff. for dissoc. of water (Dickson and Riley, 1979 )
123      cw0 = -13847.26  , &
124      cw1 = 148.9652   , &
125      cw2 = -23.6521   , &
126      cw3 = 118.67     , &
127      cw4 = -5.977     , &
128      cw5 = 1.0495     , &
129      cw6 = -0.01615
130 
131   REAL(wp) :: &             ! coeff. for dissoc. of phosphate (Millero (1974)
132      cp10 = 115.54    , &
133      cp11 = -4576.752 , &
134      cp12 = -18.453   , &
135      cp13 = -106.736  , &
136      cp14 = 0.69171   , &
137      cp15 = -0.65643  , &
138      cp16 = -0.01844  , &
139      cp20 = 172.1033  , &
140      cp21 = -8814.715 , &
141      cp22 = -27.927   , &
142      cp23 = -160.340  , &
143      cp24 = 1.3566    , &
144      cp25 = 0.37335   , &
145      cp26 = -0.05778  , &
146      cp30 = -18.126   , &
147      cp31 = -3070.75  , &
148      cp32 = 17.27039  , &
149      cp33 = 2.81197   , &
150      cp34 = -44.99486 , &
151      cp35 = -0.09984
152
153   REAL(wp) :: &             ! coeff. for dissoc. of silicates (Millero (1974) 
154      cs10 = 117.385   , & 
155      cs11 = -8904.2   , & 
156      cs12 = -19.334   , & 
157      cs13 = -458.79   , & 
158      cs14 = 3.5913    , & 
159      cs15 = 188.74    , & 
160      cs16 = -1.5998   , & 
161      cs17 = -12.1652  , & 
162      cs18 = 0.07871   , & 
163      cs19 = 0.        , & 
164      cs20 = 1.        , & 
165      cs21 = -0.001005
166
167   REAL(wp) :: &              ! volumetric solubility constants for o2 in ml/l (Weiss, 1974)
168      ox0 = -58.3877   , &
169      ox1 = 85.8079    , &
170      ox2 = 23.8439    , &
171      ox3 = -0.034892  , &
172      ox4 = 0.015568   , &
173      ox5 = -0.0019387 
174
175   REAL(wp), DIMENSION(5)  :: &  ! coeff. for seawater pressure correction
176      devk1, devk2, devk3,    &  ! (millero 95)
177      devk4, devk5
178
179   DATA devk1 / -25.5    , -15.82    , -29.48  , -25.60     , -48.76    /   
180   DATA devk2 / 0.1271   , -0.0219   , 0.1622  , 0.2324     , 0.5304    /   
181   DATA devk3 / 0.       , 0.        , 2.608E-3,  -3.6246E-3, 0.        /   
182   DATA devk4 / -3.08E-3 , 1.13E-3   , -2.84E-3, -5.13E-3   , -11.76E-3 /   
183   DATA devk5 / 0.0877E-3, -0.1475E-3,  0.     , 0.0794E-3  , 0.3692E-3 /
184
185   !!* Substitution
186#include "domzgr_substitute.h90"
187   !!----------------------------------------------------------------------
188   !! NEMO/TOP 2.0 , LOCEAN-IPSL (2007)
189   !! $Header:$
190   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
191   !!----------------------------------------------------------------------
192
193CONTAINS
194
195   SUBROUTINE p4z_che
196      !!---------------------------------------------------------------------
197      !!                     ***  ROUTINE p4z_che  ***
198      !!
199      !! ** Purpose :   Sea water chemistry computed following OCMIP protocol
200      !!
201      !! ** Method  : - ...
202      !!---------------------------------------------------------------------
203      INTEGER  ::   ji, jj, jk
204      REAL(wp) ::   ztkel, zsal , zqtt  , zbuf1 , zbuf2
205      REAL(wp) ::   zpres, ztc  , zcl   , zcpexp, zoxy  , zcpexp2
206      REAL(wp) ::   zsqrt, ztr  , zlogt , zcek1
207      REAL(wp) ::   zlqtt, zqtt2, zsal15, zis   , zis2 , zisqrt
208      REAL(wp) ::   zckb , zck1 , zck2  , zckw  , zak1 , zak2  , zakb , zaksp0, zakw
209      REAL(wp) ::   zst  , zft  , zcks  , zckf  , zaksp1
210      !!---------------------------------------------------------------------
211
212      ! CHEMICAL CONSTANTS - SURFACE LAYER
213      ! ----------------------------------
214!CDIR NOVERRCHK
215      DO jj = 1, jpj
216!CDIR NOVERRCHK
217         DO ji = 1, jpi
218
219            !                             ! SET ABSOLUTE TEMPERATURE
220            ztkel = tn(ji,jj,1) + 273.16
221            zqtt  = ztkel * 0.01
222            zqtt2 = zqtt * zqtt
223            zsal  = sn(ji,jj,1) + (1.- tmask(ji,jj,1) ) * 35.
224            zlqtt = LOG( zqtt )
225
226            !                             ! LN(K0) OF SOLUBILITY OF CO2 (EQ. 12, WEISS, 1980)
227            !                             !     AND FOR THE ATMOSPHERE FOR NON IDEAL GAS
228            zcek1 = ca0 + ca1 / zqtt + ca2 * zlqtt + ca3 * zqtt2 + zsal*( ca4 + ca5 * zqtt + ca6 * zqtt2 )
229
230            !                             ! LN(K0) OF SOLUBILITY OF O2 and N2 (EQ. 4, WEISS, 1970)
231            zoxy  = ox0 + ox1 / zqtt + ox2 * zlqtt + zsal * ( ox3 + ox4 * zqtt + ox5 * zqtt2 )
232
233            !                             ! SET SOLUBILITIES OF O2 AND CO2
234            chemc(ji,jj,1) = EXP( zcek1 ) * 1.e-6 * rhop(ji,jj,1) / 1000.
235            chemc(ji,jj,2) = EXP( zoxy  ) * oxyco
236
237         END DO
238      END DO
239
240      ! CHEMICAL CONSTANTS - DEEP OCEAN
241      ! -------------------------------
242!CDIR NOVERRCHK
243      DO jk = 1, jpk
244!CDIR NOVERRCHK
245         DO jj = 1, jpj
246!CDIR NOVERRCHK
247            DO ji = 1, jpi
248
249               ! SET PRESSION
250               zpres   = 1.025e-1 * fsdept(ji,jj,jk)
251
252               ! SET ABSOLUTE TEMPERATURE
253               ztkel   = tn(ji,jj,jk) + 273.16
254               zqtt    = ztkel * 0.01
255               zsal    = sn(ji,jj,jk) + ( 1.-tmask(ji,jj,jk) ) * 35.
256               zsqrt  = SQRT( zsal )
257               zsal15  = zsqrt * zsal
258               zlogt  = LOG( ztkel )
259               ztr    = 1. / ztkel
260               zis    = 19.924 * zsal / ( 1000.- 1.005 * zsal )
261               zis2   = zis * zis
262               zisqrt = SQRT( zis )
263               ztc     = tn(ji,jj,jk) + ( 1.- tmask(ji,jj,jk) ) * 20.
264
265               ! CHLORINITY (WOOSTER ET AL., 1969)
266               zcl     = zsal * salchl
267
268               ! TOTAL SULFATE CONCENTR. [MOLES/kg soln]
269               zst     = st1 * zcl * st2
270
271               ! TOTAL FLUORIDE CONCENTR. [MOLES/kg soln]
272               zft     = ft1 * zcl * ft2
273
274               ! DISSOCIATION CONSTANT FOR SULFATES on free H scale (Dickson 1990)
275               zcks    = EXP(  ks1 * ztr + ks0 + ks2 * zlogt                           &
276                  &                     + ( ks3 * ztr + ks4 + ks5 * zlogt ) * zisqrt   &
277                  &                     + ( ks6 * ztr + ks7 + ks8 * zlogt ) * zis      &
278                  &                     + ks9 * ztr * zis * zisqrt + ks10 * ztr *zis2 + LOG( ks11 + ks12 *zsal )  )
279
280               ! DISSOCIATION CONSTANT FOR FLUORIDES on free H scale (Dickson and Riley 79)
281               zckf    = EXP(  kf1 * ztr + kf0 + kf2 * zisqrt + LOG( kf3 + kf4 * zsal )  )
282
283               ! DISSOCIATION CONSTANT FOR CARBONATE AND BORATE
284               zckb    = ( cb0 + cb1 * zsqrt + cb2  * zsal + cb3 * zsal15 + cb4 * zsal * zsal ) * ztr   &
285                  &    + ( cb5 + cb6 * zsqrt + cb7  * zsal )                                            &
286                  &    + ( cb8 + cb9 * zsqrt + cb10 * zsal ) * zlogt + cb11 * zsqrt * ztkel             &
287                  &    + LOG(  ( 1.+ zst / zcks + zft / zckf ) / ( 1.+ zst / zcks )  )
288!!gm zsal**2 to be replaced by a *...
289               zck1    = c10 * ztr + c11 + c12 * zlogt + c13 * zsal + c14 * zsal**2
290               zck2    = c20 * ztr + c21 + c22 * zsal   + c23 * zsal**2
291
292               ! PKW (H2O) (DICKSON AND RILEY, 1979)
293               zckw    = cw0 * ztr + cw1 + cw2 * zlogt + ( cw3 * ztr + cw4 + cw5 * zlogt ) * zsqrt + cw6 * zsal
294
295
296               ! APPARENT SOLUBILITY PRODUCT K'SP OF CALCITE IN SEAWATER
297               !       (S=27-43, T=2-25 DEG C) at pres =0 (atmos. pressure) (MUCCI 1983)
298               zaksp0  = akcc1 + akcc2 * ztkel + akcc3 * ztr + akcc4 * LOG10( ztkel )   &
299                  &   + ( akcc5 + akcc6 * ztkel + akcc7 * ztr ) * zsqrt + akcc8 * zsal + akcc9 * zsal15
300
301               ! K1, K2 OF CARBONIC ACID, KB OF BORIC ACID, KW (H2O) (LIT.?)
302               zak1    = 10**(zck1)
303               zak2    = 10**(zck2)
304               zakb    = EXP( zckb  )
305               zakw    = EXP( zckw )
306               zaksp1  = 10**(zaksp0)
307
308               ! FORMULA FOR CPEXP AFTER EDMOND & GIESKES (1970)
309               !        (REFERENCE TO CULBERSON & PYTKOQICZ (1968) AS MADE
310               !        IN BROECKER ET AL. (1982) IS INCORRECT; HERE RGAS IS
311               !        TAKEN TENFOLD TO CORRECT FOR THE NOTATION OF pres  IN
312               !        DBAR INSTEAD OF BAR AND THE EXPRESSION FOR CPEXP IS
313               !        MULTIPLIED BY LN(10.) TO ALLOW USE OF EXP-FUNCTION
314               !        WITH BASIS E IN THE FORMULA FOR AKSPP (CF. EDMOND
315               !        & GIESKES (1970), P. 1285-1286 (THE SMALL
316               !        FORMULA ON P. 1286 IS RIGHT AND CONSISTENT WITH THE
317               !        SIGN IN PARTIAL MOLAR VOLUME CHANGE AS SHOWN ON P. 1285))
318               zcpexp  = zpres /(rgas*ztkel)
319               zcpexp2 = zpres * zpres/(rgas*ztkel)
320
321               ! KB OF BORIC ACID, K1,K2 OF CARBONIC ACID PRESSURE
322               !        CORRECTION AFTER CULBERSON AND PYTKOWICZ (1968)
323               !        (CF. BROECKER ET AL., 1982)
324
325               zbuf1  = -(devk1(1)+devk2(1)*ztc+devk3(1)*ztc*ztc)
326               zbuf2  = 0.5*(devk4(1)+devk5(1)*ztc)
327               ak13(ji,jj,jk) = zak1 * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
328
329               zbuf1  =     - ( devk1(2) + devk2(2) * ztc + devk3(2) * ztc * ztc )
330               zbuf2  = 0.5 * ( devk4(2) + devk5(2) * ztc )
331               ak23(ji,jj,jk) = zak2 * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
332
333               zbuf1  =     - ( devk1(3) + devk2(3) * ztc + devk3(3) * ztc * ztc )
334               zbuf2  = 0.5 * ( devk4(3) + devk5(3) * ztc )
335               akb3(ji,jj,jk) = zakb * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
336
337               zbuf1  =     - ( devk1(4) + devk2(4) * ztc + devk3(4) * ztc * ztc )
338               zbuf2  = 0.5 * ( devk4(4) + devk5(4) * ztc )
339               akw3(ji,jj,jk) = zakw * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
340
341
342               ! APPARENT SOLUBILITY PRODUCT K'SP OF CALCITE
343               !        AS FUNCTION OF PRESSURE FOLLOWING MILLERO
344               !        (P. 1285) AND BERNER (1976)
345               zbuf1  =     - ( devk1(5) + devk2(5) * ztc + devk3(5) * ztc * ztc )
346               zbuf2  = 0.5 * ( devk4(5) + devk5(5) * ztc )
347               aksp(ji,jj,jk) = zaksp1 * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
348
349
350               ! TOTAL BORATE CONCENTR. [MOLES/L]
351               borat(ji,jj,jk) = bor1 * zcl * bor2
352
353               ! Iron and SIO3 saturation concentration from ...
354               sio3eq(ji,jj,jk) = EXP(  LOG( 10.) * ( 6.44 - 968. / ztkel )  ) * 1.e-6
355               fekeq (ji,jj,jk) = 10**( 17.27 - 1565.7 / ( 273.15 + ztc ) )
356
357            END DO
358         END DO
359      END DO
360      !
361   END SUBROUTINE p4z_che
362
363#else
364   !!======================================================================
365   !!  Dummy module :                                   No PISCES bio-model
366   !!======================================================================
367CONTAINS
368   SUBROUTINE p4z_che( kt )                   ! Empty routine
369      INTEGER, INTENT( in ) ::   kt
370      WRITE(*,*) 'p4z_che: You should not have seen this print! error?', kt
371   END SUBROUTINE p4z_che
372#endif 
373
374   !!======================================================================
375END MODULE  p4zche
Note: See TracBrowser for help on using the repository browser.