New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dtadyn.F90 in trunk/NEMOGCM/NEMO/OFF_SRC – NEMO

source: trunk/NEMOGCM/NEMO/OFF_SRC/dtadyn.F90 @ 2715

Last change on this file since 2715 was 2715, checked in by rblod, 13 years ago

First attempt to put dynamic allocation on the trunk
  • Property svn:keywords set to Id
File size: 36.5 KB
Line 
1MODULE dtadyn
2   !!======================================================================
3   !!                       ***  MODULE  dtadyn  ***
4   !! Off-line : interpolation of the physical fields
5   !!======================================================================
6   !! History :   OPA  ! 1992-01 (M. Imbard) Original code
7   !!             8.0  ! 1998-04 (L.Bopp MA Foujols) slopes for isopyc.
8   !!              -   ! 1998-05 (L. Bopp) read output of coupled run
9   !!             8.2  ! 2001-01 (M. Levy et M. Benjelloul) add netcdf FORMAT
10   !!   NEMO      1.0  ! 2005-03 (O. Aumont and A. El Moussaoui) F90
11   !!              -   ! 2005-12 (C. Ethe) Adapted for DEGINT
12   !!             3.0  ! 2007-06 (C. Ethe) use of iom module
13   !!              -   ! 2007-09  (C. Ethe)  add swap_dyn_data
14   !!             3.3  ! 2010-11 (C. Ethe) Full reorganization of the off-line: phasing with the on-line
15   !!----------------------------------------------------------------------
16
17   !!----------------------------------------------------------------------
18   !!   dta_dyn_init : initialization, namelist read, and parameters control
19   !!   dta_dyn      : Interpolation of the fields
20   !!----------------------------------------------------------------------
21   USE oce             ! ocean dynamics and tracers variables
22   USE c1d             ! 1D configuration: lk_c1d
23   USE dom_oce         ! ocean domain: variables
24   USE zdf_oce         ! ocean vertical physics: variables
25   USE sbc_oce         ! surface module: variables
26   USE phycst          ! physical constants
27   USE trabbl          ! active tracer: bottom boundary layer
28   USE ldfslp          ! lateral diffusion: iso-neutral slopes
29   USE ldfeiv          ! eddy induced velocity coef.
30   USE ldftra_oce      ! ocean tracer   lateral physics
31   USE zdfmxl          ! vertical physics: mixed layer depth
32   USE eosbn2          ! equation of state - Brunt Vaisala frequency
33   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
34   USE zpshde          ! z-coord. with partial steps: horizontal derivatives
35   USE in_out_manager  ! I/O manager
36   USE iom             ! I/O library
37   USE lib_mpp         ! distributed memory computing library
38   USE prtctl          !  print control
39
40   IMPLICIT NONE
41   PRIVATE
42
43   PUBLIC   dta_dyn_init   ! called by opa.F90
44   PUBLIC   dta_dyn        ! called by step.F90
45
46   LOGICAL, PUBLIC ::   lperdyn = .TRUE.   !: boolean for periodic fields or not
47   LOGICAL, PUBLIC ::   lfirdyn = .TRUE.   !: boolean for the first call or not
48
49   INTEGER, PUBLIC ::   ndtadyn = 73       !: Number of dat in one year
50   INTEGER, PUBLIC ::   ndtatot = 73       !: Number of data in the input field
51   INTEGER, PUBLIC ::   nsptint = 1        !: type of spatial interpolation
52
53   CHARACTER(len=45) ::   cfile_grid_T = 'dyna_grid_T.nc'   ! name of the grid_T file
54   CHARACTER(len=45) ::   cfile_grid_U = 'dyna_grid_U.nc'   ! name of the grid_U file
55   CHARACTER(len=45) ::   cfile_grid_V = 'dyna_grid_V.nc'   ! name of the grid_V file
56   CHARACTER(len=45) ::   cfile_grid_W = 'dyna_grid_W.nc'   ! name of the grid_W file
57   
58   REAL(wp) ::   rnspdta    ! number of time step per 2 consecutives data
59   REAL(wp) ::   rnspdta2   ! rnspdta * 0.5
60
61   INTEGER ::   ndyn1, ndyn2    !
62   INTEGER ::   nlecoff = 0     ! switch for the first read
63   INTEGER ::   numfl_t, numfl_u, numfl_v, numfl_w
64
65   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:,:) :: tdta       ! temperature at two consecutive times
66   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:,:) :: sdta       ! salinity at two consecutive times
67   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:,:) :: udta       ! zonal velocity at two consecutive times
68   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:,:) :: vdta       ! meridional velocity at two consecutive times
69   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:,:) :: wdta       ! vertical velocity at two consecutive times
70   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:,:) :: avtdta     ! vertical diffusivity coefficient
71
72   REAL(wp), ALLOCATABLE, SAVE,   DIMENSION(:,:,:) :: hmlddta    ! mixed layer depth at two consecutive times
73   REAL(wp), ALLOCATABLE, SAVE,   DIMENSION(:,:,:) :: wspddta    ! wind speed at two consecutive times
74   REAL(wp), ALLOCATABLE, SAVE,   DIMENSION(:,:,:) :: frlddta    ! sea-ice fraction at two consecutive times
75   REAL(wp), ALLOCATABLE, SAVE,   DIMENSION(:,:,:) :: empdta     ! E-P at two consecutive times
76   REAL(wp), ALLOCATABLE, SAVE,   DIMENSION(:,:,:) :: qsrdta     ! short wave heat flux at two consecutive times
77   REAL(wp), ALLOCATABLE, SAVE,   DIMENSION(:,:,:) :: bblxdta    ! frequency of bbl in the x direction at 2 consecutive times
78   REAL(wp), ALLOCATABLE, SAVE,   DIMENSION(:,:,:) :: bblydta    ! frequency of bbl in the y direction at 2 consecutive times
79   LOGICAL :: l_offbbl
80#if defined key_ldfslp
81   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:,:) :: uslpdta    ! zonal isopycnal slopes
82   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:,:) :: vslpdta    ! meridional isopycnal slopes
83   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:,:) :: wslpidta   ! zonal diapycnal slopes
84   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:,:) :: wslpjdta   ! meridional diapycnal slopes
85#endif
86#if ! defined key_degrad &&  defined key_traldf_c2d && defined key_traldf_eiv
87   REAL(wp), ALLOCATABLE, SAVE,   DIMENSION(:,:,:) :: aeiwdta    ! G&M coefficient
88#endif
89#if defined key_degrad
90   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:,:) :: ahtudta, ahtvdta, ahtwdta   ! Lateral diffusivity
91# if defined key_traldf_eiv
92   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:,:) :: aeiudta, aeivdta, aeiwdta   ! G&M coefficient
93# endif
94#endif
95
96   !! * Substitutions
97#  include "domzgr_substitute.h90"
98#  include "vectopt_loop_substitute.h90"
99   !!----------------------------------------------------------------------
100   !! NEMO/OFF 3.3 , NEMO Consortium (2010)
101   !! $Id$
102   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
103   !!----------------------------------------------------------------------
104CONTAINS
105
106   SUBROUTINE dta_dyn( kt )
107      !!----------------------------------------------------------------------
108      !!                  ***  ROUTINE dta_dyn  ***
109      !!
110      !! ** Purpose :   Prepares dynamics and physics fields from an NEMO run
111      !!              for an off-line simulation of passive tracers
112      !!
113      !! ** Method : calculates the position of DATA to read READ DATA
114      !!             (example month changement) computes slopes IF needed
115      !!             interpolates DATA IF needed
116      !!----------------------------------------------------------------------
117      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
118      !!
119      INTEGER  ::   iper, iperm1, iswap, izt   ! local integers
120      REAL(wp) ::   zt, zweigh                 ! local scalars
121      !!----------------------------------------------------------------------
122
123      zt     = ( REAL(kt,wp) + rnspdta2 ) / rnspdta
124      izt    = INT( zt )
125      zweigh = zt - REAL( INT(zt), wp )
126
127      IF( lperdyn ) THEN   ;   iperm1 = MOD( izt, ndtadyn )
128      ELSE                 ;   iperm1 = MOD( izt, ndtatot - 1 ) + 1
129      ENDIF
130
131      iper = iperm1 + 1
132      IF( iperm1 == 0 ) THEN
133          IF( lperdyn ) THEN
134              iperm1 = ndtadyn
135          ELSE
136              IF( lfirdyn ) THEN
137                  IF(lwp) WRITE (numout,*) 'dta_dyn:  dynamic file is not periodic with or without interpolation    &
138                     &                                we take the first value for the previous period iperm1 = 0  '
139              END IF
140          END IF
141      END IF
142
143      iswap  = 0
144
145      ! 1. First call lfirdyn = true
146      ! ----------------------------
147
148      IF( lfirdyn ) THEN
149         ndyn1 = iperm1         ! store the information of the period read
150         ndyn2 = iper
151         
152         IF(lwp) THEN
153            WRITE (numout,*) ' dynamics data read for the period ndyn1 =', ndyn1,   &
154               &             ' and for the period ndyn2 = ', ndyn2
155            WRITE (numout,*) ' time step is : ', kt
156            WRITE (numout,*) ' we have ndtadyn = ', ndtadyn, ' records in the dynamic file for one year'
157         END IF
158         !
159         CALL dynrea( kt, MAX( 1, iperm1) )           ! data read for the iperm1 period
160         
161         IF( lk_ldfslp .AND. .NOT. lk_c1d ) THEN      ! Computes slopes (here tsn and avt are used as workspace)
162            tsn (:,:,:,jp_tem) = tdta  (:,:,:,2)
163            tsn (:,:,:,jp_sal) = sdta  (:,:,:,2)
164            avt(:,:,:)         = avtdta(:,:,:,2)
165         
166            CALL eos( tsn, rhd, rhop )   ! Time-filtered in situ density
167            CALL bn2( tsn, rn2 )         ! before Brunt-Vaisala frequency
168            IF( ln_zps )   &
169               &   CALL zps_hde( kt, jpts, tsn, gtsu, gtsv,  &  ! Partial steps: before Horizontal DErivative
170               &                           rhd, gru , grv   )    ! of t, s, rd at the bottom ocean level
171            CALL zdf_mxl( kt )           ! mixed layer depth
172            CALL ldf_slp( kt, rhd, rn2 )
173         
174            uslpdta (:,:,:,2) = uslp (:,:,:)
175            vslpdta (:,:,:,2) = vslp (:,:,:)
176            wslpidta(:,:,:,2) = wslpi(:,:,:)
177            wslpjdta(:,:,:,2) = wslpj(:,:,:)
178         END IF
179         !
180         CALL swap_dyn_data            ! swap from record 2 to 1
181         !
182         iswap = 1        !  indicates swap
183         !
184         CALL dynrea( kt, iper )       ! data read for the iper period
185         !
186         IF( lk_ldfslp .AND. .NOT. lk_c1d ) THEN      ! Computes slopes (here tsn and avt are used as workspace)
187            tsn (:,:,:,jp_tem) = tdta  (:,:,:,2)
188            tsn (:,:,:,jp_sal) = sdta  (:,:,:,2)
189            avt(:,:,:)         = avtdta(:,:,:,2)
190            !
191                           CALL eos( tsn, rhd, rhop )                   ! now in situ density
192                           CALL bn2( tsn, rn2 )                         ! now Brunt-Vaisala frequency
193            IF( ln_zps )   CALL zps_hde( kt, jpts, tsn, gtsu, gtsv,  &  ! Partial steps: before Horizontal DErivative
194               &                                   rhd, gru , grv   )   ! of t, s, rd at the bottom ocean level
195                           CALL zdf_mxl( kt )                           ! mixed layer depth
196                           CALL ldf_slp( kt, rhd, rn2 )                 ! slope of iso-neutral surfaces
197            !
198            uslpdta (:,:,:,2) = uslp (:,:,:)
199            vslpdta (:,:,:,2) = vslp (:,:,:)
200            wslpidta(:,:,:,2) = wslpi(:,:,:)
201            wslpjdta(:,:,:,2) = wslpj(:,:,:)
202         END IF
203         !
204         lfirdyn = .FALSE.    ! trace the first call
205      ENDIF
206      !
207      ! And now what we have to do at every time step
208      ! check the validity of the period in memory
209      !
210      IF( iperm1 /= ndyn1 ) THEN 
211         !
212         IF( iperm1 == 0 ) THEN
213            IF(lwp) THEN
214               WRITE (numout,*) ' dynamic file is not periodic with periodic interpolation'
215               WRITE (numout,*) ' we take the last value for the last period '
216               WRITE (numout,*) ' iperm1 = 12,   iper = 13  '
217            ENDIF
218            iperm1 = 12
219            iper   = 13
220         ENDIF
221         !
222         CALL swap_dyn_data         ! We have to prepare a new read of data : swap from record 2 to 1
223         !
224         iswap = 1                  !  indicates swap
225         !
226         CALL dynrea( kt, iper )    ! data read for the iper period
227         !
228         IF( lk_ldfslp .AND. .NOT. lk_c1d ) THEN
229            ! Computes slopes. Caution : here tsn and avt are used as workspace
230            tsn(:,:,:,jp_tem) = tdta  (:,:,:,2)
231            tsn(:,:,:,jp_sal) = sdta  (:,:,:,2)
232            avt(:,:,:)        = avtdta(:,:,:,2)
233            !
234                           CALL eos( tsn, rhd, rhop )                   ! now in situ density
235                           CALL bn2( tsn, rn2 )                         ! now Brunt-Vaisala frequency
236            IF( ln_zps )   CALL zps_hde( kt, jpts, tsn, gtsu, gtsv,  &  ! Partial steps: before Horizontal DErivative
237               &                                   rhd, gru , grv   )   ! of t, s, rd at the bottom ocean level
238            CALL zdf_mxl( kt )                                          ! mixed layer depth
239            CALL ldf_slp( kt, rhd, rn2 )                                ! slope of iso-neutral surfaces
240            !
241            uslpdta (:,:,:,2) = uslp (:,:,:)
242            vslpdta (:,:,:,2) = vslp (:,:,:)
243            wslpidta(:,:,:,2) = wslpi(:,:,:)
244            wslpjdta(:,:,:,2) = wslpj(:,:,:)
245         END IF
246         !
247         ndyn1 = ndyn2         ! store the information of the period read
248         ndyn2 = iper
249         !
250         IF(lwp) THEN
251            WRITE (numout,*) ' dynamics data read for the period ndyn1 =', ndyn1,   &
252               &             ' and for the period ndyn2 = ', ndyn2
253            WRITE (numout,*) ' time step is : ', kt
254         END IF
255         !
256      END IF
257      !
258      ! Compute the data at the given time step
259      !----------------------------------------     
260
261      IF( nsptint == 0 ) THEN          ! No space interpolation, data are probably correct
262         !                             ! We have to initialize data if we have changed the period         
263         CALL assign_dyn_data
264      ELSEIF( nsptint == 1 ) THEN      ! linear interpolation
265         CALL linear_interp_dyn_data( zweigh )
266      ELSE                             ! other interpolation
267         WRITE (numout,*) ' this kind of interpolation do not exist at the moment : we stop'
268         STOP 'dtadyn'         
269      END IF
270      !
271      CALL eos( tsn, rhd, rhop )       ! In any case, we need rhop
272      !
273#if ! defined key_degrad && defined key_traldf_c2d
274      !                                ! In case of 2D varying coefficients, we need aeiv and aeiu
275      IF( lk_traldf_eiv )   CALL dta_eiv( kt )      ! eddy induced velocity coefficient
276#endif
277      !
278      IF( .NOT. l_offbbl ) THEN       ! Compute bbl coefficients if needed
279         tsb(:,:,:,:) = tsn(:,:,:,:)
280         CALL bbl( kt, 'TRC')
281      END IF
282      IF(ln_ctl) THEN
283         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' tn      - : ', mask1=tmask, ovlap=1, kdim=jpk   )
284         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sn      - : ', mask1=tmask, ovlap=1, kdim=jpk   )
285         CALL prt_ctl(tab3d_1=un               , clinfo1=' un      - : ', mask1=tmask, ovlap=1, kdim=jpk   )
286         CALL prt_ctl(tab3d_1=vn               , clinfo1=' vn      - : ', mask1=tmask, ovlap=1, kdim=jpk   )
287         CALL prt_ctl(tab3d_1=wn               , clinfo1=' wn      - : ', mask1=tmask, ovlap=1, kdim=jpk   )
288         CALL prt_ctl(tab3d_1=avt              , clinfo1=' kz      - : ', mask1=tmask, ovlap=1, kdim=jpk   )
289         CALL prt_ctl(tab2d_1=fr_i             , clinfo1=' fr_i    - : ', mask1=tmask, ovlap=1 )
290         CALL prt_ctl(tab2d_1=hmld             , clinfo1=' hmld    - : ', mask1=tmask, ovlap=1 )
291         CALL prt_ctl(tab2d_1=emps             , clinfo1=' emps    - : ', mask1=tmask, ovlap=1 )
292         CALL prt_ctl(tab2d_1=wndm             , clinfo1=' wspd    - : ', mask1=tmask, ovlap=1 )
293         CALL prt_ctl(tab2d_1=qsr              , clinfo1=' qsr     - : ', mask1=tmask, ovlap=1 )
294      ENDIF
295      !
296   END SUBROUTINE dta_dyn
297
298
299   INTEGER FUNCTION dta_dyn_alloc()
300      !!---------------------------------------------------------------------
301      !!                 ***  ROUTINE dta_dyn_alloc  ***
302      !!---------------------------------------------------------------------
303
304      ALLOCATE( tdta    (jpi,jpj,jpk,2), sdta    (jpi,jpj,jpk,2),    &
305         &      udta    (jpi,jpj,jpk,2), vdta    (jpi,jpj,jpk,2),    &
306         &      wdta    (jpi,jpj,jpk,2), avtdta  (jpi,jpj,jpk,2),    &
307#if defined key_ldfslp 
308         &      uslpdta (jpi,jpj,jpk,2), vslpdta (jpi,jpj,jpk,2),    &
309         &      wslpidta(jpi,jpj,jpk,2), wslpjdta(jpi,jpj,jpk,2),    &
310#endif
311#if defined key_degrad
312         &      ahtudta (jpi,jpj,jpk,2), ahtvdta (jpi,jpj,jpk,2),    &
313         &      ahtwdta (jpi,jpj,jpk,2),                             &
314# if defined key_traldf_eiv
315         &      aeiudta (jpi,jpj,jpk,2), aeivdta (jpi,jpj,jpk,2),    &
316         &      aeiwdta (jpi,jpj,jpk,2),                             &
317# endif
318#endif
319#if ! defined key_degrad &&  defined key_traldf_c2d && defined key_traldf_eiv
320         &      aeiwdta (jpi,jpj,    2),                             &
321#endif
322         &      hmlddta (jpi,jpj,    2), wspddta (jpi,jpj,    2),    &
323         &      frlddta (jpi,jpj,    2), qsrdta  (jpi,jpj,    2),    &
324         &      empdta  (jpi,jpj,    2),                         STAT=dta_dyn_alloc ) 
325         !
326      IF( dta_dyn_alloc /= 0 )   CALL ctl_warn('dta_dyn_alloc: failed to allocate facvol array')
327      !
328   END FUNCTION dta_dyn_alloc
329
330
331   SUBROUTINE dynrea( kt, kenr )
332      !!----------------------------------------------------------------------
333      !!                  ***  ROUTINE dynrea  ***
334      !!
335      !! ** Purpose : READ dynamics fiels from OPA9 netcdf output
336      !!
337      !! ** Method : READ the kenr records of DATA and store in udta(...,2), .... 
338      !!----------------------------------------------------------------------
339      USE wrk_nemo, ONLY: wrk_in_use, wrk_not_released
340      USE wrk_nemo, ONLY: zu    => wrk_3d_1 , zv    => wrk_3d_2 , zw    => wrk_3d_3
341      USE wrk_nemo, ONLY: zt    => wrk_3d_4 , zs    => wrk_3d_5
342      USE wrk_nemo, ONLY: zavt  => wrk_3d_6 , zhdiv => wrk_3d_7
343      USE wrk_nemo, ONLY: zahtu => wrk_3d_8 , zahtv => wrk_3d_9 , zahtw => wrk_3d_10
344      USE wrk_nemo, ONLY: zaeiu => wrk_3d_11, zaeiv => wrk_3d_12, zaeiw => wrk_3d_13
345      !
346      USE wrk_nemo, ONLY: zemp  => wrk_2d_1 , zqsr  => wrk_2d_2 , zmld  => wrk_2d_3
347      USE wrk_nemo, ONLY: zice  => wrk_2d_4 , zwspd => wrk_2d_5 
348      USE wrk_nemo, ONLY: ztaux => wrk_2d_6 , ztauy => wrk_2d_7
349      USE wrk_nemo, ONLY: zbblx => wrk_2d_8 , zbbly => wrk_2d_9
350      USE wrk_nemo, ONLY: zaeiw2d => wrk_2d_10
351      !
352      INTEGER, INTENT(in) ::   kt, kenr   ! time index
353      !!
354      INTEGER ::  jkenr
355      !!----------------------------------------------------------------------
356      !
357      IF( wrk_in_use(3, 1,2,3,4,5,6,7,8,9,10,11,12,13) .OR. &
358          wrk_in_use(2, 1,2,3,4,5,6,7,8,9,10)               ) THEN
359         CALL ctl_stop('domrea/dta_dyn: requested workspace arrays unavailable')   ;   RETURN
360      ENDIF
361     
362      ! cas d'un fichier non periodique : on utilise deux fois le premier et
363      ! le dernier champ temporel
364
365      jkenr = kenr
366
367      IF(lwp) THEN
368         WRITE(numout,*)
369         WRITE(numout,*) 'Dynrea : read dynamical fields, kenr = ', jkenr
370         WRITE(numout,*) '~~~~~~~'
371#if defined key_degrad
372         WRITE(numout,*) ' Degraded fields'
373#endif
374         WRITE(numout,*)
375      ENDIF
376
377
378      IF( kt == nit000 .AND. nlecoff == 0 ) THEN
379         nlecoff = 1
380         CALL  iom_open ( cfile_grid_T, numfl_t )
381         CALL  iom_open ( cfile_grid_U, numfl_u )
382         CALL  iom_open ( cfile_grid_V, numfl_v )
383         CALL  iom_open ( cfile_grid_W, numfl_w )
384      ENDIF
385
386      ! file grid-T
387      !---------------
388      CALL iom_get( numfl_t, jpdom_data, 'votemper', zt   (:,:,:), jkenr )
389      CALL iom_get( numfl_t, jpdom_data, 'vosaline', zs   (:,:,:), jkenr )
390      CALL iom_get( numfl_t, jpdom_data, 'somixhgt', zmld (:,:  ), jkenr )
391      CALL iom_get( numfl_t, jpdom_data, 'sowaflcd', zemp (:,:  ), jkenr )
392      CALL iom_get( numfl_t, jpdom_data, 'soshfldo', zqsr (:,:  ), jkenr )
393      CALL iom_get( numfl_t, jpdom_data, 'soicecov', zice (:,:  ), jkenr )
394      IF( iom_varid( numfl_t, 'sowindsp', ldstop = .FALSE. ) > 0 ) THEN
395         CALL iom_get( numfl_t, jpdom_data, 'sowindsp', zwspd(:,:), jkenr ) 
396      ELSE
397         CALL iom_get( numfl_u, jpdom_data, 'sozotaux', ztaux(:,:), jkenr )
398         CALL iom_get( numfl_v, jpdom_data, 'sometauy', ztauy(:,:), jkenr )
399         CALL tau2wnd( ztaux, ztauy, zwspd )
400      ENDIF
401      ! files grid-U / grid_V
402      CALL iom_get( numfl_u, jpdom_data, 'vozocrtx', zu   (:,:,:), jkenr )
403      CALL iom_get( numfl_v, jpdom_data, 'vomecrty', zv   (:,:,:), jkenr )
404#if defined key_trabbl
405      IF( .NOT. lk_c1d .AND. nn_bbl_ldf == 1 ) THEN
406         IF( iom_varid( numfl_u, 'sobblcox', ldstop = .FALSE. ) > 0  .AND. &
407         &   iom_varid( numfl_v, 'sobblcoy', ldstop = .FALSE. ) > 0 ) THEN
408             CALL iom_get( numfl_u, jpdom_data, 'sobblcox', zbblx(:,:), jkenr )
409             CALL iom_get( numfl_v, jpdom_data, 'sobblcoy', zbbly(:,:), jkenr )
410             l_offbbl = .TRUE.
411         ENDIF
412      ENDIF
413#endif 
414
415      ! file grid-W
416!!      CALL iom_get ( numfl_w, jpdom_data, 'vovecrtz', zw   (:,:,:), jkenr )
417      ! Computation of vertical velocity using horizontal divergence
418      CALL wzv( zu, zv, zw, zhdiv )
419
420      IF( iom_varid( numfl_w, 'voddmavs', ldstop = .FALSE. ) > 0 ) THEN          ! avs exist: it is used
421         CALL iom_get( numfl_w, jpdom_data, 'voddmavs', zavt (:,:,:), jkenr )
422      ELSE                                                                       ! no avs: use avt
423         CALL iom_get( numfl_w, jpdom_data, 'votkeavt', zavt (:,:,:), jkenr )
424      ENDIF
425
426#if ! defined key_degrad && defined key_traldf_c2d && defined key_traldf_eiv
427      CALL iom_get( numfl_w, jpdom_data, 'soleaeiw', zaeiw2d(:,: ), jkenr )
428#endif
429
430#if defined key_degrad
431      CALL iom_get( numfl_u, jpdom_data, 'vozoahtu', zahtu(:,:,:), jkenr )
432      CALL iom_get( numfl_v, jpdom_data, 'vomeahtv', zahtv(:,:,:), jkenr )
433      CALL iom_get( numfl_w, jpdom_data, 'voveahtw', zahtw(:,:,:), jkenr )
434#  if defined key_traldf_eiv
435      CALL iom_get( numfl_u, jpdom_data, 'vozoaeiu', zaeiu(:,:,:), jkenr )
436      CALL iom_get( numfl_v, jpdom_data, 'vomeaeiv', zaeiv(:,:,:), jkenr )
437      CALL iom_get( numfl_w, jpdom_data, 'voveaeiw', zaeiw(:,:,:), jkenr )
438#  endif
439#endif
440
441      udta(:,:,:,2) = zu(:,:,:) * umask(:,:,:)
442      vdta(:,:,:,2) = zv(:,:,:) * vmask(:,:,:) 
443      wdta(:,:,:,2) = zw(:,:,:) * tmask(:,:,:)
444
445      tdta(:,:,:,2)   = zt  (:,:,:) * tmask(:,:,:)
446      sdta(:,:,:,2)   = zs  (:,:,:) * tmask(:,:,:)
447      avtdta(:,:,:,2) = zavt(:,:,:) * tmask(:,:,:)
448
449#if ! defined key_degrad && defined key_traldf_c2d && defined key_traldf_eiv
450      aeiwdta(:,:,2)  = zaeiw2d(:,:) * tmask(:,:,1)
451#endif
452
453#if defined key_degrad
454        ahtudta(:,:,:,2) = zahtu(:,:,:) * umask(:,:,:)
455        ahtvdta(:,:,:,2) = zahtv(:,:,:) * vmask(:,:,:)
456        ahtwdta(:,:,:,2) = zahtw(:,:,:) * tmask(:,:,:)
457#  if defined key_traldf_eiv
458        aeiudta(:,:,:,2) = zaeiu(:,:,:) * umask(:,:,:)
459        aeivdta(:,:,:,2) = zaeiv(:,:,:) * vmask(:,:,:)
460        aeiwdta(:,:,:,2) = zaeiw(:,:,:) * tmask(:,:,:)
461#  endif
462#endif
463
464      ! fluxes
465      !
466      wspddta(:,:,2)  = zwspd(:,:) * tmask(:,:,1)
467      frlddta(:,:,2)  = MIN( 1., zice(:,:) ) * tmask(:,:,1)
468      empdta (:,:,2)  = zemp(:,:) * tmask(:,:,1)
469      qsrdta (:,:,2)  = zqsr(:,:) * tmask(:,:,1)
470      hmlddta(:,:,2)  = zmld(:,:) * tmask(:,:,1)
471
472#if defined key_trabbl
473      IF( l_offbbl ) THEN
474         bblxdta(:,:,2) = MAX( 0., zbblx(:,:) )
475         bblydta(:,:,2) = MAX( 0., zbbly(:,:) )
476         WHERE( bblxdta(:,:,2) > 2. ) bblxdta(:,:,2) = 0.
477         WHERE( bblydta(:,:,2) > 2. ) bblydta(:,:,2) = 0.
478      ENDIF
479#endif
480     
481      IF( kt == nitend ) THEN
482         CALL iom_close ( numfl_t )
483         CALL iom_close ( numfl_u )
484         CALL iom_close ( numfl_v )
485         CALL iom_close ( numfl_w )
486      ENDIF
487      !     
488      IF( wrk_not_released(3, 1,2,3,4,5,6,7,8,9,10,11,12,13) .OR. &
489          wrk_not_released(2, 1,2,3,4,5,6,7,8,9,10)               ) THEN
490         CALL ctl_stop('domrea/dta_dyn: failed to release workspace arrays')
491      END IF
492      !
493   END SUBROUTINE dynrea
494
495
496   SUBROUTINE dta_dyn_init
497      !!----------------------------------------------------------------------
498      !!                  ***  ROUTINE dta_dyn_init  ***
499      !!
500      !! ** Purpose :   initializations of parameters for the interpolation
501      !!
502      !! ** Method :
503      !!----------------------------------------------------------------------
504      REAL(wp) :: znspyr   !: number of time step per year
505      !
506      NAMELIST/namdyn/ ndtadyn, ndtatot, nsptint, lperdyn,  &
507         &             cfile_grid_T, cfile_grid_U, cfile_grid_V, cfile_grid_W
508      !!----------------------------------------------------------------------
509      !
510      IF( dta_dyn_alloc() /= 0 )  CALL ctl_stop( 'STOP', 'dta_dyn_alloc: unable to allocate standard ocean arrays' )
511      !
512      REWIND( numnam )              ! Read Namelist namdyn : Lateral physics on tracers
513      READ  ( numnam, namdyn )
514      !
515      IF(lwp) THEN                  ! control print
516         WRITE(numout,*)
517         WRITE(numout,*) 'namdyn : offline dynamical selection'
518         WRITE(numout,*) '~~~~~~~'
519         WRITE(numout,*) '  Namelist namdyn : set parameters for the lecture of the dynamical fields'
520         WRITE(numout,*) 
521         WRITE(numout,*) ' number of elements in the FILE for a year  ndtadyn = ' , ndtadyn
522         WRITE(numout,*) ' total number of elements in the FILE       ndtatot = ' , ndtatot
523         WRITE(numout,*) ' type of interpolation                      nsptint = ' , nsptint
524         WRITE(numout,*) ' loop on the same FILE                      lperdyn = ' , lperdyn
525         WRITE(numout,*) '  '
526         WRITE(numout,*) ' name of grid_T file                   cfile_grid_T = ', TRIM(cfile_grid_T)   
527         WRITE(numout,*) ' name of grid_U file                   cfile_grid_U = ', TRIM(cfile_grid_U) 
528         WRITE(numout,*) ' name of grid_V file                   cfile_grid_V = ', TRIM(cfile_grid_V) 
529         WRITE(numout,*) ' name of grid_W file                   cfile_grid_W = ', TRIM(cfile_grid_W)     
530         WRITE(numout,*) ' '
531      ENDIF
532      !
533      znspyr   = nyear_len(1) * rday / rdt 
534      rnspdta  = znspyr / REAL( ndtadyn, wp )
535      rnspdta2 = rnspdta * 0.5 
536      !
537      CALL dta_dyn( nit000 )
538      !
539   END SUBROUTINE dta_dyn_init
540
541
542   SUBROUTINE wzv( pu, pv, pw, phdiv )
543      !!----------------------------------------------------------------------
544      !!                    ***  ROUTINE wzv  ***
545      !!
546      !! ** Purpose :   Compute the now vertical velocity after the array swap
547      !!
548      !! ** Method  : - compute the now divergence given by :
549      !!         * z-coordinate ONLY !!!!
550      !!         hdiv = 1/(e1t*e2t) [ di(e2u  u) + dj(e1v  v) ]
551      !!     - Using the incompressibility hypothesis, the vertical
552      !!      velocity is computed by integrating the horizontal divergence
553      !!      from the bottom to the surface.
554      !!        The boundary conditions are w=0 at the bottom (no flux).
555      !!----------------------------------------------------------------------
556      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in   ) :: pu, pv    !:  horizontal velocities
557      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(  out) :: pw        !:  verticla velocity
558      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) :: phdiv     !:  horizontal divergence
559      !!
560      INTEGER  ::  ji, jj, jk
561      REAL(wp) ::  zu, zu1, zv, zv1, zet
562      !!----------------------------------------------------------------------
563      !
564      ! Computation of vertical velocity using horizontal divergence
565      phdiv(:,:,:) = 0.
566      DO jk = 1, jpkm1
567         DO jj = 2, jpjm1
568            DO ji = fs_2, fs_jpim1   ! vector opt.
569               zu  = pu(ji  ,jj  ,jk) * umask(ji  ,jj  ,jk) * e2u(ji  ,jj  ) * fse3u(ji  ,jj  ,jk)
570               zu1 = pu(ji-1,jj  ,jk) * umask(ji-1,jj  ,jk) * e2u(ji-1,jj  ) * fse3u(ji-1,jj  ,jk)
571               zv  = pv(ji  ,jj  ,jk) * vmask(ji  ,jj  ,jk) * e1v(ji  ,jj  ) * fse3v(ji  ,jj  ,jk)
572               zv1 = pv(ji  ,jj-1,jk) * vmask(ji  ,jj-1,jk) * e1v(ji  ,jj-1) * fse3v(ji  ,jj-1,jk)
573               zet = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
574               phdiv(ji,jj,jk) = ( zu - zu1 + zv - zv1 ) * zet 
575            END DO
576         END DO
577      END DO
578      CALL lbc_lnk( phdiv, 'T', 1. )      ! Lateral boundary conditions on phdiv
579      !
580      ! computation of vertical velocity from the bottom
581      pw(:,:,jpk) = 0._wp
582      DO jk = jpkm1, 1, -1
583         pw(:,:,jk) = pw(:,:,jk+1) - fse3t(:,:,jk) * phdiv(:,:,jk)
584      END DO
585      !
586   END SUBROUTINE wzv
587
588
589   SUBROUTINE dta_eiv( kt )
590      !!----------------------------------------------------------------------
591      !!                  ***  ROUTINE dta_eiv  ***
592      !!
593      !! ** Purpose :   Compute the eddy induced velocity coefficient from the
594      !!      growth rate of baroclinic instability.
595      !!
596      !! ** Method : Specific to the offline model. Computes the horizontal
597      !!             values from the vertical value
598      !!----------------------------------------------------------------------
599      INTEGER, INTENT( in ) ::   kt     ! ocean time-step inedx
600      !!
601      INTEGER ::   ji, jj           ! dummy loop indices
602      !!----------------------------------------------------------------------
603      !
604      IF( kt == nit000 ) THEN
605         IF(lwp) WRITE(numout,*)
606         IF(lwp) WRITE(numout,*) 'dta_eiv : eddy induced velocity coefficients'
607         IF(lwp) WRITE(numout,*) '~~~~~~~'
608      ENDIF
609      !
610#if defined key_ldfeiv
611      ! Average the diffusive coefficient at u- v- points
612      DO jj = 2, jpjm1
613         DO ji = fs_2, fs_jpim1   ! vector opt.
614            aeiu(ji,jj) = .5 * ( aeiw(ji,jj) + aeiw(ji+1,jj  ) )
615            aeiv(ji,jj) = .5 * ( aeiw(ji,jj) + aeiw(ji  ,jj+1) )
616         END DO
617      END DO
618      CALL lbc_lnk( aeiu, 'U', 1. )   ;   CALL lbc_lnk( aeiv, 'V', 1. )    ! lateral boundary condition
619#endif
620      !
621   END SUBROUTINE dta_eiv
622
623
624   SUBROUTINE tau2wnd( ptaux, ptauy, pwspd )
625      !!---------------------------------------------------------------------
626      !!                    ***  ROUTINE sbc_tau2wnd  ***
627      !!
628      !! ** Purpose : Estimation of wind speed as a function of wind stress
629      !!
630      !! ** Method  : |tau|=rhoa*Cd*|U|^2
631      !!---------------------------------------------------------------------
632      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   ptaux, ptauy   ! wind stress in i-j direction resp.
633      REAL(wp), DIMENSION(jpi,jpj), INTENT(  out) ::   pwspd          ! wind speed
634      !!
635      REAL(wp) ::   zrhoa  = 1.22_wp       ! Air density kg/m3
636      REAL(wp) ::   zcdrag = 1.5e-3_wp     ! drag coefficient
637      REAL(wp) ::   ztx, zty, ztau, zcoef  ! temporary variables
638      INTEGER  ::   ji, jj                 ! dummy indices
639      !!---------------------------------------------------------------------
640      zcoef = 1. / ( zrhoa * zcdrag )
641!CDIR NOVERRCHK
642      DO jj = 2, jpjm1
643!CDIR NOVERRCHK
644         DO ji = fs_2, fs_jpim1   ! vector opt.
645            ztx = ptaux(ji,jj) * umask(ji,jj,1) + ptaux(ji-1,jj  ) * umask(ji-1,jj  ,1)
646            zty = ptauy(ji,jj) * vmask(ji,jj,1) + ptauy(ji  ,jj-1) * vmask(ji  ,jj-1,1)
647            ztau = 0.5 * SQRT( ztx * ztx + zty * zty )
648            pwspd(ji,jj) = SQRT ( ztau * zcoef ) * tmask(ji,jj,1)
649         END DO
650      END DO
651      CALL lbc_lnk( pwspd(:,:), 'T', 1. )
652      !
653   END SUBROUTINE tau2wnd
654
655
656   SUBROUTINE swap_dyn_data
657      !!----------------------------------------------------------------------
658      !!                    ***  ROUTINE swap_dyn_data  ***
659      !!
660      !! ** Purpose :   swap array data
661      !!----------------------------------------------------------------------
662      !
663      ! swap from record 2 to 1
664      tdta   (:,:,:,1) = tdta   (:,:,:,2)
665      sdta   (:,:,:,1) = sdta   (:,:,:,2)
666      avtdta (:,:,:,1) = avtdta (:,:,:,2)
667      udta   (:,:,:,1) = udta   (:,:,:,2)
668      vdta   (:,:,:,1) = vdta   (:,:,:,2)
669      wdta   (:,:,:,1) = wdta   (:,:,:,2)
670#if defined key_ldfslp && ! defined key_c1d
671      uslpdta (:,:,:,1) = uslpdta (:,:,:,2)
672      vslpdta (:,:,:,1) = vslpdta (:,:,:,2)
673      wslpidta(:,:,:,1) = wslpidta(:,:,:,2)
674      wslpjdta(:,:,:,1) = wslpjdta(:,:,:,2)
675#endif
676      hmlddta(:,:,1) = hmlddta(:,:,2) 
677      wspddta(:,:,1) = wspddta(:,:,2) 
678      frlddta(:,:,1) = frlddta(:,:,2) 
679      empdta (:,:,1) = empdta (:,:,2) 
680      qsrdta (:,:,1) = qsrdta (:,:,2) 
681      IF( l_offbbl ) THEN
682         bblxdta(:,:,1) = bblxdta(:,:,2)
683         bblydta(:,:,1) = bblydta(:,:,2) 
684      ENDIF
685
686#if ! defined key_degrad && defined key_traldf_c2d && defined key_traldf_eiv
687      aeiwdta(:,:,1) = aeiwdta(:,:,2)
688#endif
689
690#if defined key_degrad
691      ahtudta(:,:,:,1) = ahtudta(:,:,:,2)
692      ahtvdta(:,:,:,1) = ahtvdta(:,:,:,2)
693      ahtwdta(:,:,:,1) = ahtwdta(:,:,:,2)
694#  if defined key_traldf_eiv
695      aeiudta(:,:,:,1) = aeiudta(:,:,:,2)
696      aeivdta(:,:,:,1) = aeivdta(:,:,:,2)
697      aeiwdta(:,:,:,1) = aeiwdta(:,:,:,2)
698#  endif
699#endif
700      !
701   END SUBROUTINE swap_dyn_data
702
703
704   SUBROUTINE assign_dyn_data
705      !!----------------------------------------------------------------------
706      !!                    ***  ROUTINE assign_dyn_data  ***
707      !!
708      !! ** Purpose :   Assign dynamical data to the data that have been read
709      !!                without time interpolation
710      !!
711      !!----------------------------------------------------------------------
712     
713      tsn(:,:,:,jp_tem) = tdta  (:,:,:,2)
714      tsn(:,:,:,jp_sal) = sdta  (:,:,:,2)
715      avt(:,:,:)        = avtdta(:,:,:,2)
716     
717      un (:,:,:) = udta  (:,:,:,2) 
718      vn (:,:,:) = vdta  (:,:,:,2)
719      wn (:,:,:) = wdta  (:,:,:,2)
720     
721#if defined key_ldfslp && ! defined key_c1d
722      uslp (:,:,:) = uslpdta (:,:,:,2) 
723      vslp (:,:,:) = vslpdta (:,:,:,2) 
724      wslpi(:,:,:) = wslpidta(:,:,:,2) 
725      wslpj(:,:,:) = wslpjdta(:,:,:,2) 
726#endif
727
728      hmld(:,:) = hmlddta(:,:,2) 
729      wndm(:,:) = wspddta(:,:,2) 
730      fr_i(:,:) = frlddta(:,:,2) 
731      emp (:,:) = empdta (:,:,2) 
732      emps(:,:) = emp(:,:) 
733      qsr (:,:) = qsrdta (:,:,2) 
734#if defined key_trabbl
735      IF( l_offbbl ) THEN
736         ahu_bbl(:,:) = bblxdta(:,:,2)
737         ahv_bbl(:,:) = bblydta(:,:,2) 
738      ENDIF
739#endif
740#if ! defined key_degrad && defined key_traldf_c2d && defined key_traldf_eiv
741      aeiw(:,:) = aeiwdta(:,:,2)
742#endif
743     
744#if defined key_degrad
745      ahtu(:,:,:) = ahtudta(:,:,:,2)
746      ahtv(:,:,:) = ahtvdta(:,:,:,2)
747      ahtw(:,:,:) = ahtwdta(:,:,:,2)
748#  if defined key_traldf_eiv
749      aeiu(:,:,:) = aeiudta(:,:,:,2)
750      aeiv(:,:,:) = aeivdta(:,:,:,2)
751      aeiw(:,:,:) = aeiwdta(:,:,:,2)
752#  endif
753#endif
754      !
755   END SUBROUTINE assign_dyn_data
756
757
758   SUBROUTINE linear_interp_dyn_data( pweigh )
759      !!----------------------------------------------------------------------
760      !!               ***  ROUTINE linear_interp_dyn_data  ***
761      !!
762      !! ** Purpose :   linear interpolation of data
763      !!----------------------------------------------------------------------
764      REAL(wp), INTENT(in) ::   pweigh   ! weigh
765      !!
766      REAL(wp) :: zweighm1
767      !!----------------------------------------------------------------------
768
769      zweighm1 = 1. - pweigh
770     
771      tsn(:,:,:,jp_tem) = zweighm1 * tdta  (:,:,:,1) + pweigh * tdta  (:,:,:,2)
772      tsn(:,:,:,jp_sal) = zweighm1 * sdta  (:,:,:,1) + pweigh * sdta  (:,:,:,2)
773      avt(:,:,:)        = zweighm1 * avtdta(:,:,:,1) + pweigh * avtdta(:,:,:,2)
774     
775      un (:,:,:) = zweighm1 * udta  (:,:,:,1) + pweigh * udta  (:,:,:,2) 
776      vn (:,:,:) = zweighm1 * vdta  (:,:,:,1) + pweigh * vdta  (:,:,:,2)
777      wn (:,:,:) = zweighm1 * wdta  (:,:,:,1) + pweigh * wdta  (:,:,:,2)
778     
779#if defined key_ldfslp && ! defined key_c1d
780      uslp (:,:,:) = zweighm1 * uslpdta (:,:,:,1) + pweigh * uslpdta (:,:,:,2) 
781      vslp (:,:,:) = zweighm1 * vslpdta (:,:,:,1) + pweigh * vslpdta (:,:,:,2) 
782      wslpi(:,:,:) = zweighm1 * wslpidta(:,:,:,1) + pweigh * wslpidta(:,:,:,2) 
783      wslpj(:,:,:) = zweighm1 * wslpjdta(:,:,:,1) + pweigh * wslpjdta(:,:,:,2) 
784#endif
785
786      hmld(:,:) = zweighm1 * hmlddta(:,:,1) + pweigh  * hmlddta(:,:,2) 
787      wndm(:,:) = zweighm1 * wspddta(:,:,1) + pweigh  * wspddta(:,:,2) 
788      fr_i(:,:) = zweighm1 * frlddta(:,:,1) + pweigh  * frlddta(:,:,2) 
789      emp (:,:) = zweighm1 * empdta (:,:,1) + pweigh  * empdta (:,:,2) 
790      emps(:,:) = emp(:,:) 
791      qsr (:,:) = zweighm1 * qsrdta (:,:,1) + pweigh  * qsrdta (:,:,2) 
792#if defined key_trabbl
793      IF( l_offbbl ) THEN
794         ahu_bbl(:,:) = zweighm1 * bblxdta(:,:,1) +  pweigh  * bblxdta(:,:,2)
795         ahv_bbl(:,:) = zweighm1 * bblydta(:,:,1) +  pweigh  * bblydta(:,:,2)
796      ENDIF
797#endif
798
799#if ! defined key_degrad && defined key_traldf_c2d && defined key_traldf_eiv
800      aeiw(:,:) = zweighm1 * aeiwdta(:,:,1) + pweigh * aeiwdta(:,:,2)
801#endif
802     
803#if defined key_degrad
804      ahtu(:,:,:) = zweighm1 * ahtudta(:,:,:,1) + pweigh * ahtudta(:,:,:,2)
805      ahtv(:,:,:) = zweighm1 * ahtvdta(:,:,:,1) + pweigh * ahtvdta(:,:,:,2)
806      ahtw(:,:,:) = zweighm1 * ahtwdta(:,:,:,1) + pweigh * ahtwdta(:,:,:,2)
807#  if defined key_traldf_eiv
808      aeiu(:,:,:) = zweighm1 * aeiudta(:,:,:,1) + pweigh * aeiudta(:,:,:,2)
809      aeiv(:,:,:) = zweighm1 * aeivdta(:,:,:,1) + pweigh * aeivdta(:,:,:,2)
810      aeiw(:,:,:) = zweighm1 * aeiwdta(:,:,:,1) + pweigh * aeiwdta(:,:,:,2)
811#  endif
812#endif
813      !     
814   END SUBROUTINE linear_interp_dyn_data
815
816   !!======================================================================
817END MODULE dtadyn
Note: See TracBrowser for help on using the repository browser.