New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcldf_iso.F90 in trunk/NEMO/TOP_SRC/TRP – NEMO

source: trunk/NEMO/TOP_SRC/TRP/trcldf_iso.F90 @ 1175

Last change on this file since 1175 was 1175, checked in by cetlod, 16 years ago

update transport modules to take into account new trends organization, see ticket:248
  • Property svn:executable set to *
  • Property svn:keywords set to Id
File size: 15.5 KB
Line 
1MODULE trcldf_iso
2   !!==============================================================================
3   !!                    ***  MODULE  trcldf_iso  ***
4   !!======================================================================
5   !! Ocean passive tracers:  horizontal component of the lateral tracer mixing trend
6   !! History :
7   !!        !  94-08  (G. Madec, M. Imbard)
8   !!        !  97-05  (G. Madec)  split into traldf and trazdf
9   !!        !  98-03  (L. Bopp, MA Foujols) passive tracer generalisation
10   !!        !  00-10  (MA Foujols E Kestenare) USE passive tracer coefficient
11   !!   8.5  !  02-08  (G. Madec)  Free form, F90
12   !!   9.0  !  04-03  (C. Ethe)  Free form, F90
13   !!        !  06-08  (C. Deltel) Diagnose ML trends for passive tracers
14   !!----------------------------------------------------------------------
15#if key_top && defined key_ldfslp 
16   !!----------------------------------------------------------------------
17   !!   'key_ldfslp'                  rotation of the lateral mixing tensor
18   !!----------------------------------------------------------------------
19   !!   trc_ldf_iso : update the tracer trend with the horizontal component
20   !!                 of iso neutral laplacian operator or horizontal
21   !!                 laplacian operator in s-coordinate
22   !!----------------------------------------------------------------------
23   USE oce_trc      ! ocean dynamics and tracers variables
24   USE trp_trc      ! ocean passive tracers variables
25   USE prtctl_trc   ! Print control for debbuging
26   USE trdmld_trc
27   USE trdmld_trc_oce     
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC trc_ldf_iso  ! routine called by step.F90
33
34   !! * Substitutions
35#  include "top_substitute.h90"
36   !!----------------------------------------------------------------------
37   !!   TOP 1.0 , LOCEAN-IPSL (2005)
38   !! $Header: /home/opalod/NEMOCVSROOT/NEMO/TOP_SRC/TRP/trcldf_iso.F90,v 1.9 2006/04/10 15:38:54 opalod Exp $
39   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
40   !!----------------------------------------------------------------------
41
42CONTAINS
43
44   SUBROUTINE trc_ldf_iso( kt )
45      !!----------------------------------------------------------------------
46      !!                  ***  ROUTINE trc_ldf_iso  ***
47      !!
48      !! ** Purpose :   Compute the before horizontal tracer  diffusive
49      !!      trend and add it to the general trend of tracer equation.
50      !!
51      !! ** Method  :   The horizontal component of the lateral diffusive trends
52      !!      is provided by a 2nd order operator rotated along neural or geopo-
53      !!      tential surfaces to which an eddy induced advection can be added
54      !!      It is computed using before fields (forward in time) and isopyc-
55      !!      nal or geopotential slopes computed in routine ldfslp.
56      !!
57      !!      horizontal fluxes associated with the rotated lateral mixing:
58      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
59      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
60      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
61      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
62      !!      add horizontal Eddy Induced advective fluxes (lk_traldf_eiv=T):
63      !!         zftu = zftu - dk-1[ aht e2u mi(wslpi) ] mi( tb )
64      !!         zftv = zftv - dk-1[ aht e1v mj(wslpj) ] mj( tb )
65      !!      take the horizontal divergence of the fluxes:
66      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
67      !!      Add this trend to the general trend tra :
68      !!         tra = tra + difft
69      !!
70      !! ** Action  : - Update tra arrays with the before isopycnal or
71      !!                geopotential s-coord harmonic mixing trend.
72      !!              - Save the trends ('key_trdmld_trc')
73      !!----------------------------------------------------------------------
74      USE oce_trc       , zftu => ua,  &  ! use ua as workspace
75         &                zfsu => va      ! use va as workspace
76      !!
77      INTEGER, INTENT( in ) ::   kt                             ! ocean time-step index
78      !!                                                 
79      INTEGER ::   ji, jj, jk, jn                               ! dummy loop indices
80      REAL(wp) ::   zabe1, zabe2, zcof1, zcof2                  ! temporary scalars
81      REAL(wp) ::   zmsku, zmskv, zbtr, ztra
82#if defined key_trcldf_eiv
83      REAL(wp) ::   zcg1, zcg2, zuwk, zvwk, zuwk1, zvwk1
84      REAL(wp) ::   z_hdivn_x, z_hdivn_y
85#endif
86      REAL(wp), DIMENSION(jpi,jpj) ::   zdkt, zdk1t             ! workspace
87#if defined key_trcldf_eiv
88      REAL(wp), DIMENSION(jpi,jpj) ::   zftug, zftvg
89#endif
90      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zftv                ! workspace
91      CHARACTER (len=22) :: charout
92      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrtrd       ! trends arrays
93#   if defined key_trcldf_eiv
94      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrtrd_xei
95      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrtrd_yei
96#endif
97      !!----------------------------------------------------------------------
98
99      IF( kt == nittrc000 ) THEN
100         IF(lwp) WRITE(numout,*)
101         IF(lwp) WRITE(numout,*) 'trc_ldf_iso : iso neutral lateral diffusion or'
102         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   horizontal laplacian diffusion in s-coordinate'
103#if defined key_trcldf_eiv && defined key_diaeiv
104         u_trc_eiv(:,:,:) = 0.e0
105         v_trc_eiv(:,:,:) = 0.e0
106#endif
107      ENDIF
108
109      IF( l_trdtrc ) THEN
110         ALLOCATE( ztrtrd(jpi,jpj,jpk) )
111#   if defined key_trcldf_eiv
112         ALLOCATE( ztrtrd_xei(jpi,jpj,jpk) )
113         ALLOCATE( ztrtrd_yei(jpi,jpj,jpk) )
114#   endif
115      ENDIF
116
117      !                                                          ! ===========
118      DO jn = 1, jptra                                           ! tracer loop
119         !                                                       ! ===========
120
121!CDIR COLLAPSE
122         IF( l_trdtrc ) ztrtrd(:,:,:) = tra(:,:,:,jn)
123
124         !                                                ! ===============
125         DO jk = 1, jpkm1                                 ! Horizontal slab
126            !                                             ! ===============
127            ! 1. Vertical tracer gradient at level jk and jk+1
128            ! ------------------------------------------------
129            ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
130
131            zdk1t(:,:) = ( trb(:,:,jk,jn) - trb(:,:,jk+1,jn) ) * tmask(:,:,jk+1)
132
133            IF( jk == 1 ) THEN
134               zdkt(:,:) = zdk1t(:,:)
135            ELSE
136               zdkt(:,:) = ( trb(:,:,jk-1,jn) - trb(:,:,jk,jn) ) * tmask(:,:,jk)
137            ENDIF
138
139
140            ! 2. Horizontal fluxes
141            ! --------------------
142
143            DO jj = 1 , jpjm1
144               DO ji = 1, fs_jpim1   ! vector opt.
145                  zabe1 = ( fsahtru(ji,jj,jk) + ahtrb0 ) * e2u(ji,jj) * fse3u(ji,jj,jk) / e1u(ji,jj)
146                  zabe2 = ( fsahtrv(ji,jj,jk) + ahtrb0 ) * e1v(ji,jj) * fse3v(ji,jj,jk) / e2v(ji,jj)
147
148                  zmsku = 1. / MAX(   tmask(ji+1,jj,jk  ) + tmask(ji,jj,jk+1)   &
149                     + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk  ), 1. )
150
151                  zmskv = 1. / MAX(   tmask(ji,jj+1,jk  ) + tmask(ji,jj,jk+1)   &
152                     + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk  ), 1. )
153
154                  zcof1 = -fsahtru(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
155                  zcof2 = -fsahtrv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
156
157                  zftu(ji,jj,jk) = umask(ji,jj,jk) * (   zabe1 * (   trb(ji+1,jj,jk,jn) - trb(ji,jj,jk,jn)  )   &
158                     &                              + zcof1 * (   zdkt (ji+1,jj) + zdk1t(ji,jj)      &
159                     &                                          + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  )
160
161                  zftv(ji,jj,jk) = vmask(ji,jj,jk) * (   zabe2 * (   trb(ji,jj+1,jk,jn) - trb(ji,jj,jk,jn)  )   &
162                     &                              + zcof2 * (   zdkt (ji,jj+1) + zdk1t(ji,jj)      &
163                     &                                          + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  )
164
165               END DO
166            END DO
167
168#   if defined key_trcldf_eiv
169            !                              ! ---------------------------------------!
170            !                              ! Eddy induced vertical advective fluxes !
171            !                              ! ---------------------------------------!
172            DO jj = 1, jpjm1
173               DO ji = 1, fs_jpim1   ! vector opt.
174                  zuwk = ( wslpi(ji,jj,jk  ) + wslpi(ji+1,jj,jk  ) ) * fsaeitru(ji,jj,jk  ) * umask(ji,jj,jk  )
175                  zuwk1= ( wslpi(ji,jj,jk+1) + wslpi(ji+1,jj,jk+1) ) * fsaeitru(ji,jj,jk+1) * umask(ji,jj,jk+1)
176                  zvwk = ( wslpj(ji,jj,jk  ) + wslpj(ji,jj+1,jk  ) ) * fsaeitrv(ji,jj,jk  ) * vmask(ji,jj,jk  )
177                  zvwk1= ( wslpj(ji,jj,jk+1) + wslpj(ji,jj+1,jk+1) ) * fsaeitrv(ji,jj,jk+1) * vmask(ji,jj,jk+1)
178
179                  zcg1= -0.25 * e2u(ji,jj) * umask(ji,jj,jk) * ( zuwk-zuwk1 )
180                  zcg2= -0.25 * e1v(ji,jj) * vmask(ji,jj,jk) * ( zvwk-zvwk1 )
181
182                  zftug(ji,jj) = zcg1 * ( trb(ji+1,jj,jk,jn) + trb(ji,jj,jk,jn) )
183                  zftvg(ji,jj) = zcg2 * ( trb(ji,jj+1,jk,jn) + trb(ji,jj,jk,jn) )
184
185                  zftu(ji,jj,jk) = zftu(ji,jj,jk) + zftug(ji,jj)
186                  zftv(ji,jj,jk) = zftv(ji,jj,jk) + zftvg(ji,jj)
187
188#   if defined key_diaeiv
189                  u_trc_eiv(ji,jj,jk) = -2. * zcg1 / ( e2u(ji,jj) * fse3u(ji,jj,jk) )
190                  v_trc_eiv(ji,jj,jk) = -2. * zcg2 / ( e1v(ji,jj) * fse3v(ji,jj,jk) )
191#   endif
192               END DO
193            END DO
194#   endif
195
196            ! 3. Second derivative (divergence) and add to the general trend
197            ! --------------------------------------------------------------
198
199            DO jj = 2 , jpjm1
200               DO ji = fs_2, fs_jpim1   ! vector opt.
201                  zbtr= 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
202                  ztra = zbtr * (  zftu(ji,jj,jk) - zftu(ji-1,jj  ,jk)   &
203                       &         + zftv(ji,jj,jk) - zftv(ji  ,jj-1,jk)  )
204                  tra (ji,jj,jk,jn) = tra (ji,jj,jk,jn) + ztra
205#if defined key_trc_diatrd
206                  IF (luttrd(jn)) trtrd (ji,jj,jk,ikeep(jn),4) = ( zftu(ji,jj,jk) - zftu(ji-1,jj,jk  ) ) * zbtr
207                  IF (luttrd(jn)) trtrd (ji,jj,jk,ikeep(jn),5) = ( zftv(ji,jj,jk) - zftv(ji,jj-1,jk  ) ) * zbtr
208#endif
209
210               END DO
211            END DO
212            !                                          ! ===============
213         END DO                                        !   End of slab 
214         !                                             ! ===============
215
216         ! 4. Save the trends for diagnostic
217         ! ---------------------------------
218
219         IF( l_trdtrc ) THEN
220#   if defined key_trcldf_eiv
221
222            ! 4.1) Compute the eiv ZONAL & MERIDIONAL advective trends
223                                                          ! ===============
224            DO jk = 1, jpkm1                              ! Horizontal slab
225                                                          ! ===============
226               DO jj = 1, jpjm1
227                  DO ji = 1, fs_jpim1   ! vector opt.
228                     zuwk = ( wslpi(ji,jj,jk  ) + wslpi(ji+1,jj,jk  ) ) * fsaeitru(ji,jj,jk  ) * umask(ji,jj,jk  )
229                     zuwk1= ( wslpi(ji,jj,jk+1) + wslpi(ji+1,jj,jk+1) ) * fsaeitru(ji,jj,jk+1) * umask(ji,jj,jk+1)
230                     zvwk = ( wslpj(ji,jj,jk  ) + wslpj(ji,jj+1,jk  ) ) * fsaeitrv(ji,jj,jk  ) * vmask(ji,jj,jk  )
231                     zvwk1= ( wslpj(ji,jj,jk+1) + wslpj(ji,jj+1,jk+1) ) * fsaeitrv(ji,jj,jk+1) * vmask(ji,jj,jk+1)
232                     
233                     zcg1= -0.25 * e2u(ji,jj) * umask(ji,jj,jk) * ( zuwk-zuwk1 )
234                     zcg2= -0.25 * e1v(ji,jj) * vmask(ji,jj,jk) * ( zvwk-zvwk1 )
235                     
236                     zftug(ji,jj) = zcg1 * ( trb(ji+1,jj,jk,jn) + trb(ji,jj,jk,jn) )
237                     zftvg(ji,jj) = zcg2 * ( trb(ji,jj+1,jk,jn) + trb(ji,jj,jk,jn) )
238                  END DO
239               END DO
240               
241!CDIRR COLLAPSE
242               DO jj = 2 , jpjm1
243                  DO ji = fs_2, fs_jpim1   ! vector opt.
244                     zbtr= 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
245                     
246                     !-- Compute zonal & meridional divergences of the eiv field :
247                     !     d_x[u_trc_eiv] = 1/(e1t*e2t*e3t) ( di[e2u*e3u u_trc_eiv] )
248                     !     d_y[v_trc_eiv] = 1/(e1t*e2t*e3t) ( dj[e1v*e3v v_trc_eiv] )
249                     !   N.B.  This is only possible if key_diaeiv is switched on.
250#       if defined key_diaeiv
251                     z_hdivn_x = (  e2u(ji  ,jj) * fse3u(ji  ,jj,jk) * u_trc_eiv(ji  ,jj  ,jk)  &
252                          &       - e2u(ji-1,jj) * fse3u(ji-1,jj,jk) * u_trc_eiv(ji-1,jj  ,jk) ) * zbtr
253                     z_hdivn_y = (  e1v(ji,  jj) * fse3v(ji,jj  ,jk) * v_trc_eiv(ji,  jj  ,jk)  &
254                          &       - e1v(ji,jj-1) * fse3v(ji,jj-1,jk) * v_trc_eiv(ji  ,jj-1,jk) ) * zbtr
255#       else
256                     z_hdivn_x = 0.e0   ;   z_hdivn_y = 0.e0 
257#       endif
258                     !-- Compute the zonal advective trends associated with eiv
259                     ztrtrd_xei(ji,jj,jk) =  zbtr * ( zftug(ji,jj) - zftug(ji-1,jj  ) )          &
260                          &                 - trn(ji,jj,jk,jn) * z_hdivn_x
261                     
262                     !-- Compute the merid. advective trends associated with eiv
263                     ztrtrd_yei(ji,jj,jk) =  zbtr * ( zftvg(ji,jj) - zftvg(ji  ,jj-1) )          &
264                          &                 - trn(ji,jj,jk,jn) * z_hdivn_y
265                  END DO
266               END DO
267                                                          ! ===============
268            END DO                                        !   End of slab 
269                                                          ! ===============
270            ! 4.2) Deduce the trend
271            ztrtrd(:,:,:) = tra(:,:,:,jn) - ztrtrd(:,:,:) - ztrtrd_xei(:,:,:) - ztrtrd_yei(:,:,:)
272#   else
273            ztrtrd(:,:,:) = tra(:,:,:,jn) - ztrtrd(:,:,:)
274#   endif
275           
276            ! 4.3) save the trends for diagnostic
277            IF (luttrd(jn)) CALL trd_mod_trc( ztrtrd    , jn, jptrc_trd_ldf, kt ) 
278#   if defined key_trcldf_eiv
279            IF (luttrd(jn)) CALL trd_mod_trc( ztrtrd_xei, jn, jptrc_trd_xei, kt )
280            IF (luttrd(jn)) CALL trd_mod_trc( ztrtrd_yei, jn, jptrc_trd_yei, kt )
281#   endif
282         ENDIF
283         !                                                    ! ===========
284      END DO                                                  ! tracer loop
285      !                                                       ! ===========
286
287      IF( l_trdtrc ) THEN
288         DEALLOCATE( ztrtrd )
289#   if defined key_trcldf_eiv
290         DEALLOCATE( ztrtrd_xei )
291         DEALLOCATE( ztrtrd_yei )
292#   endif
293      ENDIF
294
295      IF( ln_ctl ) THEN        ! print mean trends (used for debugging)
296         WRITE(charout, FMT="('ldf - iso')")
297         CALL prt_ctl_trc_info(charout)
298         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
299      ENDIF
300
301   END SUBROUTINE trc_ldf_iso
302
303#else
304   !!----------------------------------------------------------------------
305   !!   Dummy module :             No rotation of the lateral mixing tensor
306   !!----------------------------------------------------------------------
307CONTAINS
308   SUBROUTINE trc_ldf_iso( kt )               ! Empty routine
309      INTEGER, INTENT(in) :: kt
310      WRITE(*,*) 'trc_ldf_iso: You should not have seen this print! error?', kt
311   END SUBROUTINE trc_ldf_iso
312#endif
313
314   !!==============================================================================
315END MODULE trcldf_iso
Note: See TracBrowser for help on using the repository browser.