New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limsbc.F90 in trunk/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: trunk/NEMOGCM/NEMO/LIM_SRC_3/limsbc.F90 @ 3294

Last change on this file since 3294 was 3294, checked in by rblod, 12 years ago

Merge of 3.4beta into the trunk

  • Property svn:keywords set to Id
File size: 22.5 KB
Line 
1MODULE limsbc
2   !!======================================================================
3   !!                       ***  MODULE limsbc   ***
4   !!           computation of the flux at the sea ice/ocean interface
5   !!======================================================================
6   !! History :   -   ! 2006-07 (M. Vancoppelle)  LIM3 original code
7   !!            3.0  ! 2008-03 (C. Tallandier)  surface module
8   !!             -   ! 2008-04 (C. Tallandier)  split in 2 + new ice-ocean coupling
9   !!            3.3  ! 2010-05 (G. Madec) decrease ocean & ice reference salinities in the Baltic sea
10   !!                 !                  + simplification of the ice-ocean stress calculation
11   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
12   !!----------------------------------------------------------------------
13#if defined key_lim3
14   !!----------------------------------------------------------------------
15   !!   'key_lim3'                                    LIM 3.0 sea-ice model
16   !!----------------------------------------------------------------------
17   !!   lim_sbc_alloc : allocate the limsbc arrays
18   !!   lim_sbc_init  : initialisation
19   !!   lim_sbc_flx   : updates mass, heat and salt fluxes at the ocean surface
20   !!   lim_sbc_tau   : update i- and j-stresses, and its modulus at the ocean surface
21   !!----------------------------------------------------------------------
22   USE par_oce          ! ocean parameters
23   USE par_ice          ! ice parameters
24   USE dom_oce          ! ocean domain
25   USE sbc_ice          ! Surface boundary condition: sea-ice fields
26   USE sbc_oce          ! Surface boundary condition: ocean fields
27   USE phycst           ! physical constants
28   USE albedo           ! albedo parameters
29   USE ice              ! LIM sea-ice variables
30   USE lbclnk           ! ocean lateral boundary condition
31   USE in_out_manager   ! I/O manager
32   USE lib_mpp          ! MPP library
33   USE wrk_nemo         ! work arrays
34   USE prtctl           ! Print control
35   USE cpl_oasis3, ONLY : lk_cpl
36
37   IMPLICIT NONE
38   PRIVATE
39
40   PUBLIC   lim_sbc_init   ! called by ice_init
41   PUBLIC   lim_sbc_flx    ! called by sbc_ice_lim
42   PUBLIC   lim_sbc_tau    ! called by sbc_ice_lim
43
44   REAL(wp)  ::   r1_rdtice            ! = 1. / rdt_ice
45   REAL(wp)  ::   epsi16 = 1.e-16_wp   ! constant values
46   REAL(wp)  ::   rzero  = 0._wp   
47   REAL(wp)  ::   rone   = 1._wp
48
49   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   utau_oce, vtau_oce   ! air-ocean surface i- & j-stress     [N/m2]
50   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   tmod_io              ! modulus of the ice-ocean velocity   [m/s]
51   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   soce_0  , sice_0     ! cst SSS and ice salinity (levitating sea-ice)
52
53   !! * Substitutions
54#  include "vectopt_loop_substitute.h90"
55   !!----------------------------------------------------------------------
56   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011)
57   !! $Id$
58   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
59   !!----------------------------------------------------------------------
60CONTAINS
61
62   INTEGER FUNCTION lim_sbc_alloc()
63      !!-------------------------------------------------------------------
64      !!             ***  ROUTINE lim_sbc_alloc ***
65      !!-------------------------------------------------------------------
66      ALLOCATE( soce_0(jpi,jpj) , utau_oce(jpi,jpj) ,                       &
67         &      sice_0(jpi,jpj) , vtau_oce(jpi,jpj) , tmod_io(jpi,jpj), STAT=lim_sbc_alloc)
68         !
69      IF( lk_mpp             )   CALL mpp_sum( lim_sbc_alloc )
70      IF( lim_sbc_alloc /= 0 )   CALL ctl_warn('lim_sbc_alloc: failed to allocate arrays')
71   END FUNCTION lim_sbc_alloc
72
73
74   SUBROUTINE lim_sbc_flx( kt )
75      !!-------------------------------------------------------------------
76      !!                ***  ROUTINE lim_sbc_flx ***
77      !! 
78      !! ** Purpose :   Update the surface ocean boundary condition for heat
79      !!              salt and mass over areas where sea-ice is non-zero
80      !!         
81      !! ** Action  : - computes the heat and freshwater/salt fluxes
82      !!              at the ice-ocean interface.
83      !!              - Update the ocean sbc
84      !!     
85      !! ** Outputs : - qsr     : sea heat flux:     solar
86      !!              - qns     : sea heat flux: non solar
87      !!              - emp     : freshwater budget: volume flux
88      !!              - emps    : freshwater budget: concentration/dillution
89      !!              - fr_i    : ice fraction
90      !!              - tn_ice  : sea-ice surface temperature
91      !!              - alb_ice : sea-ice alberdo (lk_cpl=T)
92      !!
93      !! References : Goosse, H. et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90.
94      !!              Tartinville et al. 2001 Ocean Modelling, 3, 95-108.
95      !!---------------------------------------------------------------------
96      INTEGER, INTENT(in) ::   kt    ! number of iteration
97      !
98      INTEGER  ::   ji, jj           ! dummy loop indices
99      INTEGER  ::   ierr             ! local integer
100      INTEGER  ::   ifvt, i1mfr, idfr               ! some switches
101      INTEGER  ::   iflt, ial, iadv, ifral, ifrdv
102      REAL(wp) ::   zinda, zfons, zpme              ! local scalars
103      REAL(wp), POINTER, DIMENSION(:,:) ::   zfcm1 , zfcm2    ! solar/non solar heat fluxes
104      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zalb, zalbp   ! 2D/3D workspace
105      !!---------------------------------------------------------------------
106     
107      CALL wrk_alloc( jpi, jpj, zfcm1 , zfcm2 )
108      IF( lk_cpl )   CALL wrk_alloc( jpi, jpj, jpl, zalb, zalbp )
109
110      !------------------------------------------!
111      !      heat flux at the ocean surface      !
112      !------------------------------------------!
113      ! pfrld is the lead fraction at the previous time step (actually between TRP and THD)
114      ! changed to old_frld and old ht_i
115
116      DO jj = 1, jpj
117         DO ji = 1, jpi
118            zinda   = 1.0 - MAX( rzero , SIGN( rone , - ( 1.0 - pfrld(ji,jj) ) ) )
119            ifvt    = zinda  *  MAX( rzero , SIGN( rone, -phicif  (ji,jj) ) )  !subscripts are bad here
120            i1mfr   = 1.0 - MAX( rzero , SIGN( rone ,  - ( at_i(ji,jj)       ) ) )
121            idfr    = 1.0 - MAX( rzero , SIGN( rone , ( 1.0 - at_i(ji,jj) ) - pfrld(ji,jj) ) )
122            iflt    = zinda  * (1 - i1mfr) * (1 - ifvt )
123            ial     = ifvt   * i1mfr + ( 1 - ifvt ) * idfr
124            iadv    = ( 1  - i1mfr ) * zinda
125            ifral   = ( 1  - i1mfr * ( 1 - ial ) )   
126            ifrdv   = ( 1  - ifral * ( 1 - ial ) ) * iadv 
127
128            ! switch --- 1.0 ---------------- 0.0 --------------------
129            ! ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
130            ! zinda   | if pfrld = 1       | if pfrld < 1            |
131            !  -> ifvt| if pfrld old_ht_i
132            ! i1mfr   | if frld = 1        | if frld  < 1            |
133            ! idfr    | if frld <= pfrld    | if frld > pfrld        |
134            ! iflt    |
135            ! ial     |
136            ! iadv    |
137            ! ifral
138            ! ifrdv
139
140            !   computation the solar flux at ocean surface
141            zfcm1(ji,jj)   = pfrld(ji,jj) * qsr(ji,jj)  + ( 1. - pfrld(ji,jj) ) * fstric(ji,jj)
142            ! fstric     Solar flux transmitted trough the ice
143            ! qsr        Net short wave heat flux on free ocean
144            ! new line
145            fscmbq(ji,jj) = ( 1.0 - pfrld(ji,jj) ) * fstric(ji,jj)
146
147            !  computation the non solar heat flux at ocean surface
148            zfcm2(ji,jj) = - zfcm1(ji,jj)                  &
149               &           + iflt    * ( fscmbq(ji,jj) )   & ! total abl -> fscmbq is given to the ocean
150               ! fscmbq and ffltbif are obsolete
151               !              &           + iflt * ffltbif(ji,jj) !!! only if one category is used
152               &           + ifral   * ( ial * qcmif(ji,jj) + (1 - ial) * qldif(ji,jj) ) * r1_rdtice   &
153               &           + ifrdv   * ( qfvbq(ji,jj) + qdtcn(ji,jj) )                   * r1_rdtice   &
154               &           + fhmec(ji,jj)     & ! new contribution due to snow melt in ridging!!
155               &           + fheat_rpo(ji,jj) & ! contribution from ridge formation
156               &           + fheat_res(ji,jj)
157            ! fscmbq  Part of the solar radiation transmitted through the ice and going to the ocean
158            !         computed in limthd_zdf.F90
159            ! ffltbif Total heat content of the ice (brine pockets+ice) / delta_t
160            ! qcmif   Energy needed to bring the ocean surface layer until its freezing (ok)
161            ! qldif   heat balance of the lead (or of the open ocean)
162            ! qfvbq   i think this is wrong!
163            ! ---> Array used to store energy in case of total lateral ablation
164            ! qfvbq latent heat uptake/release after accretion/ablation
165            ! qdtcn Energy from the turbulent oceanic heat flux heat flux coming in the lead
166
167            IF ( num_sal == 2 ) zfcm2(ji,jj) = zfcm2(ji,jj) + &
168               fhbri(ji,jj) ! new contribution due to brine drainage
169
170            ! bottom radiative component is sent to the computation of the
171            ! oceanic heat flux
172            fsbbq(ji,jj) = ( 1.0 - ( ifvt + iflt ) ) * fscmbq(ji,jj)     
173
174            ! used to compute the oceanic heat flux at the next time step
175            qsr(ji,jj) = zfcm1(ji,jj)                                       ! solar heat flux
176            qns(ji,jj) = zfcm2(ji,jj) - fdtcn(ji,jj)                        ! non solar heat flux
177            !                           ! fdtcn : turbulent oceanic heat flux
178
179            !!gm   this IF prevents the vertorisation of the whole loop
180            IF ( ( ji == jiindx ) .AND. ( jj == jjindx) ) THEN
181               WRITE(numout,*) ' lim_sbc : heat fluxes '
182               WRITE(numout,*) ' qsr       : ', qsr(jiindx,jjindx)
183               WRITE(numout,*) ' zfcm1     : ', zfcm1(jiindx,jjindx)
184               WRITE(numout,*) ' pfrld     : ', pfrld(jiindx,jjindx)
185               WRITE(numout,*) ' fstric    : ', fstric (jiindx,jjindx)
186               WRITE(numout,*)
187               WRITE(numout,*) ' qns       : ', qns(jiindx,jjindx)
188               WRITE(numout,*) ' zfcm2     : ', zfcm2(jiindx,jjindx)
189               WRITE(numout,*) ' zfcm1     : ', zfcm1(jiindx,jjindx)
190               WRITE(numout,*) ' ifral     : ', ifral
191               WRITE(numout,*) ' ial       : ', ial 
192               WRITE(numout,*) ' qcmif     : ', qcmif(jiindx,jjindx)
193               WRITE(numout,*) ' qldif     : ', qldif(jiindx,jjindx)
194               WRITE(numout,*) ' qcmif / dt: ', qcmif(jiindx,jjindx) * r1_rdtice
195               WRITE(numout,*) ' qldif / dt: ', qldif(jiindx,jjindx) * r1_rdtice
196               WRITE(numout,*) ' ifrdv     : ', ifrdv
197               WRITE(numout,*) ' qfvbq     : ', qfvbq(jiindx,jjindx)
198               WRITE(numout,*) ' qdtcn     : ', qdtcn(jiindx,jjindx)
199               WRITE(numout,*) ' qfvbq / dt: ', qfvbq(jiindx,jjindx) * r1_rdtice
200               WRITE(numout,*) ' qdtcn / dt: ', qdtcn(jiindx,jjindx) * r1_rdtice
201               WRITE(numout,*) ' '
202               WRITE(numout,*) ' fdtcn     : ', fdtcn(jiindx,jjindx)
203               WRITE(numout,*) ' fhmec     : ', fhmec(jiindx,jjindx)
204               WRITE(numout,*) ' fheat_rpo : ', fheat_rpo(jiindx,jjindx)
205               WRITE(numout,*) ' fhbri     : ', fhbri(jiindx,jjindx)
206               WRITE(numout,*) ' fheat_res : ', fheat_res(jiindx,jjindx)
207            ENDIF
208            !!gm   end
209         END DO
210      END DO
211
212      !------------------------------------------!
213      !      mass flux at the ocean surface      !
214      !------------------------------------------!
215
216!!gm   optimisation: this loop have to be merged with the previous one
217      DO jj = 1, jpj
218         DO ji = 1, jpi
219            !  case of realistic freshwater flux (Tartinville et al., 2001) (presently ACTIVATED)
220            !  -------------------------------------------------------------------------------------
221            !  The idea of this approach is that the system that we consider is the ICE-OCEAN system
222            !  Thus  FW  flux  =  External ( E-P+snow melt)
223            !       Salt flux  =  Exchanges in the ice-ocean system then converted into FW
224            !                     Associated to Ice formation AND Ice melting
225            !                     Even if i see Ice melting as a FW and SALT flux
226            !       
227
228            !  computing freshwater exchanges at the ice/ocean interface
229            zpme = - emp(ji,jj)     * ( 1.0 - at_i(ji,jj)          )  &   ! evaporation over oceanic fraction
230               &   + tprecip(ji,jj) *         at_i(ji,jj)             &   ! all precipitation reach the ocean
231               &   - sprecip(ji,jj) * ( 1. - (pfrld(ji,jj)**betas) )  &   ! except solid precip intercepted by sea-ice
232               &   - rdmsnif(ji,jj) * r1_rdtice                       &   ! freshwaterflux due to snow melting
233               &   + fmmec(ji,jj)                                         ! snow falling when ridging
234
235
236            !  computing salt exchanges at the ice/ocean interface
237            !  sice should be the same as computed with the ice model
238            zfons =  ( soce_0(ji,jj) - sice_0(ji,jj) ) * rdmicif(ji,jj) * r1_rdtice 
239            ! SOCE
240            zfons =  ( sss_m (ji,jj) - sice_0(ji,jj) ) * rdmicif(ji,jj) * r1_rdtice
241
242            !CT useless            !  salt flux for constant salinity
243            !CT useless            fsalt(ji,jj)      =  zfons / ( sss_m(ji,jj) + epsi16 ) + fsalt_res(ji,jj)
244            !  salt flux for variable salinity
245            zinda             = 1.0 - MAX( rzero , SIGN( rone , - ( 1.0 - pfrld(ji,jj) ) ) )
246            !  correcting brine and salt fluxes
247            fsbri(ji,jj)      =  zinda*fsbri(ji,jj)
248            !  converting the salt fluxes from ice to a freshwater flux from ocean
249            fsalt_res(ji,jj)  =  fsalt_res(ji,jj) / ( sss_m(ji,jj) + epsi16 )
250            fseqv(ji,jj)      =  fseqv(ji,jj)     / ( sss_m(ji,jj) + epsi16 )
251            fsbri(ji,jj)      =  fsbri(ji,jj)     / ( sss_m(ji,jj) + epsi16 )
252            fsalt_rpo(ji,jj)  =  fsalt_rpo(ji,jj) / ( sss_m(ji,jj) + epsi16 )
253
254            !  freshwater mass exchange (positive to the ice, negative for the ocean ?)
255            !  actually it's a salt flux (so it's minus freshwater flux)
256            !  if sea ice grows, zfons is positive, fsalt also
257            !  POSITIVE SALT FLUX FROM THE ICE TO THE OCEAN
258            !  POSITIVE FRESHWATER FLUX FROM THE OCEAN TO THE ICE [kg.m-2.s-1]
259
260            emp(ji,jj) = - zpme 
261         END DO
262      END DO
263
264      IF( num_sal == 2 ) THEN      ! variable ice salinity: brine drainage included in the salt flux
265         emps(:,:) = fsbri(:,:) + fseqv(:,:) + fsalt_res(:,:) + fsalt_rpo(:,:) + emp(:,:)
266      ELSE                         ! constant ice salinity:
267         emps(:,:) =              fseqv(:,:) + fsalt_res(:,:) + fsalt_rpo(:,:) + emp(:,:)
268      ENDIF
269
270      !-----------------------------------------------!
271      !   Storing the transmitted variables           !
272      !-----------------------------------------------!
273      fr_i  (:,:)   = at_i(:,:)             ! Sea-ice fraction           
274      tn_ice(:,:,:) = t_su(:,:,:)           ! Ice surface temperature                     
275
276      !------------------------------------------------!
277      !    Computation of snow/ice and ocean albedo    !
278      !------------------------------------------------!
279      IF( lk_cpl ) THEN          ! coupled case
280         CALL albedo_ice( t_su, ht_i, ht_s, zalbp, zalb )                  ! snow/ice albedo
281         !
282         alb_ice(:,:,:) =  0.5_wp * zalbp(:,:,:) + 0.5_wp * zalb (:,:,:)   ! Ice albedo (mean clear and overcast skys)
283      ENDIF
284
285      IF(ln_ctl) THEN
286         CALL prt_ctl( tab2d_1=qsr   , clinfo1=' lim_sbc: qsr    : ', tab2d_2=qns , clinfo2=' qns     : ' )
287         CALL prt_ctl( tab2d_1=emp   , clinfo1=' lim_sbc: emp    : ', tab2d_2=emps, clinfo2=' emps    : ' )
288         CALL prt_ctl( tab2d_1=fr_i  , clinfo1=' lim_sbc: fr_i   : ' )
289         CALL prt_ctl( tab3d_1=tn_ice, clinfo1=' lim_sbc: tn_ice : ', kdim=jpl )
290      ENDIF
291      !
292      CALL wrk_dealloc( jpi, jpj, zfcm1 , zfcm2 )
293      IF( lk_cpl )   CALL wrk_dealloc( jpi, jpj, jpl, zalb, zalbp )
294      !
295   END SUBROUTINE lim_sbc_flx
296
297
298   SUBROUTINE lim_sbc_tau( kt , pu_oce, pv_oce )
299      !!-------------------------------------------------------------------
300      !!                ***  ROUTINE lim_sbc_tau ***
301      !! 
302      !! ** Purpose : Update the ocean surface stresses due to the ice
303      !!         
304      !! ** Action  : * at each ice time step (every nn_fsbc time step):
305      !!                - compute the modulus of ice-ocean relative velocity
306      !!                  (*rho*Cd) at T-point (C-grid) or I-point (B-grid)
307      !!                      tmod_io = rhoco * | U_ice-U_oce |
308      !!                - update the modulus of stress at ocean surface
309      !!                      taum = frld * taum + (1-frld) * tmod_io * | U_ice-U_oce |
310      !!              * at each ocean time step (every kt):
311      !!                  compute linearized ice-ocean stresses as
312      !!                      Utau = tmod_io * | U_ice - pU_oce |
313      !!                using instantaneous current ocean velocity (usually before)
314      !!
315      !!    NB: - ice-ocean rotation angle no more allowed
316      !!        - here we make an approximation: taum is only computed every ice time step
317      !!          This avoids mutiple average to pass from T -> U,V grids and next from U,V grids
318      !!          to T grid. taum is used in TKE and GLS, which should not be too sensitive to this approximaton...
319      !!
320      !! ** Outputs : - utau, vtau   : surface ocean i- and j-stress (u- & v-pts) updated with ice-ocean fluxes
321      !!              - taum         : modulus of the surface ocean stress (T-point) updated with ice-ocean fluxes
322      !!---------------------------------------------------------------------
323      INTEGER ,                     INTENT(in) ::   kt               ! ocean time-step index
324      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   pu_oce, pv_oce   ! surface ocean currents
325      !!
326      INTEGER  ::   ji, jj   ! dummy loop indices
327      REAL(wp) ::   zat_u, zutau_ice, zu_t, zmodt   ! local scalar
328      REAL(wp) ::   zat_v, zvtau_ice, zv_t          !   -      -
329      !!---------------------------------------------------------------------
330      !
331      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN     !==  Ice time-step only  ==!   (i.e. surface module time-step)
332!CDIR NOVERRCHK
333         DO jj = 2, jpjm1                             !* update the modulus of stress at ocean surface (T-point)
334!CDIR NOVERRCHK
335            DO ji = fs_2, fs_jpim1
336               !                                               ! 2*(U_ice-U_oce) at T-point
337               zu_t = u_ice(ji,jj) + u_ice(ji-1,jj) - u_oce(ji,jj) - u_oce(ji-1,jj)   
338               zv_t = v_ice(ji,jj) + v_ice(ji,jj-1) - v_oce(ji,jj) - v_oce(ji,jj-1) 
339               !                                              ! |U_ice-U_oce|^2
340               zmodt =  0.25_wp * (  zu_t * zu_t + zv_t * zv_t  )
341               !                                               ! update the ocean stress modulus
342               taum(ji,jj) = ( 1._wp - at_i(ji,jj) ) * taum(ji,jj) + at_i(ji,jj) * rhoco * zmodt
343               tmod_io(ji,jj) = rhoco * SQRT( zmodt )          ! rhoco * |U_ice-U_oce| at T-point
344            END DO
345         END DO
346         CALL lbc_lnk( taum, 'T', 1. )   ;   CALL lbc_lnk( tmod_io, 'T', 1. )
347         !
348         utau_oce(:,:) = utau(:,:)                    !* save the air-ocean stresses at ice time-step
349         vtau_oce(:,:) = vtau(:,:)
350         !
351      ENDIF
352      !
353      !                                      !==  every ocean time-step  ==!
354      !
355      DO jj = 2, jpjm1                                !* update the stress WITHOUT a ice-ocean rotation angle
356         DO ji = fs_2, fs_jpim1   ! Vect. Opt.
357            zat_u  = ( at_i(ji,jj) + at_i(ji+1,jj) ) * 0.5_wp   ! ice area at u and V-points
358            zat_v  = ( at_i(ji,jj) + at_i(ji,jj+1) ) * 0.5_wp
359            !                                                   ! linearized quadratic drag formulation
360            zutau_ice   = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji+1,jj) ) * ( u_ice(ji,jj) - pu_oce(ji,jj) )
361            zvtau_ice   = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji,jj+1) ) * ( v_ice(ji,jj) - pv_oce(ji,jj) )
362            !                                                   ! stresses at the ocean surface
363            utau(ji,jj) = ( 1._wp - zat_u ) * utau_oce(ji,jj) + zat_u * zutau_ice
364            vtau(ji,jj) = ( 1._wp - zat_v ) * vtau_oce(ji,jj) + zat_v * zvtau_ice
365         END DO
366      END DO
367      CALL lbc_lnk( utau, 'U', -1. )   ;   CALL lbc_lnk( vtau, 'V', -1. )   ! lateral boundary condition
368      !
369      IF(ln_ctl)   CALL prt_ctl( tab2d_1=utau, clinfo1=' lim_sbc: utau   : ', mask1=umask,   &
370         &                       tab2d_2=vtau, clinfo2=' vtau    : '        , mask2=vmask )
371     
372   END SUBROUTINE lim_sbc_tau
373
374
375   SUBROUTINE lim_sbc_init
376      !!-------------------------------------------------------------------
377      !!                  ***  ROUTINE lim_sbc_init  ***
378      !!             
379      !! ** Purpose : Preparation of the file ice_evolu for the output of
380      !!      the temporal evolution of key variables
381      !!
382      !! ** input   : Namelist namicedia
383      !!-------------------------------------------------------------------
384      !
385      IF(lwp) WRITE(numout,*)
386      IF(lwp) WRITE(numout,*) 'lim_sbc_init : LIM-3 sea-ice - surface boundary condition'
387      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~   '
388
389      !                                      ! allocate lim_sbc array
390      IF( lim_sbc_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'lim_sbc_init : unable to allocate standard arrays' )
391      !
392      r1_rdtice = 1. / rdt_ice
393      !
394      soce_0(:,:) = soce                     ! constant SSS and ice salinity used in levitating sea-ice case
395      sice_0(:,:) = sice
396      !
397      IF( cp_cfg == "orca" ) THEN            ! decrease ocean & ice reference salinities in the Baltic sea
398         WHERE( 14._wp <= glamt(:,:) .AND. glamt(:,:) <= 32._wp .AND.   &
399            &   54._wp <= gphit(:,:) .AND. gphit(:,:) <= 66._wp         ) 
400            soce_0(:,:) = 4._wp
401            sice_0(:,:) = 2._wp
402         END WHERE
403      ENDIF
404      !
405   END SUBROUTINE lim_sbc_init
406
407#else
408   !!----------------------------------------------------------------------
409   !!   Default option :        Dummy module       NO LIM 3.0 sea-ice model
410   !!----------------------------------------------------------------------
411CONTAINS
412   SUBROUTINE lim_sbc           ! Dummy routine
413   END SUBROUTINE lim_sbc
414#endif 
415
416   !!======================================================================
417END MODULE limsbc
Note: See TracBrowser for help on using the repository browser.