New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limthd_lac.F90 in trunk/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: trunk/NEMOGCM/NEMO/LIM_SRC_3/limthd_lac.F90 @ 6403

Last change on this file since 6403 was 6403, checked in by cetlod, 8 years ago

trunk:new developments already included in 3.6 stable, see points 1, 2 and 4 of ticket #1678
  • Property svn:keywords set to Id
File size: 25.5 KB
Line 
1MODULE limthd_lac
2   !!======================================================================
3   !!                       ***  MODULE limthd_lac   ***
4   !!                lateral thermodynamic growth of the ice
5   !!======================================================================
6   !! History :  LIM  ! 2005-12 (M. Vancoppenolle)  Original code
7   !!             -   ! 2006-01 (M. Vancoppenolle)  add ITD
8   !!            3.0  ! 2007-07 (M. Vancoppenolle)  Mass and energy conservation tested
9   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
10   !!----------------------------------------------------------------------
11#if defined key_lim3
12   !!----------------------------------------------------------------------
13   !!   'key_lim3'                                      LIM3 sea-ice model
14   !!----------------------------------------------------------------------
15   !!   lim_lat_acr   : lateral accretion of ice
16   !!----------------------------------------------------------------------
17   USE par_oce        ! ocean parameters
18   USE dom_oce        ! domain variables
19   USE phycst         ! physical constants
20   USE sbc_oce        ! Surface boundary condition: ocean fields
21   USE sbc_ice        ! Surface boundary condition: ice fields
22   USE thd_ice        ! LIM thermodynamics
23   USE dom_ice        ! LIM domain
24   USE ice            ! LIM variables
25   USE limtab         ! LIM 2D <==> 1D
26   USE limcons        ! LIM conservation
27   USE in_out_manager ! I/O manager
28   USE lib_mpp        ! MPP library
29   USE wrk_nemo       ! work arrays
30   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
31   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
32   USE limthd_ent
33   USE limvar
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC lim_thd_lac     ! called by lim_thd
39
40   !!----------------------------------------------------------------------
41   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011)
42   !! $Id$
43   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE lim_thd_lac
48      !!-------------------------------------------------------------------
49      !!               ***   ROUTINE lim_thd_lac  ***
50      !! 
51      !! ** Purpose : Computation of the evolution of the ice thickness and
52      !!      concentration as a function of the heat balance in the leads.
53      !!      It is only used for lateral accretion
54      !!       
55      !! ** Method  : Ice is formed in the open water when ocean lose heat
56      !!      (heat budget of open water Bl is negative) .
57      !!      Computation of the increase of 1-A (ice concentration) fol-
58      !!      lowing the law :
59      !!      (dA/dt)acc = F[ (1-A)/(1-a) ] * [ Bl / (Li*h0) ]
60      !!       where - h0 is the thickness of ice created in the lead
61      !!             - a is a minimum fraction for leads
62      !!             - F is a monotonic non-increasing function defined as:
63      !!                  F(X)=( 1 - X**exld )**(1.0/exld)
64      !!             - exld is the exponent closure rate (=2 default val.)
65      !!
66      !! ** Action : - Adjustment of snow and ice thicknesses and heat
67      !!                content in brine pockets
68      !!             - Updating ice internal temperature
69      !!             - Computation of variation of ice volume and mass
70      !!             - Computation of frldb after lateral accretion and
71      !!               update ht_s_1d, ht_i_1d and tbif_1d(:,:)     
72      !!------------------------------------------------------------------------
73      INTEGER ::   ji,jj,jk,jl      ! dummy loop indices
74      INTEGER ::   nbpac            ! local integers
75      INTEGER ::   ii, ij, iter     !   -       -
76      REAL(wp)  ::   ztmelts, zdv, zfrazb, zweight, zde                         ! local scalars
77      REAL(wp) ::   zgamafr, zvfrx, zvgx, ztaux, ztwogp, zf , zhicol_new        !   -      -
78      REAL(wp) ::   ztenagm, zvfry, zvgy, ztauy, zvrel2, zfp, zsqcd , zhicrit   !   -      -
79      LOGICAL  ::   iterate_frazil   ! iterate frazil ice collection thickness
80      CHARACTER (len = 15) :: fieldid
81
82      REAL(wp) ::   zQm          ! enthalpy exchanged with the ocean (J/m2, >0 towards ocean)
83      REAL(wp) ::   zEi          ! sea ice specific enthalpy (J/kg)
84      REAL(wp) ::   zEw          ! seawater specific enthalpy (J/kg)
85      REAL(wp) ::   zfmdt        ! mass flux x time step (kg/m2, >0 towards ocean)
86     
87      REAL(wp) ::   zv_newfra
88 
89      INTEGER , POINTER, DIMENSION(:) ::   jcat        ! indexes of categories where new ice grows
90      REAL(wp), POINTER, DIMENSION(:) ::   zswinew     ! switch for new ice or not
91
92      REAL(wp), POINTER, DIMENSION(:) ::   zv_newice   ! volume of accreted ice
93      REAL(wp), POINTER, DIMENSION(:) ::   za_newice   ! fractional area of accreted ice
94      REAL(wp), POINTER, DIMENSION(:) ::   zh_newice   ! thickness of accreted ice
95      REAL(wp), POINTER, DIMENSION(:) ::   ze_newice   ! heat content of accreted ice
96      REAL(wp), POINTER, DIMENSION(:) ::   zs_newice   ! salinity of accreted ice
97      REAL(wp), POINTER, DIMENSION(:) ::   zo_newice   ! age of accreted ice
98      REAL(wp), POINTER, DIMENSION(:) ::   zdv_res     ! residual volume in case of excessive heat budget
99      REAL(wp), POINTER, DIMENSION(:) ::   zda_res     ! residual area in case of excessive heat budget
100      REAL(wp), POINTER, DIMENSION(:) ::   zat_i_1d    ! total ice fraction   
101      REAL(wp), POINTER, DIMENSION(:) ::   zv_frazb    ! accretion of frazil ice at the ice bottom
102      REAL(wp), POINTER, DIMENSION(:) ::   zvrel_1d    ! relative ice / frazil velocity (1D vector)
103
104      REAL(wp), POINTER, DIMENSION(:,:) ::   zv_b      ! old volume of ice in category jl
105      REAL(wp), POINTER, DIMENSION(:,:) ::   za_b      ! old area of ice in category jl
106      REAL(wp), POINTER, DIMENSION(:,:) ::   za_i_1d   ! 1-D version of a_i
107      REAL(wp), POINTER, DIMENSION(:,:) ::   zv_i_1d   ! 1-D version of v_i
108      REAL(wp), POINTER, DIMENSION(:,:) ::   zsmv_i_1d ! 1-D version of smv_i
109
110      REAL(wp), POINTER, DIMENSION(:,:,:) ::   ze_i_1d   !: 1-D version of e_i
111
112      REAL(wp), POINTER, DIMENSION(:,:) ::   zvrel                   ! relative ice / frazil velocity
113
114      REAL(wp) :: zcai = 1.4e-3_wp
115      !!-----------------------------------------------------------------------!
116
117      CALL wrk_alloc( jpij, jcat )   ! integer
118      CALL wrk_alloc( jpij, zswinew, zv_newice, za_newice, zh_newice, ze_newice, zs_newice, zo_newice )
119      CALL wrk_alloc( jpij, zdv_res, zda_res, zat_i_1d, zv_frazb, zvrel_1d )
120      CALL wrk_alloc( jpij,jpl, zv_b, za_b, za_i_1d, zv_i_1d, zsmv_i_1d )
121      CALL wrk_alloc( jpij,nlay_i,jpl, ze_i_1d )
122      CALL wrk_alloc( jpi,jpj, zvrel )
123
124      CALL lim_var_agg(1)
125      CALL lim_var_glo2eqv
126      !------------------------------------------------------------------------------|
127      ! 2) Convert units for ice internal energy
128      !------------------------------------------------------------------------------|
129      DO jl = 1, jpl
130         DO jk = 1, nlay_i
131            DO jj = 1, jpj
132               DO ji = 1, jpi
133                  !Energy of melting q(S,T) [J.m-3]
134                  rswitch          = MAX(  0._wp , SIGN( 1._wp , v_i(ji,jj,jl) - epsi20 )  )   !0 if no ice
135                  e_i(ji,jj,jk,jl) = rswitch * e_i(ji,jj,jk,jl) / MAX( v_i(ji,jj,jl), epsi20 ) * REAL( nlay_i, wp )
136               END DO
137            END DO
138         END DO
139      END DO
140
141      !------------------------------------------------------------------------------!
142      ! 3) Collection thickness of ice formed in leads and polynyas
143      !------------------------------------------------------------------------------!   
144      ! hicol is the thickness of new ice formed in open water
145      ! hicol can be either prescribed (frazswi = 0)
146      ! or computed (frazswi = 1)
147      ! Frazil ice forms in open water, is transported by wind
148      ! accumulates at the edge of the consolidated ice edge
149      ! where it forms aggregates of a specific thickness called
150      ! collection thickness.
151
152      ! Note : the following algorithm currently breaks vectorization
153      !
154
155      zvrel(:,:) = 0._wp
156
157      ! Default new ice thickness
158      hicol(:,:) = rn_hnewice
159
160      IF( ln_frazil ) THEN
161
162         !--------------------
163         ! Physical constants
164         !--------------------
165         hicol(:,:) = 0._wp
166
167         zhicrit = 0.04 ! frazil ice thickness
168         ztwogp  = 2. * rau0 / ( grav * 0.3 * ( rau0 - rhoic ) ) ! reduced grav
169         zsqcd   = 1.0 / SQRT( 1.3 * zcai ) ! 1/SQRT(airdensity*drag)
170         zgamafr = 0.03
171
172         DO jj = 2, jpj
173            DO ji = 2, jpi
174               IF ( qlead(ji,jj) < 0._wp ) THEN
175                  !-------------
176                  ! Wind stress
177                  !-------------
178                  ! C-grid wind stress components
179                  ztaux         = ( utau_ice(ji-1,jj  ) * umask(ji-1,jj  ,1)   &
180                     &          +   utau_ice(ji  ,jj  ) * umask(ji  ,jj  ,1) ) * 0.5_wp
181                  ztauy         = ( vtau_ice(ji  ,jj-1) * vmask(ji  ,jj-1,1)   &
182                     &          +   vtau_ice(ji  ,jj  ) * vmask(ji  ,jj  ,1) ) * 0.5_wp
183                  ! Square root of wind stress
184                  ztenagm       =  SQRT( SQRT( ztaux**2 + ztauy**2 ) )
185
186                  !---------------------
187                  ! Frazil ice velocity
188                  !---------------------
189                  rswitch = MAX( 0._wp, SIGN( 1._wp , ztenagm - epsi10 ) )
190                  zvfrx   = rswitch * zgamafr * zsqcd * ztaux / MAX( ztenagm, epsi10 )
191                  zvfry   = rswitch * zgamafr * zsqcd * ztauy / MAX( ztenagm, epsi10 )
192
193                  !-------------------
194                  ! Pack ice velocity
195                  !-------------------
196                  ! C-grid ice velocity
197                  rswitch = MAX(  0._wp, SIGN( 1._wp , at_i(ji,jj) )  )
198                  zvgx    = rswitch * ( u_ice(ji-1,jj  ) * umask(ji-1,jj  ,1)  + u_ice(ji,jj) * umask(ji,jj,1) ) * 0.5_wp
199                  zvgy    = rswitch * ( v_ice(ji  ,jj-1) * vmask(ji  ,jj-1,1)  + v_ice(ji,jj) * vmask(ji,jj,1) ) * 0.5_wp
200
201                  !-----------------------------------
202                  ! Relative frazil/pack ice velocity
203                  !-----------------------------------
204                  ! absolute relative velocity
205                  zvrel2 = MAX(  ( zvfrx - zvgx ) * ( zvfrx - zvgx )   &
206                     &         + ( zvfry - zvgy ) * ( zvfry - zvgy ) , 0.15 * 0.15 )
207                  zvrel(ji,jj)  = SQRT( zvrel2 )
208
209                  !---------------------
210                  ! Iterative procedure
211                  !---------------------
212                  hicol(ji,jj) = zhicrit + 0.1 
213                  hicol(ji,jj) = zhicrit +   hicol(ji,jj)    &
214                     &                   / ( hicol(ji,jj) * hicol(ji,jj) -  zhicrit * zhicrit ) * ztwogp * zvrel2
215
216!!gm better coding: above: hicol(ji,jj) * hicol(ji,jj) = (zhicrit + 0.1)*(zhicrit + 0.1)
217!!gm                                                   = zhicrit**2 + 0.2*zhicrit +0.01
218!!gm                therefore the 2 lines with hicol can be replaced by 1 line:
219!!gm              hicol(ji,jj) = zhicrit + (zhicrit + 0.1) / ( 0.2 * zhicrit + 0.01 ) * ztwogp * zvrel2
220!!gm further more (zhicrit + 0.1)/(0.2 * zhicrit + 0.01 )*ztwogp can be computed one for all outside the DO loop
221
222                  iter = 1
223                  iterate_frazil = .true.
224
225                  DO WHILE ( iter < 100 .AND. iterate_frazil ) 
226                     zf = ( hicol(ji,jj) - zhicrit ) * ( hicol(ji,jj)**2 - zhicrit**2 ) &
227                        - hicol(ji,jj) * zhicrit * ztwogp * zvrel2
228                     zfp = ( hicol(ji,jj) - zhicrit ) * ( 3.0*hicol(ji,jj) + zhicrit ) &
229                        - zhicrit * ztwogp * zvrel2
230                     zhicol_new = hicol(ji,jj) - zf/zfp
231                     hicol(ji,jj)   = zhicol_new
232
233                     iter = iter + 1
234
235                  END DO ! do while
236
237               ENDIF ! end of selection of pixels where ice forms
238
239            END DO ! loop on ji ends
240         END DO ! loop on jj ends
241      !
242      CALL lbc_lnk( zvrel(:,:), 'T', 1. )
243      CALL lbc_lnk( hicol(:,:), 'T', 1. )
244
245      ENDIF ! End of computation of frazil ice collection thickness
246
247      !------------------------------------------------------------------------------!
248      ! 4) Identify grid points where new ice forms
249      !------------------------------------------------------------------------------!
250
251      !-------------------------------------
252      ! Select points for new ice formation
253      !-------------------------------------
254      ! This occurs if open water energy budget is negative
255      nbpac = 0
256      npac(:) = 0
257      !
258      DO jj = 1, jpj
259         DO ji = 1, jpi
260            IF ( qlead(ji,jj)  <  0._wp ) THEN
261               nbpac = nbpac + 1
262               npac( nbpac ) = (jj - 1) * jpi + ji
263            ENDIF
264         END DO
265      END DO
266
267      ! debug point to follow
268      jiindex_1d = 0
269      IF( ln_icectl ) THEN
270         DO ji = mi0(iiceprt), mi1(iiceprt)
271            DO jj = mj0(jiceprt), mj1(jiceprt)
272               IF ( qlead(ji,jj)  <  0._wp ) THEN
273                  jiindex_1d = (jj - 1) * jpi + ji
274               ENDIF
275            END DO
276         END DO
277      ENDIF
278   
279      IF( ln_icectl ) WRITE(numout,*) 'lim_thd_lac : nbpac = ', nbpac
280
281      !------------------------------
282      ! Move from 2-D to 1-D vectors
283      !------------------------------
284      ! If ocean gains heat do nothing
285      ! 0therwise compute new ice formation
286
287      IF ( nbpac > 0 ) THEN
288
289         CALL tab_2d_1d( nbpac, zat_i_1d  (1:nbpac)     , at_i         , jpi, jpj, npac(1:nbpac) )
290         DO jl = 1, jpl
291            CALL tab_2d_1d( nbpac, za_i_1d  (1:nbpac,jl), a_i  (:,:,jl), jpi, jpj, npac(1:nbpac) )
292            CALL tab_2d_1d( nbpac, zv_i_1d  (1:nbpac,jl), v_i  (:,:,jl), jpi, jpj, npac(1:nbpac) )
293            CALL tab_2d_1d( nbpac, zsmv_i_1d(1:nbpac,jl), smv_i(:,:,jl), jpi, jpj, npac(1:nbpac) )
294            DO jk = 1, nlay_i
295               CALL tab_2d_1d( nbpac, ze_i_1d(1:nbpac,jk,jl), e_i(:,:,jk,jl) , jpi, jpj, npac(1:nbpac) )
296            END DO
297         END DO
298
299         CALL tab_2d_1d( nbpac, qlead_1d  (1:nbpac)     , qlead     , jpi, jpj, npac(1:nbpac) )
300         CALL tab_2d_1d( nbpac, t_bo_1d   (1:nbpac)     , t_bo      , jpi, jpj, npac(1:nbpac) )
301         CALL tab_2d_1d( nbpac, sfx_opw_1d(1:nbpac)     , sfx_opw   , jpi, jpj, npac(1:nbpac) )
302         CALL tab_2d_1d( nbpac, wfx_opw_1d(1:nbpac)     , wfx_opw   , jpi, jpj, npac(1:nbpac) )
303         CALL tab_2d_1d( nbpac, hicol_1d  (1:nbpac)     , hicol     , jpi, jpj, npac(1:nbpac) )
304         CALL tab_2d_1d( nbpac, zvrel_1d  (1:nbpac)     , zvrel     , jpi, jpj, npac(1:nbpac) )
305
306         CALL tab_2d_1d( nbpac, hfx_thd_1d(1:nbpac)     , hfx_thd   , jpi, jpj, npac(1:nbpac) )
307         CALL tab_2d_1d( nbpac, hfx_opw_1d(1:nbpac)     , hfx_opw   , jpi, jpj, npac(1:nbpac) )
308         CALL tab_2d_1d( nbpac, rn_amax_1d(1:nbpac)     , rn_amax_2d, jpi, jpj, npac(1:nbpac) )
309
310         !------------------------------------------------------------------------------!
311         ! 5) Compute thickness, salinity, enthalpy, age, area and volume of new ice
312         !------------------------------------------------------------------------------!
313
314         !-----------------------------------------
315         ! Keep old ice areas and volume in memory
316         !-----------------------------------------
317         zv_b(1:nbpac,:) = zv_i_1d(1:nbpac,:) 
318         za_b(1:nbpac,:) = za_i_1d(1:nbpac,:)
319         !----------------------
320         ! Thickness of new ice
321         !----------------------
322         DO ji = 1, nbpac
323            zh_newice(ji) = rn_hnewice
324         END DO
325         IF( ln_frazil ) zh_newice(1:nbpac) = hicol_1d(1:nbpac)
326
327         !----------------------
328         ! Salinity of new ice
329         !----------------------
330         SELECT CASE ( nn_icesal )
331         CASE ( 1 )                    ! Sice = constant
332            zs_newice(1:nbpac) = rn_icesal
333         CASE ( 2 )                    ! Sice = F(z,t) [Vancoppenolle et al (2005)]
334            DO ji = 1, nbpac
335               ii =   MOD( npac(ji) - 1 , jpi ) + 1
336               ij =      ( npac(ji) - 1 ) / jpi + 1
337               zs_newice(ji) = MIN(  4.606 + 0.91 / zh_newice(ji) , rn_simax , 0.5 * sss_m(ii,ij)  )
338            END DO
339         CASE ( 3 )                    ! Sice = F(z) [multiyear ice]
340            zs_newice(1:nbpac) =   2.3
341         END SELECT
342
343         !-------------------------
344         ! Heat content of new ice
345         !-------------------------
346         ! We assume that new ice is formed at the seawater freezing point
347         DO ji = 1, nbpac
348            ztmelts       = - tmut * zs_newice(ji) + rt0                  ! Melting point (K)
349            ze_newice(ji) =   rhoic * (  cpic * ( ztmelts - t_bo_1d(ji) )                             &
350               &                       + lfus * ( 1.0 - ( ztmelts - rt0 ) / MIN( t_bo_1d(ji) - rt0, -epsi10 ) )   &
351               &                       - rcp  *         ( ztmelts - rt0 )  )
352         END DO
353
354         !----------------
355         ! Age of new ice
356         !----------------
357         DO ji = 1, nbpac
358            zo_newice(ji) = 0._wp
359         END DO
360
361         !-------------------
362         ! Volume of new ice
363         !-------------------
364         DO ji = 1, nbpac
365
366            zEi           = - ze_newice(ji) * r1_rhoic             ! specific enthalpy of forming ice [J/kg]
367
368            zEw           = rcp * ( t_bo_1d(ji) - rt0 )            ! specific enthalpy of seawater at t_bo_1d [J/kg]
369                                                                   ! clem: we suppose we are already at the freezing point (condition qlead<0 is satisfyied)
370                                                                   
371            zdE           = zEi - zEw                              ! specific enthalpy difference [J/kg]
372                                             
373            zfmdt         = - qlead_1d(ji) / zdE                   ! Fm.dt [kg/m2] (<0)
374                                                                   ! clem: we use qlead instead of zqld (limthd) because we suppose we are at the freezing point   
375            zv_newice(ji) = - zfmdt * r1_rhoic
376
377            zQm           = zfmdt * zEw                            ! heat to the ocean >0 associated with mass flux 
378
379            ! Contribution to heat flux to the ocean [W.m-2], >0 
380            hfx_thd_1d(ji) = hfx_thd_1d(ji) + zfmdt * zEw * r1_rdtice
381            ! Total heat flux used in this process [W.m-2] 
382            hfx_opw_1d(ji) = hfx_opw_1d(ji) - zfmdt * zdE * r1_rdtice
383            ! mass flux
384            wfx_opw_1d(ji) = wfx_opw_1d(ji) - zv_newice(ji) * rhoic * r1_rdtice
385            ! salt flux
386            sfx_opw_1d(ji) = sfx_opw_1d(ji) - zv_newice(ji) * rhoic * zs_newice(ji) * r1_rdtice
387
388            ! A fraction zfrazb of frazil ice is accreted at the ice bottom
389            rswitch       = 1._wp - MAX( 0._wp, SIGN( 1._wp , - zat_i_1d(ji) ) )
390            zfrazb        = rswitch * ( TANH ( rn_Cfrazb * ( zvrel_1d(ji) - rn_vfrazb ) ) + 1.0 ) * 0.5 * rn_maxfrazb
391            zv_frazb(ji)  =         zfrazb   * zv_newice(ji)
392            zv_newice(ji) = ( 1.0 - zfrazb ) * zv_newice(ji)
393         END DO
394
395         !-----------------
396         ! Area of new ice
397         !-----------------
398         DO ji = 1, nbpac
399            za_newice(ji) = zv_newice(ji) / zh_newice(ji)
400         END DO
401
402         !------------------------------------------------------------------------------!
403         ! 6) Redistribute new ice area and volume into ice categories                  !
404         !------------------------------------------------------------------------------!
405
406         !------------------------
407         ! 6.1) lateral ice growth
408         !------------------------
409         ! If lateral ice growth gives an ice concentration gt 1, then
410         ! we keep the excessive volume in memory and attribute it later to bottom accretion
411         DO ji = 1, nbpac
412            IF ( za_newice(ji) >  ( rn_amax_1d(ji) - zat_i_1d(ji) ) ) THEN
413               zda_res(ji)   = za_newice(ji) - ( rn_amax_1d(ji) - zat_i_1d(ji) )
414               zdv_res(ji)   = zda_res  (ji) * zh_newice(ji) 
415               za_newice(ji) = za_newice(ji) - zda_res  (ji)
416               zv_newice(ji) = zv_newice(ji) - zdv_res  (ji)
417            ELSE
418               zda_res(ji) = 0._wp
419               zdv_res(ji) = 0._wp
420            ENDIF
421         END DO
422
423         ! find which category to fill
424         zat_i_1d(:) = 0._wp
425         DO jl = 1, jpl
426            DO ji = 1, nbpac
427               IF( zh_newice(ji) > hi_max(jl-1) .AND. zh_newice(ji) <= hi_max(jl) ) THEN
428                  za_i_1d (ji,jl) = za_i_1d (ji,jl) + za_newice(ji)
429                  zv_i_1d (ji,jl) = zv_i_1d (ji,jl) + zv_newice(ji)
430                  jcat    (ji)    = jl
431               ENDIF
432               zat_i_1d(ji) = zat_i_1d(ji) + za_i_1d  (ji,jl)
433            END DO
434         END DO
435
436         ! Heat content
437         DO ji = 1, nbpac
438            jl = jcat(ji)                                                    ! categroy in which new ice is put
439            zswinew  (ji) = MAX( 0._wp , SIGN( 1._wp , - za_b(ji,jl) ) )   ! 0 if old ice
440         END DO
441
442         DO jk = 1, nlay_i
443            DO ji = 1, nbpac
444               jl = jcat(ji)
445               rswitch = MAX( 0._wp, SIGN( 1._wp , zv_i_1d(ji,jl) - epsi20 ) )
446               ze_i_1d(ji,jk,jl) = zswinew(ji)   *   ze_newice(ji) +                                                      &
447                  &        ( 1.0 - zswinew(ji) ) * ( ze_newice(ji) * zv_newice(ji) + ze_i_1d(ji,jk,jl) * zv_b(ji,jl) )  &
448                  &        * rswitch / MAX( zv_i_1d(ji,jl), epsi20 )
449            END DO
450         END DO
451
452         !------------------------------------------------
453         ! 6.2) bottom ice growth + ice enthalpy remapping
454         !------------------------------------------------
455         DO jl = 1, jpl
456
457            ! for remapping
458            h_i_old (1:nbpac,0:nlay_i+1) = 0._wp
459            qh_i_old(1:nbpac,0:nlay_i+1) = 0._wp
460            DO jk = 1, nlay_i
461               DO ji = 1, nbpac
462                  h_i_old (ji,jk) = zv_i_1d(ji,jl) * r1_nlay_i
463                  qh_i_old(ji,jk) = ze_i_1d(ji,jk,jl) * h_i_old(ji,jk)
464               END DO
465            END DO
466
467            ! new volumes including lateral/bottom accretion + residual
468            DO ji = 1, nbpac
469               rswitch        = MAX( 0._wp, SIGN( 1._wp , zat_i_1d(ji) - epsi20 ) )
470               zv_newfra      = rswitch * ( zdv_res(ji) + zv_frazb(ji) ) * za_i_1d(ji,jl) / MAX( zat_i_1d(ji) , epsi20 )
471               za_i_1d(ji,jl) = rswitch * za_i_1d(ji,jl)               
472               zv_i_1d(ji,jl) = zv_i_1d(ji,jl) + zv_newfra
473               ! for remapping
474               h_i_old (ji,nlay_i+1) = zv_newfra
475               qh_i_old(ji,nlay_i+1) = ze_newice(ji) * zv_newfra
476            ENDDO
477            ! --- Ice enthalpy remapping --- !
478            CALL lim_thd_ent( 1, nbpac, ze_i_1d(1:nbpac,:,jl) ) 
479         ENDDO
480
481         !-----------------
482         ! Update salinity
483         !-----------------
484         DO jl = 1, jpl
485            DO ji = 1, nbpac
486               zdv   = zv_i_1d(ji,jl) - zv_b(ji,jl)
487               zsmv_i_1d(ji,jl) = zsmv_i_1d(ji,jl) + zdv * zs_newice(ji)
488            END DO
489         END DO
490
491         !------------------------------------------------------------------------------!
492         ! 7) Change 2D vectors to 1D vectors
493         !------------------------------------------------------------------------------!
494         DO jl = 1, jpl
495            CALL tab_1d_2d( nbpac, a_i (:,:,jl), npac(1:nbpac), za_i_1d (1:nbpac,jl), jpi, jpj )
496            CALL tab_1d_2d( nbpac, v_i (:,:,jl), npac(1:nbpac), zv_i_1d (1:nbpac,jl), jpi, jpj )
497            CALL tab_1d_2d( nbpac, smv_i (:,:,jl), npac(1:nbpac), zsmv_i_1d(1:nbpac,jl) , jpi, jpj )
498            DO jk = 1, nlay_i
499               CALL tab_1d_2d( nbpac, e_i(:,:,jk,jl), npac(1:nbpac), ze_i_1d(1:nbpac,jk,jl), jpi, jpj )
500            END DO
501         END DO
502         CALL tab_1d_2d( nbpac, sfx_opw, npac(1:nbpac), sfx_opw_1d(1:nbpac), jpi, jpj )
503         CALL tab_1d_2d( nbpac, wfx_opw, npac(1:nbpac), wfx_opw_1d(1:nbpac), jpi, jpj )
504
505         CALL tab_1d_2d( nbpac, hfx_thd, npac(1:nbpac), hfx_thd_1d(1:nbpac), jpi, jpj )
506         CALL tab_1d_2d( nbpac, hfx_opw, npac(1:nbpac), hfx_opw_1d(1:nbpac), jpi, jpj )
507         !
508      ENDIF ! nbpac > 0
509
510      !------------------------------------------------------------------------------!
511      ! 8) Change units for e_i
512      !------------------------------------------------------------------------------!   
513      DO jl = 1, jpl
514         DO jk = 1, nlay_i
515            DO jj = 1, jpj
516               DO ji = 1, jpi
517                  ! heat content in J/m2
518                  e_i(ji,jj,jk,jl) = e_i(ji,jj,jk,jl) * v_i(ji,jj,jl) * r1_nlay_i 
519               END DO
520            END DO
521         END DO
522      END DO
523
524      !
525      CALL wrk_dealloc( jpij, jcat )   ! integer
526      CALL wrk_dealloc( jpij, zswinew, zv_newice, za_newice, zh_newice, ze_newice, zs_newice, zo_newice )
527      CALL wrk_dealloc( jpij, zdv_res, zda_res, zat_i_1d, zv_frazb, zvrel_1d )
528      CALL wrk_dealloc( jpij,jpl, zv_b, za_b, za_i_1d, zv_i_1d, zsmv_i_1d )
529      CALL wrk_dealloc( jpij,nlay_i,jpl, ze_i_1d )
530      CALL wrk_dealloc( jpi,jpj, zvrel )
531      !
532   END SUBROUTINE lim_thd_lac
533
534#else
535   !!----------------------------------------------------------------------
536   !!   Default option                               NO  LIM3 sea-ice model
537   !!----------------------------------------------------------------------
538CONTAINS
539   SUBROUTINE lim_thd_lac           ! Empty routine
540   END SUBROUTINE lim_thd_lac
541#endif
542
543   !!======================================================================
544END MODULE limthd_lac
Note: See TracBrowser for help on using the repository browser.