New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
diahsb.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/DIA – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/DIA/diahsb.F90 @ 2528

Last change on this file since 2528 was 2528, checked in by rblod, 13 years ago

Update NEMOGCM from branch nemo_v3_3_beta
  • Property svn:keywords set to Id
File size: 13.0 KB
Line 
1MODULE diahsb
2   !!======================================================================
3   !!                       ***  MODULE  diahsb  ***
4   !! Ocean diagnostics: Heat, salt and volume budgets
5   !!======================================================================
6   !! History :  3.3  ! 2010-09  (M. Leclair)  Original code
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   USE oce             ! ocean dynamics and tracers
11   USE dom_oce         ! ocean space and time domain
12   USE phycst          ! physical constants
13   USE sbc_oce         ! surface thermohaline fluxes
14   USE in_out_manager  ! I/O manager
15   USE domvvl          ! vertical scale factors
16   USE traqsr          ! penetrative solar radiation
17   USE trabbc          ! bottom boundary condition
18   USE lib_mpp         ! distributed memory computing library
19   USE trabbc          ! bottom boundary condition
20   USE bdy_par         ! (for lk_bdy)
21   USE obc_par         ! (for lk_obc)
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   dia_hsb        ! routine called by step.F90
27   PUBLIC   dia_hsb_init   ! routine called by opa.F90
28
29   LOGICAL, PUBLIC ::   ln_diahsb  = .FALSE.   !: check the heat and salt budgets
30
31   INTEGER                                 ::   numhsb                           !
32   REAL(dp)                                ::   surf_tot   , vol_tot             !
33   REAL(dp)                                ::   frc_t      , frc_s     , frc_v   ! global forcing trends
34   REAL(dp)                                ::   fact1                            ! conversion factors
35   REAL(dp)                                ::   fact21    , fact22               !     -         -
36   REAL(dp)                                ::   fact31    , fact32               !     -         -
37   REAL(dp), DIMENSION(:,:)  , ALLOCATABLE ::   surf      , ssh_ini              !
38   REAL(dp), DIMENSION(:,:,:), ALLOCATABLE ::   hc_loc_ini, sc_loc_ini, e3t_ini  !
39
40   !! * Substitutions
41#  include "domzgr_substitute.h90"
42#  include "vectopt_loop_substitute.h90"
43
44   !!----------------------------------------------------------------------
45   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
46   !! $Id$
47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49
50CONTAINS
51
52   SUBROUTINE dia_hsb( kt )
53      !!---------------------------------------------------------------------------
54      !!                  ***  ROUTINE dia_hsb  ***
55      !!     
56      !! ** Purpose: Compute the ocean global heat content, salt content and volume conservation
57      !!
58      !! ** Method : - Compute the deviation of heat content, salt content and volume
59      !!             at the current time step from their values at nit000
60      !!             - Compute the contribution of forcing and remove it from these deviations
61      !!
62      !! ** Action : Write the results in the 'heat_salt_volume_budgets.txt' ASCII file
63      !!---------------------------------------------------------------------------
64      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
65      !!
66      INTEGER    ::   jk                          ! dummy loop indice
67      REAL(dp)   ::   zdiff_hc    , zdiff_sc      ! heat and salt content variations
68      REAL(dp)   ::   zdiff_v1    , zdiff_v2      ! volume variation
69      REAL(dp)   ::   z1_rau0                     ! local scalars
70      REAL(dp)   ::   zdeltat                     !    -     -
71      REAL(dp)   ::   z_frc_trd_t , z_frc_trd_s   !    -     -
72      REAL(dp)   ::   z_frc_trd_v                 !    -     -
73      !!---------------------------------------------------------------------------
74
75      ! ------------------------- !
76      ! 1 - Trends due to forcing !
77      ! ------------------------- !
78      z1_rau0 = 1.e0 / rau0
79      z_frc_trd_v = z1_rau0 * SUM( - ( emp(:,:) - rnf(:,:) ) * surf(:,:) )     ! volume fluxes
80      z_frc_trd_t =           SUM( sbc_tsc(:,:,jp_tem) * surf(:,:) )     ! heat fluxes
81      z_frc_trd_s =           SUM( sbc_tsc(:,:,jp_sal) * surf(:,:) )     ! salt fluxes
82      ! Add penetrative solar radiation
83      IF( ln_traqsr )   z_frc_trd_t = z_frc_trd_t + ro0cpr * SUM( qsr     (:,:) * surf(:,:) )
84      ! Add geothermal heat flux
85      IF( ln_trabbc )   z_frc_trd_t = z_frc_trd_t + ro0cpr * SUM( qgh_trd0(:,:) * surf(:,:) )
86      IF( lk_mpp ) THEN
87         CALL mpp_sum( z_frc_trd_v )
88         CALL mpp_sum( z_frc_trd_t )
89      ENDIF
90      frc_v = frc_v + z_frc_trd_v * rdt
91      frc_t = frc_t + z_frc_trd_t * rdt
92      frc_s = frc_s + z_frc_trd_s * rdt
93
94      ! ----------------------- !
95      ! 2 -  Content variations !
96      ! ----------------------- !
97      zdiff_v2 = 0.d0
98      zdiff_hc = 0.d0
99      zdiff_sc = 0.d0
100      ! volume variation (calculated with ssh)
101      zdiff_v1 = SUM( surf(:,:) * tmask(:,:,1) * ( sshn(:,:) - ssh_ini(:,:) ) )
102      DO jk = 1, jpkm1
103         ! volume variation (calculated with scale factors)
104         zdiff_v2 = zdiff_v2 + SUM( surf(:,:) * tmask(:,:,jk)   &
105            &                       * ( fse3t_n(:,:,jk)         &
106            &                           - e3t_ini(:,:,jk) ) )
107         ! heat content variation
108         zdiff_hc = zdiff_hc + SUM( surf(:,:) * tmask(:,:,jk)          &
109            &                       * ( fse3t_n(:,:,jk) * tn(:,:,jk)   &
110            &                           - hc_loc_ini(:,:,jk) ) )
111         ! salt content variation
112         zdiff_sc = zdiff_sc + SUM( surf(:,:) * tmask(:,:,jk)          &
113            &                       * ( fse3t_n(:,:,jk) * sn(:,:,jk)   &
114            &                           - sc_loc_ini(:,:,jk) ) )
115      ENDDO
116
117      IF( lk_mpp ) THEN
118         CALL mpp_sum( zdiff_hc )
119         CALL mpp_sum( zdiff_sc )
120         CALL mpp_sum( zdiff_v1 )
121         CALL mpp_sum( zdiff_v2 )
122      ENDIF
123
124      ! Substract forcing from heat content, salt content and volume variations
125      zdiff_v1 = zdiff_v1 - frc_v
126      zdiff_v2 = zdiff_v2 - frc_v
127      zdiff_hc = zdiff_hc - frc_t
128      zdiff_sc = zdiff_sc - frc_s
129     
130      ! ----------------------- !
131      ! 3 - Diagnostics writing !
132      ! ----------------------- !
133      zdeltat  = 1.e0 / ( ( kt - nit000 + 1 ) * rdt )
134      WRITE(numhsb , 9020) kt , zdiff_hc / vol_tot , zdiff_hc * fact1  * zdeltat,                                &
135         &                      zdiff_sc / vol_tot , zdiff_sc * fact21 * zdeltat, zdiff_sc * fact22 * zdeltat,   &
136         &                      zdiff_v1           , zdiff_v1 * fact31 * zdeltat, zdiff_v1 * fact32 * zdeltat,   &
137         &                      zdiff_v2           , zdiff_v2 * fact31 * zdeltat, zdiff_v2 * fact32 * zdeltat
138
139      IF ( kt == nitend ) CLOSE( numhsb )
140
1419020  FORMAT(I5,11D15.7)
142      !
143   END SUBROUTINE dia_hsb
144
145
146   SUBROUTINE dia_hsb_init
147      !!---------------------------------------------------------------------------
148      !!                  ***  ROUTINE dia_hsb  ***
149      !!     
150      !! ** Purpose: Initialization for the heat salt volume budgets
151      !!
152      !! ** Method : Compute initial heat content, salt content and volume
153      !!
154      !! ** Action : - Compute initial heat content, salt content and volume
155      !!             - Initialize forcing trends
156      !!             - Compute coefficients for conversion
157      !!---------------------------------------------------------------------------
158      CHARACTER (len=32) ::   cl_name  ! output file name
159      INTEGER            ::   jk       ! dummy loop indice
160      INTEGER            ::   ierror   ! local integer
161      !!
162      NAMELIST/namhsb/ ln_diahsb
163      !!----------------------------------------------------------------------
164      !
165      REWIND ( numnam )              ! Read Namelist namhsb
166      READ   ( numnam, namhsb )
167      !
168      IF(lwp) THEN                   ! Control print
169         WRITE(numout,*)
170         WRITE(numout,*) 'dia_hsb_init : check the heat and salt budgets'
171         WRITE(numout,*) '~~~~~~~~~~~~'
172         WRITE(numout,*) '   Namelist namhsb : set hsb parameters'
173         WRITE(numout,*) '      Switch for hsb diagnostic (T) or not (F)  ln_diahsb  = ', ln_diahsb
174      ENDIF
175
176      IF( .NOT. ln_diahsb )   RETURN
177
178      ! ------------------- !
179      ! 1 - Allocate memory !
180      ! ------------------- !
181      ALLOCATE( hc_loc_ini(jpi,jpj,jpk), STAT=ierror )
182      IF( ierror > 0 ) THEN
183         CALL ctl_stop( 'dia_hsb: unable to allocate hc_loc_ini' )   ;   RETURN
184      ENDIF
185      ALLOCATE( sc_loc_ini(jpi,jpj,jpk), STAT=ierror )
186      IF( ierror > 0 ) THEN
187         CALL ctl_stop( 'dia_hsb: unable to allocate sc_loc_ini' )   ;   RETURN
188      ENDIF
189      ALLOCATE( e3t_ini(jpi,jpj,jpk)   , STAT=ierror )
190      IF( ierror > 0 ) THEN
191         CALL ctl_stop( 'dia_hsb: unable to allocate e3t_ini' )      ;   RETURN
192      ENDIF
193      ALLOCATE( surf(jpi,jpj)          , STAT=ierror )
194      IF( ierror > 0 ) THEN
195         CALL ctl_stop( 'dia_hsb: unable to allocate surf' )         ;   RETURN
196      ENDIF
197      ALLOCATE( ssh_ini(jpi,jpj)       , STAT=ierror )
198      IF( ierror > 0 ) THEN
199         CALL ctl_stop( 'dia_hsb: unable to allocate ssh_ini' )      ;   RETURN
200      ENDIF
201
202      ! ----------------------------------------------- !
203      ! 2 - Time independant variables and file opening !
204      ! ----------------------------------------------- !
205      WRITE(numout,*) "dia_hsb: heat salt volume budgets activated"
206      WRITE(numout,*) "~~~~~~~  output written in the 'heat_salt_volume_budgets.txt' ASCII file"
207      IF( lk_obc .OR. lk_bdy) THEN
208         CALL ctl_warn( 'dia_hsb does not take open boundary fluxes into account' )         
209      ENDIF
210      cl_name    = 'heat_salt_volume_budgets.txt'                         ! name of output file
211      surf(:,:) = e1t(:,:) * e2t(:,:) * tmask(:,:,1) * tmask_i(:,:)      ! masked surface grid cell area
212      surf_tot  = SUM( surf(:,:) )                                       ! total ocean surface area
213      vol_tot   = 0.d0                                                   ! total ocean volume
214      DO jk = 1, jpkm1
215         vol_tot  = vol_tot + SUM( surf(:,:) * tmask(:,:,jk)     &
216            &                      * fse3t_n(:,:,jk)         )
217      END DO
218      IF( lk_mpp ) THEN
219         CALL mpp_sum( vol_tot )
220         CALL mpp_sum( surf_tot )
221      ENDIF
222
223      CALL ctl_opn( numhsb , cl_name , 'UNKNOWN' , 'FORMATTED' , 'SEQUENTIAL' , 1 , numout , lwp , 1 )
224      !                   12345678901234567890123456789012345678901234567890123456789012345678901234567890 -> 80
225      WRITE( numhsb, 9010 ) "kt   |     heat content budget     |            salt content budget             ",   &
226         !                                                   123456789012345678901234567890123456789012345 -> 45
227         &                                                  "|            volume budget (ssh)             ",   &
228         !                                                   678901234567890123456789012345678901234567890 -> 45
229         &                                                  "|            volume budget (e3t)             "
230      WRITE( numhsb, 9010 ) "     |      [C]         [W/m2]     |     [psu]        [mmm/s]          [SV]     ",   &
231         &                                                  "|     [m3]         [mmm/s]          [SV]     ",   &
232         &                                                  "|     [m3]         [mmm/s]          [SV]     "
233
234      ! --------------- !
235      ! 3 - Conversions ! (factors will be multiplied by duration afterwards)
236      ! --------------- !
237
238      ! heat content variation   =>   equivalent heat flux:
239      fact1  = rau0 * rcp / surf_tot                                         ! [C*m3]   ->  [W/m2]
240      ! salt content variation   =>   equivalent EMP and equivalent "flow":
241      fact21 = 1.e3  / ( soce * surf_tot )                                   ! [psu*m3] ->  [mm/s]
242      fact22 = 1.e-6 / soce                                                  ! [psu*m3] ->  [Sv]
243      ! volume variation         =>   equivalent EMP and equivalent "flow":
244      fact31 = 1.e3  / surf_tot                                              ! [m3]     ->  [mm/s]
245      fact32 = 1.e-6                                                         ! [m3]     ->  [SV]
246
247      ! ---------------------------------- !
248      ! 4 - initial conservation variables !
249      ! ---------------------------------- !
250      ssh_ini(:,:) = sshn(:,:)                               ! initial ssh
251      DO jk = 1, jpk
252         e3t_ini   (:,:,jk) = fse3t_n(:,:,jk)                ! initial vertical scale factors
253         hc_loc_ini(:,:,jk) = tn(:,:,jk) * fse3t_n(:,:,jk)   ! initial heat content
254         sc_loc_ini(:,:,jk) = sn(:,:,jk) * fse3t_n(:,:,jk)   ! initial salt content
255      END DO
256      frc_v = 0.d0                                           ! volume       trend due to forcing
257      frc_t = 0.d0                                           ! heat content   -    -   -    -   
258      frc_s = 0.d0                                           ! salt content   -    -   -    -         
259      !
2609010  FORMAT(A80,A45,A45)
261      !
262   END SUBROUTINE dia_hsb_init
263
264   !!======================================================================
265END MODULE diahsb
Note: See TracBrowser for help on using the repository browser.