New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limitd_th.F90 in trunk/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: trunk/NEMOGCM/NEMO/LIM_SRC_3/limitd_th.F90 @ 2715

Last change on this file since 2715 was 2715, checked in by rblod, 13 years ago

First attempt to put dynamic allocation on the trunk
  • Property svn:keywords set to Id
File size: 44.1 KB
Line 
1MODULE limitd_th
2   !!======================================================================
3   !!                       ***  MODULE limitd_th ***
4   !!              Thermodynamics of ice thickness distribution
5   !!                   computation of changes in g(h)     
6   !!======================================================================
7   !! History :   -   !          (W. H. Lipscomb and E.C. Hunke) CICE (c) original code
8   !!            3.0  ! 2005-12  (M. Vancoppenolle) adaptation to LIM-3
9   !!             -   ! 2006-06  (M. Vancoppenolle) adaptation to include salt, age and types
10   !!             -   ! 2007-04  (M. Vancoppenolle) Mass conservation checked
11   !!----------------------------------------------------------------------
12#if defined key_lim3
13   !!----------------------------------------------------------------------
14   !!   'key_lim3' :                                   LIM3 sea-ice model
15   !!----------------------------------------------------------------------
16   !!   lim_itd_th       : thermodynamics of ice thickness distribution
17   !!   lim_itd_th_rem   :
18   !!   lim_itd_th_reb   :
19   !!   lim_itd_fitline  :
20   !!   lim_itd_shiftice :
21   !!----------------------------------------------------------------------
22   USE dom_ice          ! LIM-3 domain
23   USE par_oce          ! ocean parameters
24   USE dom_oce          ! ocean domain
25   USE phycst           ! physical constants (ocean directory)
26   USE thd_ice          ! LIM-3 thermodynamic variables
27   USE ice              ! LIM-3 variables
28   USE par_ice          ! LIM-3 parameters
29   USE limthd_lac       ! LIM-3 lateral accretion
30   USE limvar           ! LIM-3 variables
31   USE limcons          ! LIM-3 conservation
32   USE prtctl           ! Print control
33   USE in_out_manager   ! I/O manager
34   USE lib_mpp          ! MPP library
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   lim_itd_th        ! called by ice_stp
40   PUBLIC   lim_itd_th_rem
41   PUBLIC   lim_itd_th_reb
42   PUBLIC   lim_itd_fitline
43   PUBLIC   lim_itd_shiftice
44
45   REAL(wp) ::   epsi20 = 1e-20_wp   ! constant values
46   REAL(wp) ::   epsi13 = 1e-13_wp   !
47   REAL(wp) ::   epsi10 = 1e-10_wp   !
48
49   !!----------------------------------------------------------------------
50   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2010)
51   !! $Id$
52   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
53   !!----------------------------------------------------------------------
54CONTAINS
55
56   SUBROUTINE lim_itd_th( kt )
57      !!------------------------------------------------------------------
58      !!                ***  ROUTINE lim_itd_th ***
59      !!
60      !! ** Purpose :   computes the thermodynamics of ice thickness distribution
61      !!
62      !! ** Method  :
63      !!------------------------------------------------------------------
64      INTEGER, INTENT(in) ::   kt   ! time step index
65      !
66      INTEGER ::   jl, ja, jm, jbnd1, jbnd2   ! ice types    dummy loop index         
67
68      !!------------------------------------------------------------------
69
70      IF( kt == nit000 .AND. lwp ) THEN
71         WRITE(numout,*)
72         WRITE(numout,*) 'lim_itd_th  : Thermodynamics of the ice thickness distribution'
73         WRITE(numout,*) '~~~~~~~~~~~'
74      ENDIF
75
76      !------------------------------------------------------------------------------|
77      !  1) Transport of ice between thickness categories.                           |
78      !------------------------------------------------------------------------------|
79      ! Given thermodynamic growth rates, transport ice between
80      ! thickness categories.
81      DO jm = 1, jpm
82         jbnd1 = ice_cat_bounds(jm,1)
83         jbnd2 = ice_cat_bounds(jm,2)
84         IF( ice_ncat_types(jm) > 1 )   CALL lim_itd_th_rem( jbnd1, jbnd2, jm, kt )
85      END DO
86      !
87      CALL lim_var_glo2eqv    ! only for info
88      CALL lim_var_agg(1)
89
90      !------------------------------------------------------------------------------|
91      !  3) Add frazil ice growing in leads.
92      !------------------------------------------------------------------------------|
93
94      CALL lim_thd_lac
95      CALL lim_var_glo2eqv    ! only for info
96
97      !----------------------------------------------------------------------------------------
98      !  4) Computation of trend terms and get back to old values     
99      !----------------------------------------------------------------------------------------
100
101      !- Trend terms
102      d_a_i_thd (:,:,:)  = a_i(:,:,:)   - old_a_i(:,:,:) 
103      d_v_s_thd (:,:,:)  = v_s(:,:,:)   - old_v_s(:,:,:)
104      d_v_i_thd (:,:,:)  = v_i(:,:,:)   - old_v_i(:,:,:) 
105      d_e_s_thd(:,:,:,:) = e_s(:,:,:,:) - old_e_s(:,:,:,:) 
106      d_e_i_thd(:,:,:,:) = e_i(:,:,:,:) - old_e_i(:,:,:,:)
107
108      d_smv_i_thd(:,:,:) = 0._wp
109      IF( num_sal == 2 .OR. num_sal == 4 )   d_smv_i_thd(:,:,:) = smv_i(:,:,:) - old_smv_i(:,:,:)
110
111      IF(ln_ctl) THEN   ! Control print
112         CALL prt_ctl_info(' ')
113         CALL prt_ctl_info(' - Cell values : ')
114         CALL prt_ctl_info('   ~~~~~~~~~~~~~ ')
115         CALL prt_ctl(tab2d_1=area , clinfo1=' lim_itd_th  : cell area :')
116         CALL prt_ctl(tab2d_1=at_i , clinfo1=' lim_itd_th  : at_i      :')
117         CALL prt_ctl(tab2d_1=vt_i , clinfo1=' lim_itd_th  : vt_i      :')
118         CALL prt_ctl(tab2d_1=vt_s , clinfo1=' lim_itd_th  : vt_s      :')
119         DO jl = 1, jpl
120            CALL prt_ctl_info(' ')
121            CALL prt_ctl_info(' - Category : ', ivar1=jl)
122            CALL prt_ctl_info('   ~~~~~~~~~~')
123            CALL prt_ctl(tab2d_1=a_i   (:,:,jl)   , clinfo1= ' lim_itd_th  : a_i      : ')
124            CALL prt_ctl(tab2d_1=ht_i  (:,:,jl)   , clinfo1= ' lim_itd_th  : ht_i     : ')
125            CALL prt_ctl(tab2d_1=ht_s  (:,:,jl)   , clinfo1= ' lim_itd_th  : ht_s     : ')
126            CALL prt_ctl(tab2d_1=v_i   (:,:,jl)   , clinfo1= ' lim_itd_th  : v_i      : ')
127            CALL prt_ctl(tab2d_1=v_s   (:,:,jl)   , clinfo1= ' lim_itd_th  : v_s      : ')
128            CALL prt_ctl(tab2d_1=e_s   (:,:,1,jl) , clinfo1= ' lim_itd_th  : e_s      : ')
129            CALL prt_ctl(tab2d_1=t_su  (:,:,jl)   , clinfo1= ' lim_itd_th  : t_su     : ')
130            CALL prt_ctl(tab2d_1=t_s   (:,:,1,jl) , clinfo1= ' lim_itd_th  : t_snow   : ')
131            CALL prt_ctl(tab2d_1=sm_i  (:,:,jl)   , clinfo1= ' lim_itd_th  : sm_i     : ')
132            CALL prt_ctl(tab2d_1=smv_i (:,:,jl)   , clinfo1= ' lim_itd_th  : smv_i    : ')
133            DO ja = 1, nlay_i
134               CALL prt_ctl_info(' ')
135               CALL prt_ctl_info(' - Layer : ', ivar1=ja)
136               CALL prt_ctl_info('   ~~~~~~~')
137               CALL prt_ctl(tab2d_1=t_i(:,:,ja,jl) , clinfo1= ' lim_itd_th  : t_i      : ')
138               CALL prt_ctl(tab2d_1=e_i(:,:,ja,jl) , clinfo1= ' lim_itd_th  : e_i      : ')
139            END DO
140         END DO
141      ENDIF
142
143      !- Recover Old values
144      a_i(:,:,:)   = old_a_i (:,:,:)
145      v_s(:,:,:)   = old_v_s (:,:,:)
146      v_i(:,:,:)   = old_v_i (:,:,:)
147      e_s(:,:,:,:) = old_e_s (:,:,:,:)
148      e_i(:,:,:,:) = old_e_i (:,:,:,:)
149      !
150      IF( num_sal == 2 .OR. num_sal == 4 )   smv_i(:,:,:)       = old_smv_i (:,:,:)
151      !
152   END SUBROUTINE lim_itd_th
153   !
154
155   SUBROUTINE lim_itd_th_rem( klbnd, kubnd, ntyp, kt )
156      !!------------------------------------------------------------------
157      !!                ***  ROUTINE lim_itd_th_rem ***
158      !!
159      !! ** Purpose :   computes the redistribution of ice thickness
160      !!              after thermodynamic growth of ice thickness
161      !!
162      !! ** Method  : Linear remapping
163      !!
164      !! References : W.H. Lipscomb, JGR 2001
165      !!------------------------------------------------------------------
166      INTEGER , INTENT (in) ::   klbnd   ! Start thickness category index point
167      INTEGER , INTENT (in) ::   kubnd   ! End point on which the  the computation is applied
168      INTEGER , INTENT (in) ::   ntyp    ! Number of the type used
169      INTEGER , INTENT (in) ::   kt      ! Ocean time step
170      !
171      INTEGER  ::   ji, jj, jl     ! dummy loop index
172      INTEGER  ::   zji, zjj, nd   ! local integer
173      REAL(wp) ::   zx1, zwk1, zdh0, zetamin, zdamax   ! local scalars
174      REAL(wp) ::   zx2, zwk2, zda0, zetamax, zhimin   !   -      -
175      REAL(wp) ::   zx3,             zareamin, zindb   !   -      -
176      CHARACTER (len = 15) :: fieldid
177
178      INTEGER , DIMENSION(jpi,jpj,jpl-1) ::   zdonor   ! donor category index
179
180      REAL(wp), DIMENSION(jpi,jpj,jpl) :: &
181         zdhice           ,  &  ! ice thickness increment
182         g0               ,  &  ! coefficients for fitting the line of the ITD
183         g1               ,  &  ! coefficients for fitting the line of the ITD
184         hL               ,  &  ! left boundary for the ITD for each thickness
185         hR               ,  &  ! left boundary for the ITD for each thickness
186         zht_i_o          ,  &  ! old ice thickness
187         dummy_es
188
189      REAL(wp), DIMENSION(jpi,jpj,jpl-1) ::   zdaice, zdvice   ! local increment of ice area and volume
190
191      REAL(wp), DIMENSION(jpi,jpj,0:jpl) ::   zhbnew           ! new boundaries of ice categories
192
193
194      REAL, DIMENSION(1:(jpi+1)*(jpj+1)) ::   zvetamin, zvetamax     ! maximum values for etas
195
196      INTEGER, DIMENSION(1:(jpi+1)*(jpj+1)) ::   nind_i, nind_j  ! compressed indices for i/j directions
197
198      INTEGER ::   nbrem             ! number of cells with ice to transfer
199
200      LOGICAL, DIMENSION(jpi,jpj) ::   zremap_flag             ! compute remapping or not ????
201
202      REAL(wp)  ::   zslope                 ! used to compute local thermodynamic "speeds"
203
204      REAL(wp), DIMENSION(jpi,jpj) ::   zhb0, zhb1             ! category boundaries for thinnes categories
205      REAL(wp), DIMENSION(jpi,jpj) ::   vt_i_init, vt_i_final   !  ice volume summed over categories
206      REAL(wp), DIMENSION(jpi,jpj) ::   vt_s_init, vt_s_final   !  snow volume summed over categories
207      REAL(wp), DIMENSION(jpi,jpj) ::   et_i_init, et_i_final   !  ice energy summed over categories
208      REAL(wp), DIMENSION(jpi,jpj) ::   et_s_init, et_s_final   !  snow energy summed over categories
209      !!------------------------------------------------------------------
210
211      zhimin   = 0.1      !minimum ice thickness tolerated by the model
212      zareamin = epsi10   !minimum area in thickness categories tolerated by the conceptors of the model
213
214      !!----------------------------------------------------------------------------------------------
215      !! 0) Conservation checkand changes in each ice category
216      !!----------------------------------------------------------------------------------------------
217      IF( con_i ) THEN
218         CALL lim_column_sum (jpl,   v_i, vt_i_init)
219         CALL lim_column_sum (jpl,   v_s, vt_s_init)
220         CALL lim_column_sum_energy (jpl, nlay_i,   e_i, et_i_init)
221         dummy_es(:,:,:) = e_s(:,:,1,:)
222         CALL lim_column_sum (jpl, dummy_es(:,:,:) , et_s_init)
223      ENDIF
224
225      !!----------------------------------------------------------------------------------------------
226      !! 1) Compute thickness and changes in each ice category
227      !!----------------------------------------------------------------------------------------------
228      IF( kt == nit000 .AND. lwp) THEN
229         WRITE(numout,*)
230         WRITE(numout,*) 'lim_itd_th_rem  : Remapping the ice thickness distribution'
231         WRITE(numout,*) '~~~~~~~~~~~~~~~'
232         WRITE(numout,*) ' klbnd :       ', klbnd
233         WRITE(numout,*) ' kubnd :       ', kubnd
234         WRITE(numout,*) ' ntyp  :       ', ntyp 
235      ENDIF
236
237      zdhice(:,:,:) = 0._wp
238      DO jl = klbnd, kubnd
239         DO jj = 1, jpj
240            DO ji = 1, jpi
241               zindb             = 1.0-MAX(0.0,SIGN(1.0,-a_i(ji,jj,jl)))     !0 if no ice and 1 if yes
242               ht_i(ji,jj,jl)    = v_i(ji,jj,jl) / MAX(a_i(ji,jj,jl),epsi10) * zindb
243               zindb             = 1.0-MAX(0.0,SIGN(1.0,-old_a_i(ji,jj,jl))) !0 if no ice and 1 if yes
244               zht_i_o(ji,jj,jl) = old_v_i(ji,jj,jl) / MAX(old_a_i(ji,jj,jl),epsi10) * zindb
245               IF( a_i(ji,jj,jl) > 1e-6 )   zdhice(ji,jj,jl) = ht_i(ji,jj,jl) - zht_i_o(ji,jj,jl) 
246            END DO
247         END DO
248      END DO
249
250      !-----------------------------------------------------------------------------------------------
251      !  2) Compute fractional ice area in each grid cell
252      !-----------------------------------------------------------------------------------------------
253      at_i(:,:) = 0._wp
254      DO jl = klbnd, kubnd
255         at_i(:,:) = at_i(:,:) + a_i(:,:,jl)
256      END DO
257
258      !-----------------------------------------------------------------------------------------------
259      !  3) Identify grid cells with ice
260      !-----------------------------------------------------------------------------------------------
261      nbrem = 0
262      DO jj = 1, jpj
263         DO ji = 1, jpi
264            IF ( at_i(ji,jj) .gt. zareamin ) THEN
265               nbrem         = nbrem + 1
266               nind_i(nbrem) = ji
267               nind_j(nbrem) = jj
268               zremap_flag(ji,jj) = .true.
269            ELSE
270               zremap_flag(ji,jj) = .false.
271            ENDIF
272         END DO !ji
273      END DO !jj
274
275      !-----------------------------------------------------------------------------------------------
276      !  4) Compute new category boundaries
277      !-----------------------------------------------------------------------------------------------
278      !- 4.1 Compute category boundaries
279      ! Tricky trick see limitd_me.F90
280      ! will be soon removed, CT
281      ! hi_max(kubnd) = 999.99
282      zhbnew(:,:,:) = 0._wp
283
284      DO jl = klbnd, kubnd - 1
285         DO ji = 1, nbrem
286            zji = nind_i(ji)
287            zjj = nind_j(ji)
288            !
289            IF ( ( zht_i_o(zji,zjj,jl)  .GT.epsi10 ) .AND. & 
290               ( zht_i_o(zji,zjj,jl+1).GT.epsi10 ) ) THEN
291               !interpolate between adjacent category growth rates
292               zslope = ( zdhice(zji,zjj,jl+1)     - zdhice(zji,zjj,jl) ) / &
293                  ( zht_i_o   (zji,zjj,jl+1) - zht_i_o   (zji,zjj,jl) )
294               zhbnew(zji,zjj,jl) = hi_max(jl) + zdhice(zji,zjj,jl) + &
295                  zslope * ( hi_max(jl) - zht_i_o(zji,zjj,jl) )
296            ELSEIF (zht_i_o(zji,zjj,jl).gt.epsi10) THEN
297               zhbnew(zji,zjj,jl) = hi_max(jl) + zdhice(zji,zjj,jl)
298            ELSEIF (zht_i_o(zji,zjj,jl+1).gt.epsi10) THEN
299               zhbnew(zji,zjj,jl) = hi_max(jl) + zdhice(zji,zjj,jl+1)
300            ELSE
301               zhbnew(zji,zjj,jl) = hi_max(jl)
302            ENDIF
303         END DO
304
305         !- 4.2 Check that each zhbnew lies between adjacent values of ice thickness
306         DO ji = 1, nbrem
307            ! jl, ji
308            zji = nind_i(ji)
309            zjj = nind_j(ji)
310            ! jl, ji
311            IF ( ( a_i(zji,zjj,jl) .GT.epsi10) .AND. & 
312               ( ht_i(zji,zjj,jl).GE. zhbnew(zji,zjj,jl) ) &
313               ) THEN
314               zremap_flag(zji,zjj) = .false.
315            ELSEIF ( ( a_i(zji,zjj,jl+1) .GT. epsi10 ) .AND. &
316               ( ht_i(zji,zjj,jl+1).LE. zhbnew(zji,zjj,jl) ) &
317               ) THEN
318               zremap_flag(zji,zjj) = .false.
319            ENDIF
320
321            !- 4.3 Check that each zhbnew does not exceed maximal values hi_max 
322            ! jl, ji
323            IF (zhbnew(zji,zjj,jl).gt.hi_max(jl+1)) THEN
324               zremap_flag(zji,zjj) = .false.
325            ENDIF
326            ! jl, ji
327            IF (zhbnew(zji,zjj,jl).lt.hi_max(jl-1)) THEN
328               zremap_flag(zji,zjj) = .false.
329            ENDIF
330            ! jl, ji
331         END DO !ji
332         ! ji
333      END DO !jl
334
335      !-----------------------------------------------------------------------------------------------
336      !  5) Identify cells where ITD is to be remapped
337      !-----------------------------------------------------------------------------------------------
338      nbrem = 0
339      DO jj = 1, jpj
340         DO ji = 1, jpi
341            IF ( zremap_flag(ji,jj) ) THEN
342               nbrem         = nbrem + 1
343               nind_i(nbrem) = ji
344               nind_j(nbrem) = jj
345            ENDIF
346         END DO !ji
347      END DO !jj
348
349      !-----------------------------------------------------------------------------------------------
350      !  6) Fill arrays with lowermost / uppermost boundaries of 'new' categories
351      !-----------------------------------------------------------------------------------------------
352      DO jj = 1, jpj
353         DO ji = 1, jpi
354            zhb0(ji,jj) = hi_max_typ(0,ntyp) ! 0eme
355            zhb1(ji,jj) = hi_max_typ(1,ntyp) ! 1er
356
357            zhbnew(ji,jj,klbnd-1) = 0._wp
358
359            IF( a_i(ji,jj,kubnd) > epsi10 ) THEN
360               zhbnew(ji,jj,kubnd) = 3._wp * ht_i(ji,jj,kubnd) - 2._wp * zhbnew(ji,jj,kubnd-1)
361            ELSE
362               zhbnew(ji,jj,kubnd) = hi_max(kubnd)
363            ENDIF
364
365            IF( zhbnew(ji,jj,kubnd) < hi_max(kubnd-1) )   zhbnew(ji,jj,kubnd) = hi_max(kubnd-1)
366
367         END DO !jj
368      END DO !jj
369
370      !-----------------------------------------------------------------------------------------------
371      !  7) Compute g(h)
372      !-----------------------------------------------------------------------------------------------
373      !- 7.1 g(h) for category 1 at start of time step
374      CALL lim_itd_fitline( klbnd, zhb0, zhb1, zht_i_o(:,:,klbnd),         &
375         &                  g0(:,:,klbnd), g1(:,:,klbnd), hL(:,:,klbnd),   &
376         &                  hR(:,:,klbnd), zremap_flag )
377
378      !- 7.2 Area lost due to melting of thin ice (first category,  klbnd)
379      DO ji = 1, nbrem
380         zji = nind_i(ji) 
381         zjj = nind_j(ji) 
382
383         !ji
384         IF (a_i(zji,zjj,klbnd) .gt. epsi10) THEN
385            zdh0 = zdhice(zji,zjj,klbnd) !decrease of ice thickness in the lower category
386            ! ji, a_i > epsi10
387            IF (zdh0 .lt. 0.0) THEN !remove area from category 1
388               ! ji, a_i > epsi10; zdh0 < 0
389               zdh0 = MIN(-zdh0,hi_max(klbnd))
390
391               !Integrate g(1) from 0 to dh0 to estimate area melted
392               zetamax = MIN(zdh0,hR(zji,zjj,klbnd)) - hL(zji,zjj,klbnd)
393               IF (zetamax.gt.0.0) THEN
394                  zx1  = zetamax
395                  zx2  = 0.5 * zetamax*zetamax 
396                  zda0 = g1(zji,zjj,klbnd) * zx2 + g0(zji,zjj,klbnd) * zx1 !ice area removed
397                  ! Constrain new thickness <= ht_i
398                  zdamax = a_i(zji,zjj,klbnd) * & 
399                     (1.0 - ht_i(zji,zjj,klbnd)/zht_i_o(zji,zjj,klbnd)) ! zdamax > 0
400                  !ice area lost due to melting of thin ice
401                  zda0   = MIN(zda0, zdamax)
402
403                  ! Remove area, conserving volume
404                  ht_i(zji,zjj,klbnd) = ht_i(zji,zjj,klbnd) & 
405                     * a_i(zji,zjj,klbnd) / ( a_i(zji,zjj,klbnd) - zda0 )
406                  a_i(zji,zjj,klbnd)  = a_i(zji,zjj,klbnd) - zda0
407                  v_i(zji,zjj,klbnd)  = a_i(zji,zjj,klbnd)*ht_i(zji,zjj,klbnd)
408               ENDIF     ! zetamax > 0
409               ! ji, a_i > epsi10
410
411            ELSE ! if ice accretion
412               ! ji, a_i > epsi10; zdh0 > 0
413               IF ( ntyp .EQ. 1 ) zhbnew(zji,zjj,klbnd-1) = MIN(zdh0,hi_max(klbnd)) 
414               ! zhbnew was 0, and is shifted to the right to account for thin ice
415               ! growth in openwater (F0 = f1)
416               IF ( ntyp .NE. 1 ) zhbnew(zji,zjj,0) = 0 
417               ! in other types there is
418               ! no open water growth (F0 = 0)
419            ENDIF ! zdh0
420
421            ! a_i > epsi10
422         ENDIF ! a_i > epsi10
423
424      END DO ! ji
425
426      !- 7.3 g(h) for each thickness category 
427      DO jl = klbnd, kubnd
428         CALL lim_itd_fitline(jl, zhbnew(:,:,jl-1), zhbnew(:,:,jl), ht_i(:,:,jl), &
429            g0(:,:,jl), g1(:,:,jl), hL(:,:,jl), hR(:,:,jl),     &
430            zremap_flag)
431      END DO
432
433      !-----------------------------------------------------------------------------------------------
434      !  8) Compute area and volume to be shifted across each boundary
435      !-----------------------------------------------------------------------------------------------
436
437      DO jl = klbnd, kubnd - 1
438         DO jj = 1, jpj
439            DO ji = 1, jpi
440               zdonor(ji,jj,jl) = 0
441               zdaice(ji,jj,jl) = 0.0
442               zdvice(ji,jj,jl) = 0.0
443            END DO
444         END DO
445
446         DO ji = 1, nbrem
447            zji = nind_i(ji)
448            zjj = nind_j(ji)
449
450            IF (zhbnew(zji,zjj,jl) .gt. hi_max(jl)) THEN ! transfer from jl to jl+1
451
452               ! left and right integration limits in eta space
453               zvetamin(ji) = MAX(hi_max(jl), hL(zji,zjj,jl)) - hL(zji,zjj,jl)
454               zvetamax(ji) = MIN(zhbnew(zji,zjj,jl), hR(zji,zjj,jl)) - hL(zji,zjj,jl)
455               zdonor(zji,zjj,jl) = jl
456
457            ELSE  ! zhbnew(jl) <= hi_max(jl) ; transfer from jl+1 to jl
458
459               ! left and right integration limits in eta space
460               zvetamin(ji) = 0.0
461               zvetamax(ji) = MIN(hi_max(jl), hR(zji,zjj,jl+1)) - hL(zji,zjj,jl+1)
462               zdonor(zji,zjj,jl) = jl + 1
463
464            ENDIF  ! zhbnew(jl) > hi_max(jl)
465
466            zetamax = MAX(zvetamax(ji), zvetamin(ji)) ! no transfer if etamax < etamin
467            zetamin = zvetamin(ji)
468
469            zx1  = zetamax - zetamin
470            zwk1 = zetamin*zetamin
471            zwk2 = zetamax*zetamax
472            zx2  = 0.5 * (zwk2 - zwk1)
473            zwk1 = zwk1 * zetamin
474            zwk2 = zwk2 * zetamax
475            zx3  = 1.0/3.0 * (zwk2 - zwk1)
476            nd   = zdonor(zji,zjj,jl)
477            zdaice(zji,zjj,jl) = g1(zji,zjj,nd)*zx2 + g0(zji,zjj,nd)*zx1
478            zdvice(zji,zjj,jl) = g1(zji,zjj,nd)*zx3 + g0(zji,zjj,nd)*zx2 + &
479               zdaice(zji,zjj,jl)*hL(zji,zjj,nd)
480
481         END DO ! ji
482      END DO ! jl klbnd -> kubnd - 1
483
484      !!----------------------------------------------------------------------------------------------
485      !! 9) Shift ice between categories
486      !!----------------------------------------------------------------------------------------------
487      CALL lim_itd_shiftice ( klbnd, kubnd, zdonor, zdaice, zdvice )
488
489      !!----------------------------------------------------------------------------------------------
490      !! 10) Make sure ht_i >= minimum ice thickness hi_min
491      !!----------------------------------------------------------------------------------------------
492
493      DO ji = 1, nbrem
494         zji = nind_i(ji)
495         zjj = nind_j(ji)
496         IF ( ( zhimin .GT. 0.0 ) .AND. & 
497            ( ( a_i(zji,zjj,1) .GT. epsi10 ) .AND. ( ht_i(zji,zjj,1) .LT. zhimin ) ) &
498            ) THEN
499            a_i(zji,zjj,1)  = a_i(zji,zjj,1) * ht_i(zji,zjj,1) / zhimin 
500            ht_i(zji,zjj,1) = zhimin
501            v_i(zji,zjj,1)  = a_i(zji,zjj,1)*ht_i(zji,zjj,1)
502         ENDIF
503      END DO !ji
504
505      !!----------------------------------------------------------------------------------------------
506      !! 11) Conservation check
507      !!----------------------------------------------------------------------------------------------
508      IF ( con_i ) THEN
509         CALL lim_column_sum (jpl,   v_i, vt_i_final)
510         fieldid = ' v_i : limitd_th '
511         CALL lim_cons_check (vt_i_init, vt_i_final, 1.0e-6, fieldid) 
512
513         CALL lim_column_sum_energy (jpl, nlay_i,  e_i, et_i_final)
514         fieldid = ' e_i : limitd_th '
515         CALL lim_cons_check (et_i_init, et_i_final, 1.0e-3, fieldid) 
516
517         CALL lim_column_sum (jpl,   v_s, vt_s_final)
518         fieldid = ' v_s : limitd_th '
519         CALL lim_cons_check (vt_s_init, vt_s_final, 1.0e-6, fieldid) 
520
521         dummy_es(:,:,:) = e_s(:,:,1,:)
522         CALL lim_column_sum (jpl, dummy_es(:,:,:) , et_s_final)
523         fieldid = ' e_s : limitd_th '
524         CALL lim_cons_check (et_s_init, et_s_final, 1.0e-3, fieldid) 
525      ENDIF
526
527   END SUBROUTINE lim_itd_th_rem
528
529
530   SUBROUTINE lim_itd_fitline( num_cat, HbL, Hbr, hice,   &
531      &                        g0, g1, hL, hR, zremap_flag )
532      !!------------------------------------------------------------------
533      !!                ***  ROUTINE lim_itd_fitline ***
534      !!
535      !! ** Purpose :   fit g(h) with a line using area, volume constraints
536      !!
537      !! ** Method  :   Fit g(h) with a line, satisfying area and volume constraints.
538      !!              To reduce roundoff errors caused by large values of g0 and g1,
539      !!              we actually compute g(eta), where eta = h - hL, and hL is the
540      !!              left boundary.
541      !!------------------------------------------------------------------
542      INTEGER                     , INTENT(in   ) ::   num_cat      ! category index
543      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   HbL, HbR     ! left and right category boundaries
544      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   hice         ! ice thickness
545      REAL(wp), DIMENSION(jpi,jpj), INTENT(  out) ::   g0, g1       ! coefficients in linear equation for g(eta)
546      REAL(wp), DIMENSION(jpi,jpj), INTENT(  out) ::   hL           ! min value of range over which g(h) > 0
547      REAL(wp), DIMENSION(jpi,jpj), INTENT(  out) ::   hR           ! max value of range over which g(h) > 0
548      LOGICAL , DIMENSION(jpi,jpj), INTENT(in   ) ::   zremap_flag  !
549      !
550      INTEGER ::   ji,jj           ! horizontal indices
551      REAL(wp) ::   zh13         ! HbL + 1/3 * (HbR - HbL)
552      REAL(wp) ::   zh23         ! HbL + 2/3 * (HbR - HbL)
553      REAL(wp) ::   zdhr         ! 1 / (hR - hL)
554      REAL(wp) ::   zwk1, zwk2   ! temporary variables
555      REAL(wp) ::   zacrith      ! critical minimum concentration in an ice category
556      !!------------------------------------------------------------------
557      !
558      zacrith       = 1.0e-6
559      !
560      DO jj = 1, jpj
561         DO ji = 1, jpi
562            !
563            IF( zremap_flag(ji,jj) .AND. a_i(ji,jj,num_cat) > zacrith   &
564               &                   .AND. hice(ji,jj)        > 0._wp     ) THEN
565
566               ! Initialize hL and hR
567
568               hL(ji,jj) = HbL(ji,jj)
569               hR(ji,jj) = HbR(ji,jj)
570
571               ! Change hL or hR if hice falls outside central third of range
572
573               zh13 = 1.0/3.0 * (2.0*hL(ji,jj) + hR(ji,jj))
574               zh23 = 1.0/3.0 * (hL(ji,jj) + 2.0*hR(ji,jj))
575
576               IF    ( hice(ji,jj) < zh13 ) THEN   ;   hR(ji,jj) = 3._wp * hice(ji,jj) - 2._wp * hL(ji,jj)
577               ELSEIF( hice(ji,jj) > zh23 ) THEN   ;   hL(ji,jj) = 3._wp * hice(ji,jj) - 2._wp * hR(ji,jj)
578               ENDIF
579
580               ! Compute coefficients of g(eta) = g0 + g1*eta
581
582               zdhr = 1._wp / (hR(ji,jj) - hL(ji,jj))
583               zwk1 = 6._wp * a_i(ji,jj,num_cat) * zdhr
584               zwk2 = ( hice(ji,jj) - hL(ji,jj) ) * zdhr
585               g0(ji,jj) = zwk1 * ( 2._wp/3._wp - zwk2 )
586               g1(ji,jj) = 2._wp * zdhr * zwk1 * (zwk2 - 0.5)
587               !
588            ELSE                   ! remap_flag = .false. or a_i < epsi10
589               hL(ji,jj) = 0._wp
590               hR(ji,jj) = 0._wp
591               g0(ji,jj) = 0._wp
592               g1(ji,jj) = 0._wp
593            ENDIF                  ! a_i > epsi10
594            !
595         END DO
596      END DO
597      !
598   END SUBROUTINE lim_itd_fitline
599
600
601   SUBROUTINE lim_itd_shiftice( klbnd, kubnd, zdonor, zdaice, zdvice )
602      !!------------------------------------------------------------------
603      !!                ***  ROUTINE lim_itd_shiftice ***
604      !!
605      !! ** Purpose :   shift ice across category boundaries, conserving everything
606      !!              ( area, volume, energy, age*vol, and mass of salt )
607      !!
608      !! ** Method  :
609      !!------------------------------------------------------------------
610      INTEGER , INTENT(in   ) ::   klbnd   ! Start thickness category index point
611      INTEGER , INTENT(in   ) ::   kubnd   ! End point on which the  the computation is applied
612
613      INTEGER , DIMENSION(jpi,jpj,jpl-1), INTENT(in   ) ::   zdonor   ! donor category index
614
615      REAL(wp), DIMENSION(jpi,jpj,jpl-1), INTENT(inout) ::   zdaice   ! ice area transferred across boundary
616      REAL(wp), DIMENSION(jpi,jpj,jpl-1), INTENT(inout) ::   zdvice   ! ice volume transferred across boundary
617
618      INTEGER ::   ji, jj, jl, jl2, jl1, jk   ! dummy loop indices
619      INTEGER ::   zji, zjj          ! indices when changing from 2D-1D is done
620
621      REAL(wp), DIMENSION(jpi,jpj,jpl) ::   zaTsfn
622
623      REAL(wp), DIMENSION(jpi,jpj) ::   zworka            ! temporary array used here
624
625      REAL(wp) ::   zdvsnow, zdesnow   ! snow volume and energy transferred
626      REAL(wp) ::   zdeice             ! ice energy transferred
627      REAL(wp) ::   zdsm_vice          ! ice salinity times volume transferred
628      REAL(wp) ::   zdo_aice           ! ice age times volume transferred
629      REAL(wp) ::   zdaTsf             ! aicen*Tsfcn transferred
630      REAL(wp) ::   zindsn             ! snow or not
631      REAL(wp) ::   zindb              ! ice or not
632
633      INTEGER, DIMENSION(1:(jpi+1)*(jpj+1)) ::   nind_i, nind_j   ! compressed indices for i/j directions
634
635      INTEGER ::   nbrem             ! number of cells with ice to transfer
636
637      LOGICAL ::   zdaice_negative         ! true if daice < -puny
638      LOGICAL ::   zdvice_negative         ! true if dvice < -puny
639      LOGICAL ::   zdaice_greater_aicen    ! true if daice > aicen
640      LOGICAL ::   zdvice_greater_vicen    ! true if dvice > vicen
641      !!------------------------------------------------------------------
642
643      !----------------------------------------------------------------------------------------------
644      ! 1) Define a variable equal to a_i*T_su
645      !----------------------------------------------------------------------------------------------
646
647      DO jl = klbnd, kubnd
648         zaTsfn(:,:,jl) = a_i(:,:,jl)*t_su(:,:,jl)
649      END DO
650
651      !----------------------------------------------------------------------------------------------
652      ! 2) Check for daice or dvice out of range, allowing for roundoff error
653      !----------------------------------------------------------------------------------------------
654      ! Note: zdaice < 0 or zdvice < 0 usually happens when category jl
655      ! has a small area, with h(n) very close to a boundary.  Then
656      ! the coefficients of g(h) are large, and the computed daice and
657      ! dvice can be in error. If this happens, it is best to transfer
658      ! either the entire category or nothing at all, depending on which
659      ! side of the boundary hice(n) lies.
660      !-----------------------------------------------------------------
661      DO jl = klbnd, kubnd-1
662
663         zdaice_negative = .false.
664         zdvice_negative = .false.
665         zdaice_greater_aicen = .false.
666         zdvice_greater_vicen = .false.
667
668         DO jj = 1, jpj
669            DO ji = 1, jpi
670
671               IF (zdonor(ji,jj,jl) .GT. 0) THEN
672                  jl1 = zdonor(ji,jj,jl)
673
674                  IF (zdaice(ji,jj,jl) .LT. 0.0) THEN
675                     IF (zdaice(ji,jj,jl) .GT. -epsi10) THEN
676                        IF ( ( jl1.EQ.jl   .AND. ht_i(ji,jj,jl1) .GT. hi_max(jl) )           &
677                           .OR.                                      &
678                           ( jl1.EQ.jl+1 .AND. ht_i(ji,jj,jl1) .LE. hi_max(jl) )           & 
679                           ) THEN                                                             
680                           zdaice(ji,jj,jl) = a_i(ji,jj,jl1)  ! shift entire category
681                           zdvice(ji,jj,jl) = v_i(ji,jj,jl1)
682                        ELSE
683                           zdaice(ji,jj,jl) = 0.0 ! shift no ice
684                           zdvice(ji,jj,jl) = 0.0
685                        ENDIF
686                     ELSE
687                        zdaice_negative = .true.
688                     ENDIF
689                  ENDIF
690
691                  IF (zdvice(ji,jj,jl) .LT. 0.0) THEN
692                     IF (zdvice(ji,jj,jl) .GT. -epsi10 ) THEN
693                        IF ( ( jl1.EQ.jl .AND. ht_i(ji,jj,jl1).GT.hi_max(jl) )     &
694                           .OR.                                     &
695                           ( jl1.EQ.jl+1 .AND. ht_i(ji,jj,jl1) .LE. hi_max(jl) ) &
696                           ) THEN
697                           zdaice(ji,jj,jl) = a_i(ji,jj,jl1) ! shift entire category
698                           zdvice(ji,jj,jl) = v_i(ji,jj,jl1) 
699                        ELSE
700                           zdaice(ji,jj,jl) = 0.0    ! shift no ice
701                           zdvice(ji,jj,jl) = 0.0
702                        ENDIF
703                     ELSE
704                        zdvice_negative = .true.
705                     ENDIF
706                  ENDIF
707
708                  ! If daice is close to aicen, set daice = aicen.
709                  IF (zdaice(ji,jj,jl) .GT. a_i(ji,jj,jl1) - epsi10 ) THEN
710                     IF (zdaice(ji,jj,jl) .LT. a_i(ji,jj,jl1)+epsi10) THEN
711                        zdaice(ji,jj,jl) = a_i(ji,jj,jl1)
712                        zdvice(ji,jj,jl) = v_i(ji,jj,jl1) 
713                     ELSE
714                        zdaice_greater_aicen = .true.
715                     ENDIF
716                  ENDIF
717
718                  IF (zdvice(ji,jj,jl) .GT. v_i(ji,jj,jl1)-epsi10) THEN
719                     IF (zdvice(ji,jj,jl) .LT. v_i(ji,jj,jl1)+epsi10) THEN
720                        zdaice(ji,jj,jl) = a_i(ji,jj,jl1)
721                        zdvice(ji,jj,jl) = v_i(ji,jj,jl1) 
722                     ELSE
723                        zdvice_greater_vicen = .true.
724                     ENDIF
725                  ENDIF
726
727               ENDIF               ! donor > 0
728            END DO                   ! i
729         END DO                 ! j
730
731      END DO !jl
732
733      !-------------------------------------------------------------------------------
734      ! 3) Transfer volume and energy between categories
735      !-------------------------------------------------------------------------------
736
737      DO jl = klbnd, kubnd - 1
738         nbrem = 0
739         DO jj = 1, jpj
740            DO ji = 1, jpi
741               IF (zdaice(ji,jj,jl) .GT. 0.0 ) THEN ! daice(n) can be < puny
742                  nbrem = nbrem + 1
743                  nind_i(nbrem) = ji
744                  nind_j(nbrem) = jj
745               ENDIF ! tmask
746            END DO
747         END DO
748
749         DO ji = 1, nbrem 
750            zji = nind_i(ji)
751            zjj = nind_j(ji)
752
753            jl1 = zdonor(zji,zjj,jl)
754            zindb             = MAX( 0.0 , SIGN( 1.0 , v_i(zji,zjj,jl1) - epsi10 ) )
755            zworka(zji,zjj)   = zdvice(zji,zjj,jl) / MAX(v_i(zji,zjj,jl1),epsi10) * zindb
756            IF( jl1 == jl) THEN   ;   jl2 = jl1+1
757            ELSE                    ;   jl2 = jl 
758            ENDIF
759
760            !--------------
761            ! Ice areas
762            !--------------
763
764            a_i(zji,zjj,jl1) = a_i(zji,zjj,jl1) - zdaice(zji,zjj,jl)
765            a_i(zji,zjj,jl2) = a_i(zji,zjj,jl2) + zdaice(zji,zjj,jl)
766
767            !--------------
768            ! Ice volumes
769            !--------------
770
771            v_i(zji,zjj,jl1) = v_i(zji,zjj,jl1) - zdvice(zji,zjj,jl) 
772            v_i(zji,zjj,jl2) = v_i(zji,zjj,jl2) + zdvice(zji,zjj,jl)
773
774            !--------------
775            ! Snow volumes
776            !--------------
777
778            zdvsnow          = v_s(zji,zjj,jl1) * zworka(zji,zjj)
779            v_s(zji,zjj,jl1) = v_s(zji,zjj,jl1) - zdvsnow
780            v_s(zji,zjj,jl2) = v_s(zji,zjj,jl2) + zdvsnow 
781
782            !--------------------
783            ! Snow heat content 
784            !--------------------
785
786            zdesnow              = e_s(zji,zjj,1,jl1) * zworka(zji,zjj)
787            e_s(zji,zjj,1,jl1)   = e_s(zji,zjj,1,jl1) - zdesnow
788            e_s(zji,zjj,1,jl2)   = e_s(zji,zjj,1,jl2) + zdesnow
789
790            !--------------
791            ! Ice age
792            !--------------
793
794            zdo_aice             = oa_i(zji,zjj,jl1) * zdaice(zji,zjj,jl)
795            oa_i(zji,zjj,jl1)    = oa_i(zji,zjj,jl1) - zdo_aice
796            oa_i(zji,zjj,jl2)    = oa_i(zji,zjj,jl2) + zdo_aice
797
798            !--------------
799            ! Ice salinity
800            !--------------
801
802            zdsm_vice            = smv_i(zji,zjj,jl1) * zworka(zji,zjj)
803            smv_i(zji,zjj,jl1)   = smv_i(zji,zjj,jl1) - zdsm_vice
804            smv_i(zji,zjj,jl2)   = smv_i(zji,zjj,jl2) + zdsm_vice
805
806            !---------------------
807            ! Surface temperature
808            !---------------------
809
810            zdaTsf               = t_su(zji,zjj,jl1) * zdaice(zji,zjj,jl)
811            zaTsfn(zji,zjj,jl1)  = zaTsfn(zji,zjj,jl1) - zdaTsf
812            zaTsfn(zji,zjj,jl2)  = zaTsfn(zji,zjj,jl2) + zdaTsf 
813
814         END DO                 ! ji
815
816         !------------------
817         ! Ice heat content
818         !------------------
819
820         DO jk = 1, nlay_i
821!CDIR NODEP
822            DO ji = 1, nbrem
823               zji = nind_i(ji)
824               zjj = nind_j(ji)
825
826               jl1 = zdonor(zji,zjj,jl)
827               IF (jl1 .EQ. jl) THEN
828                  jl2 = jl+1
829               ELSE             ! n1 = n+1
830                  jl2 = jl 
831               ENDIF
832
833               zdeice = e_i(zji,zjj,jk,jl1) * zworka(zji,zjj)
834               e_i(zji,zjj,jk,jl1) =  e_i(zji,zjj,jk,jl1) - zdeice
835               e_i(zji,zjj,jk,jl2) =  e_i(zji,zjj,jk,jl2) + zdeice 
836            END DO              ! ji
837         END DO                 ! jk
838
839      END DO                   ! boundaries, 1 to ncat-1
840
841      !-----------------------------------------------------------------
842      ! Update ice thickness and temperature
843      !-----------------------------------------------------------------
844
845      DO jl = klbnd, kubnd
846         DO jj = 1, jpj
847            DO ji = 1, jpi 
848               IF ( a_i(ji,jj,jl) > epsi10 ) THEN
849                  ht_i(ji,jj,jl)  =  v_i   (ji,jj,jl) / a_i(ji,jj,jl) 
850                  t_su(ji,jj,jl)  =  zaTsfn(ji,jj,jl) / a_i(ji,jj,jl) 
851                  zindsn          =  1.0 - MAX(0.0,SIGN(1.0,-v_s(ji,jj,jl))) !0 if no ice and 1 if yes
852               ELSE
853                  ht_i(ji,jj,jl)  = 0._wp
854                  t_su(ji,jj,jl)  = rtt
855               ENDIF
856            END DO                 ! ji
857         END DO                 ! jj
858      END DO                    ! jl
859      !
860   END SUBROUTINE lim_itd_shiftice
861   
862
863   SUBROUTINE lim_itd_th_reb( klbnd, kubnd, ntyp )
864      !!------------------------------------------------------------------
865      !!                ***  ROUTINE lim_itd_th_reb ***
866      !!
867      !! ** Purpose : rebin - rebins thicknesses into defined categories
868      !!
869      !! ** Method  :
870      !!------------------------------------------------------------------
871      INTEGER , INTENT (in) ::   klbnd   ! Start thickness category index point
872      INTEGER , INTENT (in) ::   kubnd   ! End point on which the  the computation is applied
873      INTEGER , INTENT (in) ::   ntyp    ! number of the ice type involved in the rebinning process
874      !
875      INTEGER ::   ji,jj, jl   ! dummy loop indices
876      INTEGER ::   zshiftflag          ! = .true. if ice must be shifted
877      CHARACTER (len = 15) :: fieldid
878
879      INTEGER , DIMENSION(jpi,jpj,jpl) ::   zdonor           ! donor category index
880      REAL(wp), DIMENSION(jpi,jpj,jpl) ::   zdaice, zdvice   ! ice area and volume transferred
881
882      REAL (wp), DIMENSION(jpi,jpj) ::   vt_i_init, vt_i_final   ! ice volume summed over categories
883      REAL (wp), DIMENSION(jpi,jpj) ::   vt_s_init, vt_s_final   ! snow volume summed over categories
884      !!------------------------------------------------------------------
885      !     
886      IF( con_i ) THEN                 ! conservation check
887         CALL lim_column_sum (jpl,   v_i, vt_i_init)
888         CALL lim_column_sum (jpl,   v_s, vt_s_init)
889      ENDIF
890
891      !
892      !------------------------------------------------------------------------------
893      ! 1) Compute ice thickness.
894      !------------------------------------------------------------------------------
895      DO jl = klbnd, kubnd
896         DO jj = 1, jpj
897            DO ji = 1, jpi 
898               IF( a_i(ji,jj,jl) > epsi10 ) THEN
899                  ht_i(ji,jj,jl) = v_i(ji,jj,jl) / a_i(ji,jj,jl)
900               ELSE
901                  ht_i(ji,jj,jl) = 0._wp
902               ENDIF
903            END DO
904         END DO
905      END DO
906
907      !------------------------------------------------------------------------------
908      ! 2) Make sure thickness of cat klbnd is at least hi_max_typ(klbnd)
909      !------------------------------------------------------------------------------
910      DO jj = 1, jpj 
911         DO ji = 1, jpi 
912            IF( a_i(ji,jj,klbnd) > epsi10 ) THEN
913               IF( ht_i(ji,jj,klbnd) <= hi_max_typ(0,ntyp) .AND. hi_max_typ(0,ntyp) > 0._wp ) THEN
914                  a_i(ji,jj,klbnd)  = v_i(ji,jj,klbnd) / hi_max_typ(0,ntyp) 
915                  ht_i(ji,jj,klbnd) = hi_max_typ(0,ntyp)
916               ENDIF
917            ENDIF
918         END DO
919      END DO
920
921      !------------------------------------------------------------------------------
922      ! 3) If a category thickness is not in bounds, shift the
923      ! entire area, volume, and energy to the neighboring category
924      !------------------------------------------------------------------------------
925      !-------------------------
926      ! Initialize shift arrays
927      !-------------------------
928      DO jl = klbnd, kubnd
929         zdonor(:,:,jl) = 0
930         zdaice(:,:,jl) = 0._wp
931         zdvice(:,:,jl) = 0._wp
932      END DO
933
934      !-------------------------
935      ! Move thin categories up
936      !-------------------------
937
938      DO jl = klbnd, kubnd - 1  ! loop over category boundaries
939
940         !---------------------------------------
941         ! identify thicknesses that are too big
942         !---------------------------------------
943         zshiftflag = 0
944
945         DO jj = 1, jpj 
946            DO ji = 1, jpi 
947               IF( a_i(ji,jj,jl) > epsi10 .AND. ht_i(ji,jj,jl) > hi_max(jl) ) THEN
948                  zshiftflag        = 1
949                  zdonor(ji,jj,jl)  = jl 
950                  zdaice(ji,jj,jl)  = a_i(ji,jj,jl)
951                  zdvice(ji,jj,jl)  = v_i(ji,jj,jl)
952               ENDIF
953            END DO                 ! ji
954         END DO                 ! jj
955         IF(lk_mpp)   CALL mpp_max( zshiftflag )
956
957         IF( zshiftflag == 1 ) THEN            ! Shift ice between categories
958            CALL lim_itd_shiftice( klbnd, kubnd, zdonor, zdaice, zdvice )
959            ! Reset shift parameters
960            zdonor(:,:,jl) = 0
961            zdaice(:,:,jl) = 0._wp
962            zdvice(:,:,jl) = 0._wp
963         ENDIF
964         !
965      END DO                    ! jl
966
967      !----------------------------
968      ! Move thick categories down
969      !----------------------------
970
971      DO jl = kubnd - 1, 1, -1       ! loop over category boundaries
972
973         !-----------------------------------------
974         ! Identify thicknesses that are too small
975         !-----------------------------------------
976         zshiftflag = 0
977
978         DO jj = 1, jpj
979            DO ji = 1, jpi
980               IF( a_i(ji,jj,jl+1) >  epsi10 .AND.   &
981                  ht_i(ji,jj,jl+1) <= hi_max(jl) ) THEN
982                  !
983                  zshiftflag = 1
984                  zdonor(ji,jj,jl) = jl + 1
985                  zdaice(ji,jj,jl) = a_i(ji,jj,jl+1) 
986                  zdvice(ji,jj,jl) = v_i(ji,jj,jl+1)
987               ENDIF
988            END DO                 ! ji
989         END DO                 ! jj
990
991         IF(lk_mpp)   CALL mpp_max( zshiftflag )
992         
993         IF( zshiftflag == 1 ) THEN            ! Shift ice between categories
994            CALL lim_itd_shiftice( klbnd, kubnd, zdonor, zdaice, zdvice )
995            ! Reset shift parameters
996            zdonor(:,:,jl) = 0
997            zdaice(:,:,jl) = 0._wp
998            zdvice(:,:,jl) = 0._wp
999         ENDIF
1000
1001      END DO                    ! jl
1002
1003      !------------------------------------------------------------------------------
1004      ! 4) Conservation check
1005      !------------------------------------------------------------------------------
1006
1007      IF( con_i ) THEN
1008         CALL lim_column_sum (jpl,   v_i, vt_i_final)
1009         fieldid = ' v_i : limitd_reb '
1010         CALL lim_cons_check (vt_i_init, vt_i_final, 1.0e-6, fieldid) 
1011
1012         CALL lim_column_sum (jpl,   v_s, vt_s_final)
1013         fieldid = ' v_s : limitd_reb '
1014         CALL lim_cons_check (vt_s_init, vt_s_final, 1.0e-6, fieldid) 
1015      ENDIF
1016      !
1017   END SUBROUTINE lim_itd_th_reb
1018
1019#else
1020   !!----------------------------------------------------------------------
1021   !!   Default option            Dummy module         NO LIM sea-ice model
1022   !!----------------------------------------------------------------------
1023CONTAINS
1024   SUBROUTINE lim_itd_th           ! Empty routines
1025   END SUBROUTINE lim_itd_th
1026   SUBROUTINE lim_itd_th_ini
1027   END SUBROUTINE lim_itd_th_ini
1028   SUBROUTINE lim_itd_th_rem
1029   END SUBROUTINE lim_itd_th_rem
1030   SUBROUTINE lim_itd_fitline
1031   END SUBROUTINE lim_itd_fitline
1032   SUBROUTINE lim_itd_shiftice
1033   END SUBROUTINE lim_itd_shiftice
1034   SUBROUTINE lim_itd_th_reb
1035   END SUBROUTINE lim_itd_th_reb
1036#endif
1037   !!======================================================================
1038END MODULE limitd_th
Note: See TracBrowser for help on using the repository browser.