New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zflx.F90 in trunk/NEMO/TOP_SRC/PISCES – NEMO

source: trunk/NEMO/TOP_SRC/PISCES/p4zflx.F90 @ 935

Last change on this file since 935 was 935, checked in by cetlod, 16 years ago

adding modules for PISCES SMS model, see ticket 141
  • Property svn:executable set to *
File size: 9.0 KB
RevLine 
[935]1MODULE p4zflx
2   !!======================================================================
3   !!                         ***  MODULE p4zflx  ***
4   !! TOP :   PISCES CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE
5   !!======================================================================
6   !! History :    -   !  1988-07  (E. MAIER-REIMER) Original code
7   !!              -   !  1998     (O. Aumont) additions
8   !!              -   !  1999     (C. Le Quere) modifications
9   !!             1.0  !  2004     (O. Aumont) modifications
10   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
11   !!----------------------------------------------------------------------
12#if defined key_pisces
13   !!----------------------------------------------------------------------
14   !!   'key_pisces'                                       PISCES bio-model
15   !!----------------------------------------------------------------------
16   !!   p4z_flx       :   CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE
17   !!   p4z_flx_init  :   Read the namelist
18   !!----------------------------------------------------------------------
19   USE trc
20   USE oce_trc         !
21   USE trp_trc
22   USE sms
23   USE prtctl_trc
24   USE p4zche
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   p4z_flx    ! called in p4zprg.F90
30
31   REAL(wp) :: &  ! pre-industrial atmospheric [co2] (ppm) 
32     atcox  = 0.20946 ,   &  !:
33     atcco2 = 278.           !:
34
35   REAL(wp) ::   &
36     xrhoa  = 1.22   ,   &   !: Air density kg/m3
37     xcd    = 1.5e-3         !: drag coefficient
38
39   REAL(wp) :: &
40     tco2flx = 0.            !: Total flux of carbon per year
41
42   !!* Substitution
43#  include "domzgr_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/TOP 2.0 , LOCEAN-IPSL (2007)
46   !! $Header:$
47   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49
50CONTAINS
51
52   SUBROUTINE p4z_flx ( kt )
53      !!---------------------------------------------------------------------
54      !!                     ***  ROUTINE p4z_flx  ***
55      !!
56      !! ** Purpose :   CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE
57      !!
58      !! ** Method  : - ???
59      !!---------------------------------------------------------------------
60      INTEGER, INTENT(in) :: kt
61      INTEGER  ::   ji, jj, jrorr, nspyr
62      REAL(wp) ::   zttc, ztx, zty, ztau, zws, zkgwan
63      REAL(wp) ::   zfld, zflu, zfld16, zflu16, zfact
64      REAL(wp) ::   zph, zah2, zbot, zdic, zalk, zschmitto2, zalka, zschmittco2
65      REAL(wp), DIMENSION(jpi,jpj) ::   zkgco2, zkgo2, zh2co3, ztco2flx
66      CHARACTER (len=25) :: charout
67
68      !!---------------------------------------------------------------------
69
70
71      IF( kt == nittrc000  )   CALL p4z_flx_init      ! Initialization (first time-step only)
72
73
74      ! -----------------------------------------------------
75      !     ASSIGNATION TO EXPONENTS IN THE LISS AND MERLIVAT
76      !     FORMULATION OF THE GAS EXCHANGE RATE
77      ! -----------------------------------------------------
78
79      nspyr = INT( raass / rdt )
80
81      ! SURFACE CHEMISTRY (PCO2 AND [H+] IN
82      !     SURFACE LAYER); THE RESULT OF THIS CALCULATION
83      !     IS USED TO COMPUTE AIR-SEA FLUX OF CO2
84
85      DO jrorr = 1, 10
86
87!CDIR NOVERRCHK
88         DO jj = 1, jpj
89!CDIR NOVERRCHK
90            DO ji = 1, jpi
91
92               ! DUMMY VARIABLES FOR DIC, H+, AND BORATE
93               zbot  = borat(ji,jj,1)
94               zfact = rhop(ji,jj,1) / 1000. + rtrn
95               zdic  = trn(ji,jj,1,jpdic) / zfact
96               zph   = MAX( hi(ji,jj,1), 1.e-10 ) / zfact
97               zalka = trn(ji,jj,1,jptal) / zfact
98
99               ! CALCULATE [ALK]([CO3--], [HCO3-])
100               zalk  = zalka - (  akw3(ji,jj,1) / zph - zph + zbot / ( 1.+ zph / akb3(ji,jj,1) )  )
101
102               ! CALCULATE [H+] AND [H2CO3]
103               zah2   = SQRT(  (zdic-zalk)**2 + 4.* ( zalk * ak23(ji,jj,1)   &
104                  &                                        / ak13(ji,jj,1) ) * ( 2.* zdic - zalk )  )
105               zah2   = 0.5 * ak13(ji,jj,1) / zalk * ( ( zdic - zalk ) + zah2 )
106               zh2co3(ji,jj) = ( 2.* zdic - zalk ) / ( 2.+ ak13(ji,jj,1) / zah2 ) * zfact
107               hi(ji,jj,1)   = zah2 * zfact
108            END DO
109         END DO
110      END DO
111
112
113      ! --------------
114      ! COMPUTE FLUXES
115      ! --------------
116
117      ! FIRST COMPUTE GAS EXCHANGE COEFFICIENTS
118      ! -------------------------------------------
119
120!CDIR NOVERRCHK
121      DO jj = 1, jpj
122!CDIR NOVERRCHK
123         DO ji = 1, jpi
124
125            zttc = MIN( 35., tn(ji,jj,1) )
126
127      ! Compute the schmidt Number both O2 and CO2
128      ! ------------------------------------------
129
130            zschmittco2 = 2073.1 - 125.62 * zttc + 3.6276 * zttc**2 - 0.043126 * zttc**3
131            zschmitto2  = 1953.4 - 128.0 * zttc + 3.9918 * zttc**2 - 0.050091 * zttc**3
132
133            ! Estimation of wind speed as a function of wind stress
134            ztx  = utau(ji,jj) * umask(ji,jj,1)
135            zty  = vtau(ji,jj) * vmask(ji,jj,1)
136            ztau = SQRT( ztx * ztx + zty * zty )
137            zws  = SQRT ( ztau / ( xrhoa * xcd ) )
138
139      ! Compute the piston velocity for O2 and CO2
140      ! ------------------------------------------
141
142            zkgwan = (  0.3 * zws * zws    &
143               &   + 2.5 * ( 0.5246 + zttc * ( 0.016256+zttc*0.00049946 ) ) ) &
144# if defined key_off_degrad
145               &         * facvol(ji,jj,1)      &
146# endif
147               &   / (100. * 3600.)* ( 1.- freeze(ji,jj) ) * tmask(ji,jj,1) 
148
149            ! COMPUTE GAS EXCHANGE FOR CO2
150            zkgco2(ji,jj) = zkgwan * SQRT( 660./ zschmittco2 )
151            zkgo2(ji,jj)  = zkgwan * SQRT( 660./ zschmitto2 )
152
153         END DO
154      END DO
155
156      ztco2flx(:,:) = 0.
157      DO jj = 1, jpj
158         DO ji = 1, jpi
159
160            ! Compute CO2 flux for the sea and air
161            zfld = atcco2 * tmask(ji,jj,1) * chemc(ji,jj,1) * zkgco2(ji,jj)
162            zflu = zh2co3(ji,jj) * tmask(ji,jj,1) * zkgco2(ji,jj)
163            tra(ji,jj,1,jpdic) = tra(ji,jj,1,jpdic) + ( zfld - zflu ) / fse3t(ji,jj,1)
164
165            ! compute flux of carbon
166            ztco2flx(ji,jj) = ( zfld - zflu ) * rfact &
167               &             * e1t(ji,jj) * e2t(ji,jj) * tmask(ji,jj,1) * 1000.
168
169            ! Compute O2 flux
170            zfld16 = atcox * chemc(ji,jj,2) *tmask(ji,jj,1) * zkgo2(ji,jj)
171            zflu16 = trn(ji,jj,1,jpoxy) * tmask(ji,jj,1) * zkgo2(ji,jj)
172            tra(ji,jj,1,jpoxy) = tra(ji,jj,1,jpoxy) + ( zfld16 - zflu16 ) / fse3t(ji,jj,1)
173
174# if defined key_trc_diaadd
175            ! Save diagnostics
176            trc2d(ji,jj,1) = ( zfld - zflu ) * 1000.
177            trc2d(ji,jj,2) = ( zfld16 - zflu16 ) * 1000.
178            trc2d(ji,jj,3) = zkgco2(ji,jj)
179            trc2d(ji,jj,4) = atcco2 - zh2co3(ji,jj) / ( chemc(ji,jj,1) + rtrn )
180# endif
181         END DO
182      END DO
183      !
184
185      ! Total Flux of Carbon
186      DO jj = 1, jpj
187        DO ji = 1, jpi
188           tco2flx = tco2flx + ztco2flx(ji,jj) * tmask_i(ji,jj)
189        END DO
190      END DO
191
192      IF( MOD( kt, nspyr ) == 0 ) THEN
193        WRITE(numout,*) ' Atmospheric pCO2    :'
194        WRITE(numout,*) '-------------------- : ',kt,'  ',atcco2
195        WRITE(numout,*) '(ppm)'
196        WRITE(numout,*) 'Total Flux of Carbon :'
197        WRITE(numout,*) '-------------------- : ',tco2flx * 12./1E15
198        WRITE(numout,*) '(GtC/an)'
199        tco2flx = 0.
200      ENDIF
201
202      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
203         WRITE(charout, FMT="('flx ')")
204         CALL prt_ctl_trc_info(charout)
205         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
206      ENDIF
207
208
209   END SUBROUTINE p4z_flx
210
211   SUBROUTINE p4z_flx_init
212
213      !!----------------------------------------------------------------------
214      !!                  ***  ROUTINE p4z_flx_init  ***
215      !!
216      !! ** Purpose :   Initialization of atmospheric conditions
217      !!
218      !! ** Method  :   Read the natext namelist and check the parameters
219      !!      called at the first timestep (nittrc000)
220      !! ** input   :   Namelist natext
221      !!
222      !!----------------------------------------------------------------------
223
224      NAMELIST/natext/ atcco2
225
226      REWIND( numnat )                     ! read numnat
227      READ  ( numnat, natext )
228
229      IF(lwp) THEN                         ! control print
230         WRITE(numout,*) ' '
231         WRITE(numout,*) ' Namelist parameters for air-sea exchange, natext'
232         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
233         WRITE(numout,*) '    Atmospheric pCO2      atcco2      =', atcco2
234      ENDIF
235
236   END SUBROUTINE p4z_flx_init
237
238#else
239   !!======================================================================
240   !!  Dummy module :                                   No PISCES bio-model
241   !!======================================================================
242CONTAINS
243   SUBROUTINE p4z_flx( kt )                   ! Empty routine
244      INTEGER, INTENT( in ) ::   kt
245      WRITE(*,*) 'p4z_flx: You should not have seen this print! error?', kt
246   END SUBROUTINE p4z_flx
247#endif 
248
249   !!======================================================================
250END MODULE  p4zflx
Note: See TracBrowser for help on using the repository browser.