source: trunk/NEMO/TOP_SRC/PISCES/p4zmicro.F90 @ 935

Last change on this file since 935 was 935, checked in by cetlod, 13 years ago

adding modules for PISCES SMS model, see ticket 141

  • Property svn:executable set to *
File size: 11.9 KB
Line 
1MODULE p4zmicro
2   !!======================================================================
3   !!                         ***  MODULE p4zmicro  ***
4   !! TOP :   PISCES Compute the sources/sinks for microzooplankton
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!----------------------------------------------------------------------
9#if defined key_pisces
10   !!----------------------------------------------------------------------
11   !!   'key_pisces'                                       PISCES bio-model
12   !!----------------------------------------------------------------------
13   !!   p4z_micro       :   Compute the sources/sinks for microzooplankton
14   !!   p4z_micro_init  :   Initialize and read the appropriate namelist
15   !!----------------------------------------------------------------------
16   USE trc
17   USE oce_trc         !
18   USE trp_trc         !
19   USE sms             !
20   USE prtctl_trc
21   USE p4zint
22   USE p4zsink
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   p4z_micro    ! called in p4zbio.F90
28
29   !! * Shared module variables
30   REAL(wp), PUBLIC ::   &
31      xpref2c = 0.0_wp       ,  &  !:
32      xpref2p = 0.5_wp       ,  &  !:
33      xpref2d = 0.5_wp       ,  &  !:
34      resrat = 0.03_wp      ,  &  !:
35      mzrat = 0.0_wp        ,  &  !:
36      grazrat = 4.0_wp      ,  &  !:
37      xkgraz = 20E-6_wp     ,  &  !:
38      unass  = 0.3_wp       ,  &  !:
39      sigma1 = 0.6_wp       ,  &  !:
40      epsher = 0.33_wp
41
42
43   !!* Substitution
44#  include "domzgr_substitute.h90"
45   !!----------------------------------------------------------------------
46   !! NEMO/TOP 2.0 , LOCEAN-IPSL (2007)
47   !! $Header:$
48   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
49   !!----------------------------------------------------------------------
50
51CONTAINS
52
53   SUBROUTINE p4z_micro( kt,jnt )
54      !!---------------------------------------------------------------------
55      !!                     ***  ROUTINE p4z_micro  ***
56      !!
57      !! ** Purpose :   Compute the sources/sinks for microzooplankton
58      !!
59      !! ** Method  : - ???
60      !!---------------------------------------------------------------------
61      INTEGER, INTENT(in) ::   kt, jnt ! ocean time step
62      INTEGER  :: ji, jj, jk
63      REAL(wp) :: zcompadi, zcompadi2, zcompaz , zcompaph, zcompapoc
64      REAL(wp) :: zgraze  , zdenom  , zdenom2
65      REAL(wp) :: zfact   , zstep   , zinano , zidiat, zipoc
66      REAL(wp) :: zgrarem, zgrafer, zgrapoc, zprcaca, zmortz
67      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zrespz,ztortz
68      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zgrazp, zgrazm, zgrazsd
69      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zgrazmf, zgrazsf, zgrazpf
70      CHARACTER (len=25) :: charout
71
72      !!---------------------------------------------------------------------
73
74      IF( ( kt * jnt ) == nittrc000  )   CALL p4z_micro_init      ! Initialization (first time-step only)
75
76
77        zstep = rfact2 / rjjss      ! Time step duration for biology
78
79      DO jk = 1, jpkm1
80         DO jj = 1, jpj
81            DO ji = 1, jpi
82
83               zcompaz = MAX( ( trn(ji,jj,jk,jpzoo) - 1.e-9 ), 0.e0 )
84# if defined key_off_degrad
85               zfact   = zstep * tgfunc(ji,jj,jk) * zcompaz *facvol(ji,jj,jk)
86# else
87               zfact   = zstep * tgfunc(ji,jj,jk) * zcompaz
88# endif
89
90!     Respiration rates of both zooplankton
91!     -------------------------------------
92
93               zrespz(ji,jj,jk) = resrat * zfact  * ( 1.+ 3.* nitrfac(ji,jj,jk) )     &
94                  &            * trn(ji,jj,jk,jpzoo) / ( xkmort + trn(ji,jj,jk,jpzoo) )
95
96!     Zooplankton mortality. A square function has been selected with
97!     no real reason except that it seems to be more stable and may
98!     mimic predation.
99!     ---------------------------------------------------------------
100               ztortz(ji,jj,jk) = mzrat * 1.e6 * zfact * trn(ji,jj,jk,jpzoo)
101
102            END DO
103         END DO
104      END DO
105
106
107 
108      DO jk = 1,jpkm1
109         DO jj = 1,jpj
110            DO ji = 1,jpi
111               zcompadi  = MAX( ( trn(ji,jj,jk,jpdia) - 1.e-8 ), 0.e0 )
112               zcompadi2 = MIN( zcompadi, 5.e-7 )
113               zcompaph  = MAX( ( trn(ji,jj,jk,jpphy) - 2.e-7 ), 0.e0 )
114               zcompapoc = MAX( ( trn(ji,jj,jk,jppoc) - 1.e-8 ), 0.e0 )
115               
116               !     Microzooplankton grazing
117               !     ------------------------
118               zdenom2 = 1./ ( xpref2p * zcompaph + xpref2c * zcompapoc + xpref2d * zcompadi2 + rtrn )
119
120               zgraze = grazrat * zstep * tgfunc(ji,jj,jk)     &
121# if defined key_off_degrad
122                  &      * facvol(ji,jj,jk)         &
123# endif
124                  &      * trn(ji,jj,jk,jpzoo)
125
126               zinano = xpref2p * zcompaph  * zdenom2
127               zipoc  = xpref2c * zcompapoc * zdenom2
128               zidiat = xpref2d * zcompadi2 * zdenom2
129
130               zdenom = 1./ ( xkgraz + zinano * zcompaph + zipoc * zcompapoc + zidiat * zcompadi2 )
131
132               zgrazp(ji,jj,jk)  = zgraze * zinano * zcompaph * zdenom
133               zgrazm(ji,jj,jk)  = zgraze * zipoc  * zcompapoc * zdenom
134               zgrazsd(ji,jj,jk) = zgraze * zidiat * zcompadi2 * zdenom
135
136               zgrazpf (ji,jj,jk) = zgrazp(ji,jj,jk)  * trn(ji,jj,jk,jpnfe) / (trn(ji,jj,jk,jpphy) + rtrn)
137               zgrazmf(ji,jj,jk)  = zgrazm(ji,jj,jk)  * trn(ji,jj,jk,jpsfe) / (trn(ji,jj,jk,jppoc) + rtrn)
138               zgrazsf(ji,jj,jk)  = zgrazsd(ji,jj,jk) * trn(ji,jj,jk,jpdfe) / (trn(ji,jj,jk,jpdia) + rtrn)
139
140            END DO
141         END DO
142      END DO
143     
144
145      DO jk = 1,jpkm1
146         DO jj = 1,jpj
147            DO ji = 1,jpi
148!    Various remineralization and excretion terms
149!    --------------------------------------------
150
151               zgrarem = (  zgrazp(ji,jj,jk) + zgrazm(ji,jj,jk)  + zgrazsd(ji,jj,jk)  ) &
152                  &          * ( 1.- epsher - unass )
153               zgrafer = (  zgrazpf(ji,jj,jk) + zgrazsf(ji,jj,jk)  + zgrazmf(ji,jj,jk)  ) &
154                  &        * ( 1.- epsher - unass ) + epsher *  &
155                  &  ( zgrazm(ji,jj,jk)  * MAX((trn(ji,jj,jk,jpsfe) /(trn(ji,jj,jk,jppoc)+ rtrn)-ferat3),0.e0) &
156                  &   + zgrazp(ji,jj,jk)  * MAX((trn(ji,jj,jk,jpnfe)/(trn(ji,jj,jk,jpphy)+ rtrn)-ferat3),0.e0) &
157                  &   + zgrazsd(ji,jj,jk) * MAX((trn(ji,jj,jk,jpdfe)/(trn(ji,jj,jk,jpdia)+ rtrn)-ferat3),0.e0 )  )
158               zgrapoc = (  zgrazp(ji,jj,jk) + zgrazm(ji,jj,jk) + zgrazsd(ji,jj,jk)  ) * unass
159
160               !  Update of the TRA arrays
161               !  ------------------------
162
163               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarem * sigma1
164               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgrarem * sigma1
165               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgrarem * (1.-sigma1)
166               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarem * sigma1
167               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgrafer
168               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zgrapoc
169               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarem * sigma1
170#if defined key_kriest
171               tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) + zgrapoc * xkr_ddiat
172#endif
173            END DO
174         END DO
175      END DO
176
177!
178!   Update the arrays TRA which contain the biological sources and sinks
179!   --------------------------------------------------------------------
180
181      DO jk = 1, jpkm1
182         DO jj = 1, jpj
183            DO ji = 1, jpi
184
185               zmortz = ztortz(ji,jj,jk) + zrespz(ji,jj,jk)
186               tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) - zmortz  &
187                 &     + epsher * ( zgrazp(ji,jj,jk) + zgrazm(ji,jj,jk) + zgrazsd(ji,jj,jk))
188               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgrazp(ji,jj,jk)
189               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazsd(ji,jj,jk)
190               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgrazp(ji,jj,jk)  &
191                 &     * trn(ji,jj,jk,jpnch)/(trn(ji,jj,jk,jpphy)+rtrn)
192               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazsd(ji,jj,jk) &
193                 &     * trn(ji,jj,jk,jpdch)/(trn(ji,jj,jk,jpdia)+rtrn)
194               tra(ji,jj,jk,jpbsi) = tra(ji,jj,jk,jpbsi) - zgrazsd(ji,jj,jk) &
195                 &     * trn(ji,jj,jk,jpbsi)/(trn(ji,jj,jk,jpdia)+rtrn)
196               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) + zgrazsd(ji,jj,jk) &
197                 &     * trn(ji,jj,jk,jpbsi)/(trn(ji,jj,jk,jpdia)+rtrn)
198               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgrazpf(ji,jj,jk)
199               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazsf(ji,jj,jk)
200               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zmortz - zgrazm(ji,jj,jk)
201               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + ferat3 * zmortz   &
202                 &     + unass * ( zgrazpf(ji,jj,jk) + zgrazsf (ji,jj,jk)) &
203                 &     - (1.-unass) * zgrazmf(ji,jj,jk)
204               zprcaca = xfracal(ji,jj,jk) * part * unass * zgrazp(ji,jj,jk)
205               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprcaca
206               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal)- 2. * zprcaca
207               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca
208#if defined key_kriest
209               tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) + ( zmortz - zgrazm(ji,jj,jk) ) * xkr_ddiat
210#endif
211            END DO
212         END DO
213      END DO
214      !
215       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
216         WRITE(charout, FMT="('micro')")
217         CALL prt_ctl_trc_info(charout)
218         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
219       ENDIF
220
221   END SUBROUTINE p4z_micro
222
223
224   SUBROUTINE p4z_micro_init
225
226      !!----------------------------------------------------------------------
227      !!                  ***  ROUTINE p4z_micro_init  ***
228      !!
229      !! ** Purpose :   Initialization of microzooplankton parameters
230      !!
231      !! ** Method  :   Read the natzoo namelist and check the parameters
232      !!      called at the first timestep (nittrc000)
233      !!
234      !! ** input   :   Namelist natzoo
235      !!
236      !!----------------------------------------------------------------------
237
238      NAMELIST/natzoo/ grazrat,resrat,mzrat,xpref2c, xpref2p, &
239         &             xpref2d, xkgraz, epsher, sigma1, unass
240
241      REWIND( numnat )                     ! read numnat
242      READ  ( numnat, natzoo )
243
244      IF(lwp) THEN                         ! control print
245         WRITE(numout,*) ' '
246         WRITE(numout,*) ' Namelist parameters for microzooplankton, natzoo'
247         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
248         WRITE(numout,*) '    zoo preference for POC                    xpref2c    =', xpref2c
249         WRITE(numout,*) '    zoo preference for nano                   xpref2p    =', xpref2p
250         WRITE(numout,*) '    zoo preference for diatoms                xpref2d    =', xpref2d
251         WRITE(numout,*) '    exsudation rate of microzooplankton       resrat    =', resrat
252         WRITE(numout,*) '    microzooplankton mortality rate           mzrat     =', mzrat
253         WRITE(numout,*) '    maximal microzoo grazing rate             grazrat   =', grazrat
254         WRITE(numout,*) '    non assimilated fraction of P by microzoo unass     =', unass
255         WRITE(numout,*) '    Efficicency of microzoo growth            epsher    =', epsher
256         WRITE(numout,*) '    Fraction of microzoo excretion as DOM     sigma1    =', sigma1
257         WRITE(numout,*) '    half sturation constant for grazing 1     xkgraz    =', xkgraz
258      ENDIF
259
260   END SUBROUTINE p4z_micro_init
261
262#else
263   !!======================================================================
264   !!  Dummy module :                                   No PISCES bio-model
265   !!======================================================================
266CONTAINS
267   SUBROUTINE p4z_micro                    ! Empty routine
268   END SUBROUTINE p4z_micro
269#endif 
270
271   !!======================================================================
272END MODULE  p4zmicro
Note: See TracBrowser for help on using the repository browser.