source: trunk/NEMOGCM/NEMO/LIM_SRC_2/limistate_2.F90 @ 4990

Last change on this file since 4990 was 4990, checked in by timgraham, 6 years ago

Merged branches/2014/dev_MERGE_2014 back onto the trunk as follows:

In the working copy of branch ran:
svn merge svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/trunk@HEAD
1 conflict in LIM_SRC_3/limdiahsb.F90
Resolved by keeping the version from dev_MERGE_2014 branch
and commited at r4989

In working copy run:
svn switch svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/trunk
to switch working copy

Run:
svn merge —reintegrate svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/branches/2014/dev_MERGE_2014
to merge the branch into the trunk - no conflicts at this stage.

  • Property svn:keywords set to Id
File size: 10.3 KB
Line 
1MODULE limistate_2
2   !!======================================================================
3   !!                     ***  MODULE  limistate_2  ***
4   !!              Initialisation of diagnostics ice variables
5   !!======================================================================
6   !! History :   1.0  !  01-04  (C. Ethe, G. Madec)  Original code
7   !!             2.0  !  03-08  (G. Madec)  add lim_istate_init
8   !!                  !  04-04  (S. Theetten) initialization from a file
9   !!                  !  06-07  (S. Masson)  IOM to read the restart
10   !!                  !  07-10  (G. Madec)  surface module
11   !!--------------------------------------------------------------------
12#if defined key_lim2
13   !!----------------------------------------------------------------------
14   !!   'key_lim2' :                                  LIM 2.0 sea-ice model
15   !!----------------------------------------------------------------------
16   !!   lim_istate_2      :  Initialisation of diagnostics ice variables
17   !!   lim_istate_init_2 :  initialization of ice state and namelist read
18   !!----------------------------------------------------------------------
19   USE phycst
20   USE par_ice_2       ! ice parameters
21   USE dom_ice_2
22   USE eosbn2          ! equation of state
23   USE lbclnk
24   USE oce
25   USE ice_2
26   USE iom
27   USE in_out_manager
28   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC lim_istate_2      ! routine called by lim_init_2.F90
34
35   !                        !! **  namelist (namiceini) **
36   LOGICAL  ::   ln_limini   ! Ice initialization state
37   REAL(wp) ::   ttest       ! threshold water temperature for initial sea ice
38   REAL(wp) ::   hninn       ! initial snow thickness in the north
39   REAL(wp) ::   hginn       ! initial ice thickness in the north
40   REAL(wp) ::   alinn       ! initial leads area in the north
41   REAL(wp) ::   hnins       ! initial snow thickness in the south
42   REAL(wp) ::   hgins       ! initial ice thickness in the south
43   REAL(wp) ::   alins       ! initial leads area in the south
44   
45   REAL(wp) ::   zero      = 0.e0     ! constant value = 0
46   REAL(wp) ::   zone      = 1.e0     ! constant value = 1
47   !!----------------------------------------------------------------------
48   !! NEMO/LIM2 3.3 , UCL - NEMO Consortium (2010)
49   !! $Id$
50   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
51   !!----------------------------------------------------------------------
52CONTAINS
53
54   SUBROUTINE lim_istate_2
55      !!-------------------------------------------------------------------
56      !!                    ***  ROUTINE lim_istate_2  ***
57      !!
58      !! ** Purpose :   defined the sea-ice initial state
59      !!
60      !! ** Method  :   restart from a state defined in a binary file
61      !!                or from arbitrary sea-ice conditions
62      !!--------------------------------------------------------------------
63      INTEGER  ::   ji, jj, jk                ! dummy loop indices
64      REAL(wp) ::   zidto                     ! temporary scalar
65      !--------------------------------------------------------------------
66 
67      CALL lim_istate_init_2     !  reading the initials parameters of the ice
68
69      IF( .NOT. ln_limini ) THEN 
70         
71         tfu(:,:) = eos_fzp( tsn(:,:,1,jp_sal) ) * tmask(:,:,1)       ! freezing/melting point of sea water [Celcius]
72
73         DO jj = 1, jpj
74            DO ji = 1, jpi
75               !                     ! ice if sst <= t-freez + ttest
76               IF( tsn(ji,jj,1,jp_tem)  - tfu(ji,jj) >= ttest ) THEN   ;   zidto = 0.e0      ! no ice
77               ELSE                                                    ;   zidto = 1.e0      !    ice
78               ENDIF
79               !
80               IF( fcor(ji,jj) >= 0.e0 ) THEN     !--  Northern hemisphere.
81                  hicif(ji,jj)   = zidto * hginn
82                  frld(ji,jj)    = zidto * alinn + ( 1.0 - zidto ) * 1.0
83                  hsnif(ji,jj)   = zidto * hninn
84               ELSE                               !---  Southern hemisphere.
85                  hicif(ji,jj)   = zidto * hgins
86                  frld(ji,jj)    = zidto * alins + ( 1.0 - zidto ) * 1.0
87                  hsnif(ji,jj)   = zidto * hnins
88               ENDIF
89            END DO
90         END DO
91
92         tfu(:,:) = tfu(:,:) + rt0       ! ftu converted from Celsius to Kelvin (rt0 over land)
93         
94         sist  (:,:)   = tfu(:,:)
95         tbif  (:,:,1) = tfu(:,:)
96         tbif  (:,:,2) = tfu(:,:)
97         tbif  (:,:,3) = tfu(:,:)
98
99      ENDIF
100     
101      fsbbq (:,:)   = 0.e0
102      qstoif(:,:)   = 0.e0
103      u_ice (:,:)   = 0.e0
104      v_ice (:,:)   = 0.e0
105
106      !---  Moments for advection.             
107
108      sxice (:,:)  = 0.e0   ;   sxsn (:,:)  = 0.e0   ;   sxa  (:,:)  = 0.e0
109      syice (:,:)  = 0.e0   ;   sysn (:,:)  = 0.e0   ;   sya  (:,:)  = 0.e0
110      sxxice(:,:)  = 0.e0   ;   sxxsn(:,:)  = 0.e0   ;   sxxa (:,:)  = 0.e0
111      syyice(:,:)  = 0.e0   ;   syysn(:,:)  = 0.e0   ;   syya (:,:)  = 0.e0
112      sxyice(:,:)  = 0.e0   ;   sxysn(:,:)  = 0.e0   ;   sxya (:,:)  = 0.e0
113
114      sxc0  (:,:)  = 0.e0   ;   sxc1 (:,:)  = 0.e0   ;   sxc2 (:,:)  = 0.e0
115      syc0  (:,:)  = 0.e0   ;   syc1 (:,:)  = 0.e0   ;   syc2 (:,:)  = 0.e0
116      sxxc0 (:,:)  = 0.e0   ;   sxxc1(:,:)  = 0.e0   ;   sxxc2(:,:)  = 0.e0
117      syyc0 (:,:)  = 0.e0   ;   syyc1(:,:)  = 0.e0   ;   syyc2(:,:)  = 0.e0
118      sxyc0 (:,:)  = 0.e0   ;   sxyc1(:,:)  = 0.e0   ;   sxyc2(:,:)  = 0.e0
119
120      sxst  (:,:)  = 0.e0
121      syst  (:,:)  = 0.e0
122      sxxst (:,:)  = 0.e0
123      syyst (:,:)  = 0.e0
124      sxyst (:,:)  = 0.e0
125#if ! defined key_lim2_vp
126      stress1_i (:,:) = 0._wp                          ! EVP rheology
127      stress2_i (:,:) = 0._wp
128      stress12_i(:,:) = 0._wp
129#endif
130
131      !-- lateral boundary conditions
132      CALL lbc_lnk( hicif, 'T', 1. )
133      CALL lbc_lnk( frld , 'T', 1. )
134
135      ! C A U T I O N  frld = 1 over land and lbc_lnk put zero along
136      ! *************  closed boundaries herefore we force to one over land
137      frld(:,:) = tms(:,:) * frld(:,:) + ( 1. - tms(:,:) )   
138
139      CALL lbc_lnk( hsnif, 'T', 1. )
140      CALL lbc_lnk( sist , 'T', 1. , pval = rt0 )      ! set rt0 on closed boundary (required by bulk formulation)
141      DO jk = 1, jplayersp1
142         CALL lbc_lnk(tbif(:,:,jk), 'T', 1. )
143      END DO
144      CALL lbc_lnk( fsbbq  , 'T', 1. )
145      CALL lbc_lnk( qstoif , 'T', 1. )
146
147   END SUBROUTINE lim_istate_2
148
149   
150   SUBROUTINE lim_istate_init_2
151      !!-------------------------------------------------------------------
152      !!                   ***  ROUTINE lim_istate_init_2  ***
153      !!       
154      !! ** Purpose :   Definition of initial state of the ice
155      !!
156      !! ** Method  :   Read the namiceini namelist and check the parameter
157      !!       values called at the first timestep (nit000)
158      !!
159      !! ** input   :   Namelist namiceini
160      !!-------------------------------------------------------------------
161      INTEGER :: inum_ice
162      INTEGER :: ji,jj
163      INTEGER :: ios                 ! Local integer output status for namelist read
164
165      NAMELIST/namiceini/ ln_limini, ttest, hninn, hginn, alinn, &
166         &                hnins, hgins, alins
167      !!-------------------------------------------------------------------
168                   
169      REWIND( numnam_ice_ref )              ! Namelist namiceini in reference namelist : Ice initial state
170      READ  ( numnam_ice_ref, namiceini, IOSTAT = ios, ERR = 901)
171901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namiceini in reference namelist', lwp )
172
173      REWIND( numnam_ice_cfg )              ! Namelist namiceini in configuration namelist : Ice initial state
174      READ  ( numnam_ice_cfg, namiceini, IOSTAT = ios, ERR = 902 )
175902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namiceini in configuration namelist', lwp )
176      IF(lwm) WRITE ( numoni, namiceini )
177      !
178      IF(lwp) THEN
179         WRITE(numout,*)
180         WRITE(numout,*) 'lim_istate_init_2 : ice parameters inititialisation '
181         WRITE(numout,*) '~~~~~~~~~~~~~~~~~'
182         WRITE(numout,*) '         threshold water temp. for initial sea-ice    ttest      = ', ttest
183         WRITE(numout,*) '         initial snow thickness in the north          hninn      = ', hninn
184         WRITE(numout,*) '         initial ice thickness in the north           hginn      = ', hginn 
185         WRITE(numout,*) '         initial leads area in the north              alinn      = ', alinn           
186         WRITE(numout,*) '         initial snow thickness in the south          hnins      = ', hnins 
187         WRITE(numout,*) '         initial ice thickness in the south           hgins      = ', hgins
188         WRITE(numout,*) '         initial leads area in the south              alins      = ', alins
189         WRITE(numout,*) '         Ice state initialization using input file    ln_limini  = ', ln_limini
190      ENDIF
191
192      IF( ln_limini ) THEN                      ! Ice initialization using input file
193         !
194         CALL iom_open( 'Ice_initialization.nc', inum_ice )
195         !
196         IF( inum_ice > 0 ) THEN
197            IF(lwp) WRITE(numout,*)
198            IF(lwp) WRITE(numout,*) '                  ice state initialization with : Ice_initialization.nc'
199           
200            CALL iom_get( inum_ice, jpdom_data, 'hicif', hicif )     
201            CALL iom_get( inum_ice, jpdom_data, 'hsnif', hsnif )     
202            CALL iom_get( inum_ice, jpdom_data, 'frld' , frld  )     
203            CALL iom_get( inum_ice, jpdom_data, 'ts'   , sist  )
204            CALL iom_get( inum_ice, jpdom_unknown, 'tbif', tbif(1:nlci,1:nlcj,:),   &
205                 &        kstart = (/ mig(1),mjg(1),1 /), kcount = (/ nlci,nlcj,jplayersp1 /) )
206            ! put some values in the extra-halo...
207            DO jj = nlcj+1, jpj   ;   tbif(1:nlci,jj,:) = tbif(1:nlci,nlej,:)   ;   END DO
208            DO ji = nlci+1, jpi   ;   tbif(ji    ,: ,:) = tbif(nlei  ,:   ,:)   ;   END DO
209
210            CALL iom_close( inum_ice)
211            !
212         ENDIF
213      ENDIF
214      !     
215   END SUBROUTINE lim_istate_init_2
216
217#else
218   !!----------------------------------------------------------------------
219   !!   Default option :         Empty module      NO LIM 2.0 sea-ice model
220   !!----------------------------------------------------------------------
221CONTAINS
222   SUBROUTINE lim_istate_2        ! Empty routine
223   END SUBROUTINE lim_istate_2
224#endif
225
226   !!======================================================================
227END MODULE limistate_2
Note: See TracBrowser for help on using the repository browser.