New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
bdydta.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/BDY – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/BDY/bdydta.F90 @ 3294

Last change on this file since 3294 was 3294, checked in by rblod, 12 years ago

Merge of 3.4beta into the trunk
  • Property svn:keywords set to Id
File size: 30.3 KB
Line 
1MODULE bdydta
2   !!======================================================================
3   !!                       ***  MODULE bdydta  ***
4   !! Open boundary data : read the data for the unstructured open boundaries.
5   !!======================================================================
6   !! History :  1.0  !  2005-01  (J. Chanut, A. Sellar)  Original code
7   !!             -   !  2007-01  (D. Storkey) Update to use IOM module
8   !!             -   !  2007-07  (D. Storkey) add bdy_dta_fla
9   !!            3.0  !  2008-04  (NEMO team)  add in the reference version
10   !!            3.3  !  2010-09  (E.O'Dea) modifications for Shelf configurations
11   !!            3.3  !  2010-09  (D.Storkey) add ice boundary conditions
12   !!            3.4  !  2011     (D. Storkey) rewrite in preparation for OBC-BDY merge
13   !!----------------------------------------------------------------------
14#if defined key_bdy
15   !!----------------------------------------------------------------------
16   !!   'key_bdy'                     Open Boundary Conditions
17   !!----------------------------------------------------------------------
18   !!    bdy_dta        : read external data along open boundaries from file
19   !!    bdy_dta_init   : initialise arrays etc for reading of external data
20   !!----------------------------------------------------------------------
21   USE wrk_nemo        ! Memory Allocation
22   USE timing          ! Timing
23   USE oce             ! ocean dynamics and tracers
24   USE dom_oce         ! ocean space and time domain
25   USE phycst          ! physical constants
26   USE bdy_oce         ! ocean open boundary conditions 
27   USE bdytides        ! tidal forcing at boundaries
28   USE fldread         ! read input fields
29   USE iom             ! IOM library
30   USE in_out_manager  ! I/O logical units
31#if defined key_lim2
32   USE ice_2
33#endif
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC   bdy_dta          ! routine called by step.F90 and dynspg_ts.F90
39   PUBLIC   bdy_dta_init     ! routine called by nemogcm.F90
40
41   INTEGER, ALLOCATABLE, DIMENSION(:)   ::   nb_bdy_fld        ! Number of fields to update for each boundary set.
42   INTEGER                              ::   nb_bdy_fld_sum    ! Total number of fields to update for all boundary sets.
43
44   LOGICAL,           DIMENSION(jp_bdy) ::   ln_full_vel_array ! =T => full velocities in 3D boundary conditions
45                                                               ! =F => baroclinic velocities in 3D boundary conditions
46
47   TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:), TARGET ::   bf        ! structure of input fields (file informations, fields read)
48
49   TYPE(MAP_POINTER), ALLOCATABLE, DIMENSION(:) :: nbmap_ptr   ! array of pointers to nbmap
50
51#  include "domzgr_substitute.h90"
52   !!----------------------------------------------------------------------
53   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
54   !! $Id$
55   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
56   !!----------------------------------------------------------------------
57CONTAINS
58
59      SUBROUTINE bdy_dta( kt, jit, time_offset )
60      !!----------------------------------------------------------------------
61      !!                   ***  SUBROUTINE bdy_dta  ***
62      !!                   
63      !! ** Purpose :   Update external data for open boundary conditions
64      !!
65      !! ** Method  :   Use fldread.F90
66      !!               
67      !!----------------------------------------------------------------------
68      !!
69      INTEGER, INTENT( in )           ::   kt    ! ocean time-step index
70      INTEGER, INTENT( in ), OPTIONAL ::   jit   ! subcycle time-step index (for timesplitting option)
71      INTEGER, INTENT( in ), OPTIONAL ::   time_offset  ! time offset in units of timesteps. NB. if jit
72                                                        ! is present then units = subcycle timesteps.
73                                                        ! time_offset = 0 => get data at "now" time level
74                                                        ! time_offset = -1 => get data at "before" time level
75                                                        ! time_offset = +1 => get data at "after" time level
76                                                        ! etc.
77      !!
78      INTEGER     ::  ib_bdy, jfld, jstart, jend, ib, ii, ij, ik, igrd  ! local indices
79      INTEGER,          DIMENSION(jpbgrd) ::   ilen1 
80      INTEGER, POINTER, DIMENSION(:)      ::   nblen, nblenrim  ! short cuts
81      !!
82      !!---------------------------------------------------------------------------
83      !!
84      IF( nn_timing == 1 ) CALL timing_start('bdy_dta')
85
86      ! Initialise data arrays once for all from initial conditions where required
87      !---------------------------------------------------------------------------
88      IF( kt .eq. nit000 .and. .not. PRESENT(jit) ) THEN
89
90         ! Calculate depth-mean currents
91         !-----------------------------
92         CALL wrk_alloc(jpi,jpj,pu2d,pv2d) 
93
94         pu2d(:,:) = 0.e0
95         pv2d(:,:) = 0.e0
96
97         DO ik = 1, jpkm1   !! Vertically integrated momentum trends
98             pu2d(:,:) = pu2d(:,:) + fse3u(:,:,ik) * umask(:,:,ik) * un(:,:,ik)
99             pv2d(:,:) = pv2d(:,:) + fse3v(:,:,ik) * vmask(:,:,ik) * vn(:,:,ik)
100         END DO
101         pu2d(:,:) = pu2d(:,:) * hur(:,:)
102         pv2d(:,:) = pv2d(:,:) * hvr(:,:)
103         
104         DO ib_bdy = 1, nb_bdy
105
106            nblen => idx_bdy(ib_bdy)%nblen
107            nblenrim => idx_bdy(ib_bdy)%nblenrim
108
109            IF( nn_dyn2d(ib_bdy) .gt. 0 .and. nn_dyn2d_dta(ib_bdy) .eq. 0 ) THEN
110               IF( nn_dyn2d(ib_bdy) .eq. jp_frs ) THEN
111                  ilen1(:) = nblen(:)
112               ELSE
113                  ilen1(:) = nblenrim(:)
114               ENDIF
115               igrd = 1
116               DO ib = 1, ilen1(igrd)
117                  ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
118                  ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
119                  dta_bdy(ib_bdy)%ssh(ib) = sshn(ii,ij) * tmask(ii,ij,1)         
120               END DO
121               igrd = 2
122               DO ib = 1, ilen1(igrd)
123                  ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
124                  ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
125                  dta_bdy(ib_bdy)%u2d(ib) = pu2d(ii,ij) * umask(ii,ij,1)         
126               END DO
127               igrd = 3
128               DO ib = 1, ilen1(igrd)
129                  ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
130                  ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
131                  dta_bdy(ib_bdy)%v2d(ib) = pv2d(ii,ij) * vmask(ii,ij,1)         
132               END DO
133            ENDIF
134
135            IF( nn_dyn3d(ib_bdy) .gt. 0 .and. nn_dyn3d_dta(ib_bdy) .eq. 0 ) THEN
136               IF( nn_dyn3d(ib_bdy) .eq. jp_frs ) THEN
137                  ilen1(:) = nblen(:)
138               ELSE
139                  ilen1(:) = nblenrim(:)
140               ENDIF
141               igrd = 2 
142               DO ib = 1, ilen1(igrd)
143                  DO ik = 1, jpkm1
144                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
145                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
146                     dta_bdy(ib_bdy)%u3d(ib,ik) =  ( un(ii,ij,ik) - pu2d(ii,ij) ) * umask(ii,ij,ik)         
147                  END DO
148               END DO
149               igrd = 3 
150               DO ib = 1, ilen1(igrd)
151                  DO ik = 1, jpkm1
152                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
153                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
154                     dta_bdy(ib_bdy)%v3d(ib,ik) =  ( vn(ii,ij,ik) - pv2d(ii,ij) ) * vmask(ii,ij,ik)         
155                     END DO
156               END DO
157            ENDIF
158
159            IF( nn_tra(ib_bdy) .gt. 0 .and. nn_tra_dta(ib_bdy) .eq. 0 ) THEN
160               IF( nn_tra(ib_bdy) .eq. jp_frs ) THEN
161                  ilen1(:) = nblen(:)
162               ELSE
163                  ilen1(:) = nblenrim(:)
164               ENDIF
165               igrd = 1                       ! Everything is at T-points here
166               DO ib = 1, ilen1(igrd)
167                  DO ik = 1, jpkm1
168                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
169                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
170                     dta_bdy(ib_bdy)%tem(ib,ik) = tsn(ii,ij,ik,jp_tem) * tmask(ii,ij,ik)         
171                     dta_bdy(ib_bdy)%sal(ib,ik) = tsn(ii,ij,ik,jp_sal) * tmask(ii,ij,ik)         
172                  END DO
173               END DO
174            ENDIF
175
176#if defined key_lim2
177            IF( nn_ice_lim2(ib_bdy) .gt. 0 .and. nn_ice_lim2_dta(ib_bdy) .eq. 0 ) THEN
178               IF( nn_ice_lim2(ib_bdy) .eq. jp_frs ) THEN
179                  ilen1(:) = nblen(:)
180               ELSE
181                  ilen1(:) = nblenrim(:)
182               ENDIF
183               igrd = 1                       ! Everything is at T-points here
184               DO ib = 1, ilen1(igrd)
185                  ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
186                  ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
187                  dta_bdy(ib_bdy)%frld(ib) = frld(ii,ij) * tmask(ii,ij,1)         
188                  dta_bdy(ib_bdy)%hicif(ib) = hicif(ii,ij) * tmask(ii,ij,1)         
189                  dta_bdy(ib_bdy)%hsnif(ib) = hsnif(ii,ij) * tmask(ii,ij,1)         
190               END DO
191            ENDIF
192#endif
193
194         ENDDO ! ib_bdy
195
196         CALL wrk_dealloc(jpi,jpj,pu2d,pv2d) 
197
198      ENDIF ! kt .eq. nit000
199
200      ! update external data from files
201      !--------------------------------
202     
203      jstart = 1
204      DO ib_bdy = 1, nb_bdy   
205         IF( nn_dta(ib_bdy) .eq. 1 ) THEN ! skip this bit if no external data required
206     
207            IF( PRESENT(jit) ) THEN
208               ! Update barotropic boundary conditions only
209               ! jit is optional argument for fld_read and tide_update
210               IF( nn_dyn2d(ib_bdy) .gt. 0 ) THEN
211                  IF( nn_dyn2d_dta(ib_bdy) .eq. 2 ) THEN ! tidal harmonic forcing ONLY: initialise arrays
212                     dta_bdy(ib_bdy)%ssh(:) = 0.0
213                     dta_bdy(ib_bdy)%u2d(:) = 0.0
214                     dta_bdy(ib_bdy)%v2d(:) = 0.0
215                  ENDIF
216                  IF( nn_dyn2d_dta(ib_bdy) .eq. 1 .or. nn_dyn2d_dta(ib_bdy) .eq. 3 ) THEN ! update external data
217                     jend = jstart + 2
218                     CALL fld_read( kt=kt, kn_fsbc=1, sd=bf(jstart:jend), map=nbmap_ptr(jstart:jend),   &
219                     &              jit=jit, time_offset=time_offset )
220                  ENDIF
221                  IF( nn_dyn2d_dta(ib_bdy) .ge. 2 ) THEN ! update tidal harmonic forcing
222                     CALL tide_update( kt=kt, idx=idx_bdy(ib_bdy), dta=dta_bdy(ib_bdy), td=tides(ib_bdy),   & 
223                     &                 jit=jit, time_offset=time_offset )
224                  ENDIF
225               ENDIF
226            ELSE
227               IF( nn_dyn2d(ib_bdy) .gt. 0 .and. nn_dyn2d_dta(ib_bdy) .eq. 2 ) THEN ! tidal harmonic forcing ONLY: initialise arrays
228                  dta_bdy(ib_bdy)%ssh(:) = 0.0
229                  dta_bdy(ib_bdy)%u2d(:) = 0.0
230                  dta_bdy(ib_bdy)%v2d(:) = 0.0
231               ENDIF
232               IF( nb_bdy_fld(ib_bdy) .gt. 0 ) THEN ! update external data
233                  jend = jstart + nb_bdy_fld(ib_bdy) - 1
234                  CALL fld_read( kt=kt, kn_fsbc=1, sd=bf(jstart:jend), map=nbmap_ptr(jstart:jend), time_offset=time_offset )
235               ENDIF
236               IF( nn_dyn2d(ib_bdy) .gt. 0 .and. nn_dyn2d_dta(ib_bdy) .ge. 2 ) THEN ! update tidal harmonic forcing
237                  CALL tide_update( kt=kt, idx=idx_bdy(ib_bdy), dta=dta_bdy(ib_bdy), td=tides(ib_bdy), time_offset=time_offset )
238               ENDIF
239            ENDIF
240            jstart = jend+1
241
242            ! If full velocities in boundary data then split into barotropic and baroclinic data
243            ! (Note that we have already made sure that you can't use ln_full_vel = .true. at the same
244            ! time as the dynspg_ts option).
245
246            IF( ln_full_vel_array(ib_bdy) .and.                                             & 
247           &    ( nn_dyn2d_dta(ib_bdy) .eq. 1 .or. nn_dyn2d_dta(ib_bdy) .eq. 3 .or. nn_dyn3d_dta(ib_bdy) .eq. 1 ) ) THEN
248
249               igrd = 2                      ! zonal velocity
250               dta_bdy(ib_bdy)%u2d(:) = 0.0
251               DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
252                  ii   = idx_bdy(ib_bdy)%nbi(ib,igrd)
253                  ij   = idx_bdy(ib_bdy)%nbj(ib,igrd)
254                  DO ik = 1, jpkm1
255                     dta_bdy(ib_bdy)%u2d(ib) = dta_bdy(ib_bdy)%u2d(ib) &
256              &                                + fse3u(ii,ij,ik) * umask(ii,ij,ik) * dta_bdy(ib_bdy)%u3d(ib,ik)
257                  END DO
258                  dta_bdy(ib_bdy)%u2d(ib) =  dta_bdy(ib_bdy)%u2d(ib) * hur(ii,ij)
259                  DO ik = 1, jpkm1
260                     dta_bdy(ib_bdy)%u3d(ib,ik) = dta_bdy(ib_bdy)%u3d(ib,ik) - dta_bdy(ib_bdy)%u2d(ib) 
261                  END DO
262               END DO
263
264               igrd = 3                      ! meridional velocity
265               dta_bdy(ib_bdy)%v2d(:) = 0.0
266               DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
267                  ii   = idx_bdy(ib_bdy)%nbi(ib,igrd)
268                  ij   = idx_bdy(ib_bdy)%nbj(ib,igrd)
269                  DO ik = 1, jpkm1
270                     dta_bdy(ib_bdy)%v2d(ib) = dta_bdy(ib_bdy)%v2d(ib) &
271              &                                + fse3v(ii,ij,ik) * vmask(ii,ij,ik) * dta_bdy(ib_bdy)%v3d(ib,ik)
272                  END DO
273                  dta_bdy(ib_bdy)%v2d(ib) =  dta_bdy(ib_bdy)%v2d(ib) * hvr(ii,ij)
274                  DO ik = 1, jpkm1
275                     dta_bdy(ib_bdy)%v3d(ib,ik) = dta_bdy(ib_bdy)%v3d(ib,ik) - dta_bdy(ib_bdy)%v2d(ib) 
276                  END DO
277               END DO
278   
279            ENDIF
280
281         END IF ! nn_dta(ib_bdy) = 1
282      END DO  ! ib_bdy
283
284      IF( nn_timing == 1 ) CALL timing_stop('bdy_dta')
285
286      END SUBROUTINE bdy_dta
287
288
289      SUBROUTINE bdy_dta_init
290      !!----------------------------------------------------------------------
291      !!                   ***  SUBROUTINE bdy_dta_init  ***
292      !!                   
293      !! ** Purpose :   Initialise arrays for reading of external data
294      !!                for open boundary conditions
295      !!
296      !! ** Method  :   Use fldread.F90
297      !!               
298      !!----------------------------------------------------------------------
299      USE dynspg_oce, ONLY: lk_dynspg_ts
300      !!
301      INTEGER     ::  ib_bdy, jfld, jstart, jend, ierror  ! local indices
302      !!
303      CHARACTER(len=100)                     ::   cn_dir        ! Root directory for location of data files
304      CHARACTER(len=100), DIMENSION(nb_bdy)  ::   cn_dir_array  ! Root directory for location of data files
305      LOGICAL                                ::   ln_full_vel   ! =T => full velocities in 3D boundary data
306                                                                ! =F => baroclinic velocities in 3D boundary data
307      INTEGER                                ::   ilen_global   ! Max length required for global bdy dta arrays
308      INTEGER,              DIMENSION(jpbgrd) ::  ilen0         ! size of local arrays
309      INTEGER, ALLOCATABLE, DIMENSION(:)     ::   ilen1, ilen3  ! size of 1st and 3rd dimensions of local arrays
310      INTEGER, ALLOCATABLE, DIMENSION(:)     ::   ibdy           ! bdy set for a particular jfld
311      INTEGER, ALLOCATABLE, DIMENSION(:)     ::   igrid         ! index for grid type (1,2,3 = T,U,V)
312      INTEGER, POINTER, DIMENSION(:)         ::   nblen, nblenrim  ! short cuts
313      TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) ::   blf_i         !  array of namelist information structures
314      TYPE(FLD_N) ::   bn_tem, bn_sal, bn_u3d, bn_v3d   !
315      TYPE(FLD_N) ::   bn_ssh, bn_u2d, bn_v2d           ! informations about the fields to be read
316#if defined key_lim2
317      TYPE(FLD_N) ::   bn_frld, bn_hicif, bn_hsnif      !
318#endif
319      NAMELIST/nambdy_dta/ cn_dir, bn_tem, bn_sal, bn_u3d, bn_v3d, bn_ssh, bn_u2d, bn_v2d 
320#if defined key_lim2
321      NAMELIST/nambdy_dta/ bn_frld, bn_hicif, bn_hsnif
322#endif
323      NAMELIST/nambdy_dta/ ln_full_vel
324      !!---------------------------------------------------------------------------
325
326      IF( nn_timing == 1 ) CALL timing_start('bdy_dta_init')
327
328      ! Set nn_dta
329      DO ib_bdy = 1, nb_bdy
330         nn_dta(ib_bdy) = MAX(  nn_dyn2d_dta(ib_bdy)       &
331                               ,nn_dyn3d_dta(ib_bdy)       &
332                               ,nn_tra_dta(ib_bdy)         &
333#if defined key_lim2
334                               ,nn_ice_lim2_dta(ib_bdy)    &
335#endif
336                              )
337         IF(nn_dta(ib_bdy) .gt. 1) nn_dta(ib_bdy) = 1
338      END DO
339
340      ! Work out upper bound of how many fields there are to read in and allocate arrays
341      ! ---------------------------------------------------------------------------
342      ALLOCATE( nb_bdy_fld(nb_bdy) )
343      nb_bdy_fld(:) = 0
344      DO ib_bdy = 1, nb_bdy         
345         IF( nn_dyn2d(ib_bdy) .gt. 0 .and. ( nn_dyn2d_dta(ib_bdy) .eq. 1 .or. nn_dyn2d_dta(ib_bdy) .eq. 3 ) ) THEN
346            nb_bdy_fld(ib_bdy) = nb_bdy_fld(ib_bdy) + 3
347         ENDIF
348         IF( nn_dyn3d(ib_bdy) .gt. 0 .and. nn_dyn3d_dta(ib_bdy) .eq. 1 ) THEN
349            nb_bdy_fld(ib_bdy) = nb_bdy_fld(ib_bdy) + 2
350         ENDIF
351         IF( nn_tra(ib_bdy) .gt. 0 .and. nn_tra_dta(ib_bdy) .eq. 1  ) THEN
352            nb_bdy_fld(ib_bdy) = nb_bdy_fld(ib_bdy) + 2
353         ENDIF
354#if defined key_lim2
355         IF( nn_ice_lim2(ib_bdy) .gt. 0 .and. nn_ice_lim2_dta(ib_bdy) .eq. 1  ) THEN
356            nb_bdy_fld(ib_bdy) = nb_bdy_fld(ib_bdy) + 3
357         ENDIF
358#endif               
359      ENDDO           
360
361      nb_bdy_fld_sum = SUM( nb_bdy_fld )
362
363      ALLOCATE( bf(nb_bdy_fld_sum), STAT=ierror )
364      IF( ierror > 0 ) THEN   
365         CALL ctl_stop( 'bdy_dta: unable to allocate bf structure' )   ;   RETURN 
366      ENDIF
367      ALLOCATE( blf_i(nb_bdy_fld_sum), STAT=ierror )
368      IF( ierror > 0 ) THEN   
369         CALL ctl_stop( 'bdy_dta: unable to allocate blf_i structure' )   ;   RETURN 
370      ENDIF
371      ALLOCATE( nbmap_ptr(nb_bdy_fld_sum), STAT=ierror )
372      IF( ierror > 0 ) THEN   
373         CALL ctl_stop( 'bdy_dta: unable to allocate nbmap_ptr structure' )   ;   RETURN 
374      ENDIF
375      ALLOCATE( ilen1(nb_bdy_fld_sum), ilen3(nb_bdy_fld_sum) ) 
376      ALLOCATE( ibdy(nb_bdy_fld_sum) ) 
377      ALLOCATE( igrid(nb_bdy_fld_sum) ) 
378
379      ! Read namelists
380      ! --------------
381      REWIND(numnam)
382      jfld = 0 
383      DO ib_bdy = 1, nb_bdy         
384         IF( nn_dta(ib_bdy) .eq. 1 ) THEN
385            ! set file information
386            cn_dir = './'        ! directory in which the model is executed
387            ln_full_vel = .false.
388            ! ... default values (NB: frequency positive => hours, negative => months)
389            !                    !  file       ! frequency !  variable   ! time intep !  clim   ! 'yearly' or ! weights  ! rotation  !
390            !                    !  name       ! hours !   name     !  (T/F)  !  (T/F)  !  'monthly'  ! filename ! pairs     !
391            bn_ssh     = FLD_N(  'bdy_ssh'     ,  24   , 'sossheig' , .false. , .false. ,   'yearly'  , ''       , ''        )
392            bn_u2d     = FLD_N(  'bdy_vel2d_u' ,  24   , 'vobtcrtx' , .false. , .false. ,   'yearly'  , ''       , ''        )
393            bn_v2d     = FLD_N(  'bdy_vel2d_v' ,  24   , 'vobtcrty' , .false. , .false. ,   'yearly'  , ''       , ''        )
394            bn_u3d     = FLD_N(  'bdy_vel3d_u' ,  24   , 'vozocrtx' , .false. , .false. ,   'yearly'  , ''       , ''        )
395            bn_v3d     = FLD_N(  'bdy_vel3d_v' ,  24   , 'vomecrty' , .false. , .false. ,   'yearly'  , ''       , ''        )
396            bn_tem     = FLD_N(  'bdy_tem'     ,  24   , 'votemper' , .false. , .false. ,   'yearly'  , ''       , ''        )
397            bn_sal     = FLD_N(  'bdy_sal'     ,  24   , 'vosaline' , .false. , .false. ,   'yearly'  , ''       , ''        )
398#if defined key_lim2
399            bn_frld    = FLD_N(  'bdy_frld'    ,  24   , 'ildsconc' , .false. , .false. ,   'yearly'  , ''       , ''        )
400            bn_hicif   = FLD_N(  'bdy_hicif'   ,  24   , 'iicethic' , .false. , .false. ,   'yearly'  , ''       , ''        )
401            bn_hsnif   = FLD_N(  'bdy_hsnif'   ,  24   , 'isnothic' , .false. , .false. ,   'yearly'  , ''       , ''        )
402#endif
403
404            ! Important NOT to rewind here.
405            READ( numnam, nambdy_dta )
406
407            cn_dir_array(ib_bdy) = cn_dir
408            ln_full_vel_array(ib_bdy) = ln_full_vel
409
410            IF( ln_full_vel_array(ib_bdy) .and. lk_dynspg_ts )  THEN
411               CALL ctl_stop( 'bdy_dta_init: ERROR, cannot specify full velocities in boundary data',&
412            &                  'with dynspg_ts option' )   ;   RETURN 
413            ENDIF             
414
415            nblen => idx_bdy(ib_bdy)%nblen
416            nblenrim => idx_bdy(ib_bdy)%nblenrim
417
418            ! Only read in necessary fields for this set.
419            ! Important that barotropic variables come first.
420            IF( nn_dyn2d(ib_bdy) .gt. 0 .and. ( nn_dyn2d_dta(ib_bdy) .eq. 1 .or. nn_dyn2d_dta(ib_bdy) .eq. 3 ) ) THEN
421
422               IF( nn_dyn2d(ib_bdy) .ne. jp_frs ) THEN
423                  jfld = jfld + 1
424                  blf_i(jfld) = bn_ssh
425                  ibdy(jfld) = ib_bdy
426                  igrid(jfld) = 1
427                  ilen1(jfld) = nblenrim(igrid(jfld))
428                  ilen3(jfld) = 1
429               ENDIF
430
431               IF( .not. ln_full_vel_array(ib_bdy) ) THEN
432
433                  jfld = jfld + 1
434                  blf_i(jfld) = bn_u2d
435                  ibdy(jfld) = ib_bdy
436                  igrid(jfld) = 2
437                  IF( nn_dyn2d(ib_bdy) .eq. jp_frs ) THEN
438                     ilen1(jfld) = nblen(igrid(jfld))
439                  ELSE
440                     ilen1(jfld) = nblenrim(igrid(jfld))
441                  ENDIF
442                  ilen3(jfld) = 1
443
444                  jfld = jfld + 1
445                  blf_i(jfld) = bn_v2d
446                  ibdy(jfld) = ib_bdy
447                  igrid(jfld) = 3
448                  IF( nn_dyn2d(ib_bdy) .eq. jp_frs ) THEN
449                     ilen1(jfld) = nblen(igrid(jfld))
450                  ELSE
451                     ilen1(jfld) = nblenrim(igrid(jfld))
452                  ENDIF
453                  ilen3(jfld) = 1
454
455               ENDIF
456
457            ENDIF
458
459            ! baroclinic velocities
460            IF( ( nn_dyn3d(ib_bdy) .gt. 0 .and. nn_dyn3d_dta(ib_bdy) .eq. 1 ) .or. &
461           &      ( ln_full_vel_array(ib_bdy) .and. nn_dyn2d(ib_bdy) .gt. 0 .and.  &
462           &        ( nn_dyn2d_dta(ib_bdy) .eq. 1 .or. nn_dyn2d_dta(ib_bdy) .eq. 3 ) ) ) THEN
463
464               jfld = jfld + 1
465               blf_i(jfld) = bn_u3d
466               ibdy(jfld) = ib_bdy
467               igrid(jfld) = 2
468               IF( nn_dyn3d(ib_bdy) .eq. jp_frs ) THEN
469                  ilen1(jfld) = nblen(igrid(jfld))
470               ELSE
471                  ilen1(jfld) = nblenrim(igrid(jfld))
472               ENDIF
473               ilen3(jfld) = jpk
474
475               jfld = jfld + 1
476               blf_i(jfld) = bn_v3d
477               ibdy(jfld) = ib_bdy
478               igrid(jfld) = 3
479               IF( nn_dyn3d(ib_bdy) .eq. jp_frs ) THEN
480                  ilen1(jfld) = nblen(igrid(jfld))
481               ELSE
482                  ilen1(jfld) = nblenrim(igrid(jfld))
483               ENDIF
484               ilen3(jfld) = jpk
485
486            ENDIF
487
488            ! temperature and salinity
489            IF( nn_tra(ib_bdy) .gt. 0 .and. nn_tra_dta(ib_bdy) .eq. 1 ) THEN
490
491               jfld = jfld + 1
492               blf_i(jfld) = bn_tem
493               ibdy(jfld) = ib_bdy
494               igrid(jfld) = 1
495               IF( nn_tra(ib_bdy) .eq. jp_frs ) THEN
496                  ilen1(jfld) = nblen(igrid(jfld))
497               ELSE
498                  ilen1(jfld) = nblenrim(igrid(jfld))
499               ENDIF
500               ilen3(jfld) = jpk
501
502               jfld = jfld + 1
503               blf_i(jfld) = bn_sal
504               ibdy(jfld) = ib_bdy
505               igrid(jfld) = 1
506               IF( nn_tra(ib_bdy) .eq. jp_frs ) THEN
507                  ilen1(jfld) = nblen(igrid(jfld))
508               ELSE
509                  ilen1(jfld) = nblenrim(igrid(jfld))
510               ENDIF
511               ilen3(jfld) = jpk
512
513            ENDIF
514
515#if defined key_lim2
516            ! sea ice
517            IF( nn_ice_lim2(ib_bdy) .gt. 0 .and. nn_ice_lim2_dta(ib_bdy) .eq. 1 ) THEN
518
519               jfld = jfld + 1
520               blf_i(jfld) = bn_frld
521               ibdy(jfld) = ib_bdy
522               igrid(jfld) = 1
523               IF( nn_ice_lim2(ib_bdy) .eq. jp_frs ) THEN
524                  ilen1(jfld) = nblen(igrid(jfld))
525               ELSE
526                  ilen1(jfld) = nblenrim(igrid(jfld))
527               ENDIF
528               ilen3(jfld) = 1
529
530               jfld = jfld + 1
531               blf_i(jfld) = bn_hicif
532               ibdy(jfld) = ib_bdy
533               igrid(jfld) = 1
534               IF( nn_ice_lim2(ib_bdy) .eq. jp_frs ) THEN
535                  ilen1(jfld) = nblen(igrid(jfld))
536               ELSE
537                  ilen1(jfld) = nblenrim(igrid(jfld))
538               ENDIF
539               ilen3(jfld) = 1
540
541               jfld = jfld + 1
542               blf_i(jfld) = bn_hsnif
543               ibdy(jfld) = ib_bdy
544               igrid(jfld) = 1
545               IF( nn_ice_lim2(ib_bdy) .eq. jp_frs ) THEN
546                  ilen1(jfld) = nblen(igrid(jfld))
547               ELSE
548                  ilen1(jfld) = nblenrim(igrid(jfld))
549               ENDIF
550               ilen3(jfld) = 1
551
552            ENDIF
553#endif
554            ! Recalculate field counts
555            !-------------------------
556            nb_bdy_fld_sum = 0
557            IF( ib_bdy .eq. 1 ) THEN
558               nb_bdy_fld(ib_bdy) = jfld
559               nb_bdy_fld_sum     = jfld             
560            ELSE
561               nb_bdy_fld(ib_bdy) = jfld - nb_bdy_fld_sum
562               nb_bdy_fld_sum = nb_bdy_fld_sum + nb_bdy_fld(ib_bdy)
563            ENDIF
564
565         ENDIF ! nn_dta .eq. 1
566      ENDDO ! ib_bdy
567
568
569      DO jfld = 1, nb_bdy_fld_sum
570         ALLOCATE( bf(jfld)%fnow(ilen1(jfld),1,ilen3(jfld)) )
571         IF( blf_i(jfld)%ln_tint ) ALLOCATE( bf(jfld)%fdta(ilen1(jfld),1,ilen3(jfld),2) )
572         nbmap_ptr(jfld)%ptr => idx_bdy(ibdy(jfld))%nbmap(:,igrid(jfld))
573      ENDDO
574
575      ! fill bf with blf_i and control print
576      !-------------------------------------
577      jstart = 1
578      DO ib_bdy = 1, nb_bdy
579         jend = jstart + nb_bdy_fld(ib_bdy) - 1
580         CALL fld_fill( bf(jstart:jend), blf_i(jstart:jend), cn_dir_array(ib_bdy), 'bdy_dta',   &
581         &              'open boundary conditions', 'nambdy_dta' )
582         jstart = jend + 1
583      ENDDO
584
585      ! Initialise local boundary data arrays
586      ! nn_xxx_dta=0 : allocate space - will be filled from initial conditions later
587      ! nn_xxx_dta=1 : point to "fnow" arrays
588      !-------------------------------------
589
590      jfld = 0
591      DO ib_bdy=1, nb_bdy
592
593         nblen => idx_bdy(ib_bdy)%nblen
594         nblenrim => idx_bdy(ib_bdy)%nblenrim
595
596         IF (nn_dyn2d(ib_bdy) .gt. 0) THEN
597            IF( nn_dyn2d_dta(ib_bdy) .eq. 0 .or. nn_dyn2d_dta(ib_bdy) .eq. 2 .or. ln_full_vel_array(ib_bdy) ) THEN
598               IF( nn_dyn2d(ib_bdy) .eq. jp_frs ) THEN
599                  ilen0(1:3) = nblen(1:3)
600               ELSE
601                  ilen0(1:3) = nblenrim(1:3)
602               ENDIF
603               ALLOCATE( dta_bdy(ib_bdy)%ssh(ilen0(1)) )
604               ALLOCATE( dta_bdy(ib_bdy)%u2d(ilen0(2)) )
605               ALLOCATE( dta_bdy(ib_bdy)%v2d(ilen0(3)) )
606            ELSE
607               IF( nn_dyn2d(ib_bdy) .ne. jp_frs ) THEN
608                  jfld = jfld + 1
609                  dta_bdy(ib_bdy)%ssh => bf(jfld)%fnow(:,1,1)
610               ENDIF
611               jfld = jfld + 1
612               dta_bdy(ib_bdy)%u2d => bf(jfld)%fnow(:,1,1)
613               jfld = jfld + 1
614               dta_bdy(ib_bdy)%v2d => bf(jfld)%fnow(:,1,1)
615            ENDIF
616         ENDIF
617
618         IF ( nn_dyn3d(ib_bdy) .gt. 0 .and. nn_dyn3d_dta(ib_bdy) .eq. 0 ) THEN
619            IF( nn_dyn3d(ib_bdy) .eq. jp_frs ) THEN
620               ilen0(1:3) = nblen(1:3)
621            ELSE
622               ilen0(1:3) = nblenrim(1:3)
623            ENDIF
624            ALLOCATE( dta_bdy(ib_bdy)%u3d(ilen0(2),jpk) )
625            ALLOCATE( dta_bdy(ib_bdy)%v3d(ilen0(3),jpk) )
626         ENDIF
627         IF ( ( nn_dyn3d(ib_bdy) .gt. 0 .and. nn_dyn3d_dta(ib_bdy) .eq. 1 ).or. &
628           &  ( ln_full_vel_array(ib_bdy) .and. nn_dyn2d(ib_bdy) .gt. 0 .and.   &
629           &    ( nn_dyn2d_dta(ib_bdy) .eq. 1 .or. nn_dyn2d_dta(ib_bdy) .eq. 3 ) ) ) THEN
630            jfld = jfld + 1
631            dta_bdy(ib_bdy)%u3d => bf(jfld)%fnow(:,1,:)
632            jfld = jfld + 1
633            dta_bdy(ib_bdy)%v3d => bf(jfld)%fnow(:,1,:)
634         ENDIF
635
636         IF (nn_tra(ib_bdy) .gt. 0) THEN
637            IF( nn_tra_dta(ib_bdy) .eq. 0 ) THEN
638               IF( nn_tra(ib_bdy) .eq. jp_frs ) THEN
639                  ilen0(1:3) = nblen(1:3)
640               ELSE
641                  ilen0(1:3) = nblenrim(1:3)
642               ENDIF
643               ALLOCATE( dta_bdy(ib_bdy)%tem(ilen0(1),jpk) )
644               ALLOCATE( dta_bdy(ib_bdy)%sal(ilen0(1),jpk) )
645            ELSE
646               jfld = jfld + 1
647               dta_bdy(ib_bdy)%tem => bf(jfld)%fnow(:,1,:)
648               jfld = jfld + 1
649               dta_bdy(ib_bdy)%sal => bf(jfld)%fnow(:,1,:)
650            ENDIF
651         ENDIF
652
653#if defined key_lim2
654         IF (nn_ice_lim2(ib_bdy) .gt. 0) THEN
655            IF( nn_ice_lim2_dta(ib_bdy) .eq. 0 ) THEN
656               IF( nn_ice_lim2(ib_bdy) .eq. jp_frs ) THEN
657                  ilen0(1:3) = nblen(1:3)
658               ELSE
659                  ilen0(1:3) = nblenrim(1:3)
660               ENDIF
661               ALLOCATE( dta_bdy(ib_bdy)%frld(ilen0(1)) )
662               ALLOCATE( dta_bdy(ib_bdy)%hicif(ilen0(1)) )
663               ALLOCATE( dta_bdy(ib_bdy)%hsnif(ilen0(1)) )
664            ELSE
665               jfld = jfld + 1
666               dta_bdy(ib_bdy)%frld  => bf(jfld)%fnow(:,1,1)
667               jfld = jfld + 1
668               dta_bdy(ib_bdy)%hicif => bf(jfld)%fnow(:,1,1)
669               jfld = jfld + 1
670               dta_bdy(ib_bdy)%hsnif => bf(jfld)%fnow(:,1,1)
671            ENDIF
672         ENDIF
673#endif
674
675      ENDDO ! ib_bdy
676
677      IF( nn_timing == 1 ) CALL timing_stop('bdy_dta_init')
678
679      END SUBROUTINE bdy_dta_init
680
681#else
682   !!----------------------------------------------------------------------
683   !!   Dummy module                   NO Open Boundary Conditions
684   !!----------------------------------------------------------------------
685CONTAINS
686   SUBROUTINE bdy_dta( kt, jit, time_offset ) ! Empty routine
687      INTEGER, INTENT( in )           ::   kt   
688      INTEGER, INTENT( in ), OPTIONAL ::   jit   
689      INTEGER, INTENT( in ), OPTIONAL ::   time_offset
690      WRITE(*,*) 'bdy_dta: You should not have seen this print! error?', kt
691   END SUBROUTINE bdy_dta
692   SUBROUTINE bdy_dta_init()                  ! Empty routine
693      WRITE(*,*) 'bdy_dta_init: You should not have seen this print! error?'
694   END SUBROUTINE bdy_dta_init
695#endif
696
697   !!==============================================================================
698END MODULE bdydta
Note: See TracBrowser for help on using the repository browser.