New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
bdydta.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/BDY – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/BDY/bdydta.F90 @ 7857

Last change on this file since 7857 was 7857, checked in by clem, 7 years ago

debug LIM3+BDY for the capability of having LIM3 as lateral input

  • Property svn:keywords set to Id
File size: 40.3 KB
Line 
1MODULE bdydta
2   !!======================================================================
3   !!                       ***  MODULE bdydta  ***
4   !! Open boundary data : read the data for the unstructured open boundaries.
5   !!======================================================================
6   !! History :  1.0  !  2005-01  (J. Chanut, A. Sellar)  Original code
7   !!             -   !  2007-01  (D. Storkey) Update to use IOM module
8   !!             -   !  2007-07  (D. Storkey) add bdy_dta_fla
9   !!            3.0  !  2008-04  (NEMO team)  add in the reference version
10   !!            3.3  !  2010-09  (E.O'Dea) modifications for Shelf configurations
11   !!            3.3  !  2010-09  (D.Storkey) add ice boundary conditions
12   !!            3.4  !  2011     (D. Storkey) rewrite in preparation for OBC-BDY merge
13   !!            3.6  !  2012-01  (C. Rousset) add ice boundary conditions for lim3
14   !!----------------------------------------------------------------------
15   !!    bdy_dta        : read external data along open boundaries from file
16   !!    bdy_dta_init   : initialise arrays etc for reading of external data
17   !!----------------------------------------------------------------------
18   USE timing          ! Timing
19   USE oce             ! ocean dynamics and tracers
20   USE dom_oce         ! ocean space and time domain
21   USE phycst          ! physical constants
22   USE bdy_oce         ! ocean open boundary conditions 
23   USE bdytides        ! tidal forcing at boundaries
24   USE fldread         ! read input fields
25   USE iom             ! IOM library
26   USE in_out_manager  ! I/O logical units
27#if defined key_lim2
28   USE ice_2
29#elif defined key_lim3
30   USE ice
31   USE limvar          ! redistribute ice input into categories
32#endif
33   USE sbcapr
34   USE sbctide         ! Tidal forcing or not
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   bdy_dta          ! routine called by step.F90 and dynspg_ts.F90
40   PUBLIC   bdy_dta_init     ! routine called by nemogcm.F90
41
42   INTEGER, ALLOCATABLE, DIMENSION(:)   ::   nb_bdy_fld        ! Number of fields to update for each boundary set.
43   INTEGER                              ::   nb_bdy_fld_sum    ! Total number of fields to update for all boundary sets.
44   LOGICAL,           DIMENSION(jp_bdy) ::   ln_full_vel_array ! =T => full velocities in 3D boundary conditions
45                                                               ! =F => baroclinic velocities in 3D boundary conditions
46!$AGRIF_DO_NOT_TREAT
47   TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:), TARGET ::   bf        ! structure of input fields (file informations, fields read)
48!$AGRIF_END_DO_NOT_TREAT
49   TYPE(MAP_POINTER), ALLOCATABLE, DIMENSION(:) :: nbmap_ptr   ! array of pointers to nbmap
50
51#if defined key_lim3
52   LOGICAL :: ll_bdylim3                  ! determine whether ice input is lim2 (F) or lim3 (T) type
53   INTEGER :: jfld_hti, jfld_hts, jfld_ai ! indices of ice thickness, snow thickness and concentration in bf structure
54#endif
55
56   !!----------------------------------------------------------------------
57   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
58   !! $Id$
59   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
60   !!----------------------------------------------------------------------
61CONTAINS
62
63      SUBROUTINE bdy_dta( kt, jit, time_offset )
64      !!----------------------------------------------------------------------
65      !!                   ***  SUBROUTINE bdy_dta  ***
66      !!                   
67      !! ** Purpose :   Update external data for open boundary conditions
68      !!
69      !! ** Method  :   Use fldread.F90
70      !!               
71      !!----------------------------------------------------------------------
72      INTEGER, INTENT(in)           ::   kt           ! ocean time-step index
73      INTEGER, INTENT(in), OPTIONAL ::   jit          ! subcycle time-step index (for timesplitting option)
74      INTEGER, INTENT(in), OPTIONAL ::   time_offset  ! time offset in units of timesteps. NB. if jit
75      !                                               ! is present then units = subcycle timesteps.
76      !                                               ! time_offset = 0 => get data at "now" time level
77      !                                               ! time_offset = -1 => get data at "before" time level
78      !                                               ! time_offset = +1 => get data at "after" time level
79      !                                               ! etc.
80      !
81      INTEGER ::  ib_bdy, jfld, jstart, jend, ib, ii, ij, ik, igrd, jl  ! local indices
82      INTEGER,          DIMENSION(jpbgrd) ::   ilen1 
83      INTEGER, POINTER, DIMENSION(:)      ::   nblen, nblenrim  ! short cuts
84      TYPE(OBC_DATA), POINTER             ::   dta              ! short cut
85      !!---------------------------------------------------------------------------
86      !
87      IF( nn_timing == 1 )   CALL timing_start('bdy_dta')
88      !
89      ! Initialise data arrays once for all from initial conditions where required
90      !---------------------------------------------------------------------------
91      IF( kt == nit000 .AND. .NOT.PRESENT(jit) ) THEN
92
93         ! Calculate depth-mean currents
94         !-----------------------------
95         
96         DO ib_bdy = 1, nb_bdy
97            !
98            nblen => idx_bdy(ib_bdy)%nblen
99            nblenrim => idx_bdy(ib_bdy)%nblenrim
100            dta => dta_bdy(ib_bdy)
101
102            IF( nn_dyn2d_dta(ib_bdy) == 0 ) THEN
103               ilen1(:) = nblen(:)
104               IF( dta%ll_ssh ) THEN
105                  igrd = 1
106                  DO ib = 1, ilen1(igrd)
107                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
108                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
109                     dta_bdy(ib_bdy)%ssh(ib) = sshn(ii,ij) * tmask(ii,ij,1)         
110                  END DO
111               END IF
112               IF( dta%ll_u2d ) THEN
113                  igrd = 2
114                  DO ib = 1, ilen1(igrd)
115                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
116                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
117                     dta_bdy(ib_bdy)%u2d(ib) = un_b(ii,ij) * umask(ii,ij,1)         
118                  END DO
119               END IF
120               IF( dta%ll_v2d ) THEN
121                  igrd = 3
122                  DO ib = 1, ilen1(igrd)
123                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
124                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
125                     dta_bdy(ib_bdy)%v2d(ib) = vn_b(ii,ij) * vmask(ii,ij,1)         
126                  END DO
127               END IF
128            ENDIF
129
130            IF( nn_dyn3d_dta(ib_bdy) == 0 ) THEN
131               ilen1(:) = nblen(:)
132               IF( dta%ll_u3d ) THEN
133                  igrd = 2 
134                  DO ib = 1, ilen1(igrd)
135                     DO ik = 1, jpkm1
136                        ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
137                        ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
138                        dta_bdy(ib_bdy)%u3d(ib,ik) =  ( un(ii,ij,ik) - un_b(ii,ij) ) * umask(ii,ij,ik)         
139                     END DO
140                  END DO
141               END IF
142               IF( dta%ll_v3d ) THEN
143                  igrd = 3 
144                  DO ib = 1, ilen1(igrd)
145                     DO ik = 1, jpkm1
146                        ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
147                        ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
148                        dta_bdy(ib_bdy)%v3d(ib,ik) =  ( vn(ii,ij,ik) - vn_b(ii,ij) ) * vmask(ii,ij,ik)         
149                        END DO
150                  END DO
151               END IF
152            ENDIF
153
154            IF( nn_tra_dta(ib_bdy) == 0 ) THEN
155               ilen1(:) = nblen(:)
156               IF( dta%ll_tem ) THEN
157                  igrd = 1 
158                  DO ib = 1, ilen1(igrd)
159                     DO ik = 1, jpkm1
160                        ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
161                        ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
162                        dta_bdy(ib_bdy)%tem(ib,ik) = tsn(ii,ij,ik,jp_tem) * tmask(ii,ij,ik)         
163                     END DO
164                  END DO
165               END IF
166               IF( dta%ll_sal ) THEN
167                  igrd = 1 
168                  DO ib = 1, ilen1(igrd)
169                     DO ik = 1, jpkm1
170                        ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
171                        ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
172                        dta_bdy(ib_bdy)%sal(ib,ik) = tsn(ii,ij,ik,jp_sal) * tmask(ii,ij,ik)         
173                     END DO
174                  END DO
175               END IF
176            ENDIF
177
178#if defined key_lim2
179            IF( nn_ice_lim_dta(ib_bdy) == 0 ) THEN
180               ilen1(:) = nblen(:)
181               IF( dta%ll_frld ) THEN
182                  igrd = 1 
183                  DO ib = 1, ilen1(igrd)
184                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
185                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
186                     dta_bdy(ib_bdy)%frld(ib) = frld(ii,ij) * tmask(ii,ij,1)         
187                  END DO
188               END IF
189               IF( dta%ll_hicif ) THEN
190                  igrd = 1 
191                  DO ib = 1, ilen1(igrd)
192                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
193                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
194                     dta_bdy(ib_bdy)%hicif(ib) = hicif(ii,ij) * tmask(ii,ij,1)         
195                  END DO
196               END IF
197               IF( dta%ll_hsnif ) THEN
198                  igrd = 1 
199                  DO ib = 1, ilen1(igrd)
200                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
201                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
202                     dta_bdy(ib_bdy)%hsnif(ib) = hsnif(ii,ij) * tmask(ii,ij,1)         
203                  END DO
204               END IF
205            ENDIF
206#elif defined key_lim3
207            IF( nn_ice_lim_dta(ib_bdy) == 0 ) THEN
208               ilen1(:) = nblen(:)
209               IF( dta%ll_a_i ) THEN
210                  igrd = 1   
211                  DO jl = 1, jpl
212                     DO ib = 1, ilen1(igrd)
213                        ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
214                        ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
215                        dta_bdy(ib_bdy)%a_i (ib,jl) =  a_i(ii,ij,jl) * tmask(ii,ij,1) 
216                     END DO
217                  END DO
218               ENDIF
219               IF( dta%ll_ht_i ) THEN
220                  igrd = 1   
221                  DO jl = 1, jpl
222                     DO ib = 1, ilen1(igrd)
223                        ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
224                        ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
225                        dta_bdy(ib_bdy)%ht_i (ib,jl) =  ht_i(ii,ij,jl) * tmask(ii,ij,1) 
226                     END DO
227                  END DO
228               ENDIF
229               IF( dta%ll_ht_s ) THEN
230                  igrd = 1   
231                  DO jl = 1, jpl
232                     DO ib = 1, ilen1(igrd)
233                        ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
234                        ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
235                        dta_bdy(ib_bdy)%ht_s (ib,jl) =  ht_s(ii,ij,jl) * tmask(ii,ij,1) 
236                     END DO
237                  END DO
238               ENDIF
239            ENDIF
240#endif
241         END DO ! ib_bdy
242         !
243      ENDIF ! kt == nit000
244
245      ! update external data from files
246      !--------------------------------
247     
248      jstart = 1
249      DO ib_bdy = 1, nb_bdy   
250         dta => dta_bdy(ib_bdy)
251         IF( nn_dta(ib_bdy) == 1 ) THEN ! skip this bit if no external data required
252     
253            IF( PRESENT(jit) ) THEN
254               ! Update barotropic boundary conditions only
255               ! jit is optional argument for fld_read and bdytide_update
256               IF( cn_dyn2d(ib_bdy) /= 'none' ) THEN
257                  IF( nn_dyn2d_dta(ib_bdy) == 2 ) THEN ! tidal harmonic forcing ONLY: initialise arrays
258                     IF( dta%ll_ssh ) dta%ssh(:) = 0._wp
259                     IF( dta%ll_u2d ) dta%u2d(:) = 0._wp
260                     IF( dta%ll_u3d ) dta%v2d(:) = 0._wp
261                  ENDIF
262                  IF (cn_tra(ib_bdy) /= 'runoff') THEN
263                     IF( nn_dyn2d_dta(ib_bdy) == 1 .OR. nn_dyn2d_dta(ib_bdy) == 3 ) THEN
264
265                        jend = jstart + dta%nread(2) - 1
266                        IF( ln_full_vel_array(ib_bdy) ) THEN
267                           CALL fld_read( kt=kt, kn_fsbc=1, sd=bf(jstart:jend), map=nbmap_ptr(jstart:jend),  &
268                                     & kit=jit, kt_offset=time_offset , jpk_bdy=nb_jpk_bdy, fvl=ln_full_vel_array(ib_bdy)  )
269                        ELSE
270                           CALL fld_read( kt=kt, kn_fsbc=1, sd=bf(jstart:jend), map=nbmap_ptr(jstart:jend),  &
271                                     & kit=jit, kt_offset=time_offset  )
272                        ENDIF
273
274                        ! If full velocities in boundary data then extract barotropic velocities from 3D fields
275                        IF( ln_full_vel_array(ib_bdy) .AND.                                             &
276                          &    ( nn_dyn2d_dta(ib_bdy) == 1 .OR. nn_dyn2d_dta(ib_bdy) == 3 .OR.  &
277                          &      nn_dyn3d_dta(ib_bdy) == 1 ) )THEN
278
279                           igrd = 2                      ! zonal velocity
280                           dta%u2d(:) = 0._wp
281                           DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
282                              ii   = idx_bdy(ib_bdy)%nbi(ib,igrd)
283                              ij   = idx_bdy(ib_bdy)%nbj(ib,igrd)
284                              DO ik = 1, jpkm1
285                                 dta%u2d(ib) = dta%u2d(ib) &
286                       &                          + e3u_n(ii,ij,ik) * umask(ii,ij,ik) * dta%u3d(ib,ik)
287                              END DO
288                              dta%u2d(ib) =  dta%u2d(ib) * r1_hu_n(ii,ij)
289                           END DO
290                           igrd = 3                      ! meridional velocity
291                           dta%v2d(:) = 0._wp
292                           DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
293                              ii   = idx_bdy(ib_bdy)%nbi(ib,igrd)
294                              ij   = idx_bdy(ib_bdy)%nbj(ib,igrd)
295                              DO ik = 1, jpkm1
296                                 dta%v2d(ib) = dta%v2d(ib) &
297                       &                       + e3v_n(ii,ij,ik) * vmask(ii,ij,ik) * dta%v3d(ib,ik)
298                              END DO
299                              dta%v2d(ib) =  dta%v2d(ib) * r1_hv_n(ii,ij)
300                           END DO
301                        ENDIF                   
302                     ENDIF
303                     IF( nn_dyn2d_dta(ib_bdy) .ge. 2 ) THEN ! update tidal harmonic forcing
304                        CALL bdytide_update( kt=kt, idx=idx_bdy(ib_bdy), dta=dta, td=tides(ib_bdy),   & 
305                          &                 jit=jit, time_offset=time_offset )
306                     ENDIF
307                  ENDIF
308               ENDIF
309            ELSE
310               IF (cn_tra(ib_bdy) == 'runoff') then      ! runoff condition
311                  jend = nb_bdy_fld(ib_bdy)
312                  CALL fld_read( kt=kt, kn_fsbc=1, sd=bf(jstart:jend),  &
313                               & map=nbmap_ptr(jstart:jend), kt_offset=time_offset )
314                  !
315                  igrd = 2                      ! zonal velocity
316                  DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
317                     ii   = idx_bdy(ib_bdy)%nbi(ib,igrd)
318                     ij   = idx_bdy(ib_bdy)%nbj(ib,igrd)
319                     dta%u2d(ib) = dta%u2d(ib) / ( e2u(ii,ij) * hu_0(ii,ij) )
320                  END DO
321                  !
322                  igrd = 3                      ! meridional velocity
323                  DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
324                     ii   = idx_bdy(ib_bdy)%nbi(ib,igrd)
325                     ij   = idx_bdy(ib_bdy)%nbj(ib,igrd)
326                     dta%v2d(ib) = dta%v2d(ib) / ( e1v(ii,ij) * hv_0(ii,ij) )
327                  END DO
328               ELSE
329                  IF( nn_dyn2d_dta(ib_bdy) == 2 ) THEN ! tidal harmonic forcing ONLY: initialise arrays
330                     IF( dta%ll_ssh ) dta%ssh(:) = 0._wp
331                     IF( dta%ll_u2d ) dta%u2d(:) = 0._wp
332                     IF( dta%ll_v2d ) dta%v2d(:) = 0._wp
333                  ENDIF
334                  IF( dta%nread(1) .gt. 0 ) THEN ! update external data
335                     jend = jstart + dta%nread(1) - 1
336                     CALL fld_read( kt=kt, kn_fsbc=1, sd=bf(jstart:jend), &
337                                  & map=nbmap_ptr(jstart:jend), kt_offset=time_offset, jpk_bdy=nb_jpk_bdy, fvl=ln_full_vel_array(ib_bdy) )
338                  ENDIF
339                  ! If full velocities in boundary data then split into barotropic and baroclinic data
340                  IF( ln_full_vel_array(ib_bdy) .and.                                             &
341                    & ( nn_dyn2d_dta(ib_bdy) == 1 .OR. nn_dyn2d_dta(ib_bdy) == 3 .OR. &
342                    &   nn_dyn3d_dta(ib_bdy) == 1 ) ) THEN
343                     igrd = 2                      ! zonal velocity
344                     dta%u2d(:) = 0._wp
345                     DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
346                        ii   = idx_bdy(ib_bdy)%nbi(ib,igrd)
347                        ij   = idx_bdy(ib_bdy)%nbj(ib,igrd)
348                        DO ik = 1, jpkm1
349                           dta%u2d(ib) = dta%u2d(ib) &
350                 &                       + e3u_n(ii,ij,ik) * umask(ii,ij,ik) * dta%u3d(ib,ik)
351                        END DO
352                        dta%u2d(ib) =  dta%u2d(ib) * r1_hu_n(ii,ij)
353                        DO ik = 1, jpkm1
354                           dta%u3d(ib,ik) = dta%u3d(ib,ik) - dta%u2d(ib)
355                        END DO
356                     END DO
357                     igrd = 3                      ! meridional velocity
358                     dta%v2d(:) = 0._wp
359                     DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
360                        ii   = idx_bdy(ib_bdy)%nbi(ib,igrd)
361                        ij   = idx_bdy(ib_bdy)%nbj(ib,igrd)
362                        DO ik = 1, jpkm1
363                           dta%v2d(ib) = dta%v2d(ib) &
364                 &                       + e3v_n(ii,ij,ik) * vmask(ii,ij,ik) * dta%v3d(ib,ik)
365                        END DO
366                        dta%v2d(ib) =  dta%v2d(ib) * r1_hv_n(ii,ij)
367                        DO ik = 1, jpkm1
368                           dta%v3d(ib,ik) = dta%v3d(ib,ik) - dta%v2d(ib)
369                        END DO
370                     END DO
371                  ENDIF
372
373               ENDIF
374#if defined key_lim3
375               IF( .NOT. ll_bdylim3 .AND. cn_ice_lim(ib_bdy) /= 'none' .AND. nn_ice_lim_dta(ib_bdy) == 1 ) THEN ! bdy ice input (case input is lim2 type)
376                CALL lim_var_itd ( bf(jfld_hti)%fnow(:,1,1), bf(jfld_hts)%fnow(:,1,1), bf(jfld_ai)%fnow(:,1,1), &
377                                  & dta_bdy(ib_bdy)%ht_i,     dta_bdy(ib_bdy)%ht_s,     dta_bdy(ib_bdy)%a_i     )
378               ENDIF
379#endif
380            ENDIF
381            jstart = jstart + dta%nread(1)
382         END IF ! nn_dta(ib_bdy) = 1
383      END DO  ! ib_bdy
384
385      IF ( ln_tide ) THEN
386         IF (ln_dynspg_ts) THEN      ! Fill temporary arrays with slow-varying bdy data                           
387            DO ib_bdy = 1, nb_bdy    ! Tidal component added in ts loop
388               IF ( nn_dyn2d_dta(ib_bdy) .ge. 2 ) THEN
389                  nblen => idx_bdy(ib_bdy)%nblen
390                  nblenrim => idx_bdy(ib_bdy)%nblenrim
391                  IF( cn_dyn2d(ib_bdy) == 'frs' ) THEN; ilen1(:)=nblen(:) ; ELSE ; ilen1(:)=nblenrim(:) ; ENDIF
392                  IF ( dta_bdy(ib_bdy)%ll_ssh ) dta_bdy_s(ib_bdy)%ssh(1:ilen1(1)) = dta_bdy(ib_bdy)%ssh(1:ilen1(1))
393                  IF ( dta_bdy(ib_bdy)%ll_u2d ) dta_bdy_s(ib_bdy)%u2d(1:ilen1(2)) = dta_bdy(ib_bdy)%u2d(1:ilen1(2))
394                  IF ( dta_bdy(ib_bdy)%ll_v2d ) dta_bdy_s(ib_bdy)%v2d(1:ilen1(3)) = dta_bdy(ib_bdy)%v2d(1:ilen1(3))
395               ENDIF
396            END DO
397         ELSE ! Add tides if not split-explicit free surface else this is done in ts loop
398            !
399            CALL bdy_dta_tides( kt=kt, time_offset=time_offset )
400         ENDIF
401      ENDIF
402
403      IF ( ln_apr_obc ) THEN
404         DO ib_bdy = 1, nb_bdy
405            IF (cn_tra(ib_bdy) /= 'runoff')THEN
406               igrd = 1                      ! meridional velocity
407               DO ib = 1, idx_bdy(ib_bdy)%nblenrim(igrd)
408                  ii   = idx_bdy(ib_bdy)%nbi(ib,igrd)
409                  ij   = idx_bdy(ib_bdy)%nbj(ib,igrd)
410                  dta_bdy(ib_bdy)%ssh(ib) = dta_bdy(ib_bdy)%ssh(ib) + ssh_ib(ii,ij)
411               END DO
412            ENDIF
413         END DO
414      ENDIF
415      !
416      IF( nn_timing == 1 ) CALL timing_stop('bdy_dta')
417      !
418   END SUBROUTINE bdy_dta
419
420
421   SUBROUTINE bdy_dta_init
422      !!----------------------------------------------------------------------
423      !!                   ***  SUBROUTINE bdy_dta_init  ***
424      !!                   
425      !! ** Purpose :   Initialise arrays for reading of external data
426      !!                for open boundary conditions
427      !!
428      !! ** Method  :   
429      !!               
430      !!----------------------------------------------------------------------
431      INTEGER ::   ib_bdy, jfld, jstart, jend, ierror, ios     ! Local integers
432      !
433      CHARACTER(len=100)                     ::   cn_dir        ! Root directory for location of data files
434      CHARACTER(len=100), DIMENSION(nb_bdy)  ::   cn_dir_array  ! Root directory for location of data files
435      CHARACTER(len = 256)::   clname                           ! temporary file name
436      LOGICAL                                ::   ln_full_vel   ! =T => full velocities in 3D boundary data
437                                                                ! =F => baroclinic velocities in 3D boundary data
438      INTEGER                                ::   ilen_global   ! Max length required for global bdy dta arrays
439      INTEGER, ALLOCATABLE, DIMENSION(:)     ::   ilen1, ilen3  ! size of 1st and 3rd dimensions of local arrays
440      INTEGER, ALLOCATABLE, DIMENSION(:)     ::   ibdy           ! bdy set for a particular jfld
441      INTEGER, ALLOCATABLE, DIMENSION(:)     ::   igrid         ! index for grid type (1,2,3 = T,U,V)
442      INTEGER, POINTER, DIMENSION(:)         ::   nblen, nblenrim  ! short cuts
443      TYPE(OBC_DATA), POINTER                ::   dta           ! short cut
444#if defined key_lim3
445      INTEGER               ::   zndims   ! number of dimensions in an array (i.e. 3 = wo ice cat; 4 = w ice cat)
446      INTEGER               ::   inum,id1 ! local integer
447#endif
448      TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) ::   blf_i         !  array of namelist information structures
449      TYPE(FLD_N) ::   bn_tem, bn_sal, bn_u3d, bn_v3d   !
450      TYPE(FLD_N) ::   bn_ssh, bn_u2d, bn_v2d           ! informations about the fields to be read
451#if defined key_lim2
452      TYPE(FLD_N) ::   bn_frld, bn_hicif, bn_hsnif      !
453#elif defined key_lim3
454      TYPE(FLD_N) ::   bn_a_i, bn_ht_i, bn_ht_s     
455#endif
456      NAMELIST/nambdy_dta/ cn_dir, bn_tem, bn_sal, bn_u3d, bn_v3d, bn_ssh, bn_u2d, bn_v2d 
457#if defined key_lim2
458      NAMELIST/nambdy_dta/ bn_frld, bn_hicif, bn_hsnif
459#elif defined key_lim3
460      NAMELIST/nambdy_dta/ bn_a_i, bn_ht_i, bn_ht_s
461#endif
462      NAMELIST/nambdy_dta/ ln_full_vel, nb_jpk_bdy
463      !!---------------------------------------------------------------------------
464      !
465      IF( nn_timing == 1 )   CALL timing_start('bdy_dta_init')
466      !
467      IF(lwp) WRITE(numout,*)
468      IF(lwp) WRITE(numout,*) 'bdy_dta_ini : initialization of data at the open boundaries'
469      IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
470      IF(lwp) WRITE(numout,*) ''
471
472      ! Set nn_dta
473      DO ib_bdy = 1, nb_bdy
474         nn_dta(ib_bdy) = MAX(  nn_dyn2d_dta(ib_bdy)       &
475                               ,nn_dyn3d_dta(ib_bdy)       &
476                               ,nn_tra_dta(ib_bdy)         &
477#if ( defined key_lim2 || defined key_lim3 )
478                              ,nn_ice_lim_dta(ib_bdy)    &
479#endif
480                              )
481         IF(nn_dta(ib_bdy) > 1) nn_dta(ib_bdy) = 1
482      END DO
483
484      ! Work out upper bound of how many fields there are to read in and allocate arrays
485      ! ---------------------------------------------------------------------------
486      ALLOCATE( nb_bdy_fld(nb_bdy) )
487      nb_bdy_fld(:) = 0
488      DO ib_bdy = 1, nb_bdy         
489         IF( cn_dyn2d(ib_bdy) /= 'none' .and. ( nn_dyn2d_dta(ib_bdy) == 1 .or. nn_dyn2d_dta(ib_bdy) == 3 ) ) THEN
490            nb_bdy_fld(ib_bdy) = nb_bdy_fld(ib_bdy) + 3
491         ENDIF
492         IF( cn_dyn3d(ib_bdy) /= 'none' .and. nn_dyn3d_dta(ib_bdy) == 1 ) THEN
493            nb_bdy_fld(ib_bdy) = nb_bdy_fld(ib_bdy) + 2
494         ENDIF
495         IF( cn_tra(ib_bdy) /= 'none' .and. nn_tra_dta(ib_bdy) == 1  ) THEN
496            nb_bdy_fld(ib_bdy) = nb_bdy_fld(ib_bdy) + 2
497         ENDIF
498#if ( defined key_lim2 || defined key_lim3 )
499         IF( cn_ice_lim(ib_bdy) /= 'none' .and. nn_ice_lim_dta(ib_bdy) == 1  ) THEN
500            nb_bdy_fld(ib_bdy) = nb_bdy_fld(ib_bdy) + 3
501         ENDIF
502#endif               
503         IF(lwp) WRITE(numout,*) 'Maximum number of files to open =',nb_bdy_fld(ib_bdy)
504      END DO           
505
506      nb_bdy_fld_sum = SUM( nb_bdy_fld )
507
508      ALLOCATE( bf(nb_bdy_fld_sum), STAT=ierror )
509      IF( ierror > 0 ) THEN   
510         CALL ctl_stop( 'bdy_dta: unable to allocate bf structure' )   ;   RETURN 
511      ENDIF
512      ALLOCATE( blf_i(nb_bdy_fld_sum), STAT=ierror )
513      IF( ierror > 0 ) THEN   
514         CALL ctl_stop( 'bdy_dta: unable to allocate blf_i structure' )   ;   RETURN 
515      ENDIF
516      ALLOCATE( nbmap_ptr(nb_bdy_fld_sum), STAT=ierror )
517      IF( ierror > 0 ) THEN   
518         CALL ctl_stop( 'bdy_dta: unable to allocate nbmap_ptr structure' )   ;   RETURN 
519      ENDIF
520      ALLOCATE( ilen1(nb_bdy_fld_sum), ilen3(nb_bdy_fld_sum) ) 
521      ALLOCATE( ibdy(nb_bdy_fld_sum) ) 
522      ALLOCATE( igrid(nb_bdy_fld_sum) ) 
523
524      ! Read namelists
525      ! --------------
526      REWIND(numnam_ref)
527      REWIND(numnam_cfg)
528      jfld = 0 
529      DO ib_bdy = 1, nb_bdy         
530         IF( nn_dta(ib_bdy) == 1 ) THEN
531            READ  ( numnam_ref, nambdy_dta, IOSTAT = ios, ERR = 901)
532901         IF( ios /= 0 )   CALL ctl_nam ( ios , 'nambdy_dta in reference namelist', lwp )
533
534            READ  ( numnam_cfg, nambdy_dta, IOSTAT = ios, ERR = 902 )
535902         IF( ios /= 0 )   CALL ctl_nam ( ios , 'nambdy_dta in configuration namelist', lwp )
536            IF(lwm) WRITE( numond, nambdy_dta )
537
538            cn_dir_array(ib_bdy) = cn_dir
539            ln_full_vel_array(ib_bdy) = ln_full_vel
540
541            nblen => idx_bdy(ib_bdy)%nblen
542            nblenrim => idx_bdy(ib_bdy)%nblenrim
543            dta => dta_bdy(ib_bdy)
544            dta%nread(2) = 0
545
546            ! Only read in necessary fields for this set.
547            ! Important that barotropic variables come first.
548            IF( nn_dyn2d_dta(ib_bdy) == 1 .or. nn_dyn2d_dta(ib_bdy) == 3 ) THEN
549
550               IF( dta%ll_ssh ) THEN
551                  if(lwp) write(numout,*) '++++++ reading in ssh field'
552                  jfld = jfld + 1
553                  blf_i(jfld) = bn_ssh
554                  ibdy(jfld) = ib_bdy
555                  igrid(jfld) = 1
556                  ilen1(jfld) = nblen(igrid(jfld))
557                  ilen3(jfld) = 1
558                  dta%nread(2) = dta%nread(2) + 1
559               ENDIF
560
561               IF( dta%ll_u2d .and. .not. ln_full_vel_array(ib_bdy) ) THEN
562                  if(lwp) write(numout,*) '++++++ reading in u2d field'
563                  jfld = jfld + 1
564                  blf_i(jfld) = bn_u2d
565                  ibdy(jfld) = ib_bdy
566                  igrid(jfld) = 2
567                  ilen1(jfld) = nblen(igrid(jfld))
568                  ilen3(jfld) = 1
569                  dta%nread(2) = dta%nread(2) + 1
570               ENDIF
571
572               IF( dta%ll_v2d .and. .not. ln_full_vel_array(ib_bdy) ) THEN
573                  if(lwp) write(numout,*) '++++++ reading in v2d field'
574                  jfld = jfld + 1
575                  blf_i(jfld) = bn_v2d
576                  ibdy(jfld) = ib_bdy
577                  igrid(jfld) = 3
578                  ilen1(jfld) = nblen(igrid(jfld))
579                  ilen3(jfld) = 1
580                  dta%nread(2) = dta%nread(2) + 1
581               ENDIF
582
583            ENDIF
584
585            ! read 3D velocities if baroclinic velocities require OR if
586            ! barotropic velocities required and ln_full_vel set to .true.
587            IF( nn_dyn3d_dta(ib_bdy) == 1 .OR. &
588           &  ( ln_full_vel_array(ib_bdy) .AND. ( nn_dyn2d_dta(ib_bdy) == 1 .or. nn_dyn2d_dta(ib_bdy) == 3 ) ) ) THEN
589
590               IF( dta%ll_u3d .OR. ( ln_full_vel_array(ib_bdy) .and. dta%ll_u2d ) ) THEN
591                  if(lwp) write(numout,*) '++++++ reading in u3d field'
592                  jfld = jfld + 1
593                  blf_i(jfld) = bn_u3d
594                  ibdy(jfld) = ib_bdy
595                  igrid(jfld) = 2
596                  ilen1(jfld) = nblen(igrid(jfld))
597                  ilen3(jfld) = jpk
598                  IF( ln_full_vel_array(ib_bdy) .and. dta%ll_u2d ) dta%nread(2) = dta%nread(2) + 1
599               ENDIF
600
601               IF( dta%ll_v3d .OR. ( ln_full_vel_array(ib_bdy) .and. dta%ll_v2d ) ) THEN
602                  if(lwp) write(numout,*) '++++++ reading in v3d field'
603                  jfld = jfld + 1
604                  blf_i(jfld) = bn_v3d
605                  ibdy(jfld) = ib_bdy
606                  igrid(jfld) = 3
607                  ilen1(jfld) = nblen(igrid(jfld))
608                  ilen3(jfld) = jpk
609                  IF( ln_full_vel_array(ib_bdy) .and. dta%ll_v2d ) dta%nread(2) = dta%nread(2) + 1
610               ENDIF
611
612            ENDIF
613
614            ! temperature and salinity
615            IF( nn_tra_dta(ib_bdy) == 1 ) THEN
616
617               IF( dta%ll_tem ) THEN
618                  if(lwp) write(numout,*) '++++++ reading in tem field'
619                  jfld = jfld + 1
620                  blf_i(jfld) = bn_tem
621                  ibdy(jfld) = ib_bdy
622                  igrid(jfld) = 1
623                  ilen1(jfld) = nblen(igrid(jfld))
624                  ilen3(jfld) = jpk
625               ENDIF
626
627               IF( dta%ll_sal ) THEN
628                  if(lwp) write(numout,*) '++++++ reading in sal field'
629                  jfld = jfld + 1
630                  blf_i(jfld) = bn_sal
631                  ibdy(jfld) = ib_bdy
632                  igrid(jfld) = 1
633                  ilen1(jfld) = nblen(igrid(jfld))
634                  ilen3(jfld) = jpk
635               ENDIF
636
637            ENDIF
638
639#if defined key_lim2
640            ! sea ice
641            IF( nn_ice_lim_dta(ib_bdy) == 1 ) THEN
642
643               IF( dta%ll_frld ) THEN
644                  jfld = jfld + 1
645                  blf_i(jfld) = bn_frld
646                  ibdy(jfld) = ib_bdy
647                  igrid(jfld) = 1
648                  ilen1(jfld) = nblen(igrid(jfld))
649                  ilen3(jfld) = 1
650               ENDIF
651
652               IF( dta%ll_hicif ) THEN
653                  jfld = jfld + 1
654                  blf_i(jfld) = bn_hicif
655                  ibdy(jfld) = ib_bdy
656                  igrid(jfld) = 1
657                  ilen1(jfld) = nblen(igrid(jfld))
658                  ilen3(jfld) = 1
659               ENDIF
660
661               IF( dta%ll_hsnif ) THEN
662                  jfld = jfld + 1
663                  blf_i(jfld) = bn_hsnif
664                  ibdy(jfld) = ib_bdy
665                  igrid(jfld) = 1
666                  ilen1(jfld) = nblen(igrid(jfld))
667                  ilen3(jfld) = 1
668               ENDIF
669
670            ENDIF
671#elif defined key_lim3
672            ! sea ice
673            IF( nn_ice_lim_dta(ib_bdy) == 1 ) THEN
674               ! Test for types of ice input (lim2 or lim3)
675               ! Build file name to find dimensions
676               clname=TRIM(bn_a_i%clname)
677               IF( .NOT. bn_a_i%ln_clim ) THEN   
678                                                  WRITE(clname, '(a,"_y",i4.4)' ) TRIM( bn_a_i%clname ), nyear    ! add year
679                  IF( bn_a_i%cltype /= 'yearly' ) WRITE(clname, '(a,"m" ,i2.2)' ) TRIM( clname        ), nmonth   ! add month
680               ELSE
681                  IF( bn_a_i%cltype /= 'yearly' ) WRITE(clname, '(a,"_m",i2.2)' ) TRIM( bn_a_i%clname ), nmonth   ! add month
682               ENDIF
683               IF( bn_a_i%cltype == 'daily' .OR. bn_a_i%cltype(1:4) == 'week' ) &
684               &                                  WRITE(clname, '(a,"d" ,i2.2)' ) TRIM( clname        ), nday     ! add day
685               !
686               CALL iom_open  ( clname, inum )
687               id1 = iom_varid( inum, bn_a_i%clvar, kndims=zndims, ldstop = .FALSE. )
688               CALL iom_close ( inum )
689
690                IF ( zndims == 4 ) THEN
691                 ll_bdylim3 = .TRUE.   ! lim3 input
692               ELSE
693                 ll_bdylim3 = .FALSE.  ! lim2 input     
694               ENDIF
695               ! End test
696
697               IF( dta%ll_a_i ) THEN
698                  jfld = jfld + 1
699                  blf_i(jfld) = bn_a_i
700                  ibdy(jfld) = ib_bdy
701                  igrid(jfld) = 1
702                  ilen1(jfld) = nblen(igrid(jfld))
703                  IF ( ll_bdylim3 ) THEN ; ilen3(jfld)=jpl ; ELSE ; ilen3(jfld)=1 ; ENDIF
704               ENDIF
705
706               IF( dta%ll_ht_i ) THEN
707                  jfld = jfld + 1
708                  blf_i(jfld) = bn_ht_i
709                  ibdy(jfld) = ib_bdy
710                  igrid(jfld) = 1
711                  ilen1(jfld) = nblen(igrid(jfld))
712                  IF ( ll_bdylim3 ) THEN ; ilen3(jfld)=jpl ; ELSE ; ilen3(jfld)=1 ; ENDIF
713               ENDIF
714
715               IF( dta%ll_ht_s ) THEN
716                  jfld = jfld + 1
717                   blf_i(jfld) = bn_ht_s
718                  ibdy(jfld) = ib_bdy
719                  igrid(jfld) = 1
720                  ilen1(jfld) = nblen(igrid(jfld))
721                  IF ( ll_bdylim3 ) THEN ; ilen3(jfld)=jpl ; ELSE ; ilen3(jfld)=1 ; ENDIF
722               ENDIF
723
724            ENDIF
725#endif
726            ! Recalculate field counts
727            !-------------------------
728            IF( ib_bdy == 1 ) THEN
729               nb_bdy_fld_sum = 0
730               nb_bdy_fld(ib_bdy) = jfld
731               nb_bdy_fld_sum     = jfld             
732            ELSE
733               nb_bdy_fld(ib_bdy) = jfld - nb_bdy_fld_sum
734               nb_bdy_fld_sum = nb_bdy_fld_sum + nb_bdy_fld(ib_bdy)
735            ENDIF
736
737            dta%nread(1) = nb_bdy_fld(ib_bdy)
738
739         ENDIF ! nn_dta == 1
740      ENDDO ! ib_bdy
741
742      DO jfld = 1, nb_bdy_fld_sum
743         ALLOCATE( bf(jfld)%fnow(ilen1(jfld),1,ilen3(jfld)) )
744         IF( blf_i(jfld)%ln_tint ) ALLOCATE( bf(jfld)%fdta(ilen1(jfld),1,ilen3(jfld),2) )
745         nbmap_ptr(jfld)%ptr => idx_bdy(ibdy(jfld))%nbmap(:,igrid(jfld))
746         nbmap_ptr(jfld)%ll_unstruc = ln_coords_file(ibdy(jfld))
747      ENDDO
748
749      ! fill bf with blf_i and control print
750      !-------------------------------------
751      jstart = 1
752      DO ib_bdy = 1, nb_bdy
753         jend = jstart - 1 + nb_bdy_fld(ib_bdy) 
754         CALL fld_fill( bf(jstart:jend), blf_i(jstart:jend), cn_dir_array(ib_bdy), 'bdy_dta',   &
755         &              'open boundary conditions', 'nambdy_dta' )
756         jstart = jend + 1
757      ENDDO
758
759      ! Initialise local boundary data arrays
760      ! nn_xxx_dta=0 : allocate space - will be filled from initial conditions later
761      ! nn_xxx_dta=1 : point to "fnow" arrays
762      !-------------------------------------
763
764      jfld = 0
765      DO ib_bdy=1, nb_bdy
766
767         nblen => idx_bdy(ib_bdy)%nblen
768         dta => dta_bdy(ib_bdy)
769
770         if(lwp) then
771            write(numout,*) '++++++ dta%ll_ssh = ',dta%ll_ssh
772            write(numout,*) '++++++ dta%ll_u2d = ',dta%ll_u2d
773            write(numout,*) '++++++ dta%ll_v2d = ',dta%ll_v2d
774            write(numout,*) '++++++ dta%ll_u3d = ',dta%ll_u3d
775            write(numout,*) '++++++ dta%ll_v3d = ',dta%ll_v3d
776            write(numout,*) '++++++ dta%ll_tem = ',dta%ll_tem
777            write(numout,*) '++++++ dta%ll_sal = ',dta%ll_sal
778         endif
779
780         IF ( nn_dyn2d_dta(ib_bdy) == 0 .or. nn_dyn2d_dta(ib_bdy) == 2 ) THEN
781            if(lwp) write(numout,*) '++++++ dta%ssh/u2d/u3d allocated space'
782            IF( dta%ll_ssh ) ALLOCATE( dta%ssh(nblen(1)) )
783            IF( dta%ll_u2d ) ALLOCATE( dta%u2d(nblen(2)) )
784            IF( dta%ll_v2d ) ALLOCATE( dta%v2d(nblen(3)) )
785         ENDIF
786         IF ( nn_dyn2d_dta(ib_bdy) == 1 .or. nn_dyn2d_dta(ib_bdy) == 3 ) THEN
787            IF( dta%ll_ssh ) THEN
788               if(lwp) write(numout,*) '++++++ dta%ssh pointing to fnow'
789               jfld = jfld + 1
790               dta%ssh => bf(jfld)%fnow(:,1,1)
791            ENDIF
792            IF ( dta%ll_u2d ) THEN
793               IF ( ln_full_vel_array(ib_bdy) ) THEN
794                  if(lwp) write(numout,*) '++++++ dta%u2d allocated space'
795                  ALLOCATE( dta%u2d(nblen(2)) )
796               ELSE
797                  if(lwp) write(numout,*) '++++++ dta%u2d pointing to fnow'
798                  jfld = jfld + 1
799                  dta%u2d => bf(jfld)%fnow(:,1,1)
800               ENDIF
801            ENDIF
802            IF ( dta%ll_v2d ) THEN
803               IF ( ln_full_vel_array(ib_bdy) ) THEN
804                  if(lwp) write(numout,*) '++++++ dta%v2d allocated space'
805                  ALLOCATE( dta%v2d(nblen(3)) )
806               ELSE
807                  if(lwp) write(numout,*) '++++++ dta%v2d pointing to fnow'
808                  jfld = jfld + 1
809                  dta%v2d => bf(jfld)%fnow(:,1,1)
810               ENDIF
811            ENDIF
812         ENDIF
813
814         IF ( nn_dyn3d_dta(ib_bdy) == 0 ) THEN
815            if(lwp) write(numout,*) '++++++ dta%u3d/v3d allocated space'
816            IF( dta%ll_u3d ) ALLOCATE( dta_bdy(ib_bdy)%u3d(nblen(2),jpk) )
817            IF( dta%ll_v3d ) ALLOCATE( dta_bdy(ib_bdy)%v3d(nblen(3),jpk) )
818         ENDIF
819         IF ( nn_dyn3d_dta(ib_bdy) == 1 .or. &
820           &  ( ln_full_vel_array(ib_bdy) .and. ( nn_dyn2d_dta(ib_bdy) == 1 .or. nn_dyn2d_dta(ib_bdy) == 3 ) ) ) THEN
821            IF ( dta%ll_u3d .or. ( ln_full_vel_array(ib_bdy) .and. dta%ll_u2d ) ) THEN
822               if(lwp) write(numout,*) '++++++ dta%u3d pointing to fnow'
823               jfld = jfld + 1
824               dta_bdy(ib_bdy)%u3d => bf(jfld)%fnow(:,1,:)
825            ENDIF
826            IF ( dta%ll_v3d .or. ( ln_full_vel_array(ib_bdy) .and. dta%ll_v2d ) ) THEN
827               if(lwp) write(numout,*) '++++++ dta%v3d pointing to fnow'
828               jfld = jfld + 1
829               dta_bdy(ib_bdy)%v3d => bf(jfld)%fnow(:,1,:)
830            ENDIF
831         ENDIF
832
833         IF( nn_tra_dta(ib_bdy) == 0 ) THEN
834            if(lwp) write(numout,*) '++++++ dta%tem/sal allocated space'
835            IF( dta%ll_tem ) ALLOCATE( dta_bdy(ib_bdy)%tem(nblen(1),jpk) )
836            IF( dta%ll_sal ) ALLOCATE( dta_bdy(ib_bdy)%sal(nblen(1),jpk) )
837         ELSE
838            IF( dta%ll_tem ) THEN
839               if(lwp) write(numout,*) '++++++ dta%tem pointing to fnow'
840               jfld = jfld + 1
841               dta_bdy(ib_bdy)%tem => bf(jfld)%fnow(:,1,:)
842            ENDIF
843            IF( dta%ll_sal ) THEN
844               if(lwp) write(numout,*) '++++++ dta%sal pointing to fnow'
845               jfld = jfld + 1
846               dta_bdy(ib_bdy)%sal => bf(jfld)%fnow(:,1,:)
847            ENDIF
848         ENDIF
849
850#if defined key_lim2
851         IF (cn_ice_lim(ib_bdy) /= 'none') THEN
852            IF( nn_ice_lim_dta(ib_bdy) == 0 ) THEN
853               ALLOCATE( dta_bdy(ib_bdy)%frld(nblen(1)) )
854               ALLOCATE( dta_bdy(ib_bdy)%hicif(nblen(1)) )
855               ALLOCATE( dta_bdy(ib_bdy)%hsnif(nblen(1)) )
856            ELSE
857               jfld = jfld + 1
858               dta_bdy(ib_bdy)%frld  => bf(jfld)%fnow(:,1,1)
859               jfld = jfld + 1
860               dta_bdy(ib_bdy)%hicif => bf(jfld)%fnow(:,1,1)
861               jfld = jfld + 1
862               dta_bdy(ib_bdy)%hsnif => bf(jfld)%fnow(:,1,1)
863            ENDIF
864         ENDIF
865#elif defined key_lim3
866         IF (cn_ice_lim(ib_bdy) /= 'none') THEN
867            IF( nn_ice_lim_dta(ib_bdy) == 0 ) THEN
868               ALLOCATE( dta_bdy(ib_bdy)%a_i (nblen(1),jpl) )
869               ALLOCATE( dta_bdy(ib_bdy)%ht_i(nblen(1),jpl) )
870               ALLOCATE( dta_bdy(ib_bdy)%ht_s(nblen(1),jpl) )
871            ELSE
872               IF ( ll_bdylim3 ) THEN ! case input is lim3 type
873                  jfld = jfld + 1
874                  dta_bdy(ib_bdy)%a_i  => bf(jfld)%fnow(:,1,:)
875                  jfld = jfld + 1
876                  dta_bdy(ib_bdy)%ht_i => bf(jfld)%fnow(:,1,:)
877                  jfld = jfld + 1
878                  dta_bdy(ib_bdy)%ht_s => bf(jfld)%fnow(:,1,:)
879               ELSE ! case input is lim2 type
880                  jfld_ai  = jfld + 1
881                  jfld_hti = jfld + 2
882                  jfld_hts = jfld + 3
883                  jfld     = jfld + 3
884                  ALLOCATE( dta_bdy(ib_bdy)%a_i (nblen(1),jpl) )
885                  ALLOCATE( dta_bdy(ib_bdy)%ht_i(nblen(1),jpl) )
886                  ALLOCATE( dta_bdy(ib_bdy)%ht_s(nblen(1),jpl) )
887                  dta_bdy(ib_bdy)%a_i (:,:) = 0._wp
888                  dta_bdy(ib_bdy)%ht_i(:,:) = 0._wp
889                  dta_bdy(ib_bdy)%ht_s(:,:) = 0._wp
890               ENDIF
891
892            ENDIF
893         ENDIF
894#endif
895         !
896      END DO ! ib_bdy
897      !
898      IF( nn_timing == 1 ) CALL timing_stop('bdy_dta_init')
899      !
900   END SUBROUTINE bdy_dta_init
901
902   !!==============================================================================
903END MODULE bdydta
Note: See TracBrowser for help on using the repository browser.