New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limthd_sal.F90 in trunk/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: trunk/NEMOGCM/NEMO/LIM_SRC_3/limthd_sal.F90 @ 2760

Last change on this file since 2760 was 2715, checked in by rblod, 13 years ago

First attempt to put dynamic allocation on the trunk
  • Property svn:keywords set to Id
File size: 12.7 KB
Line 
1MODULE limthd_sal
2   !!======================================================================
3   !!                       ***  MODULE limthd_sal ***
4   !! LIM-3 sea-ice :  computation of salinity variations in the ice
5   !!======================================================================
6   !! History :   -   ! 2003-05 (M. Vancoppenolle) UCL-ASTR first coding for LIM3-1D
7   !!            3.0  ! 2005-12 (M. Vancoppenolle) adapted to the 3-D version
8   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
9   !!---------------------------------------------------------------------
10#if defined key_lim3
11   !!----------------------------------------------------------------------
12   !!   'key_lim3'                                      LIM-3 sea-ice model
13   !!----------------------------------------------------------------------
14   !!   lim_thd_sal : salinity variations in the ice
15   !!----------------------------------------------------------------------
16   USE par_oce          ! ocean parameters
17   USE phycst           ! physical constants (ocean directory)
18   USE sbc_oce          ! Surface boundary condition: ocean fields
19   USE ice              ! LIM variables
20   USE par_ice          ! LIM parameters
21   USE thd_ice          ! LIM thermodynamics
22   USE limvar           ! LIM variables
23   USE wrk_nemo         ! workspace manager
24   USE in_out_manager   ! I/O manager
25   USE lib_mpp         ! MPP library
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   lim_thd_sal        ! called by limthd module
31   PUBLIC   lim_thd_sal_init   ! called by iceini module
32
33   !!----------------------------------------------------------------------
34   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011)
35   !! $Id$
36   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
37   !!----------------------------------------------------------------------
38CONTAINS
39
40   SUBROUTINE lim_thd_sal( kideb, kiut )
41      !!-------------------------------------------------------------------
42      !!                ***  ROUTINE lim_thd_sal  ***   
43      !!   
44      !! ** Purpose :   computes new salinities in the ice
45      !!
46      !! ** Method  :  4 possibilities
47      !!               -> num_sal = 1 -> constant salinity for z,t
48      !!               -> num_sal = 2 -> S = S(z,t) [simple Vancoppenolle et al 2005]
49      !!               -> num_sal = 3 -> S = S(z)   [multiyear ice]
50      !!               -> num_sal = 4 -> S = S(h)   [Cox and Weeks 74]
51      !!---------------------------------------------------------------------
52      INTEGER, INTENT(in) ::  kideb, kiut   ! thickness category index
53      !
54      INTEGER  ::   ji, jk     ! dummy loop indices
55      INTEGER  ::   zji, zjj   ! local integers
56      REAL(wp) ::   zsold, iflush, iaccrbo, igravdr, isnowic, i_ice_switch,  ztmelts   ! local scalars
57      REAL(wp) ::   zaaa, zbbb, zccc, zdiscrim   ! local scalars
58      !
59      REAL(wp), POINTER, DIMENSION(:) ::   ze_init, zhiold, zsiold
60      !!---------------------------------------------------------------------
61
62      IF(  wrk_in_use(1, 1,2,3)  ) THEN
63         CALL ctl_stop('lim_thd_dh : requestead workspace arrays unavailable.')   ;   RETURN
64      END IF
65      ! Set-up pointers to sub-arrays of workspace arrays
66      ze_init =>  wrk_1d_1 (1:jpij)
67      zhiold  =>  wrk_1d_2 (1:jpij)
68      zsiold  =>  wrk_1d_3 (1:jpij)
69
70      !------------------------------------------------------------------------------|
71      ! 1) Constant salinity, constant in time                                       |
72      !------------------------------------------------------------------------------|
73!!gm comment: if num_sal = 1 s_i_b and sm_i_b can be set to bulk_sal one for all in the initialisation phase !!
74      IF( num_sal == 1 ) THEN
75         !
76         DO jk = 1, nlay_i
77            DO ji = kideb, kiut
78               s_i_b(ji,jk) =  bulk_sal
79            END DO ! ji
80         END DO ! jk
81         !
82         DO ji = kideb, kiut
83            sm_i_b(ji)      =  bulk_sal 
84         END DO ! ji
85         !
86      ENDIF
87
88      !------------------------------------------------------------------------------|
89      !  Module 2 : Constant salinity varying in time                                |
90      !------------------------------------------------------------------------------|
91
92      IF(  num_sal == 2  .OR.  num_sal == 4  ) THEN
93
94         !---------------------------------
95         ! Thickness at previous time step
96         !---------------------------------
97         DO ji = kideb, kiut
98            zhiold(ji) = ht_i_b(ji) - dh_i_bott(ji) - dh_snowice(ji) - dh_i_surf(ji)
99         END DO
100
101         !---------------------
102         ! Global heat content
103         !---------------------
104         ze_init(:)  =  0._wp
105         DO jk = 1, nlay_i
106            DO ji = kideb, kiut
107               ze_init(ji) = ze_init(ji) + q_i_b(ji,jk) * ht_i_b(ji) / nlay_i
108            END DO
109         END DO
110
111         DO ji = kideb, kiut
112            !
113            ! Switches
114            !----------
115            iflush       =         MAX( 0._wp , SIGN( 1.0 , t_su_b(ji) - rtt )        )    ! =1 if summer
116            igravdr      =         MAX( 0._wp , SIGN( 1.0 , t_bo_b(ji) - t_su_b(ji) ) )    ! =1 if t_su < t_bo
117            iaccrbo      =         MAX( 0._wp , SIGN( 1.0 , dh_i_bott(ji) )           )    ! =1 if bottom accretion
118            i_ice_switch = 1._wp - MAX ( 0._wp , SIGN( 1._wp , - ht_i_b(ji) + 1.e-2 ) )
119            isnowic      = 1._wp - MAX ( 0._wp , SIGN( 1._wp , - dh_snowice(ji) ) ) * i_ice_switch   ! =1 if snow ice formation
120
121            !---------------------
122            ! Salinity tendencies
123            !---------------------
124            !                                   ! drainage by gravity drainage
125            dsm_i_gd_1d(ji) = - igravdr * MAX( sm_i_b(ji) - sal_G , 0._wp ) / time_G * rdt_ice 
126            !                                   ! drainage by flushing 
127            dsm_i_fl_1d(ji) = - iflush * MAX( sm_i_b(ji) - sal_F , 0._wp ) / time_F * rdt_ice
128
129            !-----------------
130            ! Update salinity   
131            !-----------------
132            ! only drainage terms ( gravity drainage and flushing )
133            ! snow ice / bottom sources are added in lim_thd_ent to conserve energy
134            zsiold(ji) = sm_i_b(ji)
135            sm_i_b(ji) = sm_i_b(ji) + dsm_i_fl_1d(ji) + dsm_i_gd_1d(ji)
136
137            ! if no ice, salinity = 0.1
138            i_ice_switch = 1._wp - MAX ( 0._wp, SIGN( 1._wp , - ht_i_b(ji) ) )
139            sm_i_b(ji)   = i_ice_switch * sm_i_b(ji) + s_i_min * ( 1._wp - i_ice_switch )
140         END DO ! ji
141
142         ! Salinity profile
143         CALL lim_var_salprof1d( kideb, kiut )
144
145         !----------------------------
146         ! Heat flux - brine drainage
147         !----------------------------
148
149         DO ji = kideb, kiut
150!!gm useless
151            ! iflush  : 1 if summer
152            iflush  =  MAX( 0._wp , SIGN ( 1._wp , t_su_b(ji) - rtt ) ) 
153            ! igravdr : 1 if t_su lt t_bo
154            igravdr =  MAX( 0._wp , SIGN ( 1._wp , t_bo_b(ji) - t_su_b(ji) ) ) 
155            ! iaccrbo : 1 if bottom accretion
156            iaccrbo =  MAX( 0._wp , SIGN ( 1._wp , dh_i_bott(ji) ) )
157!!gm end useless
158            !
159            fhbri_1d(ji) = 0._wp
160         END DO ! ji
161
162         !----------------------------
163         ! Salt flux - brine drainage
164         !----------------------------
165         DO ji = kideb, kiut
166            i_ice_switch = 1._wp - MAX ( 0._wp, SIGN( 1._wp , - ht_i_b(ji) ) )
167            fsbri_1d(ji) = fsbri_1d(ji) - i_ice_switch * rhoic * a_i_b(ji) * ht_i_b(ji)         &
168               &         * ( MAX(dsm_i_gd_1d(ji) + dsm_i_fl_1d(ji), sm_i_b(ji) - zsiold(ji) ) ) / rdt_ice
169            IF( num_sal == 4 ) fsbri_1d(ji) = 0._wp
170         END DO ! ji
171
172         ! Only necessary for conservation check since salinity is modified
173         !--------------------
174         ! Temperature update
175         !--------------------
176         DO jk = 1, nlay_i
177            DO ji = kideb, kiut
178               ztmelts    =  -tmut*s_i_b(ji,jk) + rtt
179               !Conversion q(S,T) -> T (second order equation)
180               zaaa         =  cpic
181               zbbb         =  ( rcp - cpic ) * ( ztmelts - rtt ) + q_i_b(ji,jk) / rhoic - lfus
182               zccc         =  lfus * ( ztmelts - rtt )
183               zdiscrim     =  SQRT(  MAX( zbbb*zbbb - 4.0*zaaa*zccc, 0._wp )  )
184               t_i_b(ji,jk) =  rtt - ( zbbb + zdiscrim ) / ( 2.0 *zaaa )
185            END DO
186         END DO
187         !
188      ENDIF ! num_sal .EQ. 2
189
190      !------------------------------------------------------------------------------|
191      !  Module 3 : Profile of salinity, constant in time                            |
192      !------------------------------------------------------------------------------|
193
194      IF( num_sal == 3 )   CALL lim_var_salprof1d( kideb, kiut )
195
196      !------------------------------------------------------------------------------|
197      !  Module 4 : Constant salinity varying in time                                |
198      !------------------------------------------------------------------------------|
199
200      IF( num_sal == 5 ) THEN      ! Cox and Weeks, 1974
201         !
202         DO ji = kideb, kiut
203            zsold = sm_i_b(ji)
204            IF( ht_i_b(ji) < 0.4 ) THEN
205               sm_i_b(ji) = 14.24 - 19.39 * ht_i_b(ji) 
206            ELSE
207               sm_i_b(ji) =  7.88 - 1.59 * ht_i_b(ji)
208               sm_i_b(ji) = MIN( sm_i_b(ji) , zsold ) 
209            ENDIF
210            IF( ht_i_b(ji) > 3.06918239 ) THEN
211               sm_i_b(ji) = 3._wp
212            ENDIF
213            DO jk = 1, nlay_i
214               s_i_b(ji,jk)   = sm_i_b(ji)
215            END DO
216         END DO
217         !
218      ENDIF ! num_sal
219
220      !------------------------------------------------------------------------------|
221      ! 5) Computation of salt flux due to Bottom growth
222      !------------------------------------------------------------------------------|
223
224      IF ( num_sal == 4 ) THEN
225         DO ji = kideb, kiut
226            zji = MOD( npb(ji) - 1 , jpi ) + 1
227            zjj =    ( npb(ji) - 1 ) / jpi + 1
228            fseqv_1d(ji) = fseqv_1d(ji) + ( sss_m(zji,zjj) - bulk_sal    )               &
229               &                        * rhoic * a_i_b(ji) * MAX( dh_i_bott(ji) , 0.0 ) / rdt_ice
230         END DO
231      ELSE
232         DO ji = kideb, kiut
233            zji = MOD( npb(ji) - 1 , jpi ) + 1
234            zjj =    ( npb(ji) - 1 ) / jpi + 1
235            fseqv_1d(ji) = fseqv_1d(ji) + ( sss_m(zji,zjj) - s_i_new(ji) )               &
236               &                        * rhoic * a_i_b(ji) * MAX( dh_i_bott(ji) , 0.0 ) / rdt_ice
237         END DO
238      ENDIF
239      !
240      IF( wrk_not_released(1, 1,2,3) )   CALL ctl_stop( 'lim_thd_lac : failed to release workspace arrays' )
241      !
242   END SUBROUTINE lim_thd_sal
243
244
245   SUBROUTINE lim_thd_sal_init
246      !!-------------------------------------------------------------------
247      !!                  ***  ROUTINE lim_thd_sal_init  ***
248      !!
249      !! ** Purpose :   initialization of ice salinity parameters
250      !!
251      !! ** Method  :   Read the namicesal namelist and check the parameter
252      !!              values called at the first timestep (nit000)
253      !!
254      !! ** input   :   Namelist namicesal
255      !!-------------------------------------------------------------------
256      NAMELIST/namicesal/ num_sal, bulk_sal, sal_G, time_G, sal_F, time_F,   &
257         &                s_i_max, s_i_min, s_i_0, s_i_1
258      !!-------------------------------------------------------------------
259      !
260      REWIND( numnam_ice )                   ! Read Namelist namicesal
261      READ  ( numnam_ice  , namicesal )
262      !
263      IF(lwp) THEN                           ! control print
264         WRITE(numout,*)
265         WRITE(numout,*) 'lim_thd_sal_init : Ice parameters for salinity '
266         WRITE(numout,*) '~~~~~~~~~~~~~~~~'
267         WRITE(numout,*) ' switch for salinity num_sal        : ', num_sal
268         WRITE(numout,*) ' bulk salinity value if num_sal = 1 : ', bulk_sal
269         WRITE(numout,*) ' restoring salinity for GD          : ', sal_G
270         WRITE(numout,*) ' restoring time for GD              : ', time_G
271         WRITE(numout,*) ' restoring salinity for flushing    : ', sal_F
272         WRITE(numout,*) ' restoring time for flushing        : ', time_F
273         WRITE(numout,*) ' Maximum tolerated ice salinity     : ', s_i_max
274         WRITE(numout,*) ' Minimum tolerated ice salinity     : ', s_i_min
275         WRITE(numout,*) ' 1st salinity for salinity profile  : ', s_i_0
276         WRITE(numout,*) ' 2nd salinity for salinity profile  : ', s_i_1
277      ENDIF
278      !
279   END SUBROUTINE lim_thd_sal_init
280
281#else
282   !!----------------------------------------------------------------------
283   !!   Default option         Dummy Module          No LIM-3 sea-ice model
284   !!----------------------------------------------------------------------
285#endif
286   !!======================================================================
287END MODULE limthd_sal
Note: See TracBrowser for help on using the repository browser.