New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limsbc.F90 in trunk/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: trunk/NEMOGCM/NEMO/LIM_SRC_3/limsbc.F90 @ 4614

Last change on this file since 4614 was 4614, checked in by cetlod, 10 years ago

bugfix : allow compilation when using LIM3+vvl activated, see ticket #1293

  • Property svn:keywords set to Id
File size: 24.9 KB
Line 
1MODULE limsbc
2   !!======================================================================
3   !!                       ***  MODULE limsbc   ***
4   !!           computation of the flux at the sea ice/ocean interface
5   !!======================================================================
6   !! History :   -   ! 2006-07 (M. Vancoppelle)  LIM3 original code
7   !!            3.0  ! 2008-03 (C. Tallandier)  surface module
8   !!             -   ! 2008-04 (C. Tallandier)  split in 2 + new ice-ocean coupling
9   !!            3.3  ! 2010-05 (G. Madec) decrease ocean & ice reference salinities in the Baltic sea
10   !!                 !                  + simplification of the ice-ocean stress calculation
11   !!            3.4  ! 2011-02 (G. Madec) dynamical allocation
12   !!             -   ! 2012    (D. Iovino) salt flux change
13   !!             -   ! 2012-05 (C. Rousset) add penetration solar flux
14   !!            3.5  ! 2012-10 (A. Coward, G. Madec) salt fluxes ; ice+snow mass
15   !!----------------------------------------------------------------------
16#if defined key_lim3
17   !!----------------------------------------------------------------------
18   !!   'key_lim3'                                    LIM 3.0 sea-ice model
19   !!----------------------------------------------------------------------
20   !!   lim_sbc_alloc : allocate the limsbc arrays
21   !!   lim_sbc_init  : initialisation
22   !!   lim_sbc_flx   : updates mass, heat and salt fluxes at the ocean surface
23   !!   lim_sbc_tau   : update i- and j-stresses, and its modulus at the ocean surface
24   !!----------------------------------------------------------------------
25   USE par_oce          ! ocean parameters
26   USE phycst           ! physical constants
27   USE par_ice          ! ice parameters
28   USE dom_oce          ! ocean domain
29   USE domvvl           ! ocean vertical scale factors
30   USE dom_ice,    ONLY : tms
31   USE ice              ! LIM sea-ice variables
32   USE sbc_ice          ! Surface boundary condition: sea-ice fields
33   USE sbc_oce          ! Surface boundary condition: ocean fields
34   USE sbccpl
35   USE cpl_oasis3, ONLY : lk_cpl
36   USE oce       , ONLY : iatte, oatte, sshn, sshb, snwice_mass, snwice_mass_b, snwice_fmass
37   USE albedo           ! albedo parameters
38   USE lbclnk           ! ocean lateral boundary condition - MPP exchanges
39   USE lib_mpp          ! MPP library
40   USE wrk_nemo         ! work arrays
41   USE in_out_manager   ! I/O manager
42   USE prtctl           ! Print control
43   USE lib_fortran      ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
44   USE traqsr           ! clem: add penetration of solar flux into the calculation of heat budget
45
46   IMPLICIT NONE
47   PRIVATE
48
49   PUBLIC   lim_sbc_init   ! called by ice_init
50   PUBLIC   lim_sbc_flx    ! called by sbc_ice_lim
51   PUBLIC   lim_sbc_tau    ! called by sbc_ice_lim
52
53   REAL(wp)  ::   rzero  = 0._wp   
54   REAL(wp)  ::   rone   = 1._wp
55
56   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   utau_oce, vtau_oce   ! air-ocean surface i- & j-stress     [N/m2]
57   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   tmod_io              ! modulus of the ice-ocean velocity   [m/s]
58   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   soce_0  , sice_0     ! cst SSS and ice salinity (levitating sea-ice)
59
60   !! * Substitutions
61#  include "vectopt_loop_substitute.h90"
62#  include "domzgr_substitute.h90"
63   !!----------------------------------------------------------------------
64   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011)
65   !! $Id$
66   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
67   !!----------------------------------------------------------------------
68CONTAINS
69
70   INTEGER FUNCTION lim_sbc_alloc()
71      !!-------------------------------------------------------------------
72      !!             ***  ROUTINE lim_sbc_alloc ***
73      !!-------------------------------------------------------------------
74      ALLOCATE( soce_0(jpi,jpj) , utau_oce(jpi,jpj) ,                       &
75         &      sice_0(jpi,jpj) , vtau_oce(jpi,jpj) , tmod_io(jpi,jpj), STAT=lim_sbc_alloc)
76         !
77      IF( lk_mpp             )   CALL mpp_sum( lim_sbc_alloc )
78      IF( lim_sbc_alloc /= 0 )   CALL ctl_warn('lim_sbc_alloc: failed to allocate arrays')
79   END FUNCTION lim_sbc_alloc
80
81
82   SUBROUTINE lim_sbc_flx( kt )
83      !!-------------------------------------------------------------------
84      !!                ***  ROUTINE lim_sbc_flx ***
85      !! 
86      !! ** Purpose :   Update the surface ocean boundary condition for heat
87      !!              salt and mass over areas where sea-ice is non-zero
88      !!         
89      !! ** Action  : - computes the heat and freshwater/salt fluxes
90      !!              at the ice-ocean interface.
91      !!              - Update the ocean sbc
92      !!     
93      !! ** Outputs : - qsr     : sea heat flux:     solar
94      !!              - qns     : sea heat flux: non solar
95      !!              - emp     : freshwater budget: volume flux
96      !!              - sfx     : salt flux
97      !!              - fr_i    : ice fraction
98      !!              - tn_ice  : sea-ice surface temperature
99      !!              - alb_ice : sea-ice alberdo (lk_cpl=T)
100      !!
101      !! References : Goosse, H. et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90.
102      !!              Tartinville et al. 2001 Ocean Modelling, 3, 95-108.
103      !!---------------------------------------------------------------------
104      INTEGER, INTENT(in) ::   kt    ! number of iteration
105      !
106      INTEGER  ::   ji, jj, jl           ! dummy loop indices
107      INTEGER  ::   ierr, ifvt, i1mfr, idfr           ! local integer
108      INTEGER  ::   iflt, ial , iadv , ifral, ifrdv   !   -      -
109      REAL(wp) ::   zinda, zemp, zemp_snow, zfmm      ! local scalars
110      REAL(wp) ::   zemp_snw                          !   -      -
111      REAL(wp) ::   zfcm1 , zfcm2                     !   -      -
112      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zalb, zalbp     ! 2D/3D workspace
113      REAL(wp) ::   zzfcm1, zfscmbq ! clem: for light penetration
114      !!---------------------------------------------------------------------
115     
116      IF( lk_cpl )   CALL wrk_alloc( jpi, jpj, jpl, zalb, zalbp )
117
118      !------------------------------------------!
119      !      heat flux at the ocean surface      !
120      !------------------------------------------!
121      ! pfrld is the lead fraction at the previous time step (actually between TRP and THD)
122      ! changed to old_frld and old ht_i
123
124      DO jj = 1, jpj
125         DO ji = 1, jpi
126            zinda   = 1.0 - MAX( rzero , SIGN( rone , - ( 1.0 - pfrld(ji,jj) ) ) )
127            ifvt    = zinda  *  MAX( rzero , SIGN( rone, - phicif(ji,jj) ) )  !subscripts are bad here
128            i1mfr   = 1.0 - MAX( rzero , SIGN( rone ,  - at_i(ji,jj) ) )
129            idfr    = 1.0 - MAX( rzero , SIGN( rone , ( 1.0 - at_i(ji,jj) ) - pfrld(ji,jj) ) )
130            iflt    = zinda  * (1 - i1mfr) * (1 - ifvt )
131            ial     = ifvt   * i1mfr + ( 1 - ifvt ) * idfr
132            iadv    = ( 1  - i1mfr ) * zinda
133            ifral   = ( 1  - i1mfr * ( 1 - ial ) )   
134            ifrdv   = ( 1  - ifral * ( 1 - ial ) ) * iadv 
135
136            ! switch --- 1.0 ---------------- 0.0 --------------------
137            ! ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
138            ! zinda   | if pfrld = 1       | if pfrld < 1            |
139            !  -> ifvt| if pfrld old_ht_i
140            ! i1mfr   | if frld = 1        | if frld  < 1            |
141            ! idfr    | if frld <= pfrld    | if frld > pfrld        |
142            ! iflt    |
143            ! ial     |
144            ! iadv    |
145            ! ifral
146            ! ifrdv
147
148            !   computation the solar flux at ocean surface
149            IF (lk_cpl) THEN ! be carfeful: not been tested yet
150               ! original line
151               !zfcm1 = qsr_tot(ji,jj) + fstric(ji,jj) * at_i(ji,jj)
152               ! new line to include solar penetration (not tested)
153               zfcm1 = qsr_tot(ji,jj) + fstric(ji,jj) * at_i(ji,jj) / ( 1.0 - zinda + zinda * iatte(ji,jj) )
154               DO jl = 1, jpl
155                  zfcm1 = zfcm1 - qsr_ice(ji,jj,jl) * a_i(ji,jj,jl)
156               END DO
157            ELSE
158               zfcm1   = pfrld(ji,jj) * qsr(ji,jj)  + &
159                    &    ( 1._wp - pfrld(ji,jj) ) * fstric(ji,jj) / ( 1.0 - zinda + zinda * iatte(ji,jj) )
160            ENDIF
161            ! fstric     Solar flux transmitted trough the ice
162            ! qsr        Net short wave heat flux on free ocean
163            ! new line
164            fscmbq(ji,jj) = ( 1.0 - pfrld(ji,jj) ) * fstric(ji,jj) / ( 1.0 - zinda + zinda * iatte(ji,jj) )
165
166            ! solar flux and fscmbq with light penetration (clem)
167            zzfcm1  = pfrld(ji,jj) * qsr(ji,jj) * oatte(ji,jj) + ( 1. - pfrld(ji,jj) ) * fstric(ji,jj)
168            zfscmbq = ( 1.0 - pfrld(ji,jj) ) * fstric(ji,jj)
169
170            !  computation the non solar heat flux at ocean surface
171            zfcm2 = - zzfcm1                                                                    & !
172               &    + iflt    * zfscmbq                                                         & ! total ablation: heat given to the ocean
173               &    + ifral   * ( ial * qcmif(ji,jj) + (1 - ial) * qldif(ji,jj) ) * r1_rdtice   &
174               &    + ifrdv   * (       qfvbq(ji,jj) +             qdtcn(ji,jj) ) * r1_rdtice   &
175               &    + fhmec(ji,jj)                                                              & ! snow melt when ridging
176               &    + fheat_mec(ji,jj)                                                          & ! ridge formation
177               &    + fheat_res(ji,jj)                                                            ! residual heat flux
178            ! qcmif   Energy needed to bring the ocean surface layer until its freezing (ok)
179            ! qldif   heat balance of the lead (or of the open ocean)
180            ! qfvbq   latent heat uptake/release after accretion/ablation
181            ! qdtcn   Energy from the turbulent oceanic heat flux heat flux coming in the lead
182
183            IF( num_sal == 2 )   zfcm2 = zfcm2 + fhbri(ji,jj)    ! add contribution due to brine drainage
184
185            ! bottom radiative component is sent to the computation of the oceanic heat flux
186            fsbbq(ji,jj) = ( 1._wp - ( ifvt + iflt ) ) * fscmbq(ji,jj)     
187
188            ! used to compute the oceanic heat flux at the next time step
189            qsr(ji,jj) = zfcm1                                       ! solar heat flux
190            qns(ji,jj) = zfcm2 - fdtcn(ji,jj)                        ! non solar heat flux
191            !                           ! fdtcn : turbulent oceanic heat flux
192         END DO
193      END DO
194
195      !------------------------------------------!
196      !      mass flux at the ocean surface      !
197      !------------------------------------------!
198
199!!gm   optimisation: this loop have to be merged with the previous one
200      DO jj = 1, jpj
201         DO ji = 1, jpi
202            !  case of realistic freshwater flux (Tartinville et al., 2001) (presently ACTIVATED)
203            !  -------------------------------------------------------------------------------------
204            !  The idea of this approach is that the system that we consider is the ICE-OCEAN system
205            !  Thus  FW  flux  =  External ( E-P+snow melt)
206            !       Salt flux  =  Exchanges in the ice-ocean system then converted into FW
207            !                     Associated to Ice formation AND Ice melting
208            !                     Even if i see Ice melting as a FW and SALT flux
209            !       
210
211            !  computing freshwater exchanges at the ice/ocean interface
212            IF (lk_cpl) THEN
213               zemp = - emp_tot(ji,jj) + emp_ice(ji,jj) * ( 1. - pfrld(ji,jj) )    &   !
214                  &   - rdm_snw(ji,jj) / rdt_ice
215            ELSE
216               zemp =   emp(ji,jj)     * ( 1.0 - at_i(ji,jj)          )  &   ! evaporation over oceanic fraction
217                  &   - tprecip(ji,jj) *         at_i(ji,jj)             &   ! all precipitation reach the ocean
218                  &   + sprecip(ji,jj) * ( 1. - (pfrld(ji,jj)**betas) )  &   ! except solid precip intercepted by sea-ice
219                  &   - fmmec(ji,jj)                                         ! snow falling when ridging
220            ENDIF
221
222            ! mass flux at the ocean/ice interface (sea ice fraction)
223            zemp_snw = rdm_snw(ji,jj) * r1_rdtice                         ! snow melting = pure water that enters the ocean
224            zfmm     = rdm_ice(ji,jj) * r1_rdtice                         ! Freezing minus melting 
225
226            fmmflx(ji,jj) = zfmm                                     ! F/M mass flux save at least for biogeochemical model
227
228            emp(ji,jj) = zemp + zemp_snw + zfmm  ! mass flux + F/M mass flux (always ice/ocean mass exchange)
229           
230            !  correcting brine salt fluxes   (zinda = 1  if pfrld=1 , =0 otherwise)
231            zinda        = 1.0 - MAX( rzero , SIGN( rone , - ( 1.0 - pfrld(ji,jj) ) ) )
232            sfx_bri(ji,jj) = zinda * sfx_bri(ji,jj)
233         END DO
234      END DO
235
236      !------------------------------------------!
237      !      salt flux at the ocean surface      !
238      !------------------------------------------!
239
240      IF( num_sal == 2 ) THEN      ! variable ice salinity: brine drainage included in the salt flux
241         sfx(:,:) = sfx_thd(:,:) + sfx_res(:,:) + sfx_mec(:,:) + sfx_bri(:,:)
242      ELSE                         ! constant ice salinity:
243         sfx(:,:) = sfx_thd(:,:) + sfx_res(:,:) + sfx_mec(:,:)
244      ENDIF
245      !-----------------------------------------------!
246      !   mass of snow and ice per unit area          !
247      !-----------------------------------------------!
248      IF( nn_ice_embd /= 0 ) THEN                               ! embedded sea-ice (mass required)
249         snwice_mass_b(:,:) = snwice_mass(:,:)                  ! save mass from the previous ice time step
250         !                                                      ! new mass per unit area
251         snwice_mass  (:,:) = tms(:,:) * ( rhosn * vt_s(:,:) + rhoic * vt_i(:,:)  ) 
252         !                                                      ! time evolution of snow+ice mass
253         snwice_fmass (:,:) = ( snwice_mass(:,:) - snwice_mass_b(:,:) ) * r1_rdtice
254      ENDIF
255
256      !-----------------------------------------------!
257      !   Storing the transmitted variables           !
258      !-----------------------------------------------!
259      fr_i  (:,:)   = at_i(:,:)             ! Sea-ice fraction           
260      tn_ice(:,:,:) = t_su(:,:,:)           ! Ice surface temperature                     
261
262      !------------------------------------------------!
263      !    Computation of snow/ice and ocean albedo    !
264      !------------------------------------------------!
265      IF( lk_cpl ) THEN          ! coupled case
266         CALL albedo_ice( t_su, ht_i, ht_s, zalbp, zalb )                  ! snow/ice albedo
267         !
268         alb_ice(:,:,:) =  0.5_wp * zalbp(:,:,:) + 0.5_wp * zalb (:,:,:)   ! Ice albedo (mean clear and overcast skys)
269      ENDIF
270
271      IF(ln_ctl) THEN
272         CALL prt_ctl( tab2d_1=qsr   , clinfo1=' lim_sbc: qsr    : ', tab2d_2=qns , clinfo2=' qns     : ' )
273         CALL prt_ctl( tab2d_1=emp   , clinfo1=' lim_sbc: emp    : ', tab2d_2=sfx , clinfo2=' sfx     : ' )
274         CALL prt_ctl( tab2d_1=fr_i  , clinfo1=' lim_sbc: fr_i   : ' )
275         CALL prt_ctl( tab3d_1=tn_ice, clinfo1=' lim_sbc: tn_ice : ', kdim=jpl )
276      ENDIF
277      !
278      IF( lk_cpl )   CALL wrk_dealloc( jpi, jpj, jpl, zalb, zalbp )
279      !
280   END SUBROUTINE lim_sbc_flx
281
282
283   SUBROUTINE lim_sbc_tau( kt , pu_oce, pv_oce )
284      !!-------------------------------------------------------------------
285      !!                ***  ROUTINE lim_sbc_tau ***
286      !! 
287      !! ** Purpose : Update the ocean surface stresses due to the ice
288      !!         
289      !! ** Action  : * at each ice time step (every nn_fsbc time step):
290      !!                - compute the modulus of ice-ocean relative velocity
291      !!                  (*rho*Cd) at T-point (C-grid) or I-point (B-grid)
292      !!                      tmod_io = rhoco * | U_ice-U_oce |
293      !!                - update the modulus of stress at ocean surface
294      !!                      taum = frld * taum + (1-frld) * tmod_io * | U_ice-U_oce |
295      !!              * at each ocean time step (every kt):
296      !!                  compute linearized ice-ocean stresses as
297      !!                      Utau = tmod_io * | U_ice - pU_oce |
298      !!                using instantaneous current ocean velocity (usually before)
299      !!
300      !!    NB: - ice-ocean rotation angle no more allowed
301      !!        - here we make an approximation: taum is only computed every ice time step
302      !!          This avoids mutiple average to pass from T -> U,V grids and next from U,V grids
303      !!          to T grid. taum is used in TKE and GLS, which should not be too sensitive to this approximaton...
304      !!
305      !! ** Outputs : - utau, vtau   : surface ocean i- and j-stress (u- & v-pts) updated with ice-ocean fluxes
306      !!              - taum         : modulus of the surface ocean stress (T-point) updated with ice-ocean fluxes
307      !!---------------------------------------------------------------------
308      INTEGER ,                     INTENT(in) ::   kt               ! ocean time-step index
309      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   pu_oce, pv_oce   ! surface ocean currents
310      !!
311      INTEGER  ::   ji, jj   ! dummy loop indices
312      REAL(wp) ::   zat_u, zutau_ice, zu_t, zmodt   ! local scalar
313      REAL(wp) ::   zat_v, zvtau_ice, zv_t          !   -      -
314      !!---------------------------------------------------------------------
315      !
316      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN     !==  Ice time-step only  ==!   (i.e. surface module time-step)
317!CDIR NOVERRCHK
318         DO jj = 2, jpjm1                             !* update the modulus of stress at ocean surface (T-point)
319!CDIR NOVERRCHK
320            DO ji = fs_2, fs_jpim1
321               !                                               ! 2*(U_ice-U_oce) at T-point
322               zu_t = u_ice(ji,jj) + u_ice(ji-1,jj) - u_oce(ji,jj) - u_oce(ji-1,jj)   
323               zv_t = v_ice(ji,jj) + v_ice(ji,jj-1) - v_oce(ji,jj) - v_oce(ji,jj-1) 
324               !                                              ! |U_ice-U_oce|^2
325               zmodt =  0.25_wp * (  zu_t * zu_t + zv_t * zv_t  )
326               !                                               ! update the ocean stress modulus
327               taum(ji,jj) = ( 1._wp - at_i(ji,jj) ) * taum(ji,jj) + at_i(ji,jj) * rhoco * zmodt
328               tmod_io(ji,jj) = rhoco * SQRT( zmodt )          ! rhoco * |U_ice-U_oce| at T-point
329            END DO
330         END DO
331         CALL lbc_lnk( taum, 'T', 1. )   ;   CALL lbc_lnk( tmod_io, 'T', 1. )
332         !
333         utau_oce(:,:) = utau(:,:)                    !* save the air-ocean stresses at ice time-step
334         vtau_oce(:,:) = vtau(:,:)
335         !
336      ENDIF
337      !
338      !                                      !==  every ocean time-step  ==!
339      !
340      DO jj = 2, jpjm1                                !* update the stress WITHOUT a ice-ocean rotation angle
341         DO ji = fs_2, fs_jpim1   ! Vect. Opt.
342            zat_u  = ( at_i(ji,jj) + at_i(ji+1,jj) ) * 0.5_wp   ! ice area at u and V-points
343            zat_v  = ( at_i(ji,jj) + at_i(ji,jj+1) ) * 0.5_wp
344            !                                                   ! linearized quadratic drag formulation
345            zutau_ice   = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji+1,jj) ) * ( u_ice(ji,jj) - pu_oce(ji,jj) )
346            zvtau_ice   = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji,jj+1) ) * ( v_ice(ji,jj) - pv_oce(ji,jj) )
347            !                                                   ! stresses at the ocean surface
348            utau(ji,jj) = ( 1._wp - zat_u ) * utau_oce(ji,jj) + zat_u * zutau_ice
349            vtau(ji,jj) = ( 1._wp - zat_v ) * vtau_oce(ji,jj) + zat_v * zvtau_ice
350         END DO
351      END DO
352      CALL lbc_lnk( utau, 'U', -1. )   ;   CALL lbc_lnk( vtau, 'V', -1. )   ! lateral boundary condition
353      !
354      IF(ln_ctl)   CALL prt_ctl( tab2d_1=utau, clinfo1=' lim_sbc: utau   : ', mask1=umask,   &
355         &                       tab2d_2=vtau, clinfo2=' vtau    : '        , mask2=vmask )
356     
357   END SUBROUTINE lim_sbc_tau
358
359
360   SUBROUTINE lim_sbc_init
361      !!-------------------------------------------------------------------
362      !!                  ***  ROUTINE lim_sbc_init  ***
363      !!             
364      !! ** Purpose : Preparation of the file ice_evolu for the output of
365      !!      the temporal evolution of key variables
366      !!
367      !! ** input   : Namelist namicedia
368      !!-------------------------------------------------------------------
369      REAL(wp) :: zsum, zarea
370      !
371      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
372      REAL(wp) ::   zcoefu, zcoefv, zcoeff          ! local scalar
373      IF(lwp) WRITE(numout,*)
374      IF(lwp) WRITE(numout,*) 'lim_sbc_init : LIM-3 sea-ice - surface boundary condition'
375      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~   '
376
377      !                                      ! allocate lim_sbc array
378      IF( lim_sbc_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'lim_sbc_init : unable to allocate standard arrays' )
379      !
380      soce_0(:,:) = soce                     ! constant SSS and ice salinity used in levitating sea-ice case
381      sice_0(:,:) = sice
382      !
383      IF( cp_cfg == "orca" ) THEN            ! decrease ocean & ice reference salinities in the Baltic sea
384         WHERE( 14._wp <= glamt(:,:) .AND. glamt(:,:) <= 32._wp .AND.   &
385            &   54._wp <= gphit(:,:) .AND. gphit(:,:) <= 66._wp         ) 
386            soce_0(:,:) = 4._wp
387            sice_0(:,:) = 2._wp
388         END WHERE
389      ENDIF
390      ! clem modif
391      IF( .NOT. ln_rstart ) THEN
392         iatte(:,:) = 1._wp
393         oatte(:,:) = 1._wp
394      ENDIF
395      !
396      ! clem: snwice_mass in the restart file now
397      IF( .NOT. ln_rstart ) THEN
398         !                                      ! embedded sea ice
399         IF( nn_ice_embd /= 0 ) THEN            ! mass exchanges between ice and ocean (case 1 or 2) set the snow+ice mass
400            snwice_mass  (:,:) = tms(:,:) * ( rhosn * vt_s(:,:) + rhoic * vt_i(:,:)  )
401            snwice_mass_b(:,:) = snwice_mass(:,:)
402         ELSE
403            snwice_mass  (:,:) = 0.0_wp         ! no mass exchanges
404            snwice_mass_b(:,:) = 0.0_wp         ! no mass exchanges
405         ENDIF
406         IF( nn_ice_embd == 2 ) THEN            ! full embedment (case 2) deplete the initial ssh below sea-ice area
407            sshn(:,:) = sshn(:,:) - snwice_mass(:,:) * r1_rau0
408            sshb(:,:) = sshb(:,:) - snwice_mass(:,:) * r1_rau0
409#if defined key_vvl           
410           ! key_vvl necessary? clem: yes for compilation purpose
411            DO jk = 1,jpkm1                     ! adjust initial vertical scale factors
412               fse3t_n(:,:,jk) = e3t_0(:,:,jk)*( 1._wp + sshn(:,:)*tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) )
413               fse3t_b(:,:,jk) = e3t_0(:,:,jk)*( 1._wp + sshb(:,:)*tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) )
414            ENDDO
415            fse3t_a(:,:,:) = fse3t_b(:,:,:)
416            ! Reconstruction of all vertical scale factors at now and before time
417            ! steps
418            ! =============================================================================
419            ! Horizontal scale factor interpolations
420            ! --------------------------------------
421            CALL dom_vvl_interpol( fse3t_b(:,:,:), fse3u_b(:,:,:), 'U' )
422            CALL dom_vvl_interpol( fse3t_b(:,:,:), fse3v_b(:,:,:), 'V' )
423            CALL dom_vvl_interpol( fse3t_n(:,:,:), fse3u_n(:,:,:), 'U' )
424            CALL dom_vvl_interpol( fse3t_n(:,:,:), fse3v_n(:,:,:), 'V' )
425            CALL dom_vvl_interpol( fse3u_n(:,:,:), fse3f_n(:,:,:), 'F' )
426            ! Vertical scale factor interpolations
427            ! ------------------------------------
428            CALL dom_vvl_interpol( fse3t_n(:,:,:), fse3w_n (:,:,:), 'W'  )
429            CALL dom_vvl_interpol( fse3u_n(:,:,:), fse3uw_n(:,:,:), 'UW' )
430            CALL dom_vvl_interpol( fse3v_n(:,:,:), fse3vw_n(:,:,:), 'VW' )
431            CALL dom_vvl_interpol( fse3u_b(:,:,:), fse3uw_b(:,:,:), 'UW' )
432            CALL dom_vvl_interpol( fse3v_b(:,:,:), fse3vw_b(:,:,:), 'VW' )
433            ! t- and w- points depth
434            ! ----------------------
435            fsdept_n(:,:,1) = 0.5_wp * fse3w_n(:,:,1)
436            fsdepw_n(:,:,1) = 0.0_wp
437            fsde3w_n(:,:,1) = fsdept_n(:,:,1) - sshn(:,:)
438            DO jk = 2, jpk
439               fsdept_n(:,:,jk) = fsdept_n(:,:,jk-1) + fse3w_n(:,:,jk)
440               fsdepw_n(:,:,jk) = fsdepw_n(:,:,jk-1) + fse3t_n(:,:,jk-1)
441               fsde3w_n(:,:,jk) = fsdept_n(:,:,jk  ) - sshn   (:,:)
442            END DO
443#endif
444         ENDIF
445      ENDIF ! .NOT. ln_rstart
446      !
447
448   END SUBROUTINE lim_sbc_init
449
450#else
451   !!----------------------------------------------------------------------
452   !!   Default option :        Dummy module       NO LIM 3.0 sea-ice model
453   !!----------------------------------------------------------------------
454CONTAINS
455   SUBROUTINE lim_sbc           ! Dummy routine
456   END SUBROUTINE lim_sbc
457#endif 
458
459   !!======================================================================
460END MODULE limsbc
Note: See TracBrowser for help on using the repository browser.