New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limupdate2.F90 in trunk/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: trunk/NEMOGCM/NEMO/LIM_SRC_3/limupdate2.F90 @ 4872

Last change on this file since 4872 was 4872, checked in by clem, 9 years ago

LIM3: replacing old_ by _b
File size: 13.6 KB
Line 
1MODULE limupdate2
2   !!======================================================================
3   !!                     ***  MODULE  limupdate2  ***
4   !!   LIM-3 : Update of sea-ice global variables at the end of the time step
5   !!======================================================================
6   !! History :  3.0  !  2006-04  (M. Vancoppenolle) Original code
7   !!            3.6  !  2014-06  (C. Rousset)       Complete rewriting/cleaning
8   !!----------------------------------------------------------------------
9#if defined key_lim3
10   !!----------------------------------------------------------------------
11   !!   'key_lim3'                                      LIM3 sea-ice model
12   !!----------------------------------------------------------------------
13   !!    lim_update2   : computes update of sea-ice global variables from trend terms
14   !!----------------------------------------------------------------------
15   USE limrhg          ! ice rheology
16
17   USE dom_oce
18   USE oce             ! dynamics and tracers variables
19   USE in_out_manager
20   USE sbc_oce         ! Surface boundary condition: ocean fields
21   USE sbc_ice         ! Surface boundary condition: ice fields
22   USE dom_ice
23   USE phycst          ! physical constants
24   USE ice
25   USE limdyn
26   USE limtrp
27   USE limthd
28   USE limsbc
29   USE limdiahsb
30   USE limwri
31   USE limrst
32   USE thd_ice         ! LIM thermodynamic sea-ice variables
33   USE par_ice
34   USE limitd_th
35   USE limitd_me
36   USE limvar
37   USE prtctl           ! Print control
38   USE lbclnk           ! lateral boundary condition - MPP exchanges
39   USE wrk_nemo         ! work arrays
40   USE lib_fortran     ! glob_sum
41   USE timing          ! Timing
42   USE limcons        ! conservation tests
43
44   IMPLICIT NONE
45   PRIVATE
46
47   PUBLIC   lim_update2   ! routine called by ice_step
48
49   REAL(wp)  ::   epsi10 = 1.e-10_wp   !    -       -
50   REAL(wp)  ::   epsi20 = 1.e-20_wp   
51     
52   !! * Substitutions
53#  include "vectopt_loop_substitute.h90"
54   !!----------------------------------------------------------------------
55   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011)
56   !! $Id: limupdate.F90 3294 2012-01-28 16:44:18Z rblod $
57   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
58   !!----------------------------------------------------------------------
59CONTAINS
60
61   SUBROUTINE lim_update2
62      !!-------------------------------------------------------------------
63      !!               ***  ROUTINE lim_update2  ***
64      !!               
65      !! ** Purpose :  Computes update of sea-ice global variables at
66      !!               the end of the time step.
67      !!
68      !!---------------------------------------------------------------------
69      INTEGER  ::   ji, jj, jk, jl    ! dummy loop indices
70      INTEGER  ::   i_ice_switch
71      REAL(wp) ::   zh, zsal
72      !
73      REAL(wp) :: zvi_b, zsmv_b, zei_b, zfs_b, zfw_b, zft_b 
74      !!-------------------------------------------------------------------
75      IF( nn_timing == 1 )  CALL timing_start('limupdate2')
76
77      ! conservation test
78      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limupdate2', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
79
80      !-----------------
81      ! zap small values
82      !-----------------
83      CALL lim_itd_me_zapsmall
84
85      CALL lim_var_glo2eqv
86
87      !----------------------------------------------------
88      ! Rebin categories with thickness out of bounds
89      !----------------------------------------------------
90      IF ( jpl > 1 )   CALL lim_itd_th_reb(1, jpl)
91
92      !----------------------------------------------------------------------
93      ! Constrain the thickness of the smallest category above hiclim
94      !----------------------------------------------------------------------
95      DO jj = 1, jpj 
96         DO ji = 1, jpi
97            IF( v_i(ji,jj,1) > 0._wp .AND. ht_i(ji,jj,1) < hiclim ) THEN
98               zh             = hiclim / ht_i(ji,jj,1)
99               ht_s(ji,jj,1) = ht_s(ji,jj,1) * zh
100               ht_i(ji,jj,1) = ht_i(ji,jj,1) * zh
101               a_i (ji,jj,1) = a_i(ji,jj,1)  / zh
102            ENDIF
103         END DO
104      END DO
105     
106      !-----------------------------------------------------
107      ! ice concentration should not exceed amax
108      !-----------------------------------------------------
109      at_i(:,:) = 0._wp
110      DO jl = 1, jpl
111         at_i(:,:) = a_i(:,:,jl) + at_i(:,:)
112      END DO
113
114      DO jl  = 1, jpl
115         DO jj = 1, jpj
116            DO ji = 1, jpi
117               IF( at_i(ji,jj) > amax .AND. a_i(ji,jj,jl) > 0._wp ) THEN
118                  a_i(ji,jj,jl)  = a_i(ji,jj,jl) * ( 1._wp - ( 1._wp - amax / at_i(ji,jj) ) )
119                  ht_i(ji,jj,jl) = v_i(ji,jj,jl) / a_i(ji,jj,jl)
120               ENDIF
121            END DO
122         END DO
123      END DO
124
125      at_i(:,:) = 0.0
126      DO jl = 1, jpl
127         at_i(:,:) = a_i(:,:,jl) + at_i(:,:)
128      END DO
129
130      ! --------------------------------------
131      ! Final thickness distribution rebinning
132      ! --------------------------------------
133      IF ( jpl > 1 ) CALL lim_itd_th_reb( 1, jpl )
134
135      !-----------------
136      ! zap small values
137      !-----------------
138      CALL lim_itd_me_zapsmall
139
140      !---------------------
141      ! 2.11) Ice salinity
142      !---------------------
143      IF (  num_sal == 2  ) THEN
144         DO jl = 1, jpl
145            DO jj = 1, jpj 
146               DO ji = 1, jpi
147                  zsal            = smv_i(ji,jj,jl)
148                  smv_i(ji,jj,jl) = sm_i(ji,jj,jl) * v_i(ji,jj,jl)
149                  ! salinity stays in bounds
150                  i_ice_switch    = 1._wp - MAX( 0._wp, SIGN( 1._wp, - v_i(ji,jj,jl) ) )
151                  smv_i(ji,jj,jl) = i_ice_switch * MAX( MIN( s_i_max * v_i(ji,jj,jl), smv_i(ji,jj,jl) ), s_i_min * v_i(ji,jj,jl) ) !+ s_i_min * ( 1._wp - i_ice_switch ) * v_i(ji,jj,jl)
152                  ! associated salt flux
153                  sfx_res(ji,jj) = sfx_res(ji,jj) - ( smv_i(ji,jj,jl) - zsal ) * rhoic * r1_rdtice
154               END DO ! ji
155            END DO ! jj
156         END DO !jl
157      ENDIF
158
159      !------------------------------------------------------------------------------
160      ! 2) Corrections to avoid wrong values                                        |
161      !------------------------------------------------------------------------------
162      ! Ice drift
163      !------------
164      DO jj = 2, jpjm1
165         DO ji = 2, jpim1
166            IF ( at_i(ji,jj) == 0._wp ) THEN ! what to do if there is no ice
167               IF ( at_i(ji+1,jj) == 0._wp ) u_ice(ji,jj)   = 0._wp ! right side
168               IF ( at_i(ji-1,jj) == 0._wp ) u_ice(ji-1,jj) = 0._wp ! left side
169               IF ( at_i(ji,jj+1) == 0._wp ) v_ice(ji,jj)   = 0._wp ! upper side
170               IF ( at_i(ji,jj-1) == 0._wp ) v_ice(ji,jj-1) = 0._wp ! bottom side
171            ENDIF
172         END DO
173      END DO
174      !lateral boundary conditions
175      CALL lbc_lnk( u_ice(:,:), 'U', -1. )
176      CALL lbc_lnk( v_ice(:,:), 'V', -1. )
177      !mask velocities
178      u_ice(:,:) = u_ice(:,:) * tmu(:,:)
179      v_ice(:,:) = v_ice(:,:) * tmv(:,:)
180 
181      ! -------------------------------------------------
182      ! Diagnostics
183      ! -------------------------------------------------
184      d_a_i_thd(:,:,:)   = a_i(:,:,:)   - a_i_b(:,:,:) 
185      d_v_s_thd(:,:,:)   = v_s(:,:,:)   - v_s_b(:,:,:)
186      d_v_i_thd(:,:,:)   = v_i(:,:,:)   - v_i_b(:,:,:) 
187      d_e_s_thd(:,:,:,:) = e_s(:,:,:,:) - e_s_b(:,:,:,:) 
188      d_e_i_thd(:,:,1:nlay_i,:) = e_i(:,:,1:nlay_i,:) - e_i_b(:,:,1:nlay_i,:)
189      !?? d_oa_i_thd(:,:,:)  = oa_i (:,:,:) - oa_i_b (:,:,:)
190      d_smv_i_thd(:,:,:) = 0._wp
191      IF( num_sal == 2 )   d_smv_i_thd(:,:,:) = smv_i(:,:,:) - smv_i_b(:,:,:)
192      ! diag only (clem)
193      dv_dt_thd(:,:,:) = d_v_i_thd(:,:,:) * r1_rdtice * rday
194
195      ! heat content variation (W.m-2)
196      DO jj = 1, jpj
197         DO ji = 1, jpi           
198            diag_heat_dhc(ji,jj) = ( SUM( d_e_i_trp(ji,jj,1:nlay_i,:) + d_e_i_thd(ji,jj,1:nlay_i,:) ) +  & 
199               &                     SUM( d_e_s_trp(ji,jj,1:nlay_s,:) + d_e_s_thd(ji,jj,1:nlay_s,:) )    &
200               &                   ) * unit_fac * r1_rdtice / area(ji,jj)   
201         END DO
202      END DO
203
204      ! conservation test
205      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limupdate2', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
206
207      IF(ln_ctl) THEN   ! Control print
208         CALL prt_ctl_info(' ')
209         CALL prt_ctl_info(' - Cell values : ')
210         CALL prt_ctl_info('   ~~~~~~~~~~~~~ ')
211         CALL prt_ctl(tab2d_1=area       , clinfo1=' lim_update2  : cell area   :')
212         CALL prt_ctl(tab2d_1=at_i       , clinfo1=' lim_update2  : at_i        :')
213         CALL prt_ctl(tab2d_1=vt_i       , clinfo1=' lim_update2  : vt_i        :')
214         CALL prt_ctl(tab2d_1=vt_s       , clinfo1=' lim_update2  : vt_s        :')
215         CALL prt_ctl(tab2d_1=strength   , clinfo1=' lim_update2  : strength    :')
216         CALL prt_ctl(tab2d_1=u_ice      , clinfo1=' lim_update2  : u_ice       :', tab2d_2=v_ice      , clinfo2=' v_ice       :')
217         CALL prt_ctl(tab2d_1=u_ice_b    , clinfo1=' lim_update2  : u_ice_b     :', tab2d_2=v_ice_b    , clinfo2=' v_ice_b     :')
218
219         DO jl = 1, jpl
220            CALL prt_ctl_info(' ')
221            CALL prt_ctl_info(' - Category : ', ivar1=jl)
222            CALL prt_ctl_info('   ~~~~~~~~~~')
223            CALL prt_ctl(tab2d_1=ht_i       (:,:,jl)        , clinfo1= ' lim_update2  : ht_i        : ')
224            CALL prt_ctl(tab2d_1=ht_s       (:,:,jl)        , clinfo1= ' lim_update2  : ht_s        : ')
225            CALL prt_ctl(tab2d_1=t_su       (:,:,jl)        , clinfo1= ' lim_update2  : t_su        : ')
226            CALL prt_ctl(tab2d_1=t_s        (:,:,1,jl)      , clinfo1= ' lim_update2  : t_snow      : ')
227            CALL prt_ctl(tab2d_1=sm_i       (:,:,jl)        , clinfo1= ' lim_update2  : sm_i        : ')
228            CALL prt_ctl(tab2d_1=o_i        (:,:,jl)        , clinfo1= ' lim_update2  : o_i         : ')
229            CALL prt_ctl(tab2d_1=a_i        (:,:,jl)        , clinfo1= ' lim_update2  : a_i         : ')
230            CALL prt_ctl(tab2d_1=a_i_b      (:,:,jl)        , clinfo1= ' lim_update2  : a_i_b       : ')
231            CALL prt_ctl(tab2d_1=d_a_i_thd  (:,:,jl)        , clinfo1= ' lim_update2  : d_a_i_thd   : ')
232            CALL prt_ctl(tab2d_1=v_i        (:,:,jl)        , clinfo1= ' lim_update2  : v_i         : ')
233            CALL prt_ctl(tab2d_1=v_i_b      (:,:,jl)        , clinfo1= ' lim_update2  : v_i_b       : ')
234            CALL prt_ctl(tab2d_1=d_v_i_thd  (:,:,jl)        , clinfo1= ' lim_update2  : d_v_i_thd   : ')
235            CALL prt_ctl(tab2d_1=v_s        (:,:,jl)        , clinfo1= ' lim_update2  : v_s         : ')
236            CALL prt_ctl(tab2d_1=v_s_b      (:,:,jl)        , clinfo1= ' lim_update2  : v_s_b       : ')
237            CALL prt_ctl(tab2d_1=d_v_s_thd  (:,:,jl)        , clinfo1= ' lim_update2  : d_v_s_thd   : ')
238            CALL prt_ctl(tab2d_1=e_i        (:,:,1,jl)/1.0e9, clinfo1= ' lim_update2  : e_i1        : ')
239            CALL prt_ctl(tab2d_1=e_i_b      (:,:,1,jl)/1.0e9, clinfo1= ' lim_update2  : e_i1_b      : ')
240            CALL prt_ctl(tab2d_1=d_e_i_thd  (:,:,1,jl)/1.0e9, clinfo1= ' lim_update2  : de_i1_thd   : ')
241            CALL prt_ctl(tab2d_1=e_i        (:,:,2,jl)/1.0e9, clinfo1= ' lim_update2  : e_i2        : ')
242            CALL prt_ctl(tab2d_1=e_i_b      (:,:,2,jl)/1.0e9, clinfo1= ' lim_update2  : e_i2_b      : ')
243            CALL prt_ctl(tab2d_1=d_e_i_thd  (:,:,2,jl)/1.0e9, clinfo1= ' lim_update2  : de_i2_thd   : ')
244            CALL prt_ctl(tab2d_1=e_s        (:,:,1,jl)      , clinfo1= ' lim_update2  : e_snow      : ')
245            CALL prt_ctl(tab2d_1=e_s_b      (:,:,1,jl)      , clinfo1= ' lim_update2  : e_snow_b    : ')
246            CALL prt_ctl(tab2d_1=d_e_s_thd  (:,:,1,jl)/1.0e9, clinfo1= ' lim_update2  : d_e_s_thd   : ')
247            CALL prt_ctl(tab2d_1=smv_i      (:,:,jl)        , clinfo1= ' lim_update2  : smv_i       : ')
248            CALL prt_ctl(tab2d_1=smv_i_b    (:,:,jl)        , clinfo1= ' lim_update2  : smv_i_b     : ')
249            CALL prt_ctl(tab2d_1=d_smv_i_thd(:,:,jl)        , clinfo1= ' lim_update2  : d_smv_i_thd : ')
250            CALL prt_ctl(tab2d_1=oa_i       (:,:,jl)        , clinfo1= ' lim_update2  : oa_i        : ')
251            CALL prt_ctl(tab2d_1=oa_i_b     (:,:,jl)        , clinfo1= ' lim_update2  : oa_i_b      : ')
252            CALL prt_ctl(tab2d_1=d_oa_i_thd (:,:,jl)        , clinfo1= ' lim_update2  : d_oa_i_thd  : ')
253
254            DO jk = 1, nlay_i
255               CALL prt_ctl_info(' - Layer : ', ivar1=jk)
256               CALL prt_ctl(tab2d_1=t_i(:,:,jk,jl) , clinfo1= ' lim_update2  : t_i       : ')
257            END DO
258         END DO
259
260         CALL prt_ctl_info(' ')
261         CALL prt_ctl_info(' - Heat / FW fluxes : ')
262         CALL prt_ctl_info('   ~~~~~~~~~~~~~~~~~~ ')
263         CALL prt_ctl(tab2d_1=sst_m  , clinfo1= ' lim_update2 : sst   : ', tab2d_2=sss_m     , clinfo2= ' sss       : ')
264
265         CALL prt_ctl_info(' ')
266         CALL prt_ctl_info(' - Stresses : ')
267         CALL prt_ctl_info('   ~~~~~~~~~~ ')
268         CALL prt_ctl(tab2d_1=utau       , clinfo1= ' lim_update2 : utau      : ', tab2d_2=vtau       , clinfo2= ' vtau      : ')
269         CALL prt_ctl(tab2d_1=utau_ice   , clinfo1= ' lim_update2 : utau_ice  : ', tab2d_2=vtau_ice   , clinfo2= ' vtau_ice  : ')
270         CALL prt_ctl(tab2d_1=u_oce      , clinfo1= ' lim_update2 : u_oce     : ', tab2d_2=v_oce      , clinfo2= ' v_oce     : ')
271      ENDIF
272   
273      IF( nn_timing == 1 )  CALL timing_stop('limupdate2')
274
275   END SUBROUTINE lim_update2
276#else
277   !!----------------------------------------------------------------------
278   !!   Default option         Empty Module               No sea-ice model
279   !!----------------------------------------------------------------------
280CONTAINS
281   SUBROUTINE lim_update2     ! Empty routine
282   END SUBROUTINE lim_update2
283
284#endif
285
286END MODULE limupdate2
Note: See TracBrowser for help on using the repository browser.