SUBROUTINE trcdta( kt )
!!----------------------------------------------------------------------
!!                   ***  ROUTINE trcdta  ***
!!
!! ** Purpose :   Reads passive tracer data (Levitus monthly data)
!!
!! ** Method  :   Read on unit numtr the interpolated tracer concentra-
!!      tion onto the global grid. Data begin at january. 
!!      The value is centered at the middle of month. 
!!      In the opa model, kt=1 agree with january 1. 
!!      At each time step, a linear interpolation is applied between 
!!      two monthly values.
!!
!! History :
!!   8.2  !  02-04  (O. Aumont)  Original code
!!   9.0  !  04-03  (C. Ethe)    
!!----------------------------------------------------------------------
   !!----------------------------------------------------------------------
   !!  TOP 1.0 , LOCEAN-IPSL (2005)
   !! $Header$
   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
   !!----------------------------------------------------------------------
!! * Modules used
      USE ioipsl
      USE oce_trc
      USE trc 
      USE par_sms
      USE lib_print
!! * Arguments
      INTEGER  kt 
#if  defined key_passivetrc && defined key_trc_dta 
!! * Local declarations
      INTEGER  jn, jl 
 
      INTEGER jpmois, jpf
      PARAMETER (jpmois = 12, jpf = 1 )

      INTEGER imois, iman 
      INTEGER iyy, imm, idd, i15, itime
      CHARACTER*38 clname(jptra)
      INTEGER istep(jpmois)
      REAL  zlon(jpi, jpj), zlat(jpi, jpj)
      REAL  zlev(jpk)
      INTEGER ipi,ipj,ipk
      REAL zdate0, zxy
!!----------------------------------------------------------------------

      DO jn = 1, jptra

         IF( lutini(jn) ) THEN 

            IF ( kt == nit000 ) THEN
!! 3D tracer data
               IF(lwp)WRITE(numout,*)
               IF(lwp)WRITE(numout,*) ' trcdta: reading tracer' 
               IF(lwp)WRITE(numout,*) ' data file ', jn
               IF(lwp)WRITE(numout,*)
               nlectr(jn) = 0
            ENDIF
! Initialization
            iman = jpmois
            iyy  = ndastp/10000
            imm  = (ndastp - iyy*10000)/100
            idd  = (ndastp - iyy*10000 - imm*100)
            i15  = idd/16
            imois = imm + i15 - 1
            IF( imois == 0 ) imois = iman
            itime = jpmois
            ipi = jpi
            ipj = jpj
            ipk = jpk

! First call kt=nit000
            IF ( kt == nit000 .AND. nlectr(jn) == 0 ) THEN
               ntrc1(jn) = 0
               IF(lwp) THEN
                  WRITE(numout,*)
                  WRITE(numout,*) ' Tracer monthly fields' 
                  WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~'
                  WRITE(numout,*) ' NetCDF FORMAT'
                  WRITE(numout,*)
               ENDIF

! open file 
               clname(jn) = 'LEVITUS_'//ctrcnm(jn)
               CALL flinopen(TRIM(clname(jn)),mig(1),nlci,mjg(1),nlcj,
     &                       .FALSE.,ipi,ipj,ipk,zlon,zlat,zlev,itime,
     &                        istep,zdate0,rdt,numtr(jn))

! title, dimensions and tests
               IF( itime /= jpmois ) THEN
                  IF(lwp) THEN
                     WRITE(numout,*) ' '
                     WRITE(numout,*) 'problem with time coordinates'
                     WRITE(numout,*) ' itime ',itime,' jpmois ',jpmois
                  ENDIF
                  STOP 'trc_dta'
               ENDIF
               IF( ipi /= jpidta .AND.  ipj /= jpjdta  
     &                           .AND. ipk /= jpk ) THEN
                  IF(lwp) THEN
                     WRITE(numout,*) ' '
                     WRITE(numout,*) 'problem with dimensions'
                     WRITE(numout,*) ' ipi ',ipi,' jpidta ',jpidta
                     WRITE(numout,*) ' ipj ',ipj,' jpjdta ',jpjdta
                     WRITE(numout,*) ' ipk ',ipk,' jpk ',jpk
                  ENDIF
                  STOP 'trc_dta'
               ENDIF
               IF(lwp)WRITE(numout,*) itime,istep,zdate0,rdt,numtr(jn)
               trdta(:,:,:,jn) = 0.

            ENDIF


! Read montly file
            IF( ( kt == nit000 .AND. nlectr(jn) == 0) 
     &           .OR. imois /= ntrc1(jn) ) THEN
               nlectr(jn) = 1
! Calendar computation

! ntrc1 number of the first file record used in the simulation
! ntrc2 number of the last  file record
               ntrc1(jn) = imois
               ntrc2(jn) = ntrc1(jn) + 1
               ntrc1(jn) = MOD( ntrc1(jn), iman )
               IF ( ntrc1(jn) == 0 ) ntrc1(jn) = iman
               ntrc2(jn) = MOD( ntrc2(jn), iman )
               IF ( ntrc2(jn) == 0 ) ntrc2(jn) = iman
               IF(lwp) WRITE(numout,*) 'first record file used ntrc1 ', 
     &                                 ntrc1(jn)
               IF(lwp) WRITE(numout,*) 'last  record file used ntrc2 ', 
     &                                 ntrc2(jn)

! Read montly passive tracer data Levitus 

               CALL flinget( numtr(jn),ctrcnm(jn),jpidta,jpjdta,jpk,
     &              jpmois,ntrc1(jn),ntrc1(jn),mig(1),nlci,mjg(1),nlcj,
     &              tracdta(1:nlci,1:nlcj,1:jpk,jn,1) )

               CALL flinget( numtr(jn),ctrcnm(jn),jpidta,jpjdta,jpk,
     &              jpmois,ntrc2(jn),ntrc2(jn),mig(1),nlci,mjg(1),nlcj,
     &              tracdta(1:nlci,1:nlcj,1:jpk,jn,2) )

               IF(lwp) THEN
                  WRITE(numout,*)
                  WRITE(numout,*) ' read tracer data ', ctrcnm(jn),' ok'
                  WRITE(numout,*)
               ENDIF
! Apply Mask
               DO jl = 1, 2
                  tracdta(:,:,:  ,jn,jl) = tracdta(:,:,:,jn,jl) 
     &                                   * tmask(:,:,:)
                  tracdta(:,:,jpk,jn,jl) = 0.
               END DO

            ENDIF

            IF(lwp) THEN
               WRITE(numout,*) ctrcnm(jn), 'Levitus month ', ntrc1(jn),
     $             ntrc2(jn)
               WRITE(numout,*)
               WRITE(numout,*) ' Levitus month = ', ntrc1(jn),
     $             '  level = 1'
               CALL prihre( tracdta(1,1,1,jn,1), jpi, jpj, 1, jpi, 20, 1
     $             ,jpj, 20, 1., numout )
               WRITE(numout,*) ' Levitus month = ', ntrc1(jn),
     $             '  level = ',jpk/2
               CALL prihre( tracdta(1,1,jpk/2,jn,1), jpi, jpj, 1, jpi,
     $             20, 1, jpj, 20, 1., numout )
               WRITE(numout,*) ' Levitus month = ',ntrc1(jn)
     $             ,'  level = ',jpkm1
               CALL prihre( tracdta(1,1,jpkm1,jn,1), jpi, jpj, 1, jpi,
     $             20, 1, jpj, 20, 1., numout )
            ENDIF 

! At every time step compute temperature data

            zxy = FLOAT( idd + 15 - 30 * i15 ) / 30.
            trdta(:,:,:,jn)= ( ( 1. - zxy ) * tracdta(:,:,:,jn,1) 
     &                        +       zxy   * tracdta(:,:,:,jn,2) )
   
            IF( jn == jpno3) trdta(:,:,:,jn) = trdta(:,:,:,jn) * 7.6E-6
            IF( jn == jpdic) trdta(:,:,:,jn) = trdta(:,:,:,jn) * 1.E-6
            IF( jn == jptal) trdta(:,:,:,jn) = trdta(:,:,:,jn) * 1.E-6
            IF( jn == jpoxy) trdta(:,:,:,jn) = trdta(:,:,:,jn) * 44.6E-6
            IF( jn == jpsil) trdta(:,:,:,jn) = trdta(:,:,:,jn) * 1.E-6


         ENDIF

      END DO
#else
!      No passive tracer data read
#endif
       RETURN

       END SUBROUTINE trcdta