New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limmsh_2.F90 in trunk/NEMOGCM/NEMO/LIM_SRC_2 – NEMO

source: trunk/NEMOGCM/NEMO/LIM_SRC_2/limmsh_2.F90 @ 3319

Last change on this file since 3319 was 3294, checked in by rblod, 12 years ago

Merge of 3.4beta into the trunk

  • Property svn:keywords set to Id
File size: 12.3 KB
Line 
1MODULE limmsh_2
2   !!======================================================================
3   !!                     ***  MODULE  limmsh_2  ***
4   !! LIM 2.0 ice model :   definition of the ice mesh parameters
5   !!======================================================================
6   !! History :   -   ! 2001-04 (LIM) original code
7   !!            1.0  ! 2002-08 (C. Ethe, G. Madec) F90, module
8   !!            3.3  ! 2009-05 (G. Garric, C. Bricaud) addition of the lim2_evp case
9   !!----------------------------------------------------------------------
10#if defined key_lim2
11   !!----------------------------------------------------------------------
12   !!   'key_lim2'                                     LIM 2.0sea-ice model
13   !!----------------------------------------------------------------------
14   !!   lim_msh_2   : definition of the ice mesh
15   !!----------------------------------------------------------------------
16   USE phycst
17   USE dom_oce
18   USE dom_ice_2
19   USE lbclnk
20   USE in_out_manager
21   USE lib_mpp          ! MPP library
22#if defined key_lim2_vp
23   USE wrk_nemo         ! work arrays
24#endif
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC lim_msh_2      ! routine called by ice_ini_2.F90
30
31   !!----------------------------------------------------------------------
32   !! NEMO/LIM2 3.3 , UCL - NEMO Consortium (2010)
33   !! $Id$
34   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
35   !!----------------------------------------------------------------------
36CONTAINS
37
38   SUBROUTINE lim_msh_2
39      !!-------------------------------------------------------------------
40      !!                  ***  ROUTINE lim_msh_2  ***
41      !!             
42      !! ** Purpose : Definition of the charact. of the numerical grid
43      !!       
44      !! ** Action  : - Initialisation of some variables
45      !!              - Definition of some constants linked with the grid
46      !!              - Definition of the metric coef. for the sea/ice
47      !!              - Initialization of the ice masks (tmsk, umsk)
48      !!
49      !! ** Refer.  : Deleersnijder et al. Ocean Modelling 100, 7-10
50      !!---------------------------------------------------------------------
51      INTEGER :: ji, jj      ! dummy loop indices
52      REAL(wp) ::   zusden   ! local scalars
53#if defined key_lim2_vp
54      REAL(wp) ::   zusden2           ! local scalars
55      REAL(wp) ::   zh1p  , zh2p      !   -      -
56      REAL(wp) ::   zd2d1p, zd1d2p    !   -      -
57      REAL(wp), POINTER, DIMENSION(:,:) ::   zd2d1, zd1d2   ! 2D workspace
58#endif
59      !!---------------------------------------------------------------------
60
61#if defined key_lim2_vp
62      CALL wrk_alloc( jpi, jpj, zd2d1, zd1d2 )
63#endif
64
65      IF(lwp) THEN
66         WRITE(numout,*)
67         WRITE(numout,*) 'lim_msh_2 : LIM 2.0 sea-ice model, mesh initialization'
68         WRITE(numout,*) '~~~~~~~~~'
69      ENDIF
70     
71      IF( jphgr_msh == 2 .OR. jphgr_msh == 3 .OR. jphgr_msh == 5 )   &
72          &      CALL ctl_stop(' Coriolis parameter in LIM not set for f- or beta-plane' )
73
74      !----------------------------------------------------------                         
75      !    Initialization of local and some global (common) variables
76      !------------------------------------------------------------------
77     
78      njeq   = INT( jpj / 2 )   !i bug mpp potentiel
79      njeqm1 = njeq - 1 
80
81      fcor(:,:) = 2. * omega * SIN( gphit(:,:) * rad )   !  coriolis factor at T-point
82 
83!i    DO jj = 1, jpj
84!i       zmsk(jj) = SUM( tmask(:,jj,:) )   ! = 0          if land  everywhere on a j-line
85!!ii     write(numout,*) jj, zind(jj)
86!i    END DO
87
88      IF( fcor(1,1) * fcor(1,nlcj) < 0.e0 ) THEN   ! local domain include both hemisphere
89         l_jeq = .TRUE.
90         njeq  = 1
91         DO WHILE ( njeq <= jpj .AND. fcor(1,njeq) < 0.e0 )
92            njeq = njeq + 1
93         END DO
94         IF(lwp ) WRITE(numout,*) '          the equator is inside the domain at about njeq = ', njeq
95      ELSEIF( fcor(1,1) < 0.e0 ) THEN
96         l_jeq = .FALSE.
97         njeq = jpj
98         IF(lwp ) WRITE(numout,*) '          the model domain is entirely in the southern hemisphere: njeq = ', njeq
99      ELSE
100         l_jeq = .FALSE.
101         njeq = 2
102         IF(lwp ) WRITE(numout,*) '          the model domain is entirely in the northern hemisphere: njeq = ', njeq
103      ENDIF
104
105      njeqm1 = njeq - 1
106
107
108      !   For each grid, definition of geometric tables
109      !------------------------------------------------------------------
110     
111      !-------------------
112      ! Conventions :    !
113      !-------------------
114      !  indices 1 \ 2 <-> localisation in the 2 direction x \ y
115      !  3rd indice <-> localisation on the mesh :
116      !  0 = Centre ;  1 = corner W x(i-1/2) ; 2 = corner S y(j-1/2) ;
117      !  3 = corner SW x(i-1/2),y(j-1/2)
118      !-------------------
119!!ibug ???
120      wght(:,:,:,:) = 0.e0
121      tmu(:,:)      = 0.e0
122#if defined key_lim2_vp 
123      akappa(:,:,:,:)     = 0.e0
124      alambd(:,:,:,:,:,:) = 0.e0
125#else
126      tmv(:,:) = 0.e0
127      tmf(:,:) = 0.e0
128#endif
129!!i
130     
131
132#if defined key_lim2_vp     
133      ! metric coefficients for sea ice dynamic
134      !----------------------------------------
135      !                                                       ! akappa
136      DO jj = 2, jpj
137         zd1d2(:,jj) = e1v(:,jj) - e1v(:,jj-1)
138      END DO
139      CALL lbc_lnk( zd1d2, 'T', -1. )
140
141      DO ji = 2, jpi
142         zd2d1(ji,:) = e2u(ji,:) - e2u(ji-1,:)
143      END DO
144      CALL lbc_lnk( zd2d1, 'T', -1. )
145
146      akappa(:,:,1,1) =        1.0 / ( 2.0 * e1t(:,:) )
147      akappa(:,:,1,2) = zd1d2(:,:) / ( 4.0 * e1t(:,:) * e2t(:,:) )
148      akappa(:,:,2,1) = zd2d1(:,:) / ( 4.0 * e1t(:,:) * e2t(:,:) )
149      akappa(:,:,2,2) =        1.0 / ( 2.0 * e2t(:,:) )
150     
151      !                                                      ! weights (wght)
152      DO jj = 2, jpj
153         DO ji = 2, jpi
154            zusden = 1. / (  ( e1t(ji,jj) + e1t(ji-1,jj  ) )   &
155               &           * ( e2t(ji,jj) + e2t(ji  ,jj-1) ) )
156            wght(ji,jj,1,1) = zusden * e1t(ji  ,jj) * e2t(ji,jj  )
157            wght(ji,jj,1,2) = zusden * e1t(ji  ,jj) * e2t(ji,jj-1)
158            wght(ji,jj,2,1) = zusden * e1t(ji-1,jj) * e2t(ji,jj  )
159            wght(ji,jj,2,2) = zusden * e1t(ji-1,jj) * e2t(ji,jj-1)
160         END DO
161      END DO
162      CALL lbc_lnk( wght(:,:,1,1), 'I', 1. )      ! CAUTION: even with the lbc_lnk at ice U-V-point
163      CALL lbc_lnk( wght(:,:,1,2), 'I', 1. )      ! the value of wght at jpj is wrong
164      CALL lbc_lnk( wght(:,:,2,1), 'I', 1. )      ! but it is never used
165      CALL lbc_lnk( wght(:,:,2,2), 'I', 1. )
166#else
167      ! metric coefficients for sea ice dynamic (EVP rheology)
168      !----------------------------------------
169      DO jj = 1, jpjm1                                       ! weights (wght) at F-points
170         DO ji = 1, jpim1
171            zusden = 1. / (  ( e1t(ji+1,jj  ) + e1t(ji,jj) )   &
172               &           * ( e2t(ji  ,jj+1) + e2t(ji,jj) ) ) 
173            wght(ji,jj,1,1) = zusden * e1t(ji+1,jj) * e2t(ji,jj+1)
174            wght(ji,jj,1,2) = zusden * e1t(ji+1,jj) * e2t(ji,jj  )
175            wght(ji,jj,2,1) = zusden * e1t(ji  ,jj) * e2t(ji,jj+1)
176            wght(ji,jj,2,2) = zusden * e1t(ji  ,jj) * e2t(ji,jj  )
177         END DO
178      END DO
179      CALL lbc_lnk( wght(:,:,1,1), 'F', 1. )   ;   CALL lbc_lnk( wght(:,:,1,2),'F', 1. )       ! lateral boundary cond.   
180      CALL lbc_lnk( wght(:,:,2,1), 'F', 1. )   ;   CALL lbc_lnk( wght(:,:,2,2),'F', 1. )
181#endif
182   
183      ! Coefficients for divergence of the stress tensor
184      !-------------------------------------------------
185
186#if defined key_lim2_vp
187      DO jj = 2, jpj
188         DO ji = 2, jpi   ! NO vector opt.
189            zh1p  =  e1t(ji  ,jj  ) * wght(ji,jj,2,2)   &
190               &   + e1t(ji-1,jj  ) * wght(ji,jj,1,2)   &
191               &   + e1t(ji  ,jj-1) * wght(ji,jj,2,1)   &
192               &   + e1t(ji-1,jj-1) * wght(ji,jj,1,1)
193
194            zh2p  =  e2t(ji  ,jj  ) * wght(ji,jj,2,2)   &
195               &   + e2t(ji-1,jj  ) * wght(ji,jj,1,2)   &
196               &   + e2t(ji  ,jj-1) * wght(ji,jj,2,1)   &
197               &   + e2t(ji-1,jj-1) * wght(ji,jj,1,1)
198
199! better written but change the last digit and thus solver in less than 100 timestep
200!           zh1p  = e1t(ji-1,jj  ) * wght(ji,jj,1,2) + e1t(ji,jj  ) * wght(ji,jj,2,2)   &
201!              &  + e1t(ji-1,jj-1) * wght(ji,jj,1,1) + e1t(ji,jj-1) * wght(ji,jj,2,1)
202
203!           zh2p  = e2t(ji-1,jj  ) * wght(ji,jj,1,2) + e2t(ji,jj  ) * wght(ji,jj,2,2)   &
204!              &  + e2t(ji-1,jj-1) * wght(ji,jj,1,1) + e2t(ji,jj-1) * wght(ji,jj,2,1)
205
206!!ibug =0   zusden = 1.0 / ( zh1p * zh2p * 4.e0 )
207            zusden = 1.0 / MAX( zh1p * zh2p * 4.e0 , 1.e-20 )
208            zusden2 = zusden * 2.0 
209
210            zd1d2p = zusden * 0.5 * ( -e1t(ji-1,jj-1) + e1t(ji-1,jj  ) - e1t(ji,jj-1) + e1t(ji  ,jj)   )
211            zd2d1p = zusden * 0.5 * (  e2t(ji  ,jj-1) - e2t(ji-1,jj-1) + e2t(ji,jj  ) - e2t(ji-1,jj)   )
212
213            alambd(ji,jj,2,2,2,1) = zusden2 * e2t(ji  ,jj-1)
214            alambd(ji,jj,2,2,2,2) = zusden2 * e2t(ji  ,jj  )
215            alambd(ji,jj,2,2,1,1) = zusden2 * e2t(ji-1,jj-1)
216            alambd(ji,jj,2,2,1,2) = zusden2 * e2t(ji-1,jj  )
217
218            alambd(ji,jj,1,1,2,1) = zusden2 * e1t(ji  ,jj-1)
219            alambd(ji,jj,1,1,2,2) = zusden2 * e1t(ji  ,jj  )
220            alambd(ji,jj,1,1,1,1) = zusden2 * e1t(ji-1,jj-1)
221            alambd(ji,jj,1,1,1,2) = zusden2 * e1t(ji-1,jj  )
222
223            alambd(ji,jj,1,2,2,1) = zd1d2p
224            alambd(ji,jj,1,2,2,2) = zd1d2p
225            alambd(ji,jj,1,2,1,1) = zd1d2p
226            alambd(ji,jj,1,2,1,2) = zd1d2p
227
228            alambd(ji,jj,2,1,2,1) = zd2d1p
229            alambd(ji,jj,2,1,2,2) = zd2d1p
230            alambd(ji,jj,2,1,1,1) = zd2d1p
231            alambd(ji,jj,2,1,1,2) = zd2d1p
232         END DO
233      END DO
234
235      CALL lbc_lnk( alambd(:,:,2,2,2,1), 'I', 1. )      ! CAUTION: even with the lbc_lnk at ice U-V point
236      CALL lbc_lnk( alambd(:,:,2,2,2,2), 'I', 1. )      ! the value of wght at jpj is wrong
237      CALL lbc_lnk( alambd(:,:,2,2,1,1), 'I', 1. )      ! but it is never used
238      CALL lbc_lnk( alambd(:,:,2,2,1,2), 'I', 1. )      !
239
240      CALL lbc_lnk( alambd(:,:,1,1,2,1), 'I', 1. )      ! CAUTION: idem
241      CALL lbc_lnk( alambd(:,:,1,1,2,2), 'I', 1. )      !
242      CALL lbc_lnk( alambd(:,:,1,1,1,1), 'I', 1. )      !
243      CALL lbc_lnk( alambd(:,:,1,1,1,2), 'I', 1. )      !
244
245      CALL lbc_lnk( alambd(:,:,1,2,2,1), 'I', 1. )      ! CAUTION: idem
246      CALL lbc_lnk( alambd(:,:,1,2,2,2), 'I', 1. )      !
247      CALL lbc_lnk( alambd(:,:,1,2,1,1), 'I', 1. )      !
248      CALL lbc_lnk( alambd(:,:,1,2,1,2), 'I', 1. )      !
249
250      CALL lbc_lnk( alambd(:,:,2,1,2,1), 'I', 1. )      ! CAUTION: idem
251      CALL lbc_lnk( alambd(:,:,2,1,2,2), 'I', 1. )      !
252      CALL lbc_lnk( alambd(:,:,2,1,1,1), 'I', 1. )      !
253      CALL lbc_lnk( alambd(:,:,2,1,1,2), 'I', 1. )      !
254#endif
255           
256
257      ! Initialization of ice masks
258      !----------------------------
259     
260      tms(:,:) = tmask(:,:,1)      ! ice T-point  : use surface tmask
261
262#if defined key_lim2_vp
263      ! VP rheology : ice velocity point is I-point
264!i here we can use umask with a i and j shift of -1,-1
265      tmu(:,1) = 0.e0
266      tmu(1,:) = 0.e0
267      DO jj = 2, jpj               ! ice U.V-point: computed from ice T-point mask
268         DO ji = 2, jpim1   ! NO vector opt.
269            tmu(ji,jj) =  tms(ji,jj) * tms(ji-1,jj) * tms(ji,jj-1) * tms(ji-1,jj-1)           
270         END DO
271      END DO
272      CALL lbc_lnk( tmu(:,:), 'I', 1. )      !--lateral boundary conditions   
273#else
274      ! EVP rheology : ice velocity point are U- & V-points ; ice vorticity
275      ! point is F-point
276      tmu(:,:) = umask(:,:,1)
277      tmv(:,:) = vmask(:,:,1)
278      tmf(:,:) = 0.e0                        ! used of fmask except its special value along the coast (rn_shlat)
279      WHERE( fmask(:,:,1) == 1.e0 )   tmf(:,:) = 1.e0
280#endif
281      !
282      ! unmasked and masked area of T-grid cell
283      area(:,:) = e1t(:,:) * e2t(:,:)
284      !
285#if defined key_lim2_vp
286      CALL wrk_dealloc( jpi, jpj, zd2d1, zd1d2 )
287#endif
288      !
289   END SUBROUTINE lim_msh_2
290
291#else
292   !!----------------------------------------------------------------------
293   !!   Default option            Dummy Module         NO LIM sea-ice model
294   !!----------------------------------------------------------------------
295CONTAINS
296   SUBROUTINE lim_msh_2           ! Dummy routine
297   END SUBROUTINE lim_msh_2
298#endif
299
300   !!======================================================================
301END MODULE limmsh_2
Note: See TracBrowser for help on using the repository browser.