New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limupdate2.F90 in trunk/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: trunk/NEMOGCM/NEMO/LIM_SRC_3/limupdate2.F90 @ 5125

Last change on this file since 5125 was 5123, checked in by clem, 9 years ago

major LIM3 cleaning + monocat capabilities + NEMO namelist-consistency; sette to follow
File size: 12.8 KB
Line 
1MODULE limupdate2
2   !!======================================================================
3   !!                     ***  MODULE  limupdate2  ***
4   !!   LIM-3 : Update of sea-ice global variables at the end of the time step
5   !!======================================================================
6   !! History :  3.0  !  2006-04  (M. Vancoppenolle) Original code
7   !!            3.5  !  2014-06  (C. Rousset)       Complete rewriting/cleaning
8   !!----------------------------------------------------------------------
9#if defined key_lim3
10   !!----------------------------------------------------------------------
11   !!   'key_lim3'                                      LIM3 sea-ice model
12   !!----------------------------------------------------------------------
13   !!    lim_update2   : computes update of sea-ice global variables from trend terms
14   !!----------------------------------------------------------------------
15   USE sbc_oce         ! Surface boundary condition: ocean fields
16   USE sbc_ice         ! Surface boundary condition: ice fields
17   USE dom_ice
18   USE dom_oce
19   USE phycst          ! physical constants
20   USE ice
21   USE thd_ice         ! LIM thermodynamic sea-ice variables
22   USE limitd_th
23   USE limvar
24   USE prtctl          ! Print control
25   USE lbclnk          ! lateral boundary condition - MPP exchanges
26   USE wrk_nemo        ! work arrays
27   USE timing          ! Timing
28   USE limcons         ! conservation tests
29   USE limctl
30   USE lib_mpp         ! MPP library
31   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
32   USE in_out_manager
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   lim_update2   ! routine called by ice_step
38
39   !! * Substitutions
40#  include "vectopt_loop_substitute.h90"
41   !!----------------------------------------------------------------------
42   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011)
43   !! $Id: limupdate.F90 3294 2012-01-28 16:44:18Z rblod $
44   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE lim_update2( kt )
49      !!-------------------------------------------------------------------
50      !!               ***  ROUTINE lim_update2  ***
51      !!               
52      !! ** Purpose :  Computes update of sea-ice global variables at
53      !!               the end of the time step.
54      !!
55      !!---------------------------------------------------------------------
56      INTEGER, INTENT(in) ::   kt    ! number of iteration
57      INTEGER  ::   ji, jj, jk, jl   ! dummy loop indices
58      REAL(wp) ::   zh, zsal
59      REAL(wp) ::   zvi_b, zsmv_b, zei_b, zfs_b, zfw_b, zft_b 
60      !!-------------------------------------------------------------------
61      IF( nn_timing == 1 )  CALL timing_start('limupdate2')
62
63      IF( kt == nit000 .AND. lwp ) THEN
64         WRITE(numout,*) ' lim_update2 '
65         WRITE(numout,*) ' ~~~~~~~~~~~ '
66      ENDIF
67
68      ! conservation test
69      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limupdate2', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
70
71      !-----------------
72      ! zap small values
73      !-----------------
74      CALL lim_var_agg( 1 )
75      CALL lim_var_zapsmall
76      CALL lim_var_glo2eqv
77
78      !----------------------------------------------------
79      ! Rebin categories with thickness out of bounds
80      !----------------------------------------------------
81      IF ( jpl > 1 )   CALL lim_itd_th_reb(1, jpl)
82
83      !----------------------------------------------------------------------
84      ! Constrain the thickness of the smallest category above himin
85      !----------------------------------------------------------------------
86      DO jj = 1, jpj 
87         DO ji = 1, jpi
88            IF( v_i(ji,jj,1) > 0._wp .AND. ht_i(ji,jj,1) < rn_himin ) THEN
89               zh             = rn_himin / ht_i(ji,jj,1)
90               ht_s(ji,jj,1) = ht_s(ji,jj,1) * zh
91               ht_i(ji,jj,1) = ht_i(ji,jj,1) * zh
92               a_i (ji,jj,1) = a_i(ji,jj,1)  / zh
93            ENDIF
94         END DO
95      END DO
96     
97      !-----------------------------------------------------
98      ! ice concentration should not exceed amax
99      !-----------------------------------------------------
100      at_i(:,:) = 0._wp
101      DO jl = 1, jpl
102         at_i(:,:) = a_i(:,:,jl) + at_i(:,:)
103      END DO
104
105      DO jl  = 1, jpl
106         DO jj = 1, jpj
107            DO ji = 1, jpi
108               IF( at_i(ji,jj) > rn_amax .AND. a_i(ji,jj,jl) > 0._wp ) THEN
109                  a_i(ji,jj,jl)  = a_i(ji,jj,jl) * ( 1._wp - ( 1._wp - rn_amax / at_i(ji,jj) ) )
110                  ht_i(ji,jj,jl) = v_i(ji,jj,jl) / a_i(ji,jj,jl)
111               ENDIF
112            END DO
113         END DO
114      END DO
115
116      at_i(:,:) = 0.0
117      DO jl = 1, jpl
118         at_i(:,:) = a_i(:,:,jl) + at_i(:,:)
119      END DO
120
121      ! --------------------------------------
122      ! Final thickness distribution rebinning
123      ! --------------------------------------
124      IF ( jpl > 1 ) CALL lim_itd_th_reb( 1, jpl )
125
126      !-----------------
127      ! zap small values
128      !-----------------
129      CALL lim_var_zapsmall
130
131      !---------------------
132      ! Ice salinity
133      !---------------------
134      IF (  nn_icesal == 2  ) THEN
135         DO jl = 1, jpl
136            DO jj = 1, jpj 
137               DO ji = 1, jpi
138                  zsal            = smv_i(ji,jj,jl)
139                  smv_i(ji,jj,jl) = sm_i(ji,jj,jl) * v_i(ji,jj,jl)
140                  ! salinity stays in bounds
141                  rswitch         = 1._wp - MAX( 0._wp, SIGN( 1._wp, - v_i(ji,jj,jl) ) )
142                  smv_i(ji,jj,jl) = rswitch * MAX( MIN( rn_simax * v_i(ji,jj,jl), smv_i(ji,jj,jl) ), rn_simin * v_i(ji,jj,jl) ) !+ rn_simin * ( 1._wp - rswitch ) * v_i(ji,jj,jl)
143                  ! associated salt flux
144                  sfx_res(ji,jj) = sfx_res(ji,jj) - ( smv_i(ji,jj,jl) - zsal ) * rhoic * r1_rdtice
145               END DO ! ji
146            END DO ! jj
147         END DO !jl
148      ENDIF
149
150      !------------------------------------------------------------------------------
151      ! Corrections to avoid wrong values                                        |
152      !------------------------------------------------------------------------------
153      ! Ice drift
154      !------------
155      DO jj = 2, jpjm1
156         DO ji = 2, jpim1
157            IF ( at_i(ji,jj) == 0._wp ) THEN ! what to do if there is no ice
158               IF ( at_i(ji+1,jj) == 0._wp ) u_ice(ji,jj)   = 0._wp ! right side
159               IF ( at_i(ji-1,jj) == 0._wp ) u_ice(ji-1,jj) = 0._wp ! left side
160               IF ( at_i(ji,jj+1) == 0._wp ) v_ice(ji,jj)   = 0._wp ! upper side
161               IF ( at_i(ji,jj-1) == 0._wp ) v_ice(ji,jj-1) = 0._wp ! bottom side
162            ENDIF
163         END DO
164      END DO
165      !lateral boundary conditions
166      CALL lbc_lnk( u_ice(:,:), 'U', -1. )
167      CALL lbc_lnk( v_ice(:,:), 'V', -1. )
168      !mask velocities
169      u_ice(:,:) = u_ice(:,:) * umask(:,:,1)
170      v_ice(:,:) = v_ice(:,:) * vmask(:,:,1)
171 
172      ! for outputs
173      CALL lim_var_glo2eqv            ! equivalent variables (outputs)
174      CALL lim_var_agg(2)             ! aggregate ice thickness categories
175
176      ! conservation test
177      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limupdate2', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
178
179      ! -------------------------------------------------
180      ! Diagnostics
181      ! -------------------------------------------------
182      DO jl  = 1, jpl
183         afx_thd(:,:) = afx_thd(:,:) + ( a_i(:,:,jl) - a_i_b(:,:,jl) ) * r1_rdtice
184      END DO
185      afx_tot = afx_thd + afx_dyn
186
187      ! heat content variation (W.m-2)
188      DO jj = 1, jpj
189         DO ji = 1, jpi           
190            diag_heat_dhc(ji,jj) = diag_heat_dhc(ji,jj) -  &
191               &                   ( SUM( e_i(ji,jj,1:nlay_i,:) - e_i_b(ji,jj,1:nlay_i,:) ) +  & 
192               &                     SUM( e_s(ji,jj,1:nlay_s,:) - e_s_b(ji,jj,1:nlay_s,:) )    &
193               &                   ) * r1_rdtice   
194         END DO
195      END DO
196
197      ! -------------------------------------------------
198      ! control prints
199      ! -------------------------------------------------
200      IF( ln_nicep )   CALL lim_prt( kt, jiindx, jjindx, 2, ' - Final state - ' )   ! control print
201
202      IF(ln_ctl) THEN   ! Control print
203         CALL prt_ctl_info(' ')
204         CALL prt_ctl_info(' - Cell values : ')
205         CALL prt_ctl_info('   ~~~~~~~~~~~~~ ')
206         CALL prt_ctl(tab2d_1=e12t       , clinfo1=' lim_update2  : cell area   :')
207         CALL prt_ctl(tab2d_1=at_i       , clinfo1=' lim_update2  : at_i        :')
208         CALL prt_ctl(tab2d_1=vt_i       , clinfo1=' lim_update2  : vt_i        :')
209         CALL prt_ctl(tab2d_1=vt_s       , clinfo1=' lim_update2  : vt_s        :')
210         CALL prt_ctl(tab2d_1=strength   , clinfo1=' lim_update2  : strength    :')
211         CALL prt_ctl(tab2d_1=u_ice      , clinfo1=' lim_update2  : u_ice       :', tab2d_2=v_ice      , clinfo2=' v_ice       :')
212         CALL prt_ctl(tab2d_1=u_ice_b    , clinfo1=' lim_update2  : u_ice_b     :', tab2d_2=v_ice_b    , clinfo2=' v_ice_b     :')
213
214         DO jl = 1, jpl
215            CALL prt_ctl_info(' ')
216            CALL prt_ctl_info(' - Category : ', ivar1=jl)
217            CALL prt_ctl_info('   ~~~~~~~~~~')
218            CALL prt_ctl(tab2d_1=ht_i       (:,:,jl)        , clinfo1= ' lim_update2  : ht_i        : ')
219            CALL prt_ctl(tab2d_1=ht_s       (:,:,jl)        , clinfo1= ' lim_update2  : ht_s        : ')
220            CALL prt_ctl(tab2d_1=t_su       (:,:,jl)        , clinfo1= ' lim_update2  : t_su        : ')
221            CALL prt_ctl(tab2d_1=t_s        (:,:,1,jl)      , clinfo1= ' lim_update2  : t_snow      : ')
222            CALL prt_ctl(tab2d_1=sm_i       (:,:,jl)        , clinfo1= ' lim_update2  : sm_i        : ')
223            CALL prt_ctl(tab2d_1=o_i        (:,:,jl)        , clinfo1= ' lim_update2  : o_i         : ')
224            CALL prt_ctl(tab2d_1=a_i        (:,:,jl)        , clinfo1= ' lim_update2  : a_i         : ')
225            CALL prt_ctl(tab2d_1=a_i_b      (:,:,jl)        , clinfo1= ' lim_update2  : a_i_b       : ')
226            CALL prt_ctl(tab2d_1=v_i        (:,:,jl)        , clinfo1= ' lim_update2  : v_i         : ')
227            CALL prt_ctl(tab2d_1=v_i_b      (:,:,jl)        , clinfo1= ' lim_update2  : v_i_b       : ')
228            CALL prt_ctl(tab2d_1=v_s        (:,:,jl)        , clinfo1= ' lim_update2  : v_s         : ')
229            CALL prt_ctl(tab2d_1=v_s_b      (:,:,jl)        , clinfo1= ' lim_update2  : v_s_b       : ')
230            CALL prt_ctl(tab2d_1=e_i        (:,:,1,jl)      , clinfo1= ' lim_update2  : e_i1        : ')
231            CALL prt_ctl(tab2d_1=e_i_b      (:,:,1,jl)      , clinfo1= ' lim_update2  : e_i1_b      : ')
232            CALL prt_ctl(tab2d_1=e_i        (:,:,2,jl)      , clinfo1= ' lim_update2  : e_i2        : ')
233            CALL prt_ctl(tab2d_1=e_i_b      (:,:,2,jl)      , clinfo1= ' lim_update2  : e_i2_b      : ')
234            CALL prt_ctl(tab2d_1=e_s        (:,:,1,jl)      , clinfo1= ' lim_update2  : e_snow      : ')
235            CALL prt_ctl(tab2d_1=e_s_b      (:,:,1,jl)      , clinfo1= ' lim_update2  : e_snow_b    : ')
236            CALL prt_ctl(tab2d_1=smv_i      (:,:,jl)        , clinfo1= ' lim_update2  : smv_i       : ')
237            CALL prt_ctl(tab2d_1=smv_i_b    (:,:,jl)        , clinfo1= ' lim_update2  : smv_i_b     : ')
238            CALL prt_ctl(tab2d_1=oa_i       (:,:,jl)        , clinfo1= ' lim_update2  : oa_i        : ')
239            CALL prt_ctl(tab2d_1=oa_i_b     (:,:,jl)        , clinfo1= ' lim_update2  : oa_i_b      : ')
240
241            DO jk = 1, nlay_i
242               CALL prt_ctl_info(' - Layer : ', ivar1=jk)
243               CALL prt_ctl(tab2d_1=t_i(:,:,jk,jl) , clinfo1= ' lim_update2  : t_i       : ')
244            END DO
245         END DO
246
247         CALL prt_ctl_info(' ')
248         CALL prt_ctl_info(' - Heat / FW fluxes : ')
249         CALL prt_ctl_info('   ~~~~~~~~~~~~~~~~~~ ')
250         CALL prt_ctl(tab2d_1=sst_m  , clinfo1= ' lim_update2 : sst   : ', tab2d_2=sss_m     , clinfo2= ' sss       : ')
251
252         CALL prt_ctl_info(' ')
253         CALL prt_ctl_info(' - Stresses : ')
254         CALL prt_ctl_info('   ~~~~~~~~~~ ')
255         CALL prt_ctl(tab2d_1=utau       , clinfo1= ' lim_update2 : utau      : ', tab2d_2=vtau       , clinfo2= ' vtau      : ')
256         CALL prt_ctl(tab2d_1=utau_ice   , clinfo1= ' lim_update2 : utau_ice  : ', tab2d_2=vtau_ice   , clinfo2= ' vtau_ice  : ')
257         CALL prt_ctl(tab2d_1=u_oce      , clinfo1= ' lim_update2 : u_oce     : ', tab2d_2=v_oce      , clinfo2= ' v_oce     : ')
258      ENDIF
259   
260      IF( nn_timing == 1 )  CALL timing_stop('limupdate2')
261
262   END SUBROUTINE lim_update2
263#else
264   !!----------------------------------------------------------------------
265   !!   Default option         Empty Module               No sea-ice model
266   !!----------------------------------------------------------------------
267CONTAINS
268   SUBROUTINE lim_update2     ! Empty routine
269   END SUBROUTINE lim_update2
270
271#endif
272
273END MODULE limupdate2
Note: See TracBrowser for help on using the repository browser.