New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcadv_tvd.F90 in trunk/NEMO/TOP_SRC/TRP – NEMO

source: trunk/NEMO/TOP_SRC/TRP/trcadv_tvd.F90 @ 1175

Last change on this file since 1175 was 1175, checked in by cetlod, 16 years ago

update transport modules to take into account new trends organization, see ticket:248
  • Property svn:executable set to *
  • Property svn:keywords set to Id
File size: 26.6 KB
Line 
1MODULE trcadv_tvd
2   !!======================================================================
3   !!                       ***  MODULE  trcadv_tvd  ***
4   !! Ocean passive tracers:  horizontal & vertical advective trend
5   !!======================================================================
6   !! History :       !  95-12  (L. Mortier)  Original code
7   !!                 !  00-01  (H. Loukos)  adapted to ORCA
8   !!                 !  00-10  (MA Foujols E.Kestenare)  include file not routine
9   !!                 !  00-12  (E. Kestenare M. Levy)  fix bug in trtrd indexes
10   !!                 !  01-07  (E. Durand G. Madec)  adaptation to ORCA config
11   !!            9.0  !  02-06  (C. Ethe, G. Madec)  F90: Free form and module
12   !!                 !  07-02  (C. Deltel) Diagnose ML trends for passive tracers
13   !!----------------------------------------------------------------------
14#if defined key_top
15   !!----------------------------------------------------------------------
16   !!   trc_adv_tvd  : update the passive tracer trend with the horizontal
17   !!                  and vertical advection trends using a TVD scheme
18   !!   nonosc       : compute monotonic tracer fluxes by a nonoscillatory
19   !!                  algorithm
20   !!----------------------------------------------------------------------
21   USE oce_trc             ! ocean dynamics and active tracers variables
22   USE trc                 ! ocean passive tracers variables
23   USE lbclnk              ! ocean lateral boundary conditions (or mpp link)
24   USE trcbbl              ! advective passive tracers in the BBL
25   USE prtctl_trc      ! Print control for debbuging
26   USE trdmld_trc
27   USE trdmld_trc_oce     
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC trc_adv_tvd    ! routine called by trcstp.F90
33
34   !! * Substitutions
35#  include "top_substitute.h90"
36   !!----------------------------------------------------------------------
37   !!   TOP 1.0 , LOCEAN-IPSL (2005)
38   !! $Header: /home/opalod/NEMOCVSROOT/NEMO/TOP_SRC/TRP/trcadv_tvd.F90,v 1.12 2006/04/10 15:38:54 opalod Exp $
39   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
40   !!----------------------------------------------------------------------
41
42CONTAINS
43
44   SUBROUTINE trc_adv_tvd( kt )
45      !!----------------------------------------------------------------------
46      !!                  ***  ROUTINE trc_adv_tvd  ***
47      !!
48      !! **  Purpose :   Compute the now trend due to total advection of
49      !!       tracers and add it to the general trend of tracer equations
50      !!
51      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
52      !!       corrected flux (monotonic correction)
53      !!       note: - this advection scheme needs a leap-frog time scheme
54      !!
55      !! ** Action : - update tra with the now advective tracer trends
56      !!             - save the trends ('key_trdmld_trc)
57      !!----------------------------------------------------------------------
58#if defined key_trcbbl_adv
59      USE oce_trc            , zun => ua,  &  ! use ua as workspace
60           &                   zvn => va      ! use va as workspace
61      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zwn
62#else
63      USE oce_trc            , zun => un,  &  ! When no bbl, zun == un
64           &                   zvn => vn,  &  !             zvn == vn
65           &                   zwn => wn      !             zwn == wn
66#endif
67      INTEGER, INTENT( in ) ::   kt                        ! ocean time-step
68      INTEGER  ::   ji, jj, jk, jn                         ! dummy loop indices
69      !!
70      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   ztu, ztv
71      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zti, ztw
72      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrtrd  ! trends
73      !!
74      REAL(wp) ::   z_hdivn_x, z_hdivn_y                   ! temporary scalars
75      REAL(wp) ::   z2dtt, zbtr, zeu, zev, zew, z2
76      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk
77      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk
78      REAL(wp) ::   zgm, zgz
79      CHARACTER (len=22) :: charout
80      !!----------------------------------------------------------------------
81
82      zti(:,:,:) = 0.e0
83
84      IF( kt == nittrc000  .AND. lwp ) THEN
85         WRITE(numout,*)
86         WRITE(numout,*) 'trc_adv_tvd : TVD advection scheme'
87         WRITE(numout,*) '~~~~~~~~~~~'
88      ENDIF
89
90      IF( l_trdtrc ) ALLOCATE( ztrtrd(jpi,jpj,jpk) )
91
92      IF( neuler == 0 .AND. kt == nittrc000 ) THEN
93         z2=1.
94      ELSE
95         z2=2.
96      ENDIF
97
98#if defined key_trcbbl_adv
99      ! Advective Bottom boundary layer: add the velocity
100      ! -------------------------------------------------
101      zun(:,:,:) = un (:,:,:) - u_trc_bbl(:,:,:)
102      zvn(:,:,:) = vn (:,:,:) - v_trc_bbl(:,:,:)
103      zwn(:,:,:) = wn (:,:,:) + w_trc_bbl(:,:,:)
104#endif
105
106      !                                                          ! ===========
107      DO jn = 1, jptra                                           ! tracer loop
108         !                                                       ! ===========
109
110         ! ============================================================
111         ! I.              Intermediate advective trends
112         ! ============================================================
113
114         ! 1. Bottom value : flux set to zero
115         ! ----------------------------------
116         ztu(:,:,jpk) = 0.e0    ;    ztv(:,:,jpk) = 0.e0
117         ztw(:,:,jpk) = 0.e0    ;    zti(:,:,jpk) = 0.e0
118
119
120         ! 2. Upstream advection with initial mass fluxes & intermediate update
121         ! --------------------------------------------------------------------
122
123         ! ... Upstream tracer flux in the i and j direction
124         DO jk = 1, jpkm1
125            DO jj = 1, jpjm1
126               DO ji = 1, fs_jpim1   ! vector opt.
127               !??? CD DO ji = fs_2, fs_jpim1    ! Vector opt.
128                  zeu = 0.5 * e2u(ji,jj) * fse3u(ji,jj,jk) * zun(ji,jj,jk)
129                  zev = 0.5 * e1v(ji,jj) * fse3v(ji,jj,jk) * zvn(ji,jj,jk)
130                  zfp_ui = zeu + ABS( zeu )   ! upstream scheme
131                  zfm_ui = zeu - ABS( zeu )
132                  zfp_vj = zev + ABS( zev )
133                  zfm_vj = zev - ABS( zev )
134                  ztu(ji,jj,jk) = zfp_ui * trb(ji,jj,jk,jn) + zfm_ui * trb(ji+1,jj  ,jk,jn)
135                  ztv(ji,jj,jk) = zfp_vj * trb(ji,jj,jk,jn) + zfm_vj * trb(ji  ,jj+1,jk,jn)
136               END DO
137            END DO
138         END DO
139
140         ! ... Upstream tracer flux in the k direction
141         ! Surface value
142         IF( lk_dynspg_rl ) THEN   ! rigid lid : flux set to zero
143            ztw(:,:,1) = 0.e0
144         ELSE                      ! free surface
145            DO jj = 1, jpj
146               DO ji = 1, jpi
147                  zew = e1t(ji,jj) * e2t(ji,jj) * zwn(ji,jj,1)
148                  ztw(ji,jj,1) = zew * trb(ji,jj,1,jn)
149               END DO
150            END DO
151         ENDIF
152
153         ! Interior value
154         DO jk = 2, jpkm1
155            DO jj = 1, jpj
156               DO ji = 1, jpi   ! CD ??? Vector opt.
157                  zew = 0.5 * e1t(ji,jj) * e2t(ji,jj) * zwn(ji,jj,jk)
158                  zfp_wk = zew + ABS( zew )
159                  zfm_wk = zew - ABS( zew )
160                  ztw(ji,jj,jk) = zfp_wk * trb(ji,jj,jk,jn) + zfm_wk * trb(ji,jj,jk-1,jn)
161               END DO
162            END DO
163         END DO
164
165         ! ... Total intermediate advective trend (flux divergence)
166         DO jk = 1, jpkm1
167            DO jj = 2, jpjm1
168               DO ji = fs_2, fs_jpim1   ! vector opt.
169                  zbtr = 1./ ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
170                  zti(ji,jj,jk) = - ( ztu(ji,jj,jk) - ztu(ji-1,jj  ,jk  )   &
171                     &              + ztv(ji,jj,jk) - ztv(ji  ,jj-1,jk  )   &
172                     &              + ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) * zbtr
173#if defined key_trc_diatrd
174                  IF ( luttrd(jn) ) &
175                     trtrd(ji,jj,jk,ikeep(jn),1) = trtrd(ji,jj,jk,ikeep(jn),1) -  &
176                        &                          zbtr * ( ztu(ji,jj,jk) - ztu(ji-1,jj,jk) )
177                  IF ( luttrd(jn) ) &
178                     trtrd(ji,jj,jk,ikeep(jn),2) = trtrd(ji,jj,jk,ikeep(jn),2) -  &
179                        &                          zbtr * ( ztv(ji,jj,jk) - ztv(ji,jj-1,jk) )
180                  IF ( luttrd(jn) ) &
181                     trtrd(ji,jj,jk,ikeep(jn),3) = trtrd(ji,jj,jk,ikeep(jn),3) -  &
182                        &                          zbtr * ( ztw(ji,jj,jk) - ztw(ji,jj,jk+1) )
183#endif
184               END DO
185            END DO
186         END DO
187         
188         ! 3. Save the intermediate i / j / k advective trends for diagnostics
189         ! -------------------------------------------------------------------
190
191!CDIR BEGIN COLLAPSE
192         IF( l_trdtrc ) THEN
193
194            ! 3.1) Passive tracer ZONAL advection trends
195            ztrtrd(:,:,:) = 0.e0
196
197            DO jk = 1, jpkm1
198               DO jj = 2, jpjm1
199                  DO ji = fs_2, fs_jpim1   ! vector opt.
200
201                     !-- Compute zonal divergence by splitting hdivn (see divcur.F90)
202                     !   N.B. This computation is not valid along OBCs (if any)
203                     zbtr = 1./ ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
204                     z_hdivn_x = (  e2u(ji  ,jj) * fse3u(ji  ,jj,jk) * un(ji  ,jj,jk)          &
205                          &       - e2u(ji-1,jj) * fse3u(ji-1,jj,jk) * un(ji-1,jj,jk) ) * zbtr
206
207                     !-- Compute zonal advection trends
208                     ztrtrd(ji,jj,jk) = - ( ztu(ji,jj,jk) - ztu(ji-1,jj,jk) ) * zbtr &
209                          &             + trb(ji,jj,jk,jn) * z_hdivn_x
210                  END DO
211               END DO
212            END DO
213
214            IF (luttrd(jn)) CALL trd_mod_trc(ztrtrd, jn, jptrc_trd_xad, kt)    ! save the trends
215
216            ! 3.2) Passive tracer MERIDIONAL advection trends
217            ztrtrd(:,:,:) = 0.e0
218 
219            DO jk = 1, jpkm1
220               DO jj = 2, jpjm1
221                  DO ji = fs_2, fs_jpim1   ! vector opt.
222
223                     !-- Compute merid. divergence by splitting hdivn (see divcur.F90)
224                     !   N.B. This computation is not valid along OBCs (if any)
225                     zbtr      = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
226                     z_hdivn_y = (  e1v(ji,  jj) * fse3v(ji,jj  ,jk) * vn(ji,jj  ,jk)          &
227                          &       - e1v(ji,jj-1) * fse3v(ji,jj-1,jk) * vn(ji,jj-1,jk) ) * zbtr
228
229                     !-- Compute merid. advection trends
230                     ztrtrd(ji,jj,jk) = - ( ztv(ji,jj,jk) - ztv(ji,jj-1,jk) ) * zbtr &
231                          &             + trb(ji,jj,jk,jn) * z_hdivn_y
232                  END DO
233               END DO
234            END DO
235
236            IF (luttrd(jn)) CALL trd_mod_trc(ztrtrd, jn, jptrc_trd_yad, kt)     ! save the trends
237
238            ! 3.3) Passive tracer VERTICAL advection trends
239            ztrtrd(:,:,:) = 0.e0
240            DO jk = 1, jpkm1
241               DO jj = 2, jpjm1
242                  DO ji = fs_2, fs_jpim1   ! Vector opt.
243                     zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
244                     ztrtrd(ji,jj,jk) = - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) * zbtr   &
245                          &             - trb(ji,jj,jk,jn) * hdivn(ji,jj,jk)
246                  END DO
247               END DO
248            END DO
249
250            IF (luttrd(jn)) CALL trd_mod_trc(ztrtrd, jn, jptrc_trd_zad, kt)     ! save the trends
251
252         ENDIF
253!CDIR END
254
255         ! 4. Update and guess with monotonic sheme
256         ! ----------------------------------------
257         DO jk = 1, jpkm1
258            z2dtt = z2 * rdttra(jk) * FLOAT(ndttrc)
259            DO jj = 2, jpjm1
260               DO ji = fs_2, fs_jpim1   ! vector opt.
261                  tra(ji,jj,jk,jn) =  tra(ji,jj,jk,jn) + zti(ji,jj,jk)
262                  zti (ji,jj,jk) = ( trb(ji,jj,jk,jn) + z2dtt * zti(ji,jj,jk) ) * tmask(ji,jj,jk)
263               END DO
264            END DO
265         END DO
266
267         ! 5. Lateral boundary conditions on zti, zsi (unchanged sign)
268         ! -----------------------------------------------------------
269         CALL lbc_lnk( zti, 'T', 1. )
270
271
272         ! ============================================================
273         ! II.              Corrected advective trends
274         ! ============================================================
275
276         ! 1. Antidiffusive flux : high order minus low order
277         ! --------------------------------------------------
278         ! Antidiffusive flux on i and j
279         DO jk = 1, jpkm1
280            DO jj = 1, jpjm1
281               DO ji = 1, fs_jpim1   ! vector opt.
282                  zeu = 0.5 * e2u(ji,jj) * fse3u(ji,jj,jk) * zun(ji,jj,jk)
283                  zev = 0.5 * e1v(ji,jj) * fse3v(ji,jj,jk) * zvn(ji,jj,jk)
284                  ztu(ji,jj,jk) = zeu * ( trn(ji,jj,jk,jn) + trn(ji+1,jj,jk,jn) ) - ztu(ji,jj,jk)
285                  ztv(ji,jj,jk) = zev * ( trn(ji,jj,jk,jn) + trn(ji,jj+1,jk,jn) ) - ztv(ji,jj,jk)
286               END DO
287            END DO
288         END DO
289
290         ! Antidiffusive flux on k
291         ztw(:,:,1) = 0.e0    ! surface value
292         DO jk = 2, jpkm1     ! interior value
293            DO jj = 1, jpj
294               DO ji = 1, jpi
295                  zew = 0.5 * e1t(ji,jj) * e2t(ji,jj) * zwn(ji,jj,jk)
296                  ztw(ji,jj,jk) = zew * ( trn(ji,jj,jk,jn) + trn(ji,jj,jk-1,jn) ) - ztw(ji,jj,jk)
297               END DO
298            END DO
299         END DO
300
301         ! Lateral bondary conditions
302         CALL lbc_lnk( ztu, 'U', -1. )
303         CALL lbc_lnk( ztv, 'V', -1. )
304         CALL lbc_lnk( ztw, 'W',  1. )
305
306         ! 2. Monotonicity algorithm
307         ! -------------------------
308         CALL nonosc( trb(:,:,:,jn), ztu, ztv, ztw, zti, z2 )
309
310
311         ! 3. Final trend with corrected fluxes
312         ! ------------------------------------
313         DO jk = 1, jpkm1
314            DO jj = 2, jpjm1
315               DO ji = fs_2, fs_jpim1   ! vector opt.
316                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
317                  tra(ji,jj,jk,jn) = tra(ji,jj,jk,jn)   &
318                     &         - ( ztu(ji,jj,jk) - ztu(ji-1,jj  ,jk  )   &
319                     &           + ztv(ji,jj,jk) - ztv(ji  ,jj-1,jk  )   &
320                     &           + ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) * zbtr
321#if defined key_trc_diatrd
322                  IF ( luttrd(jn) ) &
323                     trtrd(ji,jj,jk,ikeep(jn),1) = trtrd(ji,jj,jk,ikeep(jn),1) -  &
324                        &                          zbtr * ( ztu(ji,jj,jk) - ztu(ji-1,jj,jk) )
325                  IF ( luttrd(jn) ) &
326                     trtrd(ji,jj,jk,ikeep(jn),2) = trtrd(ji,jj,jk,ikeep(jn),2) -  &
327                        &                          zbtr * ( ztv(ji,jj,jk) - ztv(ji,jj-1,jk) )
328                  IF ( luttrd(jn) ) &
329                     trtrd(ji,jj,jk,ikeep(jn),3) = trtrd(ji,jj,jk,ikeep(jn),3) -  &
330                        &                          zbtr * ( ztw(ji,jj,jk) - ztw(ji,jj,jk+1) )
331#endif
332
333               END DO
334            END DO
335         END DO
336
337#if defined key_trc_diatrd
338         DO jk = 1,jpk
339            DO jj = 2,jpjm1
340               DO  ji = 2,jpim1
341                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
342                  zgm = zbtr * trn(ji,jj,jk,jn) *     &
343                     &         (  zun(ji  ,jj,jk) * e2u(ji  ,jj) * fse3u(ji  ,jj,jk)    &
344                     &          - zun(ji-1,jj,jk) * e2u(ji-1,jj) * fse3u(ji-1,jj,jk) )
345
346                  zgz = zbtr * trn(ji,jj,jk,jn) *     &
347                     &         (  zvn(ji,jj  ,jk) * e1v(ji,jj  ) * fse3v(ji,jj  ,jk)    &
348                     &          - zvn(ji,jj-1,jk) * e1v(ji,jj-1) * fse3v(ji,jj-1,jk) )
349
350                  IF (luttrd(jn)) trtrd(ji,jj,jk,ikeep(jn),1) = trtrd(ji,jj,jk,ikeep(jn),1) + zgm
351                  IF (luttrd(jn)) trtrd(ji,jj,jk,ikeep(jn),2) = trtrd(ji,jj,jk,ikeep(jn),2) + zgz
352                  IF (luttrd(jn)) trtrd(ji,jj,jk,ikeep(jn),3) = trtrd(ji,jj,jk,ikeep(jn),3)    &
353                     &            - trn(ji,jj,jk,jn) * hdivn(ji,jj,jk)
354               END DO
355            END DO
356         END DO
357
358         ! Lateral boundary conditions on trtrd:
359
360         IF (luttrd(jn)) CALL lbc_lnk( trtrd(:,:,:,ikeep(jn),1), 'T', 1. )
361         IF (luttrd(jn)) CALL lbc_lnk( trtrd(:,:,:,ikeep(jn),2), 'T', 1. )
362         IF (luttrd(jn)) CALL lbc_lnk( trtrd(:,:,:,ikeep(jn),3), 'T', 1. )
363#endif
364
365         ! 4. Save the advective trends for diagnostics
366         ! --------------------------------------------
367         ! Warning : mass fluxes should probably be converted into advection
368         ! terms in the computations below ???
369
370!CDIR BEGIN COLLAPSE
371         IF( l_trdtrc ) THEN
372           
373            ! 4.1) Passive tracer ZONAL advection trends
374            ztrtrd(:,:,:) = 0.e0
375            DO jk = 1, jpkm1
376               DO jj = 2, jpjm1
377                  DO ji = fs_2, fs_jpim1   ! vector opt.
378                     zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
379                     ztrtrd(ji,jj,jk) = - ( ztu(ji,jj,jk) - ztu(ji-1,jj,jk) ) * zbtr
380                  END DO
381               END DO
382            END DO
383           
384            IF (luttrd(jn)) CALL trd_mod_trc(ztrtrd, jn, jptrc_trd_xad, kt)   ! <<< ADD TO PREVIOUSLY COMPUTED
385
386            ! 4.2) Passive tracer MERIDIONAL advection trends
387            ztrtrd(:,:,:) = 0.e0
388            DO jk = 1, jpkm1
389               DO jj = 2, jpjm1
390                  DO ji = fs_2, fs_jpim1   ! vector opt.
391                     zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
392                     ztrtrd(ji,jj,jk) = - ( ztv(ji,jj,jk) - ztv(ji,jj-1,jk) ) * zbtr 
393                  END DO
394               END DO
395            END DO
396           
397            IF (luttrd(jn)) CALL trd_mod_trc(ztrtrd, jn, jptrc_trd_yad, kt)   ! <<< ADD TO PREVIOUSLY COMPUTED
398           
399            ! 4.3) Passive tracer VERTICAL advection trends
400            ztrtrd(:,:,:) = 0.e0
401            DO jk = 1, jpkm1
402               DO jj = 2, jpjm1
403                  DO ji = fs_2, fs_jpim1   ! vector opt.
404                     zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
405                     ztrtrd(ji,jj,jk) = - ( ztw(ji,jj,jk) - ztw(ji,jj,jk+1) ) * zbtr
406                  END DO
407               END DO
408            END DO
409           
410            IF (luttrd(jn)) CALL trd_mod_trc(ztrtrd, jn, jptrc_trd_zad, kt)   ! <<< ADD TO PREVIOUSLY COMPUTED
411           
412         ENDIF
413!CDIR END
414
415
416      END DO
417
418      IF( l_trdtrc ) DEALLOCATE( ztrtrd )
419
420      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
421         WRITE(charout, FMT="('tvd - adv')")
422         CALL prt_ctl_trc_info(charout)
423         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
424      ENDIF
425
426   END SUBROUTINE trc_adv_tvd
427
428
429   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, prdt )
430      !!---------------------------------------------------------------------
431      !!                    ***  ROUTINE nonosc  ***
432      !!     
433      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
434      !!       scheme and the before field by a nonoscillatory algorithm
435      !!
436      !! **  Method  :   ... ???
437      !!       warning : pbef and paft must be masked, but the boundaries
438      !!       conditions on the fluxes are not necessary zalezak (1979)
439      !!       drange (1995) multi-dimensional forward-in-time and upstream-
440      !!       in-space based differencing for fluid
441      !!
442      !! History :
443      !!        !  97-04  (L. Mortier) Original code
444      !!        !  00-02  (H. Loukos)  rewritting for opa8
445      !!        !  00-10  (M.A Foujols, E. Kestenare)  lateral b.c.
446      !!        !  01-03  (E. Kestenare)  add key_passivetrc
447      !!        !  01-07  (E. Durand G. Madec)  adapted for T & S
448      !!   8.5  !  02-06  (G. Madec)  F90: Free form and module
449      !!----------------------------------------------------------------------
450      !! * Arguments
451      REAL(wp), INTENT( in ) ::   &
452         prdt                               ! ???
453      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT( inout ) ::   &
454         pbef,                            & ! before field
455         paft,                            & ! after field
456         paa,                             & ! monotonic flux in the i direction
457         pbb,                             & ! monotonic flux in the j direction
458         pcc                                ! monotonic flux in the k direction
459
460      !! * Local declarations
461      INTEGER ::   ji, jj, jk               ! dummy loop indices
462      INTEGER ::   ikm1
463      REAL(wp), DIMENSION (jpi,jpj,jpk) ::   zbetup, zbetdo
464      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt
465      !!----------------------------------------------------------------------
466
467      zbig = 1.e+40
468      zrtrn = 1.e-15
469      zbetup(:,:,:) = 0.e0   ;   zbetdo(:,:,:) = 0.e0
470
471      ! Search local extrema
472      ! --------------------
473      ! large negative value (-zbig) inside land
474      ! large negative value (-zbig) inside land
475      pbef(:,:,:) = pbef(:,:,:) * tmask(:,:,:) - zbig * ( 1.e0 - tmask(:,:,:) )
476      paft(:,:,:) = paft(:,:,:) * tmask(:,:,:) - zbig * ( 1.e0 - tmask(:,:,:) )
477      ! search maximum in neighbourhood
478      DO jk = 1, jpkm1
479         ikm1 = MAX(jk-1,1)
480         DO jj = 2, jpjm1
481            DO ji = fs_2, fs_jpim1   ! vector opt.
482               zbetup(ji,jj,jk) = MAX(  pbef(ji  ,jj  ,jk  ), paft(ji  ,jj  ,jk  ),   &
483                  &                     pbef(ji-1,jj  ,jk  ), pbef(ji+1,jj  ,jk  ),   &
484                  &                     paft(ji-1,jj  ,jk  ), paft(ji+1,jj  ,jk  ),   &
485                  &                     pbef(ji  ,jj-1,jk  ), pbef(ji  ,jj+1,jk  ),   &
486                  &                     paft(ji  ,jj-1,jk  ), paft(ji  ,jj+1,jk  ),   &
487                  &                     pbef(ji  ,jj  ,ikm1), pbef(ji  ,jj  ,jk+1),   &
488                  &                     paft(ji  ,jj  ,ikm1), paft(ji  ,jj  ,jk+1)  )
489            END DO
490         END DO
491      END DO
492      ! large positive value (+zbig) inside land
493      pbef(:,:,:) = pbef(:,:,:) * tmask(:,:,:) + zbig * ( 1.e0 - tmask(:,:,:) )
494      paft(:,:,:) = paft(:,:,:) * tmask(:,:,:) + zbig * ( 1.e0 - tmask(:,:,:) )
495      ! search minimum in neighbourhood
496      DO jk = 1, jpkm1
497         ikm1 = MAX(jk-1,1)
498         DO jj = 2, jpjm1
499            DO ji = fs_2, fs_jpim1   ! vector opt.
500               zbetdo(ji,jj,jk) = MIN(  pbef(ji  ,jj  ,jk  ), paft(ji  ,jj  ,jk  ),   &
501                  &                     pbef(ji-1,jj  ,jk  ), pbef(ji+1,jj  ,jk  ),   &
502                  &                     paft(ji-1,jj  ,jk  ), paft(ji+1,jj  ,jk  ),   &
503                  &                     pbef(ji  ,jj-1,jk  ), pbef(ji  ,jj+1,jk  ),   &
504                  &                     paft(ji  ,jj-1,jk  ), paft(ji  ,jj+1,jk  ),   &
505                  &                     pbef(ji  ,jj  ,ikm1), pbef(ji  ,jj  ,jk+1),   &
506                  &                     paft(ji  ,jj  ,ikm1), paft(ji  ,jj  ,jk+1)  )
507            END DO
508         END DO
509      END DO
510
511      ! restore masked values to zero
512      pbef(:,:,:) = pbef(:,:,:) * tmask(:,:,:)
513      paft(:,:,:) = paft(:,:,:) * tmask(:,:,:)
514 
515
516      ! 2. Positive and negative part of fluxes and beta terms
517      ! ------------------------------------------------------
518
519      DO jk = 1, jpkm1
520         z2dtt = prdt * rdttra(jk) * FLOAT(ndttrc)
521         DO jj = 2, jpjm1
522            DO ji = fs_2, fs_jpim1   ! vector opt.
523               ! positive & negative part of the flux
524               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
525                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
526                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
527               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
528                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
529                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
530               ! up & down beta terms
531               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) / z2dtt
532               zbetup(ji,jj,jk) = ( zbetup(ji,jj,jk) - paft(ji,jj,jk) ) / (zpos+zrtrn) * zbt
533               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zbetdo(ji,jj,jk) ) / (zneg+zrtrn) * zbt
534            END DO
535         END DO
536      END DO
537
538      ! lateral boundary condition on zbetup & zbetdo   (unchanged sign)
539      CALL lbc_lnk( zbetup, 'T', 1. )
540      CALL lbc_lnk( zbetdo, 'T', 1. )
541
542
543      ! 3. monotonic flux in the i direction, i.e. paa
544      ! ----------------------------------------------
545      DO jk = 1, jpkm1
546         DO jj = 2, jpjm1
547            DO ji = fs_2, fs_jpim1   ! vector opt.
548               zc = paa(ji,jj,jk)
549               IF( zc >= 0. ) THEN
550                  za = MIN( 1., zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
551                  paa(ji,jj,jk) = za * zc
552               ELSE
553                  zb = MIN( 1., zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
554                  paa(ji,jj,jk) = zb * zc
555               ENDIF
556            END DO
557         END DO
558      END DO
559
560      ! lateral boundary condition on paa   (changed sign)
561      CALL lbc_lnk( paa, 'U', -1. )
562
563
564      ! 4. monotonic flux in the j direction, i.e. pbb
565      ! ----------------------------------------------
566      DO jk = 1, jpkm1
567         DO jj = 2, jpjm1
568            DO ji = fs_2, fs_jpim1   ! vector opt.
569               zc = pbb(ji,jj,jk)
570               IF( zc >= 0. ) THEN
571                  za = MIN( 1., zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
572                  pbb(ji,jj,jk) = za * zc
573               ELSE
574                  zb = MIN( 1., zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
575                  pbb(ji,jj,jk) = zb * zc
576               ENDIF
577            END DO
578         END DO
579      END DO
580
581      ! lateral boundary condition on pbb   (changed sign)
582      CALL lbc_lnk( pbb, 'V', -1. )
583
584
585      ! monotonic flux in the k direction, i.e. pcc
586      ! -------------------------------------------
587      DO jk = 2, jpkm1
588         DO jj = 2, jpjm1
589            DO ji = fs_2, fs_jpim1   ! vector opt.
590               zc = pcc(ji,jj,jk)
591               IF( zc >= 0. ) THEN
592                  za = MIN( 1., zbetdo(ji,jj,jk), zbetup(ji,jj,jk-1) )
593                  pcc(ji,jj,jk) = za * zc
594               ELSE
595                  zb = MIN( 1., zbetup(ji,jj,jk), zbetdo(ji,jj,jk-1) )
596                  pcc(ji,jj,jk) = zb * zc
597               ENDIF
598            END DO
599         END DO
600      END DO
601
602      ! lateral boundary condition on pcc   (unchanged sign)
603      CALL lbc_lnk( pcc, 'W', 1. )
604
605   END SUBROUTINE nonosc
606
607#else
608   !!----------------------------------------------------------------------
609   !!   Default option                                         Empty module
610   !!----------------------------------------------------------------------
611CONTAINS
612   SUBROUTINE trc_adv_tvd( kt ) 
613      INTEGER, INTENT(in) :: kt
614      WRITE(*,*) 'trc_adv_tvd: You should not have seen this print! error?', kt
615   END SUBROUTINE trc_adv_tvd
616#endif
617
618   !!======================================================================
619END MODULE trcadv_tvd
Note: See TracBrowser for help on using the repository browser.