New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limsbc.F90 in trunk/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: trunk/NEMOGCM/NEMO/LIM_SRC_3/limsbc.F90 @ 2760

Last change on this file since 2760 was 2715, checked in by rblod, 13 years ago

First attempt to put dynamic allocation on the trunk

  • Property svn:keywords set to Id
File size: 22.8 KB
Line 
1MODULE limsbc
2   !!======================================================================
3   !!                       ***  MODULE limsbc   ***
4   !!           computation of the flux at the sea ice/ocean interface
5   !!======================================================================
6   !! History :   -   ! 2006-07 (M. Vancoppelle)  LIM3 original code
7   !!            3.0  ! 2008-03 (C. Tallandier)  surface module
8   !!             -   ! 2008-04 (C. Tallandier)  split in 2 + new ice-ocean coupling
9   !!            3.3  ! 2010-05 (G. Madec) decrease ocean & ice reference salinities in the Baltic sea
10   !!                 !                  + simplification of the ice-ocean stress calculation
11   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
12   !!----------------------------------------------------------------------
13#if defined key_lim3
14   !!----------------------------------------------------------------------
15   !!   'key_lim3'                                    LIM 3.0 sea-ice model
16   !!----------------------------------------------------------------------
17   !!   lim_sbc_alloc : allocate the limsbc arrays
18   !!   lim_sbc_init  : initialisation
19   !!   lim_sbc_flx   : updates mass, heat and salt fluxes at the ocean surface
20   !!   lim_sbc_tau   : update i- and j-stresses, and its modulus at the ocean surface
21   !!----------------------------------------------------------------------
22   USE par_oce          ! ocean parameters
23   USE par_ice          ! ice parameters
24   USE dom_oce          ! ocean domain
25   USE sbc_ice          ! Surface boundary condition: sea-ice fields
26   USE sbc_oce          ! Surface boundary condition: ocean fields
27   USE phycst           ! physical constants
28   USE albedo           ! albedo parameters
29   USE ice              ! LIM sea-ice variables
30   USE lbclnk           ! ocean lateral boundary condition
31   USE in_out_manager   ! I/O manager
32   USE lib_mpp          ! MPP library
33   USE prtctl           ! Print control
34   USE cpl_oasis3, ONLY : lk_cpl
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   lim_sbc_init   ! called by ice_init
40   PUBLIC   lim_sbc_flx    ! called by sbc_ice_lim
41   PUBLIC   lim_sbc_tau    ! called by sbc_ice_lim
42
43   REAL(wp)  ::   r1_rdtice            ! = 1. / rdt_ice
44   REAL(wp)  ::   epsi16 = 1.e-16_wp   ! constant values
45   REAL(wp)  ::   rzero  = 0._wp   
46   REAL(wp)  ::   rone   = 1._wp
47
48   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   utau_oce, vtau_oce   ! air-ocean surface i- & j-stress     [N/m2]
49   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   tmod_io              ! modulus of the ice-ocean velocity   [m/s]
50   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   soce_0  , sice_0     ! cst SSS and ice salinity (levitating sea-ice)
51
52   !! * Substitutions
53#  include "vectopt_loop_substitute.h90"
54   !!----------------------------------------------------------------------
55   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011)
56   !! $Id$
57   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
58   !!----------------------------------------------------------------------
59CONTAINS
60
61   INTEGER FUNCTION lim_sbc_alloc()
62      !!-------------------------------------------------------------------
63      !!             ***  ROUTINE lim_sbc_alloc ***
64      !!-------------------------------------------------------------------
65      ALLOCATE( soce_0(jpi,jpj) , utau_oce(jpi,jpj) ,                       &
66         &      sice_0(jpi,jpj) , vtau_oce(jpi,jpj) , tmod_io(jpi,jpj), STAT=lim_sbc_alloc)
67         !
68      IF( lk_mpp             )   CALL mpp_sum( lim_sbc_alloc )
69      IF( lim_sbc_alloc /= 0 )   CALL ctl_warn('lim_sbc_alloc: failed to allocate arrays')
70   END FUNCTION lim_sbc_alloc
71
72
73   SUBROUTINE lim_sbc_flx( kt )
74      !!-------------------------------------------------------------------
75      !!                ***  ROUTINE lim_sbc_flx ***
76      !! 
77      !! ** Purpose :   Update the surface ocean boundary condition for heat
78      !!              salt and mass over areas where sea-ice is non-zero
79      !!         
80      !! ** Action  : - computes the heat and freshwater/salt fluxes
81      !!              at the ice-ocean interface.
82      !!              - Update the ocean sbc
83      !!     
84      !! ** Outputs : - qsr     : sea heat flux:     solar
85      !!              - qns     : sea heat flux: non solar
86      !!              - emp     : freshwater budget: volume flux
87      !!              - emps    : freshwater budget: concentration/dillution
88      !!              - fr_i    : ice fraction
89      !!              - tn_ice  : sea-ice surface temperature
90      !!              - alb_ice : sea-ice alberdo (lk_cpl=T)
91      !!
92      !! References : Goosse, H. et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90.
93      !!              Tartinville et al. 2001 Ocean Modelling, 3, 95-108.
94      !!---------------------------------------------------------------------
95      USE wrk_nemo, ONLY:   wrk_not_released, wrk_in_use
96      USE wrk_nemo, ONLY:   zfcm1 => wrk_2d_1 , zfcm2 => wrk_2d_2   ! 2D workspace
97      USE wrk_nemo, ONLY:   wrk_3d_4, wrk_3d_5                      ! 3D workspace
98      !
99      INTEGER, INTENT(in) ::   kt    ! number of iteration
100      !
101      INTEGER  ::   ji, jj           ! dummy loop indices
102      INTEGER  ::   ierr             ! local integer
103      INTEGER  ::   ifvt, i1mfr, idfr               ! some switches
104      INTEGER  ::   iflt, ial, iadv, ifral, ifrdv
105      REAL(wp) ::   zinda, zfons, zpme              ! local scalars
106      !
107      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zalb, zalbp   ! 2D/3D workspace
108      !!---------------------------------------------------------------------
109
110      IF( wrk_in_use(2, 1,2) .OR. wrk_in_use(3, 4,5) ) THEN
111         CALL ctl_stop( 'lim_sbc_flx : requested workspace arrays unavailable' )   ;   RETURN
112      ENDIF
113      ! Set-up pointers to sub-arrays of 3d workspaces
114      zalb  => wrk_3d_4(:,:,1:jpl)
115      zalbp => wrk_3d_5(:,:,1:jpl)
116
117      !------------------------------------------!
118      !      heat flux at the ocean surface      !
119      !------------------------------------------!
120      ! pfrld is the lead fraction at the previous time step (actually between TRP and THD)
121      ! changed to old_frld and old ht_i
122
123      DO jj = 1, jpj
124         DO ji = 1, jpi
125            zinda   = 1.0 - MAX( rzero , SIGN( rone , - ( 1.0 - pfrld(ji,jj) ) ) )
126            ifvt    = zinda  *  MAX( rzero , SIGN( rone, -phicif  (ji,jj) ) )  !subscripts are bad here
127            i1mfr   = 1.0 - MAX( rzero , SIGN( rone ,  - ( at_i(ji,jj)       ) ) )
128            idfr    = 1.0 - MAX( rzero , SIGN( rone , ( 1.0 - at_i(ji,jj) ) - pfrld(ji,jj) ) )
129            iflt    = zinda  * (1 - i1mfr) * (1 - ifvt )
130            ial     = ifvt   * i1mfr + ( 1 - ifvt ) * idfr
131            iadv    = ( 1  - i1mfr ) * zinda
132            ifral   = ( 1  - i1mfr * ( 1 - ial ) )   
133            ifrdv   = ( 1  - ifral * ( 1 - ial ) ) * iadv 
134
135            ! switch --- 1.0 ---------------- 0.0 --------------------
136            ! ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
137            ! zinda   | if pfrld = 1       | if pfrld < 1            |
138            !  -> ifvt| if pfrld old_ht_i
139            ! i1mfr   | if frld = 1        | if frld  < 1            |
140            ! idfr    | if frld <= pfrld    | if frld > pfrld        |
141            ! iflt    |
142            ! ial     |
143            ! iadv    |
144            ! ifral
145            ! ifrdv
146
147            !   computation the solar flux at ocean surface
148            zfcm1(ji,jj)   = pfrld(ji,jj) * qsr(ji,jj)  + ( 1. - pfrld(ji,jj) ) * fstric(ji,jj)
149            ! fstric     Solar flux transmitted trough the ice
150            ! qsr        Net short wave heat flux on free ocean
151            ! new line
152            fscmbq(ji,jj) = ( 1.0 - pfrld(ji,jj) ) * fstric(ji,jj)
153
154            !  computation the non solar heat flux at ocean surface
155            zfcm2(ji,jj) = - zfcm1(ji,jj)                  &
156               &           + iflt    * ( fscmbq(ji,jj) )   & ! total abl -> fscmbq is given to the ocean
157               ! fscmbq and ffltbif are obsolete
158               !              &           + iflt * ffltbif(ji,jj) !!! only if one category is used
159               &           + ifral   * ( ial * qcmif(ji,jj) + (1 - ial) * qldif(ji,jj) ) * r1_rdtice   &
160               &           + ifrdv   * ( qfvbq(ji,jj) + qdtcn(ji,jj) )                   * r1_rdtice   &
161               &           + fhmec(ji,jj)     & ! new contribution due to snow melt in ridging!!
162               &           + fheat_rpo(ji,jj) & ! contribution from ridge formation
163               &           + fheat_res(ji,jj)
164            ! fscmbq  Part of the solar radiation transmitted through the ice and going to the ocean
165            !         computed in limthd_zdf.F90
166            ! ffltbif Total heat content of the ice (brine pockets+ice) / delta_t
167            ! qcmif   Energy needed to bring the ocean surface layer until its freezing (ok)
168            ! qldif   heat balance of the lead (or of the open ocean)
169            ! qfvbq   i think this is wrong!
170            ! ---> Array used to store energy in case of total lateral ablation
171            ! qfvbq latent heat uptake/release after accretion/ablation
172            ! qdtcn Energy from the turbulent oceanic heat flux heat flux coming in the lead
173
174            IF ( num_sal == 2 ) zfcm2(ji,jj) = zfcm2(ji,jj) + &
175               fhbri(ji,jj) ! new contribution due to brine drainage
176
177            ! bottom radiative component is sent to the computation of the
178            ! oceanic heat flux
179            fsbbq(ji,jj) = ( 1.0 - ( ifvt + iflt ) ) * fscmbq(ji,jj)     
180
181            ! used to compute the oceanic heat flux at the next time step
182            qsr(ji,jj) = zfcm1(ji,jj)                                       ! solar heat flux
183            qns(ji,jj) = zfcm2(ji,jj) - fdtcn(ji,jj)                        ! non solar heat flux
184            !                           ! fdtcn : turbulent oceanic heat flux
185
186            !!gm   this IF prevents the vertorisation of the whole loop
187            IF ( ( ji == jiindx ) .AND. ( jj == jjindx) ) THEN
188               WRITE(numout,*) ' lim_sbc : heat fluxes '
189               WRITE(numout,*) ' qsr       : ', qsr(jiindx,jjindx)
190               WRITE(numout,*) ' zfcm1     : ', zfcm1(jiindx,jjindx)
191               WRITE(numout,*) ' pfrld     : ', pfrld(jiindx,jjindx)
192               WRITE(numout,*) ' fstric    : ', fstric (jiindx,jjindx)
193               WRITE(numout,*)
194               WRITE(numout,*) ' qns       : ', qns(jiindx,jjindx)
195               WRITE(numout,*) ' zfcm2     : ', zfcm2(jiindx,jjindx)
196               WRITE(numout,*) ' zfcm1     : ', zfcm1(jiindx,jjindx)
197               WRITE(numout,*) ' ifral     : ', ifral
198               WRITE(numout,*) ' ial       : ', ial 
199               WRITE(numout,*) ' qcmif     : ', qcmif(jiindx,jjindx)
200               WRITE(numout,*) ' qldif     : ', qldif(jiindx,jjindx)
201               WRITE(numout,*) ' qcmif / dt: ', qcmif(jiindx,jjindx) * r1_rdtice
202               WRITE(numout,*) ' qldif / dt: ', qldif(jiindx,jjindx) * r1_rdtice
203               WRITE(numout,*) ' ifrdv     : ', ifrdv
204               WRITE(numout,*) ' qfvbq     : ', qfvbq(jiindx,jjindx)
205               WRITE(numout,*) ' qdtcn     : ', qdtcn(jiindx,jjindx)
206               WRITE(numout,*) ' qfvbq / dt: ', qfvbq(jiindx,jjindx) * r1_rdtice
207               WRITE(numout,*) ' qdtcn / dt: ', qdtcn(jiindx,jjindx) * r1_rdtice
208               WRITE(numout,*) ' '
209               WRITE(numout,*) ' fdtcn     : ', fdtcn(jiindx,jjindx)
210               WRITE(numout,*) ' fhmec     : ', fhmec(jiindx,jjindx)
211               WRITE(numout,*) ' fheat_rpo : ', fheat_rpo(jiindx,jjindx)
212               WRITE(numout,*) ' fhbri     : ', fhbri(jiindx,jjindx)
213               WRITE(numout,*) ' fheat_res : ', fheat_res(jiindx,jjindx)
214            ENDIF
215            !!gm   end
216         END DO
217      END DO
218
219      !------------------------------------------!
220      !      mass flux at the ocean surface      !
221      !------------------------------------------!
222
223!!gm   optimisation: this loop have to be merged with the previous one
224      DO jj = 1, jpj
225         DO ji = 1, jpi
226            !  case of realistic freshwater flux (Tartinville et al., 2001) (presently ACTIVATED)
227            !  -------------------------------------------------------------------------------------
228            !  The idea of this approach is that the system that we consider is the ICE-OCEAN system
229            !  Thus  FW  flux  =  External ( E-P+snow melt)
230            !       Salt flux  =  Exchanges in the ice-ocean system then converted into FW
231            !                     Associated to Ice formation AND Ice melting
232            !                     Even if i see Ice melting as a FW and SALT flux
233            !       
234
235            !  computing freshwater exchanges at the ice/ocean interface
236            zpme = - emp(ji,jj)     * ( 1.0 - at_i(ji,jj)          )  &   ! evaporation over oceanic fraction
237               &   + tprecip(ji,jj) *         at_i(ji,jj)             &   ! all precipitation reach the ocean
238               &   - sprecip(ji,jj) * ( 1. - (pfrld(ji,jj)**betas) )  &   ! except solid precip intercepted by sea-ice
239               &   - rdmsnif(ji,jj) * r1_rdtice                       &   ! freshwaterflux due to snow melting
240               &   + fmmec(ji,jj)                                         ! snow falling when ridging
241
242
243            !  computing salt exchanges at the ice/ocean interface
244            !  sice should be the same as computed with the ice model
245            zfons =  ( soce_0(ji,jj) - sice_0(ji,jj) ) * rdmicif(ji,jj) * r1_rdtice 
246            ! SOCE
247            zfons =  ( sss_m (ji,jj) - sice_0(ji,jj) ) * rdmicif(ji,jj) * r1_rdtice
248
249            !CT useless            !  salt flux for constant salinity
250            !CT useless            fsalt(ji,jj)      =  zfons / ( sss_m(ji,jj) + epsi16 ) + fsalt_res(ji,jj)
251            !  salt flux for variable salinity
252            zinda             = 1.0 - MAX( rzero , SIGN( rone , - ( 1.0 - pfrld(ji,jj) ) ) )
253            !  correcting brine and salt fluxes
254            fsbri(ji,jj)      =  zinda*fsbri(ji,jj)
255            !  converting the salt fluxes from ice to a freshwater flux from ocean
256            fsalt_res(ji,jj)  =  fsalt_res(ji,jj) / ( sss_m(ji,jj) + epsi16 )
257            fseqv(ji,jj)      =  fseqv(ji,jj)     / ( sss_m(ji,jj) + epsi16 )
258            fsbri(ji,jj)      =  fsbri(ji,jj)     / ( sss_m(ji,jj) + epsi16 )
259            fsalt_rpo(ji,jj)  =  fsalt_rpo(ji,jj) / ( sss_m(ji,jj) + epsi16 )
260
261            !  freshwater mass exchange (positive to the ice, negative for the ocean ?)
262            !  actually it's a salt flux (so it's minus freshwater flux)
263            !  if sea ice grows, zfons is positive, fsalt also
264            !  POSITIVE SALT FLUX FROM THE ICE TO THE OCEAN
265            !  POSITIVE FRESHWATER FLUX FROM THE OCEAN TO THE ICE [kg.m-2.s-1]
266
267            emp(ji,jj) = - zpme 
268         END DO
269      END DO
270
271      IF( num_sal == 2 ) THEN      ! variable ice salinity: brine drainage included in the salt flux
272         emps(:,:) = fsbri(:,:) + fseqv(:,:) + fsalt_res(:,:) + fsalt_rpo(:,:) + emp(:,:)
273      ELSE                         ! constant ice salinity:
274         emps(:,:) =              fseqv(:,:) + fsalt_res(:,:) + fsalt_rpo(:,:) + emp(:,:)
275      ENDIF
276
277      !-----------------------------------------------!
278      !   Storing the transmitted variables           !
279      !-----------------------------------------------!
280      fr_i  (:,:)   = at_i(:,:)             ! Sea-ice fraction           
281      tn_ice(:,:,:) = t_su(:,:,:)           ! Ice surface temperature                     
282
283      !------------------------------------------------!
284      !    Computation of snow/ice and ocean albedo    !
285      !------------------------------------------------!
286      IF( lk_cpl ) THEN          ! coupled case
287         CALL albedo_ice( t_su, ht_i, ht_s, zalbp, zalb )                  ! snow/ice albedo
288         !
289         alb_ice(:,:,:) =  0.5_wp * zalbp(:,:,:) + 0.5_wp * zalb (:,:,:)   ! Ice albedo (mean clear and overcast skys)
290      ENDIF
291
292      IF(ln_ctl) THEN
293         CALL prt_ctl( tab2d_1=qsr   , clinfo1=' lim_sbc: qsr    : ', tab2d_2=qns , clinfo2=' qns     : ' )
294         CALL prt_ctl( tab2d_1=emp   , clinfo1=' lim_sbc: emp    : ', tab2d_2=emps, clinfo2=' emps    : ' )
295         CALL prt_ctl( tab2d_1=fr_i  , clinfo1=' lim_sbc: fr_i   : ' )
296         CALL prt_ctl( tab3d_1=tn_ice, clinfo1=' lim_sbc: tn_ice : ', kdim=jpl )
297      ENDIF
298      !
299      IF( wrk_not_released(2, 1,2)    .OR.   &
300          wrk_not_released(3, 4,5)  )        &
301          CALL ctl_stop( 'lim_sbc_flx: failed to release workspace arrays' )
302      !
303   END SUBROUTINE lim_sbc_flx
304
305
306   SUBROUTINE lim_sbc_tau( kt , pu_oce, pv_oce )
307      !!-------------------------------------------------------------------
308      !!                ***  ROUTINE lim_sbc_tau ***
309      !! 
310      !! ** Purpose : Update the ocean surface stresses due to the ice
311      !!         
312      !! ** Action  : * at each ice time step (every nn_fsbc time step):
313      !!                - compute the modulus of ice-ocean relative velocity
314      !!                  (*rho*Cd) at T-point (C-grid) or I-point (B-grid)
315      !!                      tmod_io = rhoco * | U_ice-U_oce |
316      !!                - update the modulus of stress at ocean surface
317      !!                      taum = frld * taum + (1-frld) * tmod_io * | U_ice-U_oce |
318      !!              * at each ocean time step (every kt):
319      !!                  compute linearized ice-ocean stresses as
320      !!                      Utau = tmod_io * | U_ice - pU_oce |
321      !!                using instantaneous current ocean velocity (usually before)
322      !!
323      !!    NB: - ice-ocean rotation angle no more allowed
324      !!        - here we make an approximation: taum is only computed every ice time step
325      !!          This avoids mutiple average to pass from T -> U,V grids and next from U,V grids
326      !!          to T grid. taum is used in TKE and GLS, which should not be too sensitive to this approximaton...
327      !!
328      !! ** Outputs : - utau, vtau   : surface ocean i- and j-stress (u- & v-pts) updated with ice-ocean fluxes
329      !!              - taum         : modulus of the surface ocean stress (T-point) updated with ice-ocean fluxes
330      !!---------------------------------------------------------------------
331      INTEGER ,                     INTENT(in) ::   kt               ! ocean time-step index
332      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   pu_oce, pv_oce   ! surface ocean currents
333      !!
334      INTEGER  ::   ji, jj   ! dummy loop indices
335      REAL(wp) ::   zat_u, zutau_ice, zu_t, zmodt   ! local scalar
336      REAL(wp) ::   zat_v, zvtau_ice, zv_t          !   -      -
337      !!---------------------------------------------------------------------
338      !
339      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN     !==  Ice time-step only  ==!   (i.e. surface module time-step)
340!CDIR NOVERRCHK
341         DO jj = 2, jpjm1                             !* update the modulus of stress at ocean surface (T-point)
342!CDIR NOVERRCHK
343            DO ji = fs_2, fs_jpim1
344               !                                               ! 2*(U_ice-U_oce) at T-point
345               zu_t = u_ice(ji,jj) + u_ice(ji-1,jj) - u_oce(ji,jj) - u_oce(ji-1,jj)   
346               zv_t = v_ice(ji,jj) + v_ice(ji,jj-1) - v_oce(ji,jj) - v_oce(ji,jj-1) 
347               !                                              ! |U_ice-U_oce|^2
348               zmodt =  0.25_wp * (  zu_t * zu_t + zv_t * zv_t  )
349               !                                               ! update the ocean stress modulus
350               taum(ji,jj) = ( 1._wp - at_i(ji,jj) ) * taum(ji,jj) + at_i(ji,jj) * rhoco * zmodt
351               tmod_io(ji,jj) = rhoco * SQRT( zmodt )          ! rhoco * |U_ice-U_oce| at T-point
352            END DO
353         END DO
354         CALL lbc_lnk( taum, 'T', 1. )   ;   CALL lbc_lnk( tmod_io, 'T', 1. )
355         !
356         utau_oce(:,:) = utau(:,:)                    !* save the air-ocean stresses at ice time-step
357         vtau_oce(:,:) = vtau(:,:)
358         !
359      ENDIF
360      !
361      !                                      !==  every ocean time-step  ==!
362      !
363      DO jj = 2, jpjm1                                !* update the stress WITHOUT a ice-ocean rotation angle
364         DO ji = fs_2, fs_jpim1   ! Vect. Opt.
365            zat_u  = ( at_i(ji,jj) + at_i(ji+1,jj) ) * 0.5_wp   ! ice area at u and V-points
366            zat_v  = ( at_i(ji,jj) + at_i(ji,jj+1) ) * 0.5_wp
367            !                                                   ! linearized quadratic drag formulation
368            zutau_ice   = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji+1,jj) ) * ( u_ice(ji,jj) - pu_oce(ji,jj) )
369            zvtau_ice   = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji,jj+1) ) * ( v_ice(ji,jj) - pv_oce(ji,jj) )
370            !                                                   ! stresses at the ocean surface
371            utau(ji,jj) = ( 1._wp - zat_u ) * utau_oce(ji,jj) + zat_u * zutau_ice
372            vtau(ji,jj) = ( 1._wp - zat_v ) * vtau_oce(ji,jj) + zat_v * zvtau_ice
373         END DO
374      END DO
375      CALL lbc_lnk( utau, 'U', -1. )   ;   CALL lbc_lnk( vtau, 'V', -1. )   ! lateral boundary condition
376      !
377      IF(ln_ctl)   CALL prt_ctl( tab2d_1=utau, clinfo1=' lim_sbc: utau   : ', mask1=umask,   &
378         &                       tab2d_2=vtau, clinfo2=' vtau    : '        , mask2=vmask )
379     
380   END SUBROUTINE lim_sbc_tau
381
382
383   SUBROUTINE lim_sbc_init
384      !!-------------------------------------------------------------------
385      !!                  ***  ROUTINE lim_sbc_init  ***
386      !!             
387      !! ** Purpose : Preparation of the file ice_evolu for the output of
388      !!      the temporal evolution of key variables
389      !!
390      !! ** input   : Namelist namicedia
391      !!-------------------------------------------------------------------
392      !
393      IF(lwp) WRITE(numout,*)
394      IF(lwp) WRITE(numout,*) 'lim_sbc_init : LIM-3 sea-ice - surface boundary condition'
395      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~   '
396
397      !                                      ! allocate lim_sbc array
398      IF( lim_sbc_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'lim_sbc_init : unable to allocate standard arrays' )
399      !
400      r1_rdtice = 1. / rdt_ice
401      !
402      soce_0(:,:) = soce                     ! constant SSS and ice salinity used in levitating sea-ice case
403      sice_0(:,:) = sice
404      !
405      IF( cp_cfg == "orca" ) THEN            ! decrease ocean & ice reference salinities in the Baltic sea
406         WHERE( 14._wp <= glamt(:,:) .AND. glamt(:,:) <= 32._wp .AND.   &
407            &   54._wp <= gphit(:,:) .AND. gphit(:,:) <= 66._wp         ) 
408            soce_0(:,:) = 4._wp
409            sice_0(:,:) = 2._wp
410         END WHERE
411      ENDIF
412      !
413   END SUBROUTINE lim_sbc_init
414
415#else
416   !!----------------------------------------------------------------------
417   !!   Default option :        Dummy module       NO LIM 3.0 sea-ice model
418   !!----------------------------------------------------------------------
419CONTAINS
420   SUBROUTINE lim_sbc           ! Dummy routine
421   END SUBROUTINE lim_sbc
422#endif 
423
424   !!======================================================================
425END MODULE limsbc
Note: See TracBrowser for help on using the repository browser.