New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limthd_ent.F90 in trunk/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: trunk/NEMOGCM/NEMO/LIM_SRC_3/limthd_ent.F90 @ 3319

Last change on this file since 3319 was 3294, checked in by rblod, 12 years ago

Merge of 3.4beta into the trunk

  • Property svn:keywords set to Id
File size: 27.0 KB
Line 
1MODULE limthd_ent
2   !!======================================================================
3   !!                       ***  MODULE limthd_ent   ***
4   !!                  Redistribution of Enthalpy in the ice
5   !!                        on the new vertical grid
6   !!                       after vertical growth/decay
7   !!======================================================================
8   !! History :  LIM  ! 2003-05 (M. Vancoppenolle) Original code in 1D
9   !!                 ! 2005-07 (M. Vancoppenolle) 3D version
10   !!                 ! 2006-11 (X. Fettweis) Vectorized
11   !!            3.0  ! 2008-03 (M. Vancoppenolle) Energy conservation and clean code
12   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
13   !!----------------------------------------------------------------------
14#if defined key_lim3
15   !!----------------------------------------------------------------------
16   !!   'key_lim3'                                      LIM3 sea-ice model
17   !!----------------------------------------------------------------------
18   !!   lim_thd_ent : ice redistribution of enthalpy
19   !!----------------------------------------------------------------------
20   USE par_oce          ! ocean parameters
21   USE dom_oce          ! domain variables
22   USE domain           !
23   USE phycst           ! physical constants
24   USE ice              ! LIM variables
25   USE par_ice          ! LIM parameters
26   USE thd_ice          ! LIM thermodynamics
27   USE limvar           ! LIM variables
28   USE in_out_manager   ! I/O manager
29   USE lib_mpp          ! MPP library
30   USE wrk_nemo         ! work arrays
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   lim_thd_ent         ! called by lim_thd
36
37   REAL(wp) ::   epsi20 = 1e-20_wp   ! constant values
38   REAL(wp) ::   epsi13 = 1e-13_wp   !
39   REAL(wp) ::   epsi10 = 1e-10_wp   !
40   REAL(wp) ::   epsi06 = 1e-06_wp   !
41   REAL(wp) ::   zzero  = 0._wp      !
42   REAL(wp) ::   zone   = 1._wp      !
43
44   !!----------------------------------------------------------------------
45   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011)
46   !! $Id$
47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49CONTAINS
50 
51   SUBROUTINE lim_thd_ent( kideb, kiut, jl )
52      !!-------------------------------------------------------------------
53      !!               ***   ROUTINE lim_thd_ent  ***
54      !!
55      !! ** Purpose :
56      !!           This routine computes new vertical grids
57      !!           in the ice and in the snow, and consistently redistributes
58      !!           temperatures in the snow / ice.
59      !!           Redistribution is made so as to ensure to energy conservation
60      !!
61      !!
62      !! ** Method  : linear conservative remapping
63      !!           
64      !! ** Steps : 1) Grid
65      !!            2) Switches
66      !!            3) Snow redistribution
67      !!            4) Ice enthalpy redistribution
68      !!            5) Ice salinity, recover temperature
69      !!
70      !! References : Bitz & Lipscomb, JGR 99; Vancoppenolle et al., GRL, 2005
71      !!-------------------------------------------------------------------
72      INTEGER , INTENT(in) ::   kideb, kiut   ! Start/End point on which the  the computation is applied
73      INTEGER , INTENT(in) ::   jl            ! Thickness cateogry number
74
75      INTEGER ::   ji,jk   !  dummy loop indices
76      INTEGER ::   zji, zjj       ,   &  !  dummy indices
77         ntop0          ,   &  !  old layer top index
78         nbot1          ,   &  !  new layer bottom index
79         ntop1          ,   &  !  new layer top index
80         limsum         ,   &  !  temporary loop index
81         nlayi0,nlays0  ,   &  !  old number of layers
82         maxnbot0       ,   &  !  old layer bottom index
83         layer0, layer1        !  old/new layer indexes
84
85
86      REAL(wp) :: &
87         ztmelts        ,   &  ! ice melting point
88         zqsnic         ,   &  ! enthalpy of snow ice layer
89         zhsnow         ,   &  ! temporary snow thickness variable
90         zswitch        ,   &  ! dummy switch argument
91         zfac1          ,   &  ! dummy factor
92         zfac2          ,   &  ! dummy factor
93         ztform         ,   &  !: bottom formation temperature
94         zaaa           ,   &  !: dummy factor
95         zbbb           ,   &  !: dummy factor
96         zccc           ,   &  !: dummy factor
97         zdiscrim              !: dummy factor
98
99      INTEGER, POINTER, DIMENSION(:) ::   snswi     !  snow switch
100      INTEGER, POINTER, DIMENSION(:) ::   nbot0     !  old layer bottom index
101      INTEGER, POINTER, DIMENSION(:) ::   icsuind   !  ice surface index
102      INTEGER, POINTER, DIMENSION(:) ::   icsuswi   !  ice surface switch
103      INTEGER, POINTER, DIMENSION(:) ::   icboind   !  ice bottom index
104      INTEGER, POINTER, DIMENSION(:) ::   icboswi   !  ice bottom switch
105      INTEGER, POINTER, DIMENSION(:) ::   snicind   !  snow ice index
106      INTEGER, POINTER, DIMENSION(:) ::   snicswi   !  snow ice switch
107      INTEGER, POINTER, DIMENSION(:) ::   snind     !  snow index
108      !
109      REAL(wp), POINTER, DIMENSION(:) ::   zh_i   ! thickness of an ice layer
110      REAL(wp), POINTER, DIMENSION(:) ::   zh_s          ! thickness of a snow layer
111      REAL(wp), POINTER, DIMENSION(:) ::   zqsnow        ! enthalpy of the snow put in snow ice   
112      REAL(wp), POINTER, DIMENSION(:) ::   zdeltah       ! temporary variable
113      REAL(wp), POINTER, DIMENSION(:) ::   zqti_in, zqts_in
114      REAL(wp), POINTER, DIMENSION(:) ::   zqti_fin, zqts_fin
115
116      REAL(wp), POINTER, DIMENSION(:,:) ::   zm0       !  old layer-system vertical cotes
117      REAL(wp), POINTER, DIMENSION(:,:) ::   qm0       !  old layer-system heat content
118      REAL(wp), POINTER, DIMENSION(:,:) ::   z_s       !  new snow system vertical cotes
119      REAL(wp), POINTER, DIMENSION(:,:) ::   z_i       !  new ice system vertical cotes
120      REAL(wp), POINTER, DIMENSION(:,:) ::   zthick0   !  old ice thickness
121      REAL(wp), POINTER, DIMENSION(:,:) ::   zhl0      ! old and new layer thicknesses
122      REAL(wp), POINTER, DIMENSION(:,:) ::   zrl01
123      !!-------------------------------------------------------------------
124
125      CALL wrk_alloc( jpij, snswi, nbot0, icsuind, icsuswi, icboind, icboswi, snicind, snicswi, snind )   ! integer
126      CALL wrk_alloc( jpij, zh_i, zh_s, zqsnow, zdeltah, zqti_in, zqts_in, zqti_fin, zqts_fin )           ! real
127      CALL wrk_alloc( jpij,jkmax+4, zm0, qm0, z_s, z_i, zthick0, zhl0, kjstart = 0 )
128      CALL wrk_alloc( jkmax+4,jkmax+4, zrl01, kistart = 0, kjstart = 0 )
129
130      zthick0(:,:) = 0._wp
131      zm0    (:,:) = 0._wp
132      qm0    (:,:) = 0._wp
133      zrl01  (:,:) = 0._wp
134      zhl0   (:,:) = 0._wp
135      z_i    (:,:) = 0._wp
136      z_s    (:,:) = 0._wp
137
138      !
139      !------------------------------------------------------------------------------|
140      !  1) Grid                                                                     |
141      !------------------------------------------------------------------------------|
142      nlays0 = nlay_s
143      nlayi0 = nlay_i
144
145      DO ji = kideb, kiut
146         zh_i(ji) = old_ht_i_b(ji) / nlay_i 
147         zh_s(ji) = old_ht_s_b(ji) / nlay_s
148      END DO
149
150      !
151      !------------------------------------------------------------------------------|
152      !  2) Switches                                                                 |
153      !------------------------------------------------------------------------------|
154      ! 2.1 snind(ji), snswi(ji)
155      ! snow surface behaviour : computation of snind(ji)-snswi(ji)
156      ! snind(ji) : index which equals
157      !   0 if snow is accumulating
158      !   1 if 1st layer is melting
159      !   2 if 2nd layer is melting ...
160      DO ji = kideb, kiut
161         snind  (ji) = 0
162         zdeltah(ji) = 0._wp
163      ENDDO !ji
164
165      DO jk = 1, nlays0
166         DO ji = kideb, kiut
167            snind(ji)  = jk        *      INT(MAX(0.0,SIGN(1.0,-dh_s_tot(ji)-zdeltah(ji)-epsi20))) &
168               + snind(ji) * (1 - INT(MAX(0.0,SIGN(1.0,-dh_s_tot(ji)-zdeltah(ji)-epsi20))))
169            zdeltah(ji)= zdeltah(ji) + zh_s(ji)
170         END DO ! ji
171      END DO ! jk
172
173      ! snswi(ji) : switch which value equals 1 if snow melts
174      !              0 if not
175      DO ji = kideb, kiut
176         snswi(ji)     = MAX(0,INT(-dh_s_tot(ji)/MAX(epsi20,ABS(dh_s_tot(ji)))))
177      END DO ! ji
178
179      ! 2.2 icsuind(ji), icsuswi(ji)
180      ! ice surface behaviour : computation of icsuind(ji)-icsuswi(ji)
181      ! icsuind(ji) : index which equals
182      !     0 if nothing happens at the surface
183      !     1 if first layer is melting
184      !     2 if 2nd layer is reached by melt ...
185      DO ji = kideb, kiut
186         icsuind(ji) = 0
187         zdeltah(ji) = 0._wp
188      END DO !ji
189      DO jk = 1, nlayi0
190         DO ji = kideb, kiut
191            icsuind(ji) = jk          *      INT(MAX(0.0,SIGN(1.0,-dh_i_surf(ji)-zdeltah(ji)-epsi20))) &
192               + icsuind(ji) * (1 - INT(MAX(0.0,SIGN(1.0,-dh_i_surf(ji)-zdeltah(ji)-epsi20))))
193            zdeltah(ji) = zdeltah(ji) + zh_i(ji)
194         END DO ! ji
195      ENDDO !jk
196
197      ! icsuswi(ji) : switch which equals
198      !     1 if ice melts at the surface
199      !     0 if not
200      DO ji = kideb, kiut
201         icsuswi(ji)  = MAX(0,INT(-dh_i_surf(ji)/MAX(epsi20 , ABS(dh_i_surf(ji)) ) ) )
202      ENDDO
203
204      ! 2.3 icboind(ji), icboswi(ji)
205      ! ice bottom behaviour : computation of icboind(ji)-icboswi(ji)
206      ! icboind(ji) : index which equals
207      !     0 if accretion is on the way
208      !     1 if last layer has started to melt
209      !     2 if penultiem layer is melting ... and so on
210      !            N+1 if all layers melt and that snow transforms into ice
211      DO ji = kideb, kiut 
212         icboind(ji) = 0
213         zdeltah(ji) = 0._wp
214      END DO
215      DO jk = nlayi0, 1, -1
216         DO ji = kideb, kiut
217            icboind(ji) = (nlayi0+1-jk) *      INT(MAX(0.0,SIGN(1.0,-dh_i_bott(ji)-zdeltah(ji)-epsi20))) &
218               &          + icboind(ji) * (1 - INT(MAX(0.0,SIGN(1.0,-dh_i_bott(ji)-zdeltah(ji)-epsi20)))) 
219            zdeltah(ji) = zdeltah(ji) + zh_i(ji)
220         END DO
221      END DO
222
223      DO ji = kideb, kiut
224         ! case of total ablation with remaining snow
225         IF ( ( ht_i_b(ji) .GT. epsi20 ) .AND. &
226            ( ht_i_b(ji) - dh_snowice(ji) .LT. epsi20 ) ) icboind(ji) = nlay_i + 1
227      END DO
228
229      ! icboswi(ji) : switch which equals
230      !     1 if ice accretion is on the way
231      !     0 if ablation is on the way
232      DO ji = kideb, kiut 
233         icboswi(ji) = MAX(0,INT(dh_i_bott(ji) / MAX(epsi20,ABS(dh_i_bott(ji)))))
234      END DO
235
236      ! 2.4 snicind(ji), snicswi(ji)
237      ! snow ice formation : calcul de snicind(ji)-snicswi(ji)
238      ! snicind(ji) : index which equals
239      !     0 if no snow-ice forms
240      !     1 if last layer of snow has started to melt
241      !     2 if penultiem layer ...
242      DO ji = kideb, kiut
243         snicind(ji) = 0
244         zdeltah(ji) = 0._wp
245      END DO
246      DO jk = nlays0, 1, -1
247         DO ji = kideb, kiut
248            snicind(ji) = (nlays0+1-jk) &
249               *      INT(MAX(0.0,SIGN(1.0,dh_snowice(ji)-zdeltah(ji)-epsi20))) + snicind(ji)   &
250               * (1 - INT(MAX(0.0,SIGN(1.0,dh_snowice(ji)-zdeltah(ji)-epsi20))))
251            zdeltah(ji) = zdeltah(ji) + zh_s(ji)
252         END DO
253      END DO
254
255      ! snicswi(ji) : switch which equals
256      !     1 if snow-ice forms
257      !     0 if not
258      DO ji = kideb, kiut
259         snicswi(ji)   = MAX(0,INT(dh_snowice(ji)/MAX(epsi20,ABS(dh_snowice(ji)))))
260      ENDDO
261
262      !
263      !------------------------------------------------------------------------------|
264      !  3) Snow redistribution                                                      |
265      !------------------------------------------------------------------------------|
266      !
267      !-------------
268      ! Old profile
269      !-------------
270
271      ! by 'old', it is meant that layers coming from accretion are included,
272      ! and that interfacial layers which were partly melted are reduced
273
274      ! indexes of the vectors
275      !------------------------
276      ntop0    =  1
277      maxnbot0 =  0
278
279      DO ji = kideb, kiut
280         nbot0(ji) =  nlays0  + 1 - snind(ji) + ( 1. - snicind(ji) ) * snicswi(ji)
281         ! cotes of the top of the layers
282         zm0(ji,0) =  0._wp
283         maxnbot0 =  MAX ( maxnbot0 , nbot0(ji) )
284      END DO
285      IF( lk_mpp )   CALL mpp_max( maxnbot0, kcom=ncomm_ice )
286
287      DO jk = 1, maxnbot0
288         DO ji = kideb, kiut
289            !change
290            limsum = ( 1 - snswi(ji) ) * ( jk - 1 ) + snswi(ji) * ( jk + snind(ji) - 1 )
291            limsum = MIN( limsum , nlay_s )
292            zm0(ji,jk) =  dh_s_tot(ji) + zh_s(ji) * limsum
293         END DO
294      END DO
295
296      DO ji = kideb, kiut
297         zm0(ji,nbot0(ji)) =  dh_s_tot(ji) - snicswi(ji) * dh_snowice(ji) + zh_s(ji) * nlays0
298         zm0(ji,1)         =  dh_s_tot(ji) * (1 -snswi(ji) ) + snswi(ji) * zm0(ji,1)
299      END DO
300
301      DO jk = ntop0, maxnbot0
302         DO ji = kideb, kiut
303            zthick0(ji,jk)  =  zm0(ji,jk) - zm0(ji,jk-1)            ! layer thickness
304         END DO
305      END DO
306
307      zqts_in(:) = 0._wp
308
309      DO ji = kideb, kiut         ! layer heat content
310         qm0    (ji,1) =  rhosn * (  cpic * ( rtt - ( 1. - snswi(ji) ) * tatm_ice_1d(ji)        &
311            &                                            - snswi(ji)   * t_s_b      (ji,1)  )   &
312            &                      + lfus  ) * zthick0(ji,1)
313         zqts_in(ji)   =  zqts_in(ji) + qm0(ji,1) 
314      END DO
315
316      DO jk = 2, maxnbot0
317         DO ji = kideb, kiut
318            limsum      = ( 1 - snswi(ji) ) * ( jk - 1 ) + snswi(ji) * ( jk + snind(ji) - 1 )
319            limsum      = MIN( limsum , nlay_s )
320            qm0(ji,jk)  = rhosn * ( cpic * ( rtt - t_s_b(ji,limsum) ) + lfus ) * zthick0(ji,jk)
321            zswitch = 1.0 - MAX (0.0, SIGN ( 1.0, epsi20 - ht_s_b(ji) ) )
322            zqts_in(ji) = zqts_in(ji) + ( 1. - snswi(ji) ) * qm0(ji,jk) * zswitch
323         END DO ! jk
324      END DO ! ji
325
326      !------------------------------------------------
327      ! Energy given by the snow in snow-ice formation
328      !------------------------------------------------
329      ! zqsnow, enthalpy of the flooded snow
330      DO ji = kideb, kiut
331         zqsnow (ji) =  rhosn * lfus
332         zdeltah(ji) =  0._wp
333      END DO
334
335      DO jk =  nlays0, 1, -1
336         DO ji = kideb, kiut
337            zhsnow =  MAX( 0._wp , dh_snowice(ji)-zdeltah(ji) )
338            zqsnow (ji) =  zqsnow (ji) + rhosn*cpic*(rtt-t_s_b(ji,jk))
339            zdeltah(ji) =  zdeltah(ji) + zh_s(ji)
340         END DO
341      END DO
342
343      DO ji = kideb, kiut
344         zqsnow(ji) = zqsnow(ji) * dh_snowice(ji)
345      END DO
346
347      !------------------
348      ! new snow profile
349      !------------------
350
351      !--------------
352      ! Vector index   
353      !--------------
354      ntop1 =  1
355      nbot1 =  nlay_s
356
357      !-------------------
358      ! Layer coordinates
359      !-------------------
360      DO ji = kideb, kiut
361         zh_s(ji)  = ht_s_b(ji) / nlay_s
362         z_s(ji,0) =  0._wp
363      ENDDO
364
365      DO jk = 1, nlay_s
366         DO ji = kideb, kiut
367            z_s(ji,jk) =  zh_s(ji) * jk
368         END DO
369      END DO
370
371      !-----------------
372      ! Layer thickness
373      !-----------------
374      DO layer0 = ntop0, maxnbot0
375         DO ji = kideb, kiut
376            zhl0(ji,layer0) = zm0(ji,layer0) - zm0(ji,layer0-1)
377         END DO
378      END DO
379
380      DO layer1 = ntop1, nbot1
381         DO ji = kideb, kiut
382            q_s_b(ji,layer1) = 0._wp
383         END DO
384      END DO
385
386      !----------------
387      ! Weight factors
388      !----------------
389      DO layer0 = ntop0, maxnbot0
390         DO layer1 = ntop1, nbot1
391            DO ji = kideb, kiut
392               zrl01(layer1,layer0) = MAX(0.0,( MIN(zm0(ji,layer0),z_s(ji,layer1))   &
393                  &                 - MAX(zm0(ji,layer0-1), z_s(ji,layer1-1))) / MAX(zhl0(ji,layer0),epsi10)) 
394               q_s_b(ji,layer1) = q_s_b(ji,layer1) + zrl01(layer1,layer0)*qm0(ji,layer0)   &
395                  &                                * MAX(0.0,SIGN(1.0,nbot0(ji)-layer0+epsi20))
396            END DO
397         END DO
398      END DO
399
400      ! Heat conservation
401      zqts_fin(:) = 0._wp
402      DO jk = 1, nlay_s
403         DO ji = kideb, kiut
404            zqts_fin(ji) = zqts_fin(ji) + q_s_b(ji,jk)
405         END DO
406      END DO
407
408      IF ( con_i ) THEN
409         DO ji = kideb, kiut
410            IF ( ABS ( zqts_in(ji) - zqts_fin(ji) ) / rdt_ice .GT. 1.0e-6 ) THEN
411               zji                 = MOD( npb(ji) - 1, jpi ) + 1
412               zjj                 = ( npb(ji) - 1 ) / jpi + 1
413               WRITE(numout,*) ' violation of heat conservation : ',             &
414                  ABS ( zqts_in(ji) - zqts_fin(ji) ) / rdt_ice
415               WRITE(numout,*) ' ji, jj   : ', zji, zjj
416               WRITE(numout,*) ' ht_s_b   : ', ht_s_b(ji)
417               WRITE(numout,*) ' zqts_in  : ', zqts_in(ji) / rdt_ice
418               WRITE(numout,*) ' zqts_fin : ', zqts_fin(ji) / rdt_ice
419               WRITE(numout,*) ' dh_snowice : ', dh_snowice(ji)
420               WRITE(numout,*) ' dh_s_tot : ', dh_s_tot(ji)
421               WRITE(numout,*) ' snswi    : ', snswi(ji)
422            ENDIF
423         END DO
424      ENDIF
425
426      !---------------------
427      ! Recover heat content
428      !---------------------
429      DO jk = 1, nlay_s
430         DO ji = kideb, kiut
431            q_s_b(ji,jk) = q_s_b(ji,jk) / MAX( zh_s(ji) , epsi20 )
432         END DO !ji
433      END DO !jk 
434
435      !---------------------
436      ! Recover temperature
437      !---------------------
438      zfac1 = 1. / ( rhosn * cpic )
439      zfac2 = lfus / cpic 
440      DO jk = 1, nlay_s
441         DO ji = kideb, kiut
442            zswitch = MAX ( 0.0 , SIGN ( 1.0, epsi20 - ht_s_b(ji) ) )
443            t_s_b(ji,jk) = rtt + ( 1.0 - zswitch ) * ( - zfac1 * q_s_b(ji,jk) + zfac2 )
444         END DO
445      END DO
446      !
447      !------------------------------------------------------------------------------|
448      !  4) Ice redistribution                                                       |
449      !------------------------------------------------------------------------------|
450      !
451      !-------------
452      ! OLD PROFILE
453      !-------------
454
455      !----------------
456      ! Vector indexes
457      !----------------
458      ntop0    =  1
459      maxnbot0 =  0
460
461      DO ji = kideb, kiut
462         ! reference number of the bottommost layer
463         nbot0(ji) =  MAX( 1 ,  MIN( nlayi0 + ( 1 - icboind(ji) ) +        &
464            &                           ( 1 - icsuind(ji) ) * icsuswi(ji) + snicswi(ji) , nlay_i + 2 ) )
465         ! maximum reference number of the bottommost layer over all domain
466         maxnbot0 =  MAX( maxnbot0 , nbot0(ji) )
467      END DO
468
469      !-------------------------
470      ! Cotes of old ice layers
471      !-------------------------
472      zm0(:,0) =  0._wp
473
474      DO jk = 1, maxnbot0
475         DO ji = kideb, kiut
476            ! jk goes from 1 to nbot0
477            ! the ice layer number goes from 1 to nlay_i
478            ! limsum is the real ice layer number corresponding to present jk
479            limsum    =  ( (icsuswi(ji)*(icsuind(ji)+jk-1) + & 
480               (1-icsuswi(ji))*jk))*(1-snicswi(ji)) + (jk-1)*snicswi(ji)
481            zm0(ji,jk)=  icsuswi(ji)*dh_i_surf(ji) + snicswi(ji)*dh_snowice(ji) &
482               +  limsum * zh_i(ji)
483         END DO
484      END DO
485
486      DO ji = kideb, kiut
487         zm0(ji,nbot0(ji)) =  icsuswi(ji)*dh_i_surf(ji) + snicswi(ji)*dh_snowice(ji) + dh_i_bott(ji) &
488            +  zh_i(ji) * nlayi0
489         zm0(ji,1)         =  snicswi(ji)*dh_snowice(ji) + (1-snicswi(ji))*zm0(ji,1)
490      END DO
491
492      !-----------------------------
493      ! Thickness of old ice layers
494      !-----------------------------
495      DO jk = ntop0, maxnbot0
496         DO ji = kideb, kiut
497            zthick0(ji,jk) =  zm0(ji,jk) - zm0(ji,jk-1)
498         END DO
499      END DO
500
501      !---------------------------
502      ! Inner layers heat content
503      !---------------------------
504      qm0(:,:) =  0.0
505      zqti_in(:) = 0.0
506
507      DO jk = ntop0, maxnbot0
508         DO ji = kideb, kiut
509            limsum =  MAX(1,MIN(snicswi(ji)*(jk-1) + icsuswi(ji)*(jk-1+icsuind(ji)) + &
510               (1-icsuswi(ji))*(1-snicswi(ji))*jk,nlay_i))
511            ztmelts = -tmut * s_i_b(ji,limsum) + rtt
512            qm0(ji,jk) = rhoic * ( cpic * (ztmelts-t_i_b(ji,limsum)) + lfus * ( 1.0-(ztmelts-rtt)/ &
513               MIN((t_i_b(ji,limsum)-rtt),-epsi20) ) - rcp*(ztmelts-rtt) ) &
514               * zthick0(ji,jk)
515         END DO
516      END DO
517
518      !----------------------------
519      ! Bottom layers heat content
520      !----------------------------
521      DO ji = kideb, kiut       
522         ztmelts    = ( 1.0 - icboswi(ji) ) * (-tmut * s_i_b  (ji,nlayi0) )   &   ! case of melting ice
523            &       +         icboswi(ji)   * (-tmut * s_i_new(ji)        )   &   ! case of forming ice
524            &       + rtt                                                         ! in Kelvin
525
526         ! bottom formation temperature
527         ztform = t_i_b(ji,nlay_i)
528         IF ( ( num_sal .EQ. 2 ) .OR. ( num_sal .EQ. 4 ) ) ztform = t_bo_b(ji)
529         qm0(ji,nbot0(ji)) = ( 1.0 - icboswi(ji) )*qm0(ji,nbot0(ji))             &   ! case of melting ice
530            &              + icboswi(ji) * rhoic * ( cpic*(ztmelts-ztform)       &   ! case of forming ice
531            + lfus *( 1.0-(ztmelts-rtt) / MIN ( (ztform-rtt) , - epsi10 ) )      & 
532            - rcp*(ztmelts-rtt) ) * zthick0(ji,nbot0(ji)  )
533      END DO
534
535      !-----------------------------
536      ! Snow ice layer heat content
537      !-----------------------------
538      DO ji = kideb, kiut
539         ! energy of the flooding seawater
540         zqsnic = rau0 * rcp * ( rtt - t_bo_b(ji) ) * dh_snowice(ji) * &
541            (rhoic - rhosn) / rhoic * snicswi(ji) ! generally positive
542         ! Heat conservation diagnostic
543         qt_i_in(ji,jl) = qt_i_in(ji,jl) + zqsnic 
544
545         qldif_1d(ji)   = qldif_1d(ji) + zqsnic * a_i_b(ji)
546
547         ! enthalpy of the newly formed snow-ice layer
548         ! = enthalpy of snow + enthalpy of frozen water
549         zqsnic         =  zqsnow(ji) + zqsnic
550         qm0(ji,1)      =  snicswi(ji) * zqsnic + ( 1 - snicswi(ji) ) * qm0(ji,1)
551
552      END DO ! ji
553
554      DO jk = ntop0, maxnbot0
555         DO ji = kideb, kiut
556            ! Heat conservation
557            zqti_in(ji) = zqti_in(ji) + qm0(ji,jk) * MAX( 0.0 , SIGN(1.0,ht_i_b(ji)-epsi06+epsi20) ) &
558               &                                   * MAX( 0.0 , SIGN( 1. , nbot0(ji) - jk + epsi20 ) )
559         END DO
560      END DO
561
562      !-------------
563      ! NEW PROFILE
564      !-------------
565
566      !---------------
567      ! Vectors index
568      !---------------
569      ntop1 =  1 
570      nbot1 =  nlay_i
571
572      !------------------
573      ! Layers thickness
574      !------------------
575      DO ji = kideb, kiut
576         zh_i(ji) = ht_i_b(ji) / nlay_i
577      ENDDO
578
579      !-------------
580      ! Layer cotes     
581      !-------------
582      z_i(:,0) =  0._wp
583      DO jk = 1, nlay_i
584         DO ji = kideb, kiut
585            z_i(ji,jk) =  zh_i(ji) * jk
586         END DO
587      END DO
588
589      !--thicknesses of the layers
590      DO layer0 = ntop0, maxnbot0
591         DO ji = kideb, kiut
592            zhl0(ji,layer0) = zm0(ji,layer0) - zm0(ji,layer0-1)   ! thicknesses of the layers
593         END DO
594      END DO
595
596      !------------------------
597      ! Weights for relayering
598      !------------------------
599      q_i_b(:,:) = 0._wp
600      DO layer0 = ntop0, maxnbot0
601         DO layer1 = ntop1, nbot1
602            DO ji = kideb, kiut
603               zrl01(layer1,layer0) = MAX(0.0,( MIN(zm0(ji,layer0),z_i(ji,layer1)) &
604                  - MAX(zm0(ji,layer0-1), z_i(ji,layer1-1)))/MAX(zhl0(ji,layer0),epsi10))
605               q_i_b(ji,layer1) = q_i_b(ji,layer1) & 
606                  + zrl01(layer1,layer0)*qm0(ji,layer0) &
607                  * MAX(0.0,SIGN(1.0,ht_i_b(ji)-epsi06+epsi20)) &
608                  * MAX(0.0,SIGN(1.0,nbot0(ji)-layer0+epsi20))
609            END DO
610         END DO
611      END DO
612
613      !-------------------------
614      ! Heat conservation check
615      !-------------------------
616      zqti_fin(:) = 0._wp
617      DO jk = 1, nlay_i
618         DO ji = kideb, kiut
619            zqti_fin(ji) = zqti_fin(ji) + q_i_b(ji,jk)
620         END DO
621      END DO
622      !
623      DO ji = kideb, kiut
624         IF ( ABS ( zqti_in(ji) - zqti_fin(ji) ) / rdt_ice .GT. 1.0e-6 ) THEN
625            zji                 = MOD( npb(ji) - 1, jpi ) + 1
626            zjj                 = ( npb(ji) - 1 ) / jpi + 1
627            WRITE(numout,*) ' violation of heat conservation : ', ABS ( zqti_in(ji) - zqti_fin(ji) ) / rdt_ice
628            WRITE(numout,*) ' ji, jj   : ', zji, zjj
629            WRITE(numout,*) ' ht_i_b   : ', ht_i_b(ji)
630            WRITE(numout,*) ' zqti_in  : ', zqti_in(ji) / rdt_ice
631            WRITE(numout,*) ' zqti_fin : ', zqti_fin(ji) / rdt_ice
632            WRITE(numout,*) ' dh_i_bott: ', dh_i_bott(ji)
633            WRITE(numout,*) ' dh_i_surf: ', dh_i_surf(ji)
634            WRITE(numout,*) ' dh_snowice:', dh_snowice(ji)
635            WRITE(numout,*) ' icsuswi  : ', icsuswi(ji)
636            WRITE(numout,*) ' icboswi  : ', icboswi(ji)
637            WRITE(numout,*) ' snicswi  : ', snicswi(ji)
638         ENDIF
639      END DO
640
641      !----------------------
642      ! Recover heat content
643      !----------------------
644      DO jk = 1, nlay_i
645         DO ji = kideb, kiut
646            q_i_b(ji,jk) = q_i_b(ji,jk) / MAX( zh_i(ji) , epsi20 )
647         END DO !ji
648      END DO !jk 
649
650      ! Heat conservation
651      zqti_fin(:) = 0.0
652      DO jk = 1, nlay_i
653         DO ji = kideb, kiut
654            zqti_fin(ji) = zqti_fin(ji) + q_i_b(ji,jk) * zh_i(ji)
655         END DO
656      END DO
657
658      !
659      !------------------------------------------------------------------------------|
660      !  5) Update salinity and recover temperature                                  |
661      !------------------------------------------------------------------------------|
662      !
663      ! Update salinity (basal entrapment, snow ice formation)
664      DO ji = kideb, kiut
665         sm_i_b(ji) = sm_i_b(ji) + dsm_i_se_1d(ji) + dsm_i_si_1d(ji)
666      END DO !ji
667
668      ! Recover temperature
669      DO jk = 1, nlay_i
670         DO ji = kideb, kiut
671            ztmelts    =  -tmut*s_i_b(ji,jk) + rtt
672            !Conversion q(S,T) -> T (second order equation)
673            zaaa         =  cpic
674            zbbb         =  ( rcp - cpic ) * ( ztmelts - rtt ) + q_i_b(ji,jk) / rhoic - lfus
675            zccc         =  lfus * ( ztmelts - rtt )
676            zdiscrim     =  SQRT( MAX(zbbb*zbbb - 4.0*zaaa*zccc,0.0) )
677            t_i_b(ji,jk) =  rtt - ( zbbb + zdiscrim ) / ( 2.0 *zaaa )
678         END DO !ji
679
680      END DO !jk
681      !
682      CALL wrk_dealloc( jpij, snswi, nbot0, icsuind, icsuswi, icboind, icboswi, snicind, snicswi, snind )   ! integer
683      CALL wrk_dealloc( jpij, zh_i, zh_s, zqsnow, zdeltah, zqti_in, zqts_in, zqti_fin, zqts_fin )           ! real
684      CALL wrk_dealloc( jpij,jkmax+4, zm0, qm0, z_s, z_i, zthick0, zhl0, kjstart = 0 )
685      CALL wrk_dealloc( jkmax+4,jkmax+4, zrl01, kistart = 0, kjstart = 0 )
686      !
687   END SUBROUTINE lim_thd_ent
688
689#else
690   !!----------------------------------------------------------------------
691   !!   Default option                               NO  LIM3 sea-ice model
692   !!----------------------------------------------------------------------
693CONTAINS
694   SUBROUTINE lim_thd_ent          ! Empty routine
695   END SUBROUTINE lim_thd_ent
696#endif
697
698   !!======================================================================
699END MODULE limthd_ent
Note: See TracBrowser for help on using the repository browser.