New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynadv_cen2.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/DYN/dynadv_cen2.F90 @ 6140

Last change on this file since 6140 was 6140, checked in by timgraham, 8 years ago

Merge of branches/2015/dev_merge_2015 back into trunk. Merge excludes NEMOGCM/TOOLS/OBSTOOLS/ for now due to issues with the change of file type. Will sort these manually with further commits.

Branch merged as follows:
In the working copy of branch ran:
svn merge svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/trunk@HEAD
Small conflicts due to bug fixes applied to trunk since the dev_merge_2015 was copied. Bug fixes were applied to the branch as well so these were easy to resolve.
Branch committed at this stage

In working copy run:
svn switch svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/trunk
to switch working copy

Run:
svn merge --reintegrate svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/branches/2015/dev_merge_2015
to merge the branch into the trunk and then commit - no conflicts at this stage.

  • Property svn:keywords set to Id
File size: 7.5 KB
Line 
1MODULE dynadv_cen2
2   !!======================================================================
3   !!                       ***  MODULE  dynadv  ***
4   !! Ocean dynamics: Update the momentum trend with the flux form advection
5   !!                 using a 2nd order centred scheme
6   !!======================================================================
7   !! History :  2.0  ! 2006-08  (G. Madec, S. Theetten)  Original code
8   !!            3.2  ! 2009-07  (R. Benshila)  Suppression of rigid-lid option
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   dyn_adv_cen2  : flux form momentum advection (ln_dynadv_cen2=T) using a 2nd order centred scheme 
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers
15   USE dom_oce        ! ocean space and time domain
16   USE trd_oce        ! trends: ocean variables
17   USE trddyn         ! trend manager: dynamics
18   !
19   USE in_out_manager ! I/O manager
20   USE lib_mpp        ! MPP library
21   USE prtctl         ! Print control
22   USE wrk_nemo       ! Memory Allocation
23   USE timing         ! Timing
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   dyn_adv_cen2   ! routine called by step.F90
29
30   !! * Substitutions
31#  include "vectopt_loop_substitute.h90"
32   !!----------------------------------------------------------------------
33   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
34   !! $Id$
35   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
36   !!----------------------------------------------------------------------
37CONTAINS
38
39   SUBROUTINE dyn_adv_cen2( kt )
40      !!----------------------------------------------------------------------
41      !!                  ***  ROUTINE dyn_adv_cen2  ***
42      !!
43      !! ** Purpose :   Compute the now momentum advection trend in flux form
44      !!              and the general trend of the momentum equation.
45      !!
46      !! ** Method  :   Trend evaluated using now fields (centered in time)
47      !!
48      !! ** Action  :   (ua,va) updated with the now vorticity term trend
49      !!----------------------------------------------------------------------
50      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
51      !
52      INTEGER  ::   ji, jj, jk   ! dummy loop indices
53      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zfu_t, zfv_t, zfu_f, zfv_f, zfu_uw, zfv_vw, zfw
54      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zfu, zfv
55      !!----------------------------------------------------------------------
56      !
57      IF( nn_timing == 1 )  CALL timing_start('dyn_adv_cen2')
58      !
59      CALL wrk_alloc( jpi,jpj,jpk,   zfu_t, zfv_t, zfu_f, zfv_f, zfu_uw, zfv_vw, zfu, zfv, zfw )
60      !
61      IF( kt == nit000 .AND. lwp ) THEN
62         WRITE(numout,*)
63         WRITE(numout,*) 'dyn_adv_cen2 : 2nd order flux form momentum advection'
64         WRITE(numout,*) '~~~~~~~~~~~~'
65      ENDIF
66      !
67      IF( l_trddyn ) THEN           ! trends: store the input trends
68         zfu_uw(:,:,:) = ua(:,:,:)
69         zfv_vw(:,:,:) = va(:,:,:)
70      ENDIF
71      !
72      !                             !==  Horizontal advection  ==!
73      !
74      DO jk = 1, jpkm1                    ! horizontal transport
75         zfu(:,:,jk) = 0.25_wp * e2u(:,:) * e3u_n(:,:,jk) * un(:,:,jk)
76         zfv(:,:,jk) = 0.25_wp * e1v(:,:) * e3v_n(:,:,jk) * vn(:,:,jk)
77         DO jj = 1, jpjm1                 ! horizontal momentum fluxes (at T- and F-point)
78            DO ji = 1, fs_jpim1   ! vector opt.
79               zfu_t(ji+1,jj  ,jk) = ( zfu(ji,jj,jk) + zfu(ji+1,jj,jk) ) * ( un(ji,jj,jk) + un(ji+1,jj  ,jk) )
80               zfv_f(ji  ,jj  ,jk) = ( zfv(ji,jj,jk) + zfv(ji+1,jj,jk) ) * ( un(ji,jj,jk) + un(ji  ,jj+1,jk) )
81               zfu_f(ji  ,jj  ,jk) = ( zfu(ji,jj,jk) + zfu(ji,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji+1,jj  ,jk) )
82               zfv_t(ji  ,jj+1,jk) = ( zfv(ji,jj,jk) + zfv(ji,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji  ,jj+1,jk) )
83            END DO
84         END DO
85         DO jj = 2, jpjm1                 ! divergence of horizontal momentum fluxes
86            DO ji = fs_2, fs_jpim1   ! vector opt.
87               ua(ji,jj,jk) = ua(ji,jj,jk) - (  zfu_t(ji+1,jj,jk) - zfu_t(ji,jj  ,jk)    &
88                  &                           + zfv_f(ji  ,jj,jk) - zfv_f(ji,jj-1,jk)  ) * r1_e1e2u(ji,jj) / e3u_n(ji,jj,jk)
89               va(ji,jj,jk) = va(ji,jj,jk) - (  zfu_f(ji,jj  ,jk) - zfu_f(ji-1,jj,jk)    &
90                  &                           + zfv_t(ji,jj+1,jk) - zfv_t(ji  ,jj,jk)  ) * r1_e1e2v(ji,jj) / e3v_n(ji,jj,jk)
91            END DO
92         END DO
93      END DO
94      !
95      IF( l_trddyn ) THEN           ! trends: send trend to trddyn for diagnostic
96         zfu_uw(:,:,:) = ua(:,:,:) - zfu_uw(:,:,:)
97         zfv_vw(:,:,:) = va(:,:,:) - zfv_vw(:,:,:)
98         CALL trd_dyn( zfu_uw, zfv_vw, jpdyn_keg, kt )
99         zfu_t(:,:,:) = ua(:,:,:)
100         zfv_t(:,:,:) = va(:,:,:)
101      ENDIF
102      !
103      !                             !==  Vertical advection  ==!
104      !
105      DO jj = 2, jpjm1                    ! surface/bottom advective fluxes set to zero
106         DO ji = fs_2, fs_jpim1
107            zfu_uw(ji,jj,jpk) = 0._wp   ;   zfv_vw(jj,jj,jpk) = 0._wp
108            zfu_uw(ji,jj, 1 ) = 0._wp   ;   zfv_vw(jj,jj, 1 ) = 0._wp
109         END DO
110      END DO
111      IF( ln_linssh ) THEN                ! linear free surface: advection through the surface
112         DO jj = 2, jpjm1
113            DO ji = fs_2, fs_jpim1
114               zfu_uw(ji,jj,1) = 0.5_wp * ( e1e2t(ji,jj) * wn(ji,jj,1) + e1e2t(ji+1,jj) * wn(ji+1,jj,1) ) * un(ji,jj,1)
115               zfv_vw(ji,jj,1) = 0.5_wp * ( e1e2t(ji,jj) * wn(ji,jj,1) + e1e2t(ji,jj+1) * wn(ji,jj+1,1) ) * vn(ji,jj,1)
116            END DO
117         END DO
118      ENDIF
119      DO jk = 2, jpkm1                    ! interior advective fluxes
120         DO jj = 2, jpjm1                       ! 1/4 * Vertical transport
121            DO ji = fs_2, fs_jpim1
122               zfw(ji,jj,jk) = 0.25_wp * e1e2t(ji,jj) * wn(ji,jj,jk)
123            END DO
124         END DO
125         DO jj = 2, jpjm1
126            DO ji = fs_2, fs_jpim1   ! vector opt.
127               zfu_uw(ji,jj,jk) = ( zfw(ji,jj,jk) + zfw(ji+1,jj  ,jk) ) * ( un(ji,jj,jk) + un(ji,jj,jk-1) )
128               zfv_vw(ji,jj,jk) = ( zfw(ji,jj,jk) + zfw(ji  ,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji,jj,jk-1) )
129            END DO
130         END DO
131      END DO
132      DO jk = 1, jpkm1                    ! divergence of vertical momentum flux divergence
133         DO jj = 2, jpjm1 
134            DO ji = fs_2, fs_jpim1   ! vector opt.
135               ua(ji,jj,jk) = ua(ji,jj,jk) - ( zfu_uw(ji,jj,jk) - zfu_uw(ji,jj,jk+1) ) * r1_e1e2u(ji,jj) / e3u_n(ji,jj,jk)
136               va(ji,jj,jk) = va(ji,jj,jk) - ( zfv_vw(ji,jj,jk) - zfv_vw(ji,jj,jk+1) ) * r1_e1e2v(ji,jj) / e3v_n(ji,jj,jk)
137            END DO
138         END DO
139      END DO
140      !
141      IF( l_trddyn ) THEN                 ! trends: send trend to trddyn for diagnostic
142         zfu_t(:,:,:) = ua(:,:,:) - zfu_t(:,:,:)
143         zfv_t(:,:,:) = va(:,:,:) - zfv_t(:,:,:)
144         CALL trd_dyn( zfu_t, zfv_t, jpdyn_zad, kt )
145      ENDIF
146      !                                   ! Control print
147      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' cen2 adv - Ua: ', mask1=umask,   &
148         &                       tab3d_2=va, clinfo2=           ' Va: ', mask2=vmask, clinfo3='dyn' )
149      !
150      CALL wrk_dealloc( jpi, jpj, jpk, zfu_t, zfv_t, zfu_f, zfv_f, zfu_uw, zfv_vw, zfu, zfv, zfw )
151      !
152      IF( nn_timing == 1 )  CALL timing_stop('dyn_adv_cen2')
153      !
154   END SUBROUTINE dyn_adv_cen2
155
156   !!==============================================================================
157END MODULE dynadv_cen2
Note: See TracBrowser for help on using the repository browser.