New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zlys.F90 in trunk/NEMO/TOP_SRC/PISCES – NEMO

source: trunk/NEMO/TOP_SRC/PISCES/p4zlys.F90 @ 1678

Last change on this file since 1678 was 1678, checked in by cetlod, 15 years ago

Improve PISCES diagnostics for IPCC AR5 exercise, see ticket:567
  • Property svn:executable set to *
  • Property svn:keywords set to Id
File size: 8.7 KB
Line 
1MODULE p4zlys
2   !!======================================================================
3   !!                         ***  MODULE p4zlys  ***
4   !! TOP :   PISCES
5   !!======================================================================
6   !! History :    -   !  1988-07  (E. MAIER-REIMER) Original code
7   !!              -   !  1998     (O. Aumont) additions
8   !!              -   !  1999     (C. Le Quere) modifications
9   !!             1.0  !  2004     (O. Aumont) modifications
10   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
11   !!----------------------------------------------------------------------
12#if defined key_pisces
13   !!----------------------------------------------------------------------
14   !!   'key_pisces'                                       PISCES bio-model
15   !!----------------------------------------------------------------------
16   !!   p4z_lys        :   Compute the CaCO3 dissolution
17   !!   p4z_lys_init   :   Read the namelist parameters
18   !!----------------------------------------------------------------------
19   USE trc
20   USE oce_trc         !
21   USE trc
22   USE sms_pisces
23   USE prtctl_trc
24   USE iom
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   p4z_lys    ! called in p4zprg.F90
30
31   !! * Shared module variables
32   REAL(wp), PUBLIC ::   &
33     kdca = 0.327e3_wp   ,  &  !:
34     nca  = 1.0_wp             !:
35
36   !! * Module variables
37   REAL(wp) :: &
38      calcon = 1.03E-2        ! mean calcite concentration [Ca2+] in sea water [mole/kg solution]
39
40   !!----------------------------------------------------------------------
41   !! NEMO/TOP 2.0 , LOCEAN-IPSL (2007)
42   !! $Id$
43   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45
46CONTAINS
47
48   SUBROUTINE p4z_lys( kt )
49      !!---------------------------------------------------------------------
50      !!                     ***  ROUTINE p4z_lys  ***
51      !!
52      !! ** Purpose :   CALCULATES DEGREE OF CACO3 SATURATION IN THE WATER
53      !!                COLUMN, DISSOLUTION/PRECIPITATION OF CACO3 AND LOSS
54      !!                OF CACO3 TO THE CACO3 SEDIMENT POOL.
55      !!
56      !! ** Method  : - ???
57      !!---------------------------------------------------------------------
58      INTEGER, INTENT(in) ::   kt ! ocean time step
59      INTEGER  ::   ji, jj, jk, jn
60      REAL(wp) ::   zbot, zalk, zdic, zph, zremco3, zah2
61      REAL(wp) ::   zdispot, zfact, zalka
62      REAL(wp) ::   zomegaca, zexcess, zexcess0
63      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zco3
64#if defined key_trc_dia3d && defined key_iomput
65      REAL(wp) ::   zrfact2
66      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zcaldiss, zw3d
67#endif
68      CHARACTER (len=25) :: charout
69      !!---------------------------------------------------------------------
70
71      IF( kt == nittrc000  )   CALL p4z_lys_init      ! Initialization (first time-step only)
72
73      zco3(:,:,:) = 0.
74
75# if defined key_trc_dia3d && defined key_iomput
76      zcaldiss(:,:,:) = 0.
77# endif
78      !     -------------------------------------------
79      !     COMPUTE [CO3--] and [H+] CONCENTRATIONS
80      !     -------------------------------------------
81     
82      DO jn = 1, 5                               !  BEGIN OF ITERATION
83         !
84!CDIR NOVERRCHK
85         DO jk = 1, jpkm1
86!CDIR NOVERRCHK
87            DO jj = 1, jpj
88!CDIR NOVERRCHK
89               DO ji = 1, jpi
90
91                  ! SET DUMMY VARIABLE FOR TOTAL BORATE
92                  zbot  = borat(ji,jj,jk)
93                  zfact = rhop (ji,jj,jk) / 1000. + rtrn
94
95                  ! SET DUMMY VARIABLE FOR [H+]
96                  zph   = hi(ji,jj,jk) * tmask(ji,jj,jk) / zfact + ( 1.-tmask(ji,jj,jk) ) * 1.e-9
97
98                  ! SET DUMMY VARIABLE FOR [SUM(CO2)]GIVEN
99                  zdic  = trn(ji,jj,jk,jpdic) / zfact
100                  zalka = trn(ji,jj,jk,jptal) / zfact
101
102                  ! CALCULATE [ALK]([CO3--], [HCO3-])
103                  zalk  = zalka - (  akw3(ji,jj,jk) / zph - zph   &
104                     &             + zbot / (1.+ zph / akb3(ji,jj,jk) )  )
105
106                  ! CALCULATE [H+] and [CO3--]
107                  zah2 = SQRT( (zdic-zalk)*(zdic-zalk)+   &
108                     &     4.*(zalk*ak23(ji,jj,jk)/ak13(ji,jj,jk))   &
109                     &     *(2*zdic-zalk))
110
111                  zah2=0.5*ak13(ji,jj,jk)/zalk*((zdic-zalk)+zah2)
112                  zco3(ji,jj,jk) = zalk/(2.+zah2/ak23(ji,jj,jk))*zfact
113
114                  hi(ji,jj,jk)  = zah2*zfact
115
116               END DO
117            END DO
118         END DO
119         !
120      END DO 
121
122      !     ---------------------------------------------------------
123      !        CALCULATE DEGREE OF CACO3 SATURATION AND CORRESPONDING
124      !        DISSOLOUTION AND PRECIPITATION OF CACO3 (BE AWARE OF
125      !        MGCO3)
126      !     ---------------------------------------------------------
127
128      DO jk = 1, jpkm1
129         DO jj = 1, jpj
130            DO ji = 1, jpi
131
132               ! DEVIATION OF [CO3--] FROM SATURATION VALUE
133               zomegaca = ( calcon * zco3(ji,jj,jk) ) / aksp(ji,jj,jk)
134
135               ! SET DEGREE OF UNDER-/SUPERSATURATION
136               zexcess0 = MAX( 0., ( 1.- zomegaca ) )
137               zexcess  = zexcess0**nca
138
139               ! AMOUNT CACO3 (12C) THAT RE-ENTERS SOLUTION
140               !       (ACCORDING TO THIS FORMULATION ALSO SOME PARTICULATE
141               !       CACO3 GETS DISSOLVED EVEN IN THE CASE OF OVERSATURATION)
142# if defined key_off_degrad
143              zdispot = kdca * zexcess * trn(ji,jj,jk,jpcal) * facvol(ji,jj,jk)
144# else
145              zdispot = kdca * zexcess * trn(ji,jj,jk,jpcal)
146# endif
147
148              !  CHANGE OF [CO3--] , [ALK], PARTICULATE [CACO3],
149              !       AND [SUM(CO2)] DUE TO CACO3 DISSOLUTION/PRECIPITATION
150              zremco3 = zdispot / rmoss
151              zco3(ji,jj,jk) = zco3(ji,jj,jk) + zremco3 * rfact
152              tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + 2. * zremco3
153              tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) -      zremco3
154              tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) +      zremco3
155
156# if defined key_trc_dia3d && defined key_iomput
157              zcaldiss(ji,jj,jk) = zremco3  ! calcite dissolution
158# endif
159            END DO
160         END DO
161      END DO
162
163# if defined key_trc_diaadd &&  defined key_trc_dia3d
164#  if ! defined key_iomput
165      trc3d(:,:,:,jp_pcs0_3d    ) = hi  (:,:,:)          * tmask(:,:,:)
166      trc3d(:,:,:,jp_pcs0_3d + 1) = zco3(:,:,:)          * tmask(:,:,:)
167      trc3d(:,:,:,jp_pcs0_3d + 2) = aksp(:,:,:) / calcon * tmask(:,:,:)
168#  else
169      zrfact2 = 1.e3 * rfact2r
170      zw3d(:,:,:) = hi  (:,:,:)                    * tmask(:,:,:)
171      CALL iom_put( "PH", zw3d )
172      zw3d(:,:,:) = zco3(:,:,:)                    * tmask(:,:,:)
173      CALL iom_put( "CO3", zw3d )
174      zw3d(:,:,:) = aksp(:,:,:) / calcon           * tmask(:,:,:)
175      CALL iom_put( "CO3sat", zw3d )
176      zw3d(:,:,:) = zcaldiss(:,:,:) * zrfact2 * tmask(:,:,:)
177      CALL iom_put( "Dcal", zw3d )
178#  endif
179# endif
180      !
181       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
182         WRITE(charout, FMT="('lys ')")
183         CALL prt_ctl_trc_info(charout)
184         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
185       ENDIF
186
187   END SUBROUTINE p4z_lys
188
189   SUBROUTINE p4z_lys_init
190
191      !!----------------------------------------------------------------------
192      !!                  ***  ROUTINE p4z_lys_init  ***
193      !!
194      !! ** Purpose :   Initialization of CaCO3 dissolution parameters
195      !!
196      !! ** Method  :   Read the nampiscal namelist and check the parameters
197      !!      called at the first timestep (nittrc000)
198      !!
199      !! ** input   :   Namelist nampiscal
200      !!
201      !!----------------------------------------------------------------------
202
203      NAMELIST/nampiscal/ kdca, nca
204
205      REWIND( numnat )                     ! read numnat
206      READ  ( numnat, nampiscal )
207
208      IF(lwp) THEN                         ! control print
209         WRITE(numout,*) ' '
210         WRITE(numout,*) ' Namelist parameters for CaCO3 dissolution, nampiscal'
211         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
212         WRITE(numout,*) '    diss. rate constant calcite (per month)   kdca      =', kdca
213         WRITE(numout,*) '    order of reaction for calcite dissolution nca       =', nca
214      ENDIF
215
216   END SUBROUTINE p4z_lys_init
217
218#else
219   !!======================================================================
220   !!  Dummy module :                                   No PISCES bio-model
221   !!======================================================================
222CONTAINS
223   SUBROUTINE p4z_lys( kt )                   ! Empty routine
224      INTEGER, INTENT( in ) ::   kt
225      WRITE(*,*) 'p4z_lys: You should not have seen this print! error?', kt
226   END SUBROUTINE p4z_lys
227#endif 
228
229   !!======================================================================
230END MODULE  p4zlys
Note: See TracBrowser for help on using the repository browser.