source: trunk/NEMOGCM/CONFIG/ORCA2_LIM/IDL_scripts/ts_mean_SSH.pro @ 2556

pro ts_mean_SSH, sEXP1, sEXP2, year1, year2, s_iodir_data, POSTSCRIPT = postscript, _extra = ex

  compile_opt idl2, strictarrsubs
  
  @common
  
  @initorca2
  
  if KEYWORD_SET(POSTSCRIPT) then begin
     openps, sEXP1+'_SSH_mean.ps', portrait = 1
  endif
  
  ts_SSH = 0.
  ts_SSH2 = 0.
  ts_Time = 0.

  masknp = read_ncdf('tmaskutil', file = 'mesh_mask_partial.nc', /nostruct)
  
  for year=year1,year2 do begin
     
     date1 = year * 10000L + 101
     date2 = year * 10000L + 1231
     filename = getname(s_iodir_data,sEXP1,'1Y','grid_T',date1)
     filename2 = getname(s_iodir_data,sEXP2,'1Y','grid_T',date1)
     
     SSH = read_ncdf('zos',date1 ,date2 , filename = filename, /nostruct)
     SSH2 = read_ncdf('zos',date1 ,date2 , filename = filename2, /nostruct)

     ts_SSH = [ ts_SSH, moyenne(SSH, 'xy', mask2d = masknp)]
     ts_SSH2 = [ ts_SSH2, moyenne(SSH2, 'xy', mask2d = masknp)]
     ts_Time = [ ts_Time, Time] ; Time = date
     
  endfor
  
  ts_SSH = ts_SSH[1:*]          ; remove first record of 0
  ts_SSH2 = ts_SSH2[1:*]          ; remove first record of 0
  Time = ts_Time[1:*]           ; remove first record of 0
  
  jpt = n_elements(Time)
  
  title = sEXP1+' Global Annual Mean SSH --- year '+strtrim(year1,1)+' - '+strtrim(year2,1)
  pltt,ts_SSH,'t', -.001, .001, year1 * 10000L + 101, year2 * 10000L + 1231 , /REMPLI $
       , small = [1,2,1], YTITLE = 'm', TITLE = title, FORMAT = '(I3)', /PORTRAIT, _extra = ex
  
  if sEXP2 ne sEXP1 then begin
     
     title = sEXP1+' - '+sEXP2+' Global Annual Mean SSH --- year '+strtrim(year1,1)+' - '+strtrim(year2,1)
     pltt, ts_SSH - ts_SSH2,'t', -.0001, .0001, year1 * 10000L + 101, year2 * 10000L + 1231 , /REMPLI, /NOERASE $
           , COLOR = 250, small = [1,2,2], YTITLE = 'm', TITLE = title, FORMAT = '(I3)', /PORTRAIT, _extra = ex
     
  endif
  

 
  if KEYWORD_SET(POSTSCRIPT) then begin
     closeps
  endif


  return
end