New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynkeg.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/DYN/dynkeg.F90 @ 7753

Last change on this file since 7753 was 7753, checked in by mocavero, 7 years ago

Reverting trunk to remove OpenMP

  • Property svn:keywords set to Id
File size: 9.0 KB
Line 
1MODULE dynkeg
2   !!======================================================================
3   !!                       ***  MODULE  dynkeg  ***
4   !! Ocean dynamics:  kinetic energy gradient trend
5   !!======================================================================
6   !! History :  1.0  !  1987-09  (P. Andrich, M.-A. Foujols)  Original code
7   !!            7.0  !  1997-05  (G. Madec)  Split dynber into dynkeg and dynhpg
8   !!  NEMO      1.0  !  2002-07  (G. Madec)  F90: Free form and module
9   !!            3.6  !  2015-05  (N. Ducousso, G. Madec)  add Hollingsworth scheme as an option
10   !!----------------------------------------------------------------------
11   
12   !!----------------------------------------------------------------------
13   !!   dyn_keg      : update the momentum trend with the horizontal tke
14   !!----------------------------------------------------------------------
15   USE oce             ! ocean dynamics and tracers
16   USE dom_oce         ! ocean space and time domain
17   USE trd_oce         ! trends: ocean variables
18   USE trddyn          ! trend manager: dynamics
19   !
20   USE in_out_manager  ! I/O manager
21   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
22   USE lib_mpp         ! MPP library
23   USE prtctl          ! Print control
24   USE wrk_nemo        ! Memory Allocation
25   USE timing          ! Timing
26   USE bdy_oce         ! ocean open boundary conditions
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   dyn_keg    ! routine called by step module
32   
33   INTEGER, PARAMETER, PUBLIC  ::   nkeg_C2  = 0   !: 2nd order centered scheme (standard scheme)
34   INTEGER, PARAMETER, PUBLIC  ::   nkeg_HW  = 1   !: Hollingsworth et al., QJRMS, 1983
35   !
36   REAL(wp) ::   r1_48 = 1._wp / 48._wp   !: =1/(4*2*6)
37   
38   !! * Substitutions
39#  include "vectopt_loop_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/OPA 3.6 , NEMO Consortium (2015)
42   !! $Id$
43   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE dyn_keg( kt, kscheme )
48      !!----------------------------------------------------------------------
49      !!                  ***  ROUTINE dyn_keg  ***
50      !!
51      !! ** Purpose :   Compute the now momentum trend due to the horizontal
52      !!      gradient of the horizontal kinetic energy and add it to the
53      !!      general momentum trend.
54      !!
55      !! ** Method  : * kscheme = nkeg_C2 : 2nd order centered scheme that
56      !!      conserve kinetic energy. Compute the now horizontal kinetic energy
57      !!         zhke = 1/2 [ mi-1( un^2 ) + mj-1( vn^2 ) ]
58      !!              * kscheme = nkeg_HW : Hollingsworth correction following
59      !!      Arakawa (2001). The now horizontal kinetic energy is given by:
60      !!         zhke = 1/6 [ mi-1(  2 * un^2 + ((un(j+1)+un(j-1))/2)^2  )
61      !!                    + mj-1(  2 * vn^2 + ((vn(i+1)+vn(i-1))/2)^2  ) ]
62      !!     
63      !!      Take its horizontal gradient and add it to the general momentum
64      !!      trend (ua,va).
65      !!         ua = ua - 1/e1u di[ zhke ]
66      !!         va = va - 1/e2v dj[ zhke ]
67      !!
68      !! ** Action : - Update the (ua, va) with the hor. ke gradient trend
69      !!             - send this trends to trd_dyn (l_trddyn=T) for post-processing
70      !!
71      !! ** References : Arakawa, A., International Geophysics 2001.
72      !!                 Hollingsworth et al., Quart. J. Roy. Meteor. Soc., 1983.
73      !!----------------------------------------------------------------------
74      INTEGER, INTENT( in ) ::   kt        ! ocean time-step index
75      INTEGER, INTENT( in ) ::   kscheme   ! =0/1   type of KEG scheme
76      !
77      INTEGER  ::   ji, jj, jk   ! dummy loop indices
78      REAL(wp) ::   zu, zv       ! temporary scalars
79      REAL(wp), POINTER, DIMENSION(:,:,:) :: zhke
80      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdu, ztrdv 
81      INTEGER  ::   jb                 ! dummy loop indices
82      INTEGER  ::   ii, ij, igrd, ib_bdy   ! local integers
83      INTEGER  ::   fu, fv
84      !!----------------------------------------------------------------------
85      !
86      IF( nn_timing == 1 )   CALL timing_start('dyn_keg')
87      !
88      CALL wrk_alloc( jpi,jpj,jpk,   zhke )
89      !
90      IF( kt == nit000 ) THEN
91         IF(lwp) WRITE(numout,*)
92         IF(lwp) WRITE(numout,*) 'dyn_keg : kinetic energy gradient trend, scheme number=', kscheme
93         IF(lwp) WRITE(numout,*) '~~~~~~~'
94      ENDIF
95
96      IF( l_trddyn ) THEN           ! Save ua and va trends
97         CALL wrk_alloc( jpi,jpj,jpk,   ztrdu, ztrdv )
98         ztrdu(:,:,:) = ua(:,:,:) 
99         ztrdv(:,:,:) = va(:,:,:) 
100      ENDIF
101     
102      zhke(:,:,jpk) = 0._wp
103     
104      IF (ln_bdy) THEN
105         ! Maria Luneva & Fred Wobus: July-2016
106         ! compensate for lack of turbulent kinetic energy on liquid bdy points
107         DO ib_bdy = 1, nb_bdy
108            IF( cn_dyn3d(ib_bdy) /= 'none' ) THEN
109               igrd = 2           ! Copying normal velocity into points outside bdy
110               DO jb = 1, idx_bdy(ib_bdy)%nblenrim(igrd)
111                  DO jk = 1, jpkm1
112                     ii   = idx_bdy(ib_bdy)%nbi(jb,igrd)
113                     ij   = idx_bdy(ib_bdy)%nbj(jb,igrd)
114                     fu   = NINT( idx_bdy(ib_bdy)%flagu(jb,igrd) )
115                     un(ii-fu,ij,jk) = un(ii,ij,jk) * umask(ii,ij,jk)
116                  END DO
117               END DO
118               !
119               igrd = 3           ! Copying normal velocity into points outside bdy
120               DO jb = 1, idx_bdy(ib_bdy)%nblenrim(igrd)
121                  DO jk = 1, jpkm1
122                     ii   = idx_bdy(ib_bdy)%nbi(jb,igrd)
123                     ij   = idx_bdy(ib_bdy)%nbj(jb,igrd)
124                     fv   = NINT( idx_bdy(ib_bdy)%flagv(jb,igrd) )
125                     vn(ii,ij-fv,jk) = vn(ii,ij,jk) * vmask(ii,ij,jk)
126                  END DO
127               END DO
128            ENDIF
129         ENDDO 
130      ENDIF
131
132      SELECT CASE ( kscheme )             !== Horizontal kinetic energy at T-point  ==!
133      !
134      CASE ( nkeg_C2 )                          !--  Standard scheme  --!
135         DO jk = 1, jpkm1
136            DO jj = 2, jpj
137               DO ji = fs_2, jpi   ! vector opt.
138                  zu =    un(ji-1,jj  ,jk) * un(ji-1,jj  ,jk)   &
139                     &  + un(ji  ,jj  ,jk) * un(ji  ,jj  ,jk)
140                  zv =    vn(ji  ,jj-1,jk) * vn(ji  ,jj-1,jk)   &
141                     &  + vn(ji  ,jj  ,jk) * vn(ji  ,jj  ,jk)
142                  zhke(ji,jj,jk) = 0.25_wp * ( zv + zu )
143               END DO 
144            END DO
145         END DO
146         !
147      CASE ( nkeg_HW )                          !--  Hollingsworth scheme  --!
148         DO jk = 1, jpkm1
149            DO jj = 2, jpjm1       
150               DO ji = fs_2, jpim1   ! vector opt.
151                  zu = 8._wp * ( un(ji-1,jj  ,jk) * un(ji-1,jj  ,jk)    &
152                     &         + un(ji  ,jj  ,jk) * un(ji  ,jj  ,jk) )  &
153                     &   +     ( un(ji-1,jj-1,jk) + un(ji-1,jj+1,jk) ) * ( un(ji-1,jj-1,jk) + un(ji-1,jj+1,jk) )   &
154                     &   +     ( un(ji  ,jj-1,jk) + un(ji  ,jj+1,jk) ) * ( un(ji  ,jj-1,jk) + un(ji  ,jj+1,jk) )
155                     !
156                  zv = 8._wp * ( vn(ji  ,jj-1,jk) * vn(ji  ,jj-1,jk)    &
157                     &         + vn(ji  ,jj  ,jk) * vn(ji  ,jj  ,jk) )  &
158                     &  +      ( vn(ji-1,jj-1,jk) + vn(ji+1,jj-1,jk) ) * ( vn(ji-1,jj-1,jk) + vn(ji+1,jj-1,jk) )   &
159                     &  +      ( vn(ji-1,jj  ,jk) + vn(ji+1,jj  ,jk) ) * ( vn(ji-1,jj  ,jk) + vn(ji+1,jj  ,jk) )
160                  zhke(ji,jj,jk) = r1_48 * ( zv + zu )
161               END DO 
162            END DO
163         END DO
164         CALL lbc_lnk( zhke, 'T', 1. )
165         !
166      END SELECT
167
168      IF (ln_bdy) THEN
169         ! restore velocity masks at points outside boundary
170         un(:,:,:) = un(:,:,:) * umask(:,:,:)
171         vn(:,:,:) = vn(:,:,:) * vmask(:,:,:)
172      ENDIF     
173
174
175      !
176      DO jk = 1, jpkm1                    !==  grad( KE ) added to the general momentum trends  ==!
177         DO jj = 2, jpjm1
178            DO ji = fs_2, fs_jpim1   ! vector opt.
179               ua(ji,jj,jk) = ua(ji,jj,jk) - ( zhke(ji+1,jj  ,jk) - zhke(ji,jj,jk) ) / e1u(ji,jj)
180               va(ji,jj,jk) = va(ji,jj,jk) - ( zhke(ji  ,jj+1,jk) - zhke(ji,jj,jk) ) / e2v(ji,jj)
181            END DO
182         END DO
183      END DO
184      !
185      IF( l_trddyn ) THEN                 ! save the Kinetic Energy trends for diagnostic
186         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
187         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
188         CALL trd_dyn( ztrdu, ztrdv, jpdyn_keg, kt )
189         CALL wrk_dealloc( jpi,jpj,jpk,   ztrdu, ztrdv )
190      ENDIF
191      !
192      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' keg  - Ua: ', mask1=umask,   &
193         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
194      !
195      CALL wrk_dealloc( jpi,jpj,jpk,   zhke )
196      !
197      IF( nn_timing == 1 )   CALL timing_stop('dyn_keg')
198      !
199   END SUBROUTINE dyn_keg
200
201   !!======================================================================
202END MODULE dynkeg
Note: See TracBrowser for help on using the repository browser.