New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcldf_iso_zps.F90 in trunk/NEMO/TOP_SRC/TRP – NEMO

source: trunk/NEMO/TOP_SRC/TRP/trcldf_iso_zps.F90 @ 724

Last change on this file since 724 was 724, checked in by cetlod, 17 years ago

Update modules for passive tracers transport trends computation, see ticket:13
  • Property svn:eol-style set to native
  • Property svn:executable set to *
  • Property svn:keywords set to Author Date Id Revision
File size: 12.2 KB
Line 
1MODULE trcldf_iso_zps
2   !!==============================================================================
3   !!                   ***  MODULE  trcldf_iso_zps  ***
4   !! Ocean passive tracers:  horizontal component of the lateral tracer mixing trend
5   !!==============================================================================
6#if key_passivetrc &&  defined key_ldfslp 
7   !!----------------------------------------------------------------------
8   !!   'key_ldfslp'               slope of the lateral diffusive direction
9   !!----------------------------------------------------------------------
10   !!   trc_ldf_iso_zps : update the tracer trend with the horizontal
11   !!                     component of a iso-neutral laplacian operator
12   !!----------------------------------------------------------------------
13   !! * Modules used
14   USE oce_trc             ! ocean dynamics and active tracers variables
15   USE trc                 ! ocean passive tracers variables
16   USE prtctl_trc          ! Print control for debbuging
17
18   IMPLICIT NONE
19   PRIVATE
20
21   !! * Accessibility
22   PUBLIC trc_ldf_iso_zps  ! routine called by step.F90
23
24   !! * Substitutions
25#  include "passivetrc_substitute.h90"
26   !!----------------------------------------------------------------------
27   !!   TOP 1.0 , LOCEAN-IPSL (2005)
28   !! $Header: /home/opalod/NEMOCVSROOT/NEMO/TOP_SRC/TRP/trcldf_iso_zps.F90,v 1.11 2007/10/12 09:26:30 opalod Exp $
29   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
30   !!----------------------------------------------------------------------
31
32CONTAINS
33
34   SUBROUTINE trc_ldf_iso_zps( kt )
35      !!----------------------------------------------------------------------
36      !!                  ***  ROUTINE trc_ldf_iso_zps  ***
37      !!
38      !! ** Purpose :   Compute the before horizontal tracer  diffusive
39      !!      trend and add it to the general trend of tracer equation.
40      !!
41      !! ** Method  :   The horizontal component of the lateral diffusive trends
42      !!      is provided by a 2nd order operator rotated along neural or geopo-
43      !!      tential surfaces to which an eddy induced advection can be added
44      !!      It is computed using before fields (forward in time) and isopyc-
45      !!      nal or geopotential slopes computed in routine ldfslp.
46      !!
47      !!      horizontal fluxes associated with the rotated lateral mixing:
48      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
49      !!               - aht       e2u*uslp    dk[ mi(mk(trb)) ]
50      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
51      !!               - aht       e2u*vslp    dk[ mj(mk(trb)) ]
52      !!      add horizontal Eddy Induced advective fluxes (lk_traldf_eiv=T):
53      !!         zftu = zftu - dk-1[ aht e2u mi(wslpi) ] mi( trb )
54      !!         zftv = zftv - dk-1[ aht e1v mj(wslpj) ] mj( trb )
55      !!      take the horizontal divergence of the fluxes:
56      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
57      !!      Add this trend to the general trend tra :
58      !!         tra = tra + difft
59      !!
60      !!      'key_trdtra' defined: the trend is saved for diagnostics.
61      !!
62      !!      macro-tasked on horizontal slab (jk-loop).
63      !!
64      !! ** Action :
65      !!         Update tra arrays with the before along level biharmonic
66      !!      mixing trend.
67      !!         Save in trtrd arrays the trends if 'key_trc_diatrd' defined
68      !!
69      !! History :
70      !!        !  94-08  (G. Madec, M. Imbard)
71      !!        !  97-05  (G. Madec)  split into traldf and trazdf
72      !!   8.5  !  02-08  (G. Madec)  Free form, F90
73      !!   9.0  !  04-03  (C. Ethe)  adapted for passive tracers
74      !!----------------------------------------------------------------------
75      !! * Modules used
76      USE oce_trc       , zftu => ua,  &  ! use ua as workspace
77         &                zfsu => va      ! use va as workspace
78
79      !! * Arguments
80      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
81
82      !! * Local declarations
83      INTEGER ::   ji, jj, jk,jn          ! dummy loop indices
84      INTEGER ::   iku, ikv               ! temporary integer
85      REAL(wp) ::   &
86         zabe1, zabe2, zcof1, zcof2,   &  ! temporary scalars
87         zmsku, zmskv, zbtr, ztra       
88
89      REAL(wp), DIMENSION(jpi,jpj) ::   &
90         zdkt , zdk1t                     ! temporary workspace
91
92      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   & 
93         zftv, zgtbu, zgtbv               ! temporary workspace
94
95#if defined key_trcldf_eiv
96      REAL(wp), DIMENSION(jpi,jpj) ::   &
97         zftug, zftvg                    ! temporary workspace
98
99      REAL(wp) ::   &
100         zuwk, zvwk,                   &
101         zuwk1, zvwk1,                 &
102         zcg1,zcg2
103
104#if defined key_trc_diatrd
105      REAL(wp) ::   &
106         ztagu, ztagv
107#endif
108
109#endif
110      CHARACTER (len=22) :: charout
111      !!----------------------------------------------------------------------
112
113      IF( kt == nittrc000 ) THEN
114         IF(lwp) WRITE(numout,*)
115         IF(lwp) WRITE(numout,*) 'trc_ldf_iso_zps : iso neutral laplacian diffusion in '
116         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~   z-coordinates with partial steps'
117#if defined key_trcldf_eiv && defined key_diaeiv
118         u_trc_eiv(:,:,:) = 0.e0
119         v_trc_eiv(:,:,:) = 0.e0
120#endif
121      ENDIF
122
123      DO jn = 1, jptra
124
125#if defined key_trcldf_eiv && key_trc_diatrd
126         ztagu = 0.e0
127         ztagv = 0.e0
128#endif
129
130         ! Horizontal passive tracer gradient
131         DO jk = 1, jpk
132            DO jj = 1, jpj-1
133               DO ji = 1, fs_jpim1   ! vector opt.
134                  zgtbu(ji,jj,jk) = tmask(ji,jj,jk) * ( trb(ji+1,jj  ,jk,jn) - trb(ji,jj,jk,jn) )
135                  zgtbv(ji,jj,jk) = tmask(ji,jj,jk) * ( trb(ji  ,jj+1,jk,jn) - trb(ji,jj,jk,jn) )
136               END DO
137            END DO
138         END DO
139         ! partial steps correction at the last level
140         DO jj = 1, jpj-1
141            DO ji = 1, jpi-1
142               ! last level
143               iku = MIN( mbathy(ji,jj), mbathy(ji+1,jj  ) ) - 1
144               ikv = MIN( mbathy(ji,jj), mbathy(ji  ,jj+1) ) - 1
145               zgtbu(ji,jj,iku) = gtru(ji,jj,jn)               
146               zgtbv(ji,jj,ikv) = gtrv(ji,jj,jn)               
147            END DO
148         END DO
149
150         !                                                ! ===============
151         DO jk = 1, jpkm1                                 ! Horizontal slab
152            !                                             ! ===============
153            ! 1. Vertical tracer gradient at level jk and jk+1
154            ! ------------------------------------------------
155            ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
156
157            zdk1t(:,:) = ( trb(:,:,jk,jn) - trb(:,:,jk+1,jn) ) * tmask(:,:,jk+1)
158
159            IF( jk == 1 ) THEN
160               zdkt(:,:) = zdk1t(:,:)
161            ELSE
162               zdkt(:,:) = ( trb(:,:,jk-1,jn) - trb(:,:,jk,jn) ) * tmask(:,:,jk)
163            ENDIF
164
165
166            ! 2. Horizontal fluxes
167            ! --------------------
168
169            DO jj = 1 , jpjm1
170               DO ji = 1, fs_jpim1   ! vector opt.
171                  zabe1 = ( fsahtru(ji,jj,jk) + ahtrb0 ) * e2u(ji,jj) * fse3u(ji,jj,jk) / e1u(ji,jj)
172                  zabe2 = ( fsahtrv(ji,jj,jk) + ahtrb0 ) * e1v(ji,jj) * fse3v(ji,jj,jk) / e2v(ji,jj)
173
174                  zmsku = 1. / MAX(  tmask(ji+1,jj,jk  ) + tmask(ji,jj,jk+1)   &
175                     + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk  ), 1. )
176
177                  zmskv = 1. / MAX(  tmask(ji,jj+1,jk  ) + tmask(ji,jj,jk+1)   &
178                     + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk  ), 1. )
179
180                  zcof1 = -fsahtru(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
181                  zcof2 = -fsahtrv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
182
183                  zftu(ji,jj,jk) = umask(ji,jj,jk) * (  zabe1 * zgtbu(ji,jj,jk)   &
184                     &                                + zcof1 * (  zdkt (ji+1,jj) + zdk1t(ji,jj)      &
185                     &                                           + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  )
186                  zftv(ji,jj,jk) = vmask(ji,jj,jk) * (  zabe2 * zgtbv(ji,jj,jk)   &
187                     &                                + zcof2 * (  zdkt (ji,jj+1) + zdk1t(ji,jj)      &
188                     &                                           + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  )
189               END DO
190            END DO
191
192# if defined key_trcldf_eiv
193            ! ---------------------------------------!
194            ! Eddy induced vertical advective fluxes !
195            ! ---------------------------------------!
196            DO jj = 1, jpjm1
197               DO ji = 1, fs_jpim1   ! vector opt.
198                  zuwk = ( wslpi(ji,jj,jk  ) + wslpi(ji+1,jj  ,jk  ) ) * fsaeitru(ji,jj,jk  ) * umask(ji,jj,jk  )
199                  zuwk1= ( wslpi(ji,jj,jk+1) + wslpi(ji+1,jj  ,jk+1) ) * fsaeitru(ji,jj,jk+1) * umask(ji,jj,jk+1)
200                  zvwk = ( wslpj(ji,jj,jk  ) + wslpj(ji  ,jj+1,jk  ) ) * fsaeitrv(ji,jj,jk  ) * vmask(ji,jj,jk  )
201                  zvwk1= ( wslpj(ji,jj,jk+1) + wslpj(ji  ,jj+1,jk+1) ) * fsaeitrv(ji,jj,jk+1) * vmask(ji,jj,jk+1)
202
203                  zcg1= -0.25 * e2u(ji,jj) * umask(ji,jj,jk) * ( zuwk-zuwk1 )
204                  zcg2= -0.25 * e1v(ji,jj) * vmask(ji,jj,jk) * ( zvwk-zvwk1 )
205
206                  zftug(ji,jj) = zcg1 * ( trb(ji+1,jj,jk,jn) + trb(ji,jj,jk,jn) )
207                  zftvg(ji,jj) = zcg2 * ( trb(ji,jj+1,jk,jn) + trb(ji,jj,jk,jn) )
208
209                  zftu(ji,jj,jk) = zftu(ji,jj,jk) + zftug(ji,jj)
210                  zftv(ji,jj,jk) = zftv(ji,jj,jk) + zftvg(ji,jj)
211
212#   if defined key_diaeiv
213                  u_trc_eiv(ji,jj,jk) = -2. * zcg1 / ( e2u(ji,jj) * fse3u(ji,jj,jk) )
214                  v_trc_eiv(ji,jj,jk) = -2. * zcg2 / ( e1v(ji,jj) * fse3v(ji,jj,jk) )
215#   endif
216               END DO
217            END DO
218# endif
219
220            ! II.4 Second derivative (divergence) and add to the general trend
221            ! ----------------------------------------------------------------
222
223            DO jj = 2 , jpjm1
224               DO ji = fs_2, fs_jpim1   ! vector opt.
225                  zbtr= 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
226                  ztra = zbtr * ( zftu(ji,jj,jk) - zftu(ji-1,jj,jk) + zftv(ji,jj,jk) - zftv(ji,jj-1,jk)  )
227                  tra (ji,jj,jk,jn) = tra (ji,jj,jk,jn) + ztra
228#if defined key_trc_diatrd
229                  IF (luttrd(jn)) trtrd (ji,jj,jk,ikeep(jn),4) = zbtr * ( zftu(ji,jj,jk) - zftu(ji-1,  jj,jk) )
230                  IF (luttrd(jn)) trtrd (ji,jj,jk,ikeep(jn),5) = zbtr * ( zftv(ji,jj,jk) - zftv(ji  ,jj-1,jk) )
231#endif
232               END DO
233            END DO
234#if defined key_trc_diatrd
235#   if defined key_trcldf_eiv
236            DO jj = 2 , jpjm1
237               DO ji = fs_2, fs_jpim1   ! vector opt.
238                  zbtr= 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
239                  ztagu = ( zftug(ji,jj) - zftug(ji-1,jj  ) ) * zbtr
240                  ztagv = ( zftvg(ji,jj) - zftvg(ji  ,jj-1) ) * zbtr
241                  IF (luttrd(jn)) trtrd (ji,jj,jk,ikeep(jn),4) = trtrd(ji,jj,jk,ikeep(jn),4) - ztagu
242                  IF (luttrd(jn)) trtrd (ji,jj,jk,ikeep(jn),5) = trtrd(ji,jj,jk,ikeep(jn),5) - ztagv
243                  IF (luttrd(jn)) trtrd (ji,jj,jk,ikeep(jn),7) = ztagu
244                  IF (luttrd(jn)) trtrd (ji,jj,jk,ikeep(jn),8) = ztagv
245               END DO
246            END DO
247#   endif
248#endif
249            !                                          ! ===============
250         END DO                                        !   End of slab 
251         !                                             ! ===============
252      END DO
253
254      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
255         WRITE(charout, FMT="('ldf - iso/zps')")
256         CALL prt_ctl_trc_info(charout)
257         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
258      ENDIF
259
260   END SUBROUTINE trc_ldf_iso_zps
261
262#else
263   !!----------------------------------------------------------------------
264   !!   default option :   Dummy code   NO rotation of the diffusive tensor
265   !!----------------------------------------------------------------------
266CONTAINS
267   SUBROUTINE trc_ldf_iso_zps( kt )               ! Empty routine
268      INTEGER, INTENT(in) :: kt
269      WRITE(*,*) 'trc_ldf_iso_zps: You should not have seen this print! error?', kt
270   END SUBROUTINE trc_ldf_iso_zps
271#endif
272
273   !!==============================================================================
274END MODULE trcldf_iso_zps
Note: See TracBrowser for help on using the repository browser.