source: trunk/NEMOGCM/NEMO/OPA_SRC/BDY/bdytra.F90 @ 7753

Last change on this file since 7753 was 7646, checked in by timgraham, 4 years ago

Merge of dev_merge_2016 into trunk. UPDATE TO ARCHFILES NEEDED for XIOS2.
LIM_SRC_s/limrhg.F90 to follow in next commit due to change of kind (I'm unable to do it in this commit).
Merged using the following steps:

1) svn merge —reintegrate svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/trunk .
2) Resolve minor conflicts in sette.sh and namelist_cfg for ORCA2LIM3 (due to a change in trunk after branch was created)
3) svn commit
4) svn switch svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/trunk
5) svn merge svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/branches/2016/dev_merge_2016 .
6) At this stage I checked out a clean copy of the branch to compare against what is about to be committed to the trunk.
6) svn commit #Commit code to the trunk

In this commit I have also reverted a change to Fcheck_archfile.sh which was causing problems on the Paris machine.

  • Property svn:keywords set to Id
File size: 7.1 KB
Line 
1MODULE bdytra
2   !!======================================================================
3   !!                       ***  MODULE  bdytra  ***
4   !! Ocean tracers:   Apply boundary conditions for tracers
5   !!======================================================================
6   !! History :  1.0  !  2005-01  (J. Chanut, A. Sellar)  Original code
7   !!            3.0  !  2008-04  (NEMO team)  add in the reference version
8   !!            3.4  !  2011     (D. Storkey) rewrite in preparation for OBC-BDY merge
9   !!            3.5  !  2012     (S. Mocavero, I. Epicoco) Optimization of BDY communications
10   !!            4.0  !  2016     (T. Lovato) Generalize OBC structure
11   !!----------------------------------------------------------------------
12   !!   bdy_tra       : Apply open boundary conditions & damping to T and S
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers variables
15   USE dom_oce        ! ocean space and time domain variables
16   USE bdy_oce        ! ocean open boundary conditions
17   USE bdylib         ! for orlanski library routines
18   !
19   USE in_out_manager ! I/O manager
20   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
21   USE timing         ! Timing
22
23   IMPLICIT NONE
24   PRIVATE
25
26   ! Local structure to rearrange tracers data
27   TYPE, PUBLIC ::   ztrabdy
28      REAL(wp), POINTER, DIMENSION(:,:) ::  tra
29   END TYPE
30
31   PUBLIC   bdy_tra      ! called in tranxt.F90
32   PUBLIC   bdy_tra_dmp  ! called in step.F90
33
34   !!----------------------------------------------------------------------
35   !! NEMO/OPA 4.0, NEMO Consortium (2016)
36   !! $Id$
37   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
38   !!----------------------------------------------------------------------
39CONTAINS
40
41   SUBROUTINE bdy_tra( kt )
42      !!----------------------------------------------------------------------
43      !!                  ***  SUBROUTINE bdy_tra  ***
44      !!
45      !! ** Purpose : - Apply open boundary conditions for temperature and salinity
46      !!
47      !!----------------------------------------------------------------------
48      INTEGER, INTENT(in) ::   kt   ! Main time step counter
49      !
50      INTEGER                        :: ib_bdy, jn, igrd   ! Loop indeces
51      TYPE(ztrabdy), DIMENSION(jpts) :: zdta               ! Temporary data structure
52      !!----------------------------------------------------------------------
53      igrd = 1 
54
55      DO ib_bdy=1, nb_bdy
56         !
57         zdta(1)%tra => dta_bdy(ib_bdy)%tem
58         zdta(2)%tra => dta_bdy(ib_bdy)%sal
59         !
60         DO jn = 1, jpts
61            !
62            SELECT CASE( TRIM(cn_tra(ib_bdy)) )
63            CASE('none'        )   ;   CYCLE
64            CASE('frs'         )   ;   CALL bdy_frs ( idx_bdy(ib_bdy),                tsa(:,:,:,jn), zdta(jn)%tra )
65            CASE('specified'   )   ;   CALL bdy_spe ( idx_bdy(ib_bdy),                tsa(:,:,:,jn), zdta(jn)%tra )
66            CASE('neumann'     )   ;   CALL bdy_nmn ( idx_bdy(ib_bdy), igrd         , tsa(:,:,:,jn)               )
67            CASE('orlanski'    )   ;   CALL bdy_orl ( idx_bdy(ib_bdy), tsb(:,:,:,jn), tsa(:,:,:,jn), zdta(jn)%tra, ll_npo=.false. )
68            CASE('orlanski_npo')   ;   CALL bdy_orl ( idx_bdy(ib_bdy), tsb(:,:,:,jn), tsa(:,:,:,jn), zdta(jn)%tra, ll_npo=.true. )
69            CASE('runoff'      )   ;   CALL bdy_rnf ( idx_bdy(ib_bdy),                tsa(:,:,:,jn),               jn )
70            CASE DEFAULT           ;   CALL ctl_stop( 'bdy_tra : unrecognised option for open boundaries for T and S' )
71            END SELECT
72            ! Boundary points should be updated
73            CALL lbc_bdy_lnk( tsa(:,:,:,jn), 'T', 1., ib_bdy )
74            !
75         END DO
76      END DO
77      !
78   END SUBROUTINE bdy_tra
79
80   SUBROUTINE bdy_rnf( idx, pta, jpa )
81      !!----------------------------------------------------------------------
82      !!                 ***  SUBROUTINE bdy_rnf  ***
83      !!                   
84      !! ** Purpose : Specialized routine to apply TRA runoff values at OBs:
85      !!                  - duplicate the neighbour value for the temperature
86      !!                  - specified to 0.1 PSU for the salinity
87      !!
88      !!----------------------------------------------------------------------
89      TYPE(OBC_INDEX),                     INTENT(in) ::   idx  ! OBC indices
90      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pta  ! tracer trend
91      INTEGER,                             INTENT(in) ::   jpa  ! TRA index
92      !
93      REAL(wp) ::   zwgt           ! boundary weight
94      INTEGER  ::   ib, ik, igrd   ! dummy loop indices
95      INTEGER  ::   ii, ij, ip, jp ! 2D addresses
96      !!----------------------------------------------------------------------
97      !
98      IF( nn_timing == 1 )   CALL timing_start('bdy_rnf')
99      !
100      igrd = 1                       ! Everything is at T-points here
101      DO ib = 1, idx%nblenrim(igrd)
102         ii = idx%nbi(ib,igrd)
103         ij = idx%nbj(ib,igrd)
104         DO ik = 1, jpkm1
105            ip = bdytmask(ii+1,ij  ) - bdytmask(ii-1,ij  )
106            jp = bdytmask(ii  ,ij+1) - bdytmask(ii  ,ij-1)
107            if (jpa == jp_tem) pta(ii,ij,ik) = pta(ii+ip,ij+jp,ik) * tmask(ii,ij,ik)
108            if (jpa == jp_sal) pta(ii,ij,ik) =                 0.1 * tmask(ii,ij,ik)
109         END DO
110      END DO
111      !
112      IF( nn_timing == 1 )   CALL timing_stop('bdy_rnf')
113      !
114   END SUBROUTINE bdy_rnf
115
116   SUBROUTINE bdy_tra_dmp( kt )
117      !!----------------------------------------------------------------------
118      !!                 ***  SUBROUTINE bdy_tra_dmp  ***
119      !!                   
120      !! ** Purpose : Apply damping for tracers at open boundaries.
121      !!
122      !!----------------------------------------------------------------------
123      INTEGER, INTENT(in) ::   kt   !
124      !
125      REAL(wp) ::   zwgt           ! boundary weight
126      REAL(wp) ::   zta, zsa, ztime
127      INTEGER  ::   ib, ik, igrd   ! dummy loop indices
128      INTEGER  ::   ii, ij         ! 2D addresses
129      INTEGER  ::   ib_bdy         ! Loop index
130      !!----------------------------------------------------------------------
131      !
132      IF( nn_timing == 1 )   CALL timing_start('bdy_tra_dmp')
133      !
134      DO ib_bdy = 1, nb_bdy
135         IF( ln_tra_dmp(ib_bdy) ) THEN
136            igrd = 1                       ! Everything is at T-points here
137            DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
138               ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
139               ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
140               zwgt = idx_bdy(ib_bdy)%nbd(ib,igrd)
141               DO ik = 1, jpkm1
142                  zta = zwgt * ( dta_bdy(ib_bdy)%tem(ib,ik) - tsb(ii,ij,ik,jp_tem) ) * tmask(ii,ij,ik)
143                  zsa = zwgt * ( dta_bdy(ib_bdy)%sal(ib,ik) - tsb(ii,ij,ik,jp_sal) ) * tmask(ii,ij,ik)
144                  tsa(ii,ij,ik,jp_tem) = tsa(ii,ij,ik,jp_tem) + zta
145                  tsa(ii,ij,ik,jp_sal) = tsa(ii,ij,ik,jp_sal) + zsa
146               END DO
147            END DO
148         ENDIF
149      END DO
150      !
151      IF( nn_timing == 1 )   CALL timing_stop('bdy_tra_dmp')
152      !
153   END SUBROUTINE bdy_tra_dmp
154 
155   !!======================================================================
156END MODULE bdytra
Note: See TracBrowser for help on using the repository browser.