New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcadv_tvd.F90 in trunk/NEMO/TOP_SRC/TRP – NEMO

source: trunk/NEMO/TOP_SRC/TRP/trcadv_tvd.F90 @ 1189

Last change on this file since 1189 was 1189, checked in by cetlod, 16 years ago

update transport modules to take into account new trends organization, see ticket:248
  • Property svn:executable set to *
  • Property svn:keywords set to Id
File size: 26.6 KB
Line 
1MODULE trcadv_tvd
2   !!======================================================================
3   !!                       ***  MODULE  trcadv_tvd  ***
4   !! Ocean passive tracers:  horizontal & vertical advective trend
5   !!======================================================================
6   !! History :       !  95-12  (L. Mortier)  Original code
7   !!                 !  00-01  (H. Loukos)  adapted to ORCA
8   !!                 !  00-10  (MA Foujols E.Kestenare)  include file not routine
9   !!                 !  00-12  (E. Kestenare M. Levy)  fix bug in trtrd indexes
10   !!                 !  01-07  (E. Durand G. Madec)  adaptation to ORCA config
11   !!            9.0  !  02-06  (C. Ethe, G. Madec)  F90: Free form and module
12   !!                 !  07-02  (C. Deltel) Diagnose ML trends for passive tracers
13   !!----------------------------------------------------------------------
14#if defined key_top
15   !!----------------------------------------------------------------------
16   !!   trc_adv_tvd  : update the passive tracer trend with the horizontal
17   !!                  and vertical advection trends using a TVD scheme
18   !!   nonosc       : compute monotonic tracer fluxes by a nonoscillatory
19   !!                  algorithm
20   !!----------------------------------------------------------------------
21   USE oce_trc             ! ocean dynamics and active tracers variables
22   USE trc                 ! ocean passive tracers variables
23   USE trp_trc
24   USE lbclnk              ! ocean lateral boundary conditions (or mpp link)
25   USE trcbbl              ! advective passive tracers in the BBL
26   USE prtctl_trc      ! Print control for debbuging
27   USE trdmld_trc
28   USE trdmld_trc_oce     
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC trc_adv_tvd    ! routine called by trcstp.F90
34
35   !! * Substitutions
36#  include "top_substitute.h90"
37   !!----------------------------------------------------------------------
38   !!   TOP 1.0 , LOCEAN-IPSL (2005)
39   !! $Header: /home/opalod/NEMOCVSROOT/NEMO/TOP_SRC/TRP/trcadv_tvd.F90,v 1.12 2006/04/10 15:38:54 opalod Exp $
40   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
41   !!----------------------------------------------------------------------
42
43CONTAINS
44
45   SUBROUTINE trc_adv_tvd( kt )
46      !!----------------------------------------------------------------------
47      !!                  ***  ROUTINE trc_adv_tvd  ***
48      !!
49      !! **  Purpose :   Compute the now trend due to total advection of
50      !!       tracers and add it to the general trend of tracer equations
51      !!
52      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
53      !!       corrected flux (monotonic correction)
54      !!       note: - this advection scheme needs a leap-frog time scheme
55      !!
56      !! ** Action : - update tra with the now advective tracer trends
57      !!             - save the trends ('key_trdmld_trc)
58      !!----------------------------------------------------------------------
59#if defined key_trcbbl_adv
60      USE oce_trc            , zun => ua,  &  ! use ua as workspace
61           &                   zvn => va      ! use va as workspace
62      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zwn
63#else
64      USE oce_trc            , zun => un,  &  ! When no bbl, zun == un
65           &                   zvn => vn,  &  !             zvn == vn
66           &                   zwn => wn      !             zwn == wn
67#endif
68      INTEGER, INTENT( in ) ::   kt                        ! ocean time-step
69      INTEGER  ::   ji, jj, jk, jn                         ! dummy loop indices
70      !!
71      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   ztu, ztv
72      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zti, ztw
73      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrtrd  ! trends
74      !!
75      REAL(wp) ::   z_hdivn_x, z_hdivn_y                   ! temporary scalars
76      REAL(wp) ::   z2dtt, zbtr, zeu, zev, zew, z2
77      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk
78      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk
79      REAL(wp) ::   zgm, zgz
80      CHARACTER (len=22) :: charout
81      !!----------------------------------------------------------------------
82
83      zti(:,:,:) = 0.e0
84
85      IF( kt == nittrc000  .AND. lwp ) THEN
86         WRITE(numout,*)
87         WRITE(numout,*) 'trc_adv_tvd : TVD advection scheme'
88         WRITE(numout,*) '~~~~~~~~~~~'
89      ENDIF
90
91      IF( l_trdtrc ) ALLOCATE( ztrtrd(jpi,jpj,jpk) )
92
93      IF( neuler == 0 .AND. kt == nittrc000 ) THEN
94         z2=1.
95      ELSE
96         z2=2.
97      ENDIF
98
99#if defined key_trcbbl_adv
100      ! Advective Bottom boundary layer: add the velocity
101      ! -------------------------------------------------
102      zun(:,:,:) = un (:,:,:) - u_trc_bbl(:,:,:)
103      zvn(:,:,:) = vn (:,:,:) - v_trc_bbl(:,:,:)
104      zwn(:,:,:) = wn (:,:,:) + w_trc_bbl(:,:,:)
105#endif
106
107      !                                                          ! ===========
108      DO jn = 1, jptra                                           ! tracer loop
109         !                                                       ! ===========
110
111         ! ============================================================
112         ! I.              Intermediate advective trends
113         ! ============================================================
114
115         ! 1. Bottom value : flux set to zero
116         ! ----------------------------------
117         ztu(:,:,jpk) = 0.e0    ;    ztv(:,:,jpk) = 0.e0
118         ztw(:,:,jpk) = 0.e0    ;    zti(:,:,jpk) = 0.e0
119
120
121         ! 2. Upstream advection with initial mass fluxes & intermediate update
122         ! --------------------------------------------------------------------
123
124         ! ... Upstream tracer flux in the i and j direction
125         DO jk = 1, jpkm1
126            DO jj = 1, jpjm1
127               DO ji = 1, fs_jpim1   ! vector opt.
128               !??? CD DO ji = fs_2, fs_jpim1    ! Vector opt.
129                  zeu = 0.5 * e2u(ji,jj) * fse3u(ji,jj,jk) * zun(ji,jj,jk)
130                  zev = 0.5 * e1v(ji,jj) * fse3v(ji,jj,jk) * zvn(ji,jj,jk)
131                  zfp_ui = zeu + ABS( zeu )   ! upstream scheme
132                  zfm_ui = zeu - ABS( zeu )
133                  zfp_vj = zev + ABS( zev )
134                  zfm_vj = zev - ABS( zev )
135                  ztu(ji,jj,jk) = zfp_ui * trb(ji,jj,jk,jn) + zfm_ui * trb(ji+1,jj  ,jk,jn)
136                  ztv(ji,jj,jk) = zfp_vj * trb(ji,jj,jk,jn) + zfm_vj * trb(ji  ,jj+1,jk,jn)
137               END DO
138            END DO
139         END DO
140
141         ! ... Upstream tracer flux in the k direction
142         ! Surface value
143         IF( lk_dynspg_rl ) THEN   ! rigid lid : flux set to zero
144            ztw(:,:,1) = 0.e0
145         ELSE                      ! free surface
146            DO jj = 1, jpj
147               DO ji = 1, jpi
148                  zew = e1t(ji,jj) * e2t(ji,jj) * zwn(ji,jj,1)
149                  ztw(ji,jj,1) = zew * trb(ji,jj,1,jn)
150               END DO
151            END DO
152         ENDIF
153
154         ! Interior value
155         DO jk = 2, jpkm1
156            DO jj = 1, jpj
157               DO ji = 1, jpi   ! CD ??? Vector opt.
158                  zew = 0.5 * e1t(ji,jj) * e2t(ji,jj) * zwn(ji,jj,jk)
159                  zfp_wk = zew + ABS( zew )
160                  zfm_wk = zew - ABS( zew )
161                  ztw(ji,jj,jk) = zfp_wk * trb(ji,jj,jk,jn) + zfm_wk * trb(ji,jj,jk-1,jn)
162               END DO
163            END DO
164         END DO
165
166         ! ... Total intermediate advective trend (flux divergence)
167         DO jk = 1, jpkm1
168            DO jj = 2, jpjm1
169               DO ji = fs_2, fs_jpim1   ! vector opt.
170                  zbtr = 1./ ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
171                  zti(ji,jj,jk) = - ( ztu(ji,jj,jk) - ztu(ji-1,jj  ,jk  )   &
172                     &              + ztv(ji,jj,jk) - ztv(ji  ,jj-1,jk  )   &
173                     &              + ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) * zbtr
174#if defined key_trc_diatrd
175                  IF ( luttrd(jn) ) &
176                     trtrd(ji,jj,jk,ikeep(jn),1) = trtrd(ji,jj,jk,ikeep(jn),1) -  &
177                        &                          zbtr * ( ztu(ji,jj,jk) - ztu(ji-1,jj,jk) )
178                  IF ( luttrd(jn) ) &
179                     trtrd(ji,jj,jk,ikeep(jn),2) = trtrd(ji,jj,jk,ikeep(jn),2) -  &
180                        &                          zbtr * ( ztv(ji,jj,jk) - ztv(ji,jj-1,jk) )
181                  IF ( luttrd(jn) ) &
182                     trtrd(ji,jj,jk,ikeep(jn),3) = trtrd(ji,jj,jk,ikeep(jn),3) -  &
183                        &                          zbtr * ( ztw(ji,jj,jk) - ztw(ji,jj,jk+1) )
184#endif
185               END DO
186            END DO
187         END DO
188         
189         ! 3. Save the intermediate i / j / k advective trends for diagnostics
190         ! -------------------------------------------------------------------
191
192!CDIR BEGIN COLLAPSE
193         IF( l_trdtrc ) THEN
194
195            ! 3.1) Passive tracer ZONAL advection trends
196            ztrtrd(:,:,:) = 0.e0
197
198            DO jk = 1, jpkm1
199               DO jj = 2, jpjm1
200                  DO ji = fs_2, fs_jpim1   ! vector opt.
201
202                     !-- Compute zonal divergence by splitting hdivn (see divcur.F90)
203                     !   N.B. This computation is not valid along OBCs (if any)
204                     zbtr = 1./ ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
205                     z_hdivn_x = (  e2u(ji  ,jj) * fse3u(ji  ,jj,jk) * un(ji  ,jj,jk)          &
206                          &       - e2u(ji-1,jj) * fse3u(ji-1,jj,jk) * un(ji-1,jj,jk) ) * zbtr
207
208                     !-- Compute zonal advection trends
209                     ztrtrd(ji,jj,jk) = - ( ztu(ji,jj,jk) - ztu(ji-1,jj,jk) ) * zbtr &
210                          &             + trb(ji,jj,jk,jn) * z_hdivn_x
211                  END DO
212               END DO
213            END DO
214
215            IF (luttrd(jn)) CALL trd_mod_trc(ztrtrd, jn, jptrc_trd_xad, kt)    ! save the trends
216
217            ! 3.2) Passive tracer MERIDIONAL advection trends
218            ztrtrd(:,:,:) = 0.e0
219 
220            DO jk = 1, jpkm1
221               DO jj = 2, jpjm1
222                  DO ji = fs_2, fs_jpim1   ! vector opt.
223
224                     !-- Compute merid. divergence by splitting hdivn (see divcur.F90)
225                     !   N.B. This computation is not valid along OBCs (if any)
226                     zbtr      = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
227                     z_hdivn_y = (  e1v(ji,  jj) * fse3v(ji,jj  ,jk) * vn(ji,jj  ,jk)          &
228                          &       - e1v(ji,jj-1) * fse3v(ji,jj-1,jk) * vn(ji,jj-1,jk) ) * zbtr
229
230                     !-- Compute merid. advection trends
231                     ztrtrd(ji,jj,jk) = - ( ztv(ji,jj,jk) - ztv(ji,jj-1,jk) ) * zbtr &
232                          &             + trb(ji,jj,jk,jn) * z_hdivn_y
233                  END DO
234               END DO
235            END DO
236
237            IF (luttrd(jn)) CALL trd_mod_trc(ztrtrd, jn, jptrc_trd_yad, kt)     ! save the trends
238
239            ! 3.3) Passive tracer VERTICAL advection trends
240            ztrtrd(:,:,:) = 0.e0
241            DO jk = 1, jpkm1
242               DO jj = 2, jpjm1
243                  DO ji = fs_2, fs_jpim1   ! Vector opt.
244                     zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
245                     ztrtrd(ji,jj,jk) = - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) * zbtr   &
246                          &             - trb(ji,jj,jk,jn) * hdivn(ji,jj,jk)
247                  END DO
248               END DO
249            END DO
250
251            IF (luttrd(jn)) CALL trd_mod_trc(ztrtrd, jn, jptrc_trd_zad, kt)     ! save the trends
252
253         ENDIF
254!CDIR END
255
256         ! 4. Update and guess with monotonic sheme
257         ! ----------------------------------------
258         DO jk = 1, jpkm1
259            z2dtt = z2 * rdttra(jk) * FLOAT(ndttrc)
260            DO jj = 2, jpjm1
261               DO ji = fs_2, fs_jpim1   ! vector opt.
262                  tra(ji,jj,jk,jn) =  tra(ji,jj,jk,jn) + zti(ji,jj,jk)
263                  zti (ji,jj,jk) = ( trb(ji,jj,jk,jn) + z2dtt * zti(ji,jj,jk) ) * tmask(ji,jj,jk)
264               END DO
265            END DO
266         END DO
267
268         ! 5. Lateral boundary conditions on zti, zsi (unchanged sign)
269         ! -----------------------------------------------------------
270         CALL lbc_lnk( zti, 'T', 1. )
271
272
273         ! ============================================================
274         ! II.              Corrected advective trends
275         ! ============================================================
276
277         ! 1. Antidiffusive flux : high order minus low order
278         ! --------------------------------------------------
279         ! Antidiffusive flux on i and j
280         DO jk = 1, jpkm1
281            DO jj = 1, jpjm1
282               DO ji = 1, fs_jpim1   ! vector opt.
283                  zeu = 0.5 * e2u(ji,jj) * fse3u(ji,jj,jk) * zun(ji,jj,jk)
284                  zev = 0.5 * e1v(ji,jj) * fse3v(ji,jj,jk) * zvn(ji,jj,jk)
285                  ztu(ji,jj,jk) = zeu * ( trn(ji,jj,jk,jn) + trn(ji+1,jj,jk,jn) ) - ztu(ji,jj,jk)
286                  ztv(ji,jj,jk) = zev * ( trn(ji,jj,jk,jn) + trn(ji,jj+1,jk,jn) ) - ztv(ji,jj,jk)
287               END DO
288            END DO
289         END DO
290
291         ! Antidiffusive flux on k
292         ztw(:,:,1) = 0.e0    ! surface value
293         DO jk = 2, jpkm1     ! interior value
294            DO jj = 1, jpj
295               DO ji = 1, jpi
296                  zew = 0.5 * e1t(ji,jj) * e2t(ji,jj) * zwn(ji,jj,jk)
297                  ztw(ji,jj,jk) = zew * ( trn(ji,jj,jk,jn) + trn(ji,jj,jk-1,jn) ) - ztw(ji,jj,jk)
298               END DO
299            END DO
300         END DO
301
302         ! Lateral bondary conditions
303         CALL lbc_lnk( ztu, 'U', -1. )
304         CALL lbc_lnk( ztv, 'V', -1. )
305         CALL lbc_lnk( ztw, 'W',  1. )
306
307         ! 2. Monotonicity algorithm
308         ! -------------------------
309         CALL nonosc( trb(:,:,:,jn), ztu, ztv, ztw, zti, z2 )
310
311
312         ! 3. Final trend with corrected fluxes
313         ! ------------------------------------
314         DO jk = 1, jpkm1
315            DO jj = 2, jpjm1
316               DO ji = fs_2, fs_jpim1   ! vector opt.
317                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
318                  tra(ji,jj,jk,jn) = tra(ji,jj,jk,jn)   &
319                     &         - ( ztu(ji,jj,jk) - ztu(ji-1,jj  ,jk  )   &
320                     &           + ztv(ji,jj,jk) - ztv(ji  ,jj-1,jk  )   &
321                     &           + ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) * zbtr
322#if defined key_trc_diatrd
323                  IF ( luttrd(jn) ) &
324                     trtrd(ji,jj,jk,ikeep(jn),1) = trtrd(ji,jj,jk,ikeep(jn),1) -  &
325                        &                          zbtr * ( ztu(ji,jj,jk) - ztu(ji-1,jj,jk) )
326                  IF ( luttrd(jn) ) &
327                     trtrd(ji,jj,jk,ikeep(jn),2) = trtrd(ji,jj,jk,ikeep(jn),2) -  &
328                        &                          zbtr * ( ztv(ji,jj,jk) - ztv(ji,jj-1,jk) )
329                  IF ( luttrd(jn) ) &
330                     trtrd(ji,jj,jk,ikeep(jn),3) = trtrd(ji,jj,jk,ikeep(jn),3) -  &
331                        &                          zbtr * ( ztw(ji,jj,jk) - ztw(ji,jj,jk+1) )
332#endif
333
334               END DO
335            END DO
336         END DO
337
338#if defined key_trc_diatrd
339         DO jk = 1,jpk
340            DO jj = 2,jpjm1
341               DO  ji = 2,jpim1
342                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
343                  zgm = zbtr * trn(ji,jj,jk,jn) *     &
344                     &         (  zun(ji  ,jj,jk) * e2u(ji  ,jj) * fse3u(ji  ,jj,jk)    &
345                     &          - zun(ji-1,jj,jk) * e2u(ji-1,jj) * fse3u(ji-1,jj,jk) )
346
347                  zgz = zbtr * trn(ji,jj,jk,jn) *     &
348                     &         (  zvn(ji,jj  ,jk) * e1v(ji,jj  ) * fse3v(ji,jj  ,jk)    &
349                     &          - zvn(ji,jj-1,jk) * e1v(ji,jj-1) * fse3v(ji,jj-1,jk) )
350
351                  IF (luttrd(jn)) trtrd(ji,jj,jk,ikeep(jn),1) = trtrd(ji,jj,jk,ikeep(jn),1) + zgm
352                  IF (luttrd(jn)) trtrd(ji,jj,jk,ikeep(jn),2) = trtrd(ji,jj,jk,ikeep(jn),2) + zgz
353                  IF (luttrd(jn)) trtrd(ji,jj,jk,ikeep(jn),3) = trtrd(ji,jj,jk,ikeep(jn),3)    &
354                     &            - trn(ji,jj,jk,jn) * hdivn(ji,jj,jk)
355               END DO
356            END DO
357         END DO
358
359         ! Lateral boundary conditions on trtrd:
360
361         IF (luttrd(jn)) CALL lbc_lnk( trtrd(:,:,:,ikeep(jn),1), 'T', 1. )
362         IF (luttrd(jn)) CALL lbc_lnk( trtrd(:,:,:,ikeep(jn),2), 'T', 1. )
363         IF (luttrd(jn)) CALL lbc_lnk( trtrd(:,:,:,ikeep(jn),3), 'T', 1. )
364#endif
365
366         ! 4. Save the advective trends for diagnostics
367         ! --------------------------------------------
368         ! Warning : mass fluxes should probably be converted into advection
369         ! terms in the computations below ???
370
371!CDIR BEGIN COLLAPSE
372         IF( l_trdtrc ) THEN
373           
374            ! 4.1) Passive tracer ZONAL advection trends
375            ztrtrd(:,:,:) = 0.e0
376            DO jk = 1, jpkm1
377               DO jj = 2, jpjm1
378                  DO ji = fs_2, fs_jpim1   ! vector opt.
379                     zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
380                     ztrtrd(ji,jj,jk) = - ( ztu(ji,jj,jk) - ztu(ji-1,jj,jk) ) * zbtr
381                  END DO
382               END DO
383            END DO
384           
385            IF (luttrd(jn)) CALL trd_mod_trc(ztrtrd, jn, jptrc_trd_xad, kt)   ! <<< ADD TO PREVIOUSLY COMPUTED
386
387            ! 4.2) Passive tracer MERIDIONAL advection trends
388            ztrtrd(:,:,:) = 0.e0
389            DO jk = 1, jpkm1
390               DO jj = 2, jpjm1
391                  DO ji = fs_2, fs_jpim1   ! vector opt.
392                     zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
393                     ztrtrd(ji,jj,jk) = - ( ztv(ji,jj,jk) - ztv(ji,jj-1,jk) ) * zbtr 
394                  END DO
395               END DO
396            END DO
397           
398            IF (luttrd(jn)) CALL trd_mod_trc(ztrtrd, jn, jptrc_trd_yad, kt)   ! <<< ADD TO PREVIOUSLY COMPUTED
399           
400            ! 4.3) Passive tracer VERTICAL advection trends
401            ztrtrd(:,:,:) = 0.e0
402            DO jk = 1, jpkm1
403               DO jj = 2, jpjm1
404                  DO ji = fs_2, fs_jpim1   ! vector opt.
405                     zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
406                     ztrtrd(ji,jj,jk) = - ( ztw(ji,jj,jk) - ztw(ji,jj,jk+1) ) * zbtr
407                  END DO
408               END DO
409            END DO
410           
411            IF (luttrd(jn)) CALL trd_mod_trc(ztrtrd, jn, jptrc_trd_zad, kt)   ! <<< ADD TO PREVIOUSLY COMPUTED
412           
413         ENDIF
414!CDIR END
415
416
417      END DO
418
419      IF( l_trdtrc ) DEALLOCATE( ztrtrd )
420
421      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
422         WRITE(charout, FMT="('tvd - adv')")
423         CALL prt_ctl_trc_info(charout)
424         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
425      ENDIF
426
427   END SUBROUTINE trc_adv_tvd
428
429
430   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, prdt )
431      !!---------------------------------------------------------------------
432      !!                    ***  ROUTINE nonosc  ***
433      !!     
434      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
435      !!       scheme and the before field by a nonoscillatory algorithm
436      !!
437      !! **  Method  :   ... ???
438      !!       warning : pbef and paft must be masked, but the boundaries
439      !!       conditions on the fluxes are not necessary zalezak (1979)
440      !!       drange (1995) multi-dimensional forward-in-time and upstream-
441      !!       in-space based differencing for fluid
442      !!
443      !! History :
444      !!        !  97-04  (L. Mortier) Original code
445      !!        !  00-02  (H. Loukos)  rewritting for opa8
446      !!        !  00-10  (M.A Foujols, E. Kestenare)  lateral b.c.
447      !!        !  01-03  (E. Kestenare)  add key_passivetrc
448      !!        !  01-07  (E. Durand G. Madec)  adapted for T & S
449      !!   8.5  !  02-06  (G. Madec)  F90: Free form and module
450      !!----------------------------------------------------------------------
451      !! * Arguments
452      REAL(wp), INTENT( in ) ::   &
453         prdt                               ! ???
454      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT( inout ) ::   &
455         pbef,                            & ! before field
456         paft,                            & ! after field
457         paa,                             & ! monotonic flux in the i direction
458         pbb,                             & ! monotonic flux in the j direction
459         pcc                                ! monotonic flux in the k direction
460
461      !! * Local declarations
462      INTEGER ::   ji, jj, jk               ! dummy loop indices
463      INTEGER ::   ikm1
464      REAL(wp), DIMENSION (jpi,jpj,jpk) ::   zbetup, zbetdo
465      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt
466      !!----------------------------------------------------------------------
467
468      zbig = 1.e+40
469      zrtrn = 1.e-15
470      zbetup(:,:,:) = 0.e0   ;   zbetdo(:,:,:) = 0.e0
471
472      ! Search local extrema
473      ! --------------------
474      ! large negative value (-zbig) inside land
475      ! large negative value (-zbig) inside land
476      pbef(:,:,:) = pbef(:,:,:) * tmask(:,:,:) - zbig * ( 1.e0 - tmask(:,:,:) )
477      paft(:,:,:) = paft(:,:,:) * tmask(:,:,:) - zbig * ( 1.e0 - tmask(:,:,:) )
478      ! search maximum in neighbourhood
479      DO jk = 1, jpkm1
480         ikm1 = MAX(jk-1,1)
481         DO jj = 2, jpjm1
482            DO ji = fs_2, fs_jpim1   ! vector opt.
483               zbetup(ji,jj,jk) = MAX(  pbef(ji  ,jj  ,jk  ), paft(ji  ,jj  ,jk  ),   &
484                  &                     pbef(ji-1,jj  ,jk  ), pbef(ji+1,jj  ,jk  ),   &
485                  &                     paft(ji-1,jj  ,jk  ), paft(ji+1,jj  ,jk  ),   &
486                  &                     pbef(ji  ,jj-1,jk  ), pbef(ji  ,jj+1,jk  ),   &
487                  &                     paft(ji  ,jj-1,jk  ), paft(ji  ,jj+1,jk  ),   &
488                  &                     pbef(ji  ,jj  ,ikm1), pbef(ji  ,jj  ,jk+1),   &
489                  &                     paft(ji  ,jj  ,ikm1), paft(ji  ,jj  ,jk+1)  )
490            END DO
491         END DO
492      END DO
493      ! large positive value (+zbig) inside land
494      pbef(:,:,:) = pbef(:,:,:) * tmask(:,:,:) + zbig * ( 1.e0 - tmask(:,:,:) )
495      paft(:,:,:) = paft(:,:,:) * tmask(:,:,:) + zbig * ( 1.e0 - tmask(:,:,:) )
496      ! search minimum in neighbourhood
497      DO jk = 1, jpkm1
498         ikm1 = MAX(jk-1,1)
499         DO jj = 2, jpjm1
500            DO ji = fs_2, fs_jpim1   ! vector opt.
501               zbetdo(ji,jj,jk) = MIN(  pbef(ji  ,jj  ,jk  ), paft(ji  ,jj  ,jk  ),   &
502                  &                     pbef(ji-1,jj  ,jk  ), pbef(ji+1,jj  ,jk  ),   &
503                  &                     paft(ji-1,jj  ,jk  ), paft(ji+1,jj  ,jk  ),   &
504                  &                     pbef(ji  ,jj-1,jk  ), pbef(ji  ,jj+1,jk  ),   &
505                  &                     paft(ji  ,jj-1,jk  ), paft(ji  ,jj+1,jk  ),   &
506                  &                     pbef(ji  ,jj  ,ikm1), pbef(ji  ,jj  ,jk+1),   &
507                  &                     paft(ji  ,jj  ,ikm1), paft(ji  ,jj  ,jk+1)  )
508            END DO
509         END DO
510      END DO
511
512      ! restore masked values to zero
513      pbef(:,:,:) = pbef(:,:,:) * tmask(:,:,:)
514      paft(:,:,:) = paft(:,:,:) * tmask(:,:,:)
515 
516
517      ! 2. Positive and negative part of fluxes and beta terms
518      ! ------------------------------------------------------
519
520      DO jk = 1, jpkm1
521         z2dtt = prdt * rdttra(jk) * FLOAT(ndttrc)
522         DO jj = 2, jpjm1
523            DO ji = fs_2, fs_jpim1   ! vector opt.
524               ! positive & negative part of the flux
525               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
526                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
527                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
528               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
529                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
530                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
531               ! up & down beta terms
532               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) / z2dtt
533               zbetup(ji,jj,jk) = ( zbetup(ji,jj,jk) - paft(ji,jj,jk) ) / (zpos+zrtrn) * zbt
534               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zbetdo(ji,jj,jk) ) / (zneg+zrtrn) * zbt
535            END DO
536         END DO
537      END DO
538
539      ! lateral boundary condition on zbetup & zbetdo   (unchanged sign)
540      CALL lbc_lnk( zbetup, 'T', 1. )
541      CALL lbc_lnk( zbetdo, 'T', 1. )
542
543
544      ! 3. monotonic flux in the i direction, i.e. paa
545      ! ----------------------------------------------
546      DO jk = 1, jpkm1
547         DO jj = 2, jpjm1
548            DO ji = fs_2, fs_jpim1   ! vector opt.
549               zc = paa(ji,jj,jk)
550               IF( zc >= 0. ) THEN
551                  za = MIN( 1., zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
552                  paa(ji,jj,jk) = za * zc
553               ELSE
554                  zb = MIN( 1., zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
555                  paa(ji,jj,jk) = zb * zc
556               ENDIF
557            END DO
558         END DO
559      END DO
560
561      ! lateral boundary condition on paa   (changed sign)
562      CALL lbc_lnk( paa, 'U', -1. )
563
564
565      ! 4. monotonic flux in the j direction, i.e. pbb
566      ! ----------------------------------------------
567      DO jk = 1, jpkm1
568         DO jj = 2, jpjm1
569            DO ji = fs_2, fs_jpim1   ! vector opt.
570               zc = pbb(ji,jj,jk)
571               IF( zc >= 0. ) THEN
572                  za = MIN( 1., zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
573                  pbb(ji,jj,jk) = za * zc
574               ELSE
575                  zb = MIN( 1., zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
576                  pbb(ji,jj,jk) = zb * zc
577               ENDIF
578            END DO
579         END DO
580      END DO
581
582      ! lateral boundary condition on pbb   (changed sign)
583      CALL lbc_lnk( pbb, 'V', -1. )
584
585
586      ! monotonic flux in the k direction, i.e. pcc
587      ! -------------------------------------------
588      DO jk = 2, jpkm1
589         DO jj = 2, jpjm1
590            DO ji = fs_2, fs_jpim1   ! vector opt.
591               zc = pcc(ji,jj,jk)
592               IF( zc >= 0. ) THEN
593                  za = MIN( 1., zbetdo(ji,jj,jk), zbetup(ji,jj,jk-1) )
594                  pcc(ji,jj,jk) = za * zc
595               ELSE
596                  zb = MIN( 1., zbetup(ji,jj,jk), zbetdo(ji,jj,jk-1) )
597                  pcc(ji,jj,jk) = zb * zc
598               ENDIF
599            END DO
600         END DO
601      END DO
602
603      ! lateral boundary condition on pcc   (unchanged sign)
604      CALL lbc_lnk( pcc, 'W', 1. )
605
606   END SUBROUTINE nonosc
607
608#else
609   !!----------------------------------------------------------------------
610   !!   Default option                                         Empty module
611   !!----------------------------------------------------------------------
612CONTAINS
613   SUBROUTINE trc_adv_tvd( kt ) 
614      INTEGER, INTENT(in) :: kt
615      WRITE(*,*) 'trc_adv_tvd: You should not have seen this print! error?', kt
616   END SUBROUTINE trc_adv_tvd
617#endif
618
619   !!======================================================================
620END MODULE trcadv_tvd
Note: See TracBrowser for help on using the repository browser.