source: trunk/NEMOGCM/NEMO/OPA_SRC/DOM/domngb.F90 @ 2715

Last change on this file since 2715 was 2715, checked in by rblod, 10 years ago

First attempt to put dynamic allocation on the trunk

  • Property svn:keywords set to Id
File size: 4.0 KB
Line 
1MODULE domngb
2   !!======================================================================
3   !!                       ***  MODULE  domngb  ***
4   !! Grid search:  find the closest grid point from a given on/lat position
5   !!======================================================================
6   !! History : 3.2  !  2009-11  (S. Masson)  Original code
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!   dom_ngb       : find the closest grid point from a given lon/lat position
11   !!----------------------------------------------------------------------
12   USE dom_oce        ! ocean space and time domain
13   USE lib_mpp        ! for mppsum
14
15   IMPLICIT NONE
16   PRIVATE
17
18   PUBLIC   dom_ngb   ! routine called in iom.F90 module
19
20   !!----------------------------------------------------------------------
21   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
22   !! $Id$
23   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
24   !!----------------------------------------------------------------------
25CONTAINS
26
27   SUBROUTINE dom_ngb( plon, plat, kii, kjj, cdgrid )
28      !!----------------------------------------------------------------------
29      !!                    ***  ROUTINE dom_ngb  ***
30      !!
31      !! ** Purpose :   find the closest grid point from a given lon/lat position
32      !!
33      !! ** Method  :   look for minimum distance in cylindrical projection
34      !!                -> not good if located at too high latitude...
35      !!----------------------------------------------------------------------
36      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
37      USE wrk_nemo, ONLY:   zglam => wrk_2d_2 , zgphi => wrk_2d_3 , zmask => wrk_2d_4 , zdist => wrk_2d_5
38      !
39      REAL(wp)        , INTENT(in   ) ::   plon, plat   ! longitude,latitude of the point
40      INTEGER         , INTENT(  out) ::   kii, kjj     ! i-,j-index of the closes grid point
41      CHARACTER(len=1), INTENT(in   ) ::   cdgrid       ! grid name 'T', 'U', 'V', 'W'
42      !
43      INTEGER , DIMENSION(2) ::   iloc
44      REAL(wp)               ::   zlon, zmini
45      !!--------------------------------------------------------------------
46      !
47      IF( wrk_in_use(2, 2,3,4,5) )   CALL ctl_stop('dom_ngb: Requested workspaces already in use')
48      !
49      zmask(:,:) = 0._wp
50      SELECT CASE( cdgrid )
51      CASE( 'U' )  ; zglam(:,:) = glamu(:,:) ; zgphi(:,:) = gphiu(:,:) ; zmask(nldi:nlei,nldj:nlej) = umask(nldi:nlei,nldj:nlej,1)
52      CASE( 'V' )  ; zglam(:,:) = glamv(:,:) ; zgphi(:,:) = gphiv(:,:) ; zmask(nldi:nlei,nldj:nlej) = vmask(nldi:nlei,nldj:nlej,1)
53      CASE( 'F' )  ; zglam(:,:) = glamf(:,:) ; zgphi(:,:) = gphif(:,:) ; zmask(nldi:nlei,nldj:nlej) = fmask(nldi:nlei,nldj:nlej,1)
54      CASE DEFAULT ; zglam(:,:) = glamt(:,:) ; zgphi(:,:) = gphit(:,:) ; zmask(nldi:nlei,nldj:nlej) = tmask(nldi:nlei,nldj:nlej,1)
55      END SELECT
56
57      zlon       = MOD( plon       + 720., 360. )                                     ! plon between    0 and 360
58      zglam(:,:) = MOD( zglam(:,:) + 720., 360. )                                     ! glam between    0 and 360
59      IF( zlon > 270. )   zlon = zlon - 360.                                          ! zlon between  -90 and 270
60      IF( zlon <  90. )   WHERE( zglam(:,:) > 180. ) zglam(:,:) = zglam(:,:) - 360.   ! glam between -180 and 180
61
62      zglam(:,:) = zglam(:,:) - zlon
63      zgphi(:,:) = zgphi(:,:) - plat
64      zdist(:,:) = zglam(:,:) * zglam(:,:) + zgphi(:,:) * zgphi(:,:)
65     
66      IF( lk_mpp ) THEN 
67         CALL mpp_minloc( zdist(:,:), zmask, zmini, kii, kjj)
68      ELSE
69         iloc(:) = MINLOC( zdist(:,:), mask = zmask(:,:) == 1.e0 )
70         kii = iloc(1) + nimpp - 1
71         kjj = iloc(2) + njmpp - 1
72      ENDIF
73      !
74      IF( wrk_not_released(2, 2,3,4,5) )   CALL ctl_stop('dom_ngb: error releasing workspaces')
75      !
76   END SUBROUTINE dom_ngb
77
78   !!======================================================================
79END MODULE domngb
Note: See TracBrowser for help on using the repository browser.