New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
domcfg.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/DOM – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/DOM/domcfg.F90 @ 2528

Last change on this file since 2528 was 2528, checked in by rblod, 13 years ago

Update NEMOGCM from branch nemo_v3_3_beta
  • Property svn:keywords set to Id
File size: 9.6 KB
Line 
1MODULE domcfg
2   !!==============================================================================
3   !!                       ***  MODULE domcfg   ***
4   !! Ocean initialization : domain configuration initialization
5   !!==============================================================================
6   !! History :  1.0  ! 2003-09  (G. Madec)  Original code
7   !!            3.2  ! 2009-07  (R. Benshila) Suppression of rigid-lid option
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   dom_cfg        : initialize the domain configuration
12   !!----------------------------------------------------------------------
13   USE dom_oce         ! ocean space and time domain
14   USE phycst          ! physical constants
15   USE in_out_manager  ! I/O manager
16   USE lib_mpp         ! distributed memory computing library
17
18   IMPLICIT NONE
19   PRIVATE
20
21   PUBLIC   dom_cfg    ! called by opa.F90
22
23   !!----------------------------------------------------------------------
24   !! NEMO/OPA 3.2 , LODYC-IPSL  (2009)
25   !! $Id$
26   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
27   !!----------------------------------------------------------------------
28
29CONTAINS
30
31   SUBROUTINE dom_cfg
32      !!----------------------------------------------------------------------
33      !!                  ***  ROUTINE dom_cfg  ***
34      !!                   
35      !! ** Purpose :   set the domain configuration
36      !!
37      !!----------------------------------------------------------------------
38
39      IF(lwp) THEN                   ! Control print
40         WRITE(numout,*)
41         WRITE(numout,*) 'dom_cfg : set the ocean configuration'
42         WRITE(numout,*) '~~~~~~~ '
43         WRITE(numout,*) '   ocean model configuration used :   cp_cfg = ', cp_cfg, ' jp_cfg = ', jp_cfg
44         !
45         WRITE(numout,*) '   global domain lateral boundaries'
46         !
47         IF( jperio == 0 )   WRITE(numout,*) '      jperio= 0, closed'
48         IF( jperio == 1 )   WRITE(numout,*) '      jperio= 1, cyclic east-west'
49         IF( jperio == 2 )   WRITE(numout,*) '      jperio= 2, equatorial symmetric'
50         IF( jperio == 3 )   WRITE(numout,*) '      jperio= 3, north fold with T-point pivot'
51         IF( jperio == 4 )   WRITE(numout,*) '      jperio= 4, cyclic east-west and north fold with T-point pivot'
52         IF( jperio == 5 )   WRITE(numout,*) '      jperio= 5, north fold with F-point pivot'
53         IF( jperio == 6 )   WRITE(numout,*) '      jperio= 6, cyclic east-west and north fold with F-point pivot'
54      ENDIF
55      !
56      IF( jperio <  0 .OR. jperio > 6 )   CALL ctl_stop( 'jperio is out of range' )
57      !
58      CALL dom_glo                   ! global domain versus zoom and/or local domain
59      !
60   END SUBROUTINE dom_cfg
61
62
63   SUBROUTINE dom_glo
64      !!----------------------------------------------------------------------
65      !!                     ***  ROUTINE dom_glo  ***
66      !!
67      !! ** Purpose :   initialization for global domain, zoom and local domain
68      !!
69      !! ** Method  :   
70      !!
71      !! ** Action  : - mig  , mjg :
72      !!              - mi0  , mi1   :
73      !!              - mj0, , mj1   :
74      !!----------------------------------------------------------------------
75      INTEGER ::   ji, jj   ! dummy loop argument
76      !!----------------------------------------------------------------------
77
78      !                        ! ============== !
79      !                        !  Local domain  !
80      !                        ! ============== !
81      DO ji = 1, jpi                 ! local domain indices ==> data domain indices
82        mig(ji) = ji + jpizoom - 1 + nimpp - 1
83      END DO
84      DO jj = 1, jpj
85        mjg(jj) = jj + jpjzoom - 1 + njmpp - 1
86      END DO
87      !
88      !                              ! data domain indices ==> local domain indices
89      !                                   ! (return (m.0,m.1)=(1,0) if data domain gridpoint is to the west/south of the
90      !                                   !local domain, or (m.0,m.1)=(jp.+1,jp.) to the east/north of local domain.
91      DO ji = 1, jpidta
92        mi0(ji) = MAX( 1, MIN( ji - jpizoom + 1 - nimpp + 1, jpi+1 ) )
93        mi1(ji) = MAX( 0, MIN( ji - jpizoom + 1 - nimpp + 1, jpi   ) )
94      END DO
95      DO jj = 1, jpjdta
96        mj0(jj) = MAX( 1, MIN( jj - jpjzoom + 1 - njmpp + 1, jpj+1 ) )
97        mj1(jj) = MAX( 0, MIN( jj - jpjzoom + 1 - njmpp + 1, jpj   ) )
98      END DO
99
100      IF(lwp) THEN                   ! control print
101         WRITE(numout,*)
102         WRITE(numout,*) 'dom_glo : domain: data / local '
103         WRITE(numout,*) '~~~~~~~ '
104         WRITE(numout,*) '          data input domain    : jpidta = ', jpidta,   &
105            &                                            ' jpjdta = ', jpjdta, ' jpkdta = ', jpkdta
106         WRITE(numout,*) '          global or zoom domain: jpiglo = ', jpiglo,   &
107            &                                            ' jpjglo = ', jpjglo, ' jpk    = ', jpk
108         WRITE(numout,*) '          local domain         : jpi    = ', jpi   ,   &
109            &                                            ' jpj    = ', jpj   , ' jpk    = ', jpk
110         WRITE(numout,*)
111         WRITE(numout,*) '          south-west indices    jpizoom = ', jpizoom,   &
112            &                                           ' jpjzoom = ', jpjzoom
113         WRITE(numout,*)
114         WRITE(numout,*) '          conversion local  ==> data i-index domain'
115         WRITE(numout,25)              (mig(ji),ji = 1,jpi)
116         WRITE(numout,*)
117         WRITE(numout,*) '          conversion data   ==> local  i-index domain'
118         WRITE(numout,*) '             starting index'
119         WRITE(numout,25)              (mi0(ji),ji = 1,jpidta)
120         WRITE(numout,*) '             ending index'
121         WRITE(numout,25)              (mi1(ji),ji = 1,jpidta)
122         WRITE(numout,*)
123         WRITE(numout,*) '          conversion local  ==> data j-index domain'
124         WRITE(numout,25)              (mjg(jj),jj = 1,jpj)
125         WRITE(numout,*)
126         WRITE(numout,*) '          conversion data  ==> local j-index domain'
127         WRITE(numout,*) '             starting index'
128         WRITE(numout,25)              (mj0(jj),jj = 1,jpjdta)
129         WRITE(numout,*) '             ending index'
130         WRITE(numout,25)              (mj1(jj),jj = 1,jpjdta)
131      ENDIF
132 25   FORMAT( 100(10x,19i4,/) )
133
134      !                        ! ============== !
135      !                        !  Zoom domain   !
136      !                        ! ============== !
137      !                              ! zoom control
138      IF( jpiglo + jpizoom - 1  >  jpidta .OR.   &
139          jpjglo + jpjzoom - 1  >  jpjdta      ) &
140          &   CALL ctl_stop( ' global or zoom domain exceed the data domain ! ' )
141
142      !                              ! set zoom flag
143      IF( jpiglo < jpidta .OR. jpjglo < jpjdta )   lzoom = .TRUE.
144
145      !                              ! set zoom type flags
146      IF( lzoom .AND. jpizoom /= 1 )   lzoom_w = .TRUE.                     !
147      IF( lzoom .AND. jpjzoom /= 1 )   lzoom_s = .TRUE.
148      IF( lzoom .AND. jpiglo + jpizoom -1 /= jpidta )   lzoom_e = .TRUE.
149      IF( lzoom .AND. jpjglo + jpjzoom -1 /= jpjdta )   lzoom_n = .TRUE.
150
151      IF(lwp) THEN
152         WRITE(numout,*)
153         WRITE(numout,*) '          zoom flags : '
154         WRITE(numout,*) '             lzoom   = ', lzoom  , ' (T = zoom, F = global )'
155         WRITE(numout,*) '             lzoom_e = ', lzoom_e, ' (T = forced closed east  boundary)'
156         WRITE(numout,*) '             lzoom_w = ', lzoom_w, ' (T = forced closed west  boundary)'
157         WRITE(numout,*) '             lzoom_s = ', lzoom_s, ' (T = forced closed South boundary)'
158         WRITE(numout,*) '             lzoom_n = ', lzoom_n, ' (T = forced closed North boundary)'
159      ENDIF
160      IF(  ( lzoom_e .OR. lzoom_w )  .AND.  ( jperio == 1 .OR. jperio == 4 .OR. jperio == 6 )  )   &
161           &   CALL ctl_stop( ' Your zoom choice is inconsistent with east-west cyclic boundary condition' )
162      IF(  lzoom_n  .AND.  ( 3 <= jperio .AND. jperio <= 6 )  )   &
163           &   CALL ctl_stop( ' Your zoom choice is inconsistent with North fold boundary condition' )
164
165      !                              ! Pre-defined arctic/antarctic zoom of ORCA configuration flag
166      IF( cp_cfg == "orca" ) THEN
167         SELECT CASE ( jp_cfg )
168         CASE ( 2 )                               !  ORCA_R2 configuration
169            IF(  jpiglo  == 142    .AND. jpjglo  ==  53 .AND.   &
170               & jpizoom ==  21    .AND. jpjzoom ==  97         )   lzoom_arct = .TRUE.
171            IF(  jpiglo  == jpidta .AND. jpjglo  ==  50 .AND.   &
172               & jpizoom ==   1    .AND. jpjzoom ==   1         )   lzoom_anta = .TRUE.
173            !                             
174         CASE ( 05 )                              !  ORCA_R05 configuration
175            IF(  jpiglo  == 562    .AND. jpjglo  == 202 .AND.   &
176               & jpizoom ==  81    .AND. jpjzoom == 301         )   lzoom_arct = .TRUE.
177            IF(  jpiglo  == jpidta .AND. jpjglo  == 187 .AND.   &
178               & jpizoom ==   1    .AND. jpjzoom ==   1         )   lzoom_anta = .TRUE.
179         END SELECT
180         !
181         IF(lwp) WRITE(numout,*) '          ORCA configuration: antarctic/arctic zoom flags : '
182         IF(lwp) WRITE(numout,*) '             lzoom_arct = ', lzoom_arct, ' (T=   arctic zoom, F=global)'
183         IF(lwp) WRITE(numout,*) '             lzoom_anta = ', lzoom_anta, ' (T=antarctic zoom, F=global)'
184         !
185      ENDIF
186      !
187   END SUBROUTINE dom_glo
188
189   !!======================================================================
190END MODULE domcfg
Note: See TracBrowser for help on using the repository browser.