New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynspg.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/DYN/dynspg.F90 @ 7698

Last change on this file since 7698 was 7698, checked in by mocavero, 7 years ago

update trunk with OpenMP parallelization
  • Property svn:keywords set to Id
File size: 12.8 KB
Line 
1MODULE dynspg
2   !!======================================================================
3   !!                       ***  MODULE  dynspg  ***
4   !! Ocean dynamics:  surface pressure gradient control
5   !!======================================================================
6   !! History :  1.0  ! 2005-12  (C. Talandier, G. Madec, V. Garnier)  Original code
7   !!            3.2  ! 2009-07  (R. Benshila)  Suppression of rigid-lid option
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   dyn_spg     : update the dynamics trend with surface pressure gradient
12   !!   dyn_spg_init: initialization, namelist read, and parameters control
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers variables
15   USE dom_oce        ! ocean space and time domain variables
16   USE c1d            ! 1D vertical configuration
17   USE phycst         ! physical constants
18   USE sbc_oce        ! surface boundary condition: ocean
19   USE sbcapr         ! surface boundary condition: atmospheric pressure
20   USE dynspg_exp     ! surface pressure gradient     (dyn_spg_exp routine)
21   USE dynspg_ts      ! surface pressure gradient     (dyn_spg_ts  routine)
22   USE sbctide        !
23   USE updtide        !
24   USE trd_oce        ! trends: ocean variables
25   USE trddyn         ! trend manager: dynamics
26   !
27   USE prtctl         ! Print control                     (prt_ctl routine)
28   USE in_out_manager ! I/O manager
29   USE lib_mpp        ! MPP library
30   USE wrk_nemo       ! Memory Allocation
31   USE timing         ! Timing
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   dyn_spg        ! routine called by step module
37   PUBLIC   dyn_spg_init   ! routine called by opa module
38
39   INTEGER ::   nspg = 0   ! type of surface pressure gradient scheme defined from lk_dynspg_...
40
41   !                       ! Parameter to control the surface pressure gradient scheme
42   INTEGER, PARAMETER ::   np_TS  = 1   ! split-explicit time stepping (Time-Splitting)
43   INTEGER, PARAMETER ::   np_EXP = 0   !       explicit time stepping
44   INTEGER, PARAMETER ::   np_NO  =-1   ! no surface pressure gradient, no scheme
45
46   !! * Substitutions
47#  include "vectopt_loop_substitute.h90"
48   !!----------------------------------------------------------------------
49   !! NEMO/OPA 3.2 , LODYC-IPSL  (2009)
50   !! $Id$
51   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
52   !!----------------------------------------------------------------------
53CONTAINS
54
55   SUBROUTINE dyn_spg( kt )
56      !!----------------------------------------------------------------------
57      !!                  ***  ROUTINE dyn_spg  ***
58      !!
59      !! ** Purpose :   compute surface pressure gradient including the
60      !!              atmospheric pressure forcing (ln_apr_dyn=T).
61      !!
62      !! ** Method  :   Two schemes:
63      !!              - explicit       : the spg is evaluated at now
64      !!              - split-explicit : a time splitting technique is used
65      !!
66      !!              ln_apr_dyn=T : the atmospheric pressure forcing is applied
67      !!             as the gradient of the inverse barometer ssh:
68      !!                apgu = - 1/rau0 di[apr] = 0.5*grav di[ssh_ib+ssh_ibb]
69      !!                apgv = - 1/rau0 dj[apr] = 0.5*grav dj[ssh_ib+ssh_ibb]
70      !!             Note that as all external forcing a time averaging over a two rdt
71      !!             period is used to prevent the divergence of odd and even time step.
72      !!----------------------------------------------------------------------
73      INTEGER, INTENT(in   ) ::   kt       ! ocean time-step index
74      !
75      INTEGER  ::   ji, jj, jk                             ! dummy loop indices
76      REAL(wp) ::   z2dt, zg_2, zintp, zgrau0r             ! temporary scalar
77      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
78      REAL(wp), POINTER, DIMENSION(:,:)   ::  zpice
79      !!----------------------------------------------------------------------
80      !
81      IF( nn_timing == 1 )  CALL timing_start('dyn_spg')
82      !
83      IF( l_trddyn )   THEN                      ! temporary save of ta and sa trends
84         CALL wrk_alloc( jpi,jpj,jpk,   ztrdu, ztrdv ) 
85!$OMP PARALLEL DO schedule(static) private(jk, jj, ji)
86        DO jk = 1, jpk
87           DO jj = 1, jpj
88              DO ji = 1, jpi
89                 ztrdu(ji,jj,jk) = ua(ji,jj,jk)
90                 ztrdv(ji,jj,jk) = va(ji,jj,jk)
91              END DO
92           END DO
93        END DO
94      ENDIF
95      !
96      IF(      ln_apr_dyn                                                &   ! atmos. pressure
97         .OR.  ( .NOT.ln_dynspg_ts .AND. (ln_tide_pot .AND. ln_tide) )   &   ! tide potential (no time slitting)
98         .OR.  nn_ice_embd == 2  ) THEN                                      ! embedded sea-ice
99         !
100!$OMP PARALLEL DO schedule(static) private(jj, ji)
101         DO jj = 2, jpjm1
102            DO ji = fs_2, fs_jpim1   ! vector opt.
103               spgu(ji,jj) = 0._wp
104               spgv(ji,jj) = 0._wp
105            END DO
106         END DO         
107         !
108         IF( ln_apr_dyn .AND. .NOT.ln_dynspg_ts ) THEN   !==  Atmospheric pressure gradient (added later in time-split case) ==!
109            zg_2 = grav * 0.5
110!$OMP PARALLEL DO schedule(static) private(jj, ji)
111            DO jj = 2, jpjm1                          ! gradient of Patm using inverse barometer ssh
112               DO ji = fs_2, fs_jpim1   ! vector opt.
113                  spgu(ji,jj) = spgu(ji,jj) + zg_2 * (  ssh_ib (ji+1,jj) - ssh_ib (ji,jj)    &
114                     &                      + ssh_ibb(ji+1,jj) - ssh_ibb(ji,jj)  ) * r1_e1u(ji,jj)
115                  spgv(ji,jj) = spgv(ji,jj) + zg_2 * (  ssh_ib (ji,jj+1) - ssh_ib (ji,jj)    &
116                     &                      + ssh_ibb(ji,jj+1) - ssh_ibb(ji,jj)  ) * r1_e2v(ji,jj)
117               END DO
118            END DO
119         ENDIF
120         !
121         !                                    !==  tide potential forcing term  ==!
122         IF( .NOT.ln_dynspg_ts .AND. ( ln_tide_pot .AND. ln_tide )  ) THEN   ! N.B. added directly at sub-time-step in ts-case
123            !
124            CALL upd_tide( kt )                      ! update tide potential
125            !
126!$OMP PARALLEL DO schedule(static) private(jj, ji)
127            DO jj = 2, jpjm1                         ! add tide potential forcing
128               DO ji = fs_2, fs_jpim1   ! vector opt.
129                  spgu(ji,jj) = spgu(ji,jj) + grav * ( pot_astro(ji+1,jj) - pot_astro(ji,jj) ) * r1_e1u(ji,jj)
130                  spgv(ji,jj) = spgv(ji,jj) + grav * ( pot_astro(ji,jj+1) - pot_astro(ji,jj) ) * r1_e2v(ji,jj)
131               END DO
132            END DO
133         ENDIF
134         !
135         IF( nn_ice_embd == 2 ) THEN          !== embedded sea ice: Pressure gradient due to snow-ice mass ==!
136            CALL wrk_alloc( jpi,jpj,   zpice )
137            !                                           
138            zintp = REAL( MOD( kt-1, nn_fsbc ) ) / REAL( nn_fsbc )
139            zgrau0r     = - grav * r1_rau0
140!$OMP PARALLEL
141!$OMP DO schedule(static) private(jj, ji)
142            DO jj = 1, jpj
143               DO ji = 1, jpi
144                  zpice(ji,jj) = (  zintp * snwice_mass(ji,jj) + ( 1.- zintp ) * snwice_mass_b(ji,jj)  ) * zgrau0r
145               END DO
146            END DO
147!$OMP DO schedule(static) private(jj, ji)
148            DO jj = 2, jpjm1
149               DO ji = fs_2, fs_jpim1   ! vector opt.
150                  spgu(ji,jj) = spgu(ji,jj) + ( zpice(ji+1,jj) - zpice(ji,jj) ) * r1_e1u(ji,jj)
151                  spgv(ji,jj) = spgv(ji,jj) + ( zpice(ji,jj+1) - zpice(ji,jj) ) * r1_e2v(ji,jj)
152               END DO
153            END DO
154!$OMP END PARALLEL
155            !
156            CALL wrk_dealloc( jpi,jpj,   zpice )         
157         ENDIF
158         !
159!$OMP PARALLEL DO schedule(static) private(jk, jj, ji)
160         DO jk = 1, jpkm1                    !== Add all terms to the general trend
161            DO jj = 2, jpjm1
162               DO ji = fs_2, fs_jpim1   ! vector opt.
163                  ua(ji,jj,jk) = ua(ji,jj,jk) + spgu(ji,jj)
164                  va(ji,jj,jk) = va(ji,jj,jk) + spgv(ji,jj)
165               END DO
166            END DO
167         END DO   
168         !
169!!gm add here a call to dyn_trd for ice pressure gradient, the surf pressure trends ????
170         !   
171      ENDIF
172      !
173      SELECT CASE ( nspg )                   !== surface pressure gradient computed and add to the general trend ==!
174      CASE ( np_EXP )   ;   CALL dyn_spg_exp( kt )              ! explicit
175      CASE ( np_TS  )   ;   CALL dyn_spg_ts ( kt )              ! time-splitting
176      END SELECT
177      !                   
178      IF( l_trddyn )   THEN                  ! save the surface pressure gradient trends for further diagnostics
179!$OMP PARALLEL DO schedule(static) private(jk, jj, ji)
180           DO jk = 1, jpk
181              DO jj = 1, jpj
182                 DO ji = 1, jpi
183                    ztrdu(ji,jj,jk) = ua(ji,jj,jk) - ztrdu(ji,jj,jk)
184                    ztrdv(ji,jj,jk) = va(ji,jj,jk) - ztrdv(ji,jj,jk)
185                 END DO
186              END DO
187           END DO
188         CALL trd_dyn( ztrdu, ztrdv, jpdyn_spg, kt )
189         CALL wrk_dealloc( jpi,jpj,jpk,   ztrdu, ztrdv ) 
190      ENDIF
191      !                                      ! print mean trends (used for debugging)
192      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' spg  - Ua: ', mask1=umask, &
193         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
194      !
195      IF( nn_timing == 1 )  CALL timing_stop('dyn_spg')
196      !
197   END SUBROUTINE dyn_spg
198
199
200   SUBROUTINE dyn_spg_init
201      !!---------------------------------------------------------------------
202      !!                  ***  ROUTINE dyn_spg_init  ***
203      !!               
204      !! ** Purpose :   Control the consistency between namelist options for
205      !!              surface pressure gradient schemes
206      !!----------------------------------------------------------------------
207      INTEGER ::   ioptio, ios   ! local integers
208      !
209      NAMELIST/namdyn_spg/ ln_dynspg_exp       , ln_dynspg_ts,   &
210      &                    ln_bt_fw, ln_bt_av  , ln_bt_auto  ,   &
211      &                    nn_baro , rn_bt_cmax, nn_bt_flt
212      !!----------------------------------------------------------------------
213      !
214      IF( nn_timing == 1 )  CALL timing_start('dyn_spg_init')
215      !
216      REWIND( numnam_ref )              ! Namelist namdyn_spg in reference namelist : Free surface
217      READ  ( numnam_ref, namdyn_spg, IOSTAT = ios, ERR = 901)
218901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdyn_spg in reference namelist', lwp )
219      !
220      REWIND( numnam_cfg )              ! Namelist namdyn_spg in configuration namelist : Free surface
221      READ  ( numnam_cfg, namdyn_spg, IOSTAT = ios, ERR = 902 )
222902   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdyn_spg in configuration namelist', lwp )
223      IF(lwm) WRITE ( numond, namdyn_spg )
224      !
225      IF(lwp) THEN             ! Namelist print
226         WRITE(numout,*)
227         WRITE(numout,*) 'dyn_spg_init : choice of the surface pressure gradient scheme'
228         WRITE(numout,*) '~~~~~~~~~~~'
229         WRITE(numout,*) '     Explicit free surface                  ln_dynspg_exp = ', ln_dynspg_exp
230         WRITE(numout,*) '     Free surface with time splitting       ln_dynspg_ts  = ', ln_dynspg_ts
231      ENDIF
232      !                          ! Control of surface pressure gradient scheme options
233                                     nspg =  np_NO    ;   ioptio = 0
234      IF( ln_dynspg_exp ) THEN   ;   nspg =  np_EXP   ;   ioptio = ioptio + 1   ;   ENDIF
235      IF( ln_dynspg_ts  ) THEN   ;   nspg =  np_TS    ;   ioptio = ioptio + 1   ;   ENDIF
236      !
237      IF( ioptio  > 1 )   CALL ctl_stop( 'Choose only one surface pressure gradient scheme' )
238      IF( ioptio == 0 )   CALL ctl_warn( 'NO surface pressure gradient trend in momentum Eqs.' )
239      IF( ln_dynspg_exp .AND. ln_isfcav )   &
240           &   CALL ctl_stop( ' dynspg_exp not tested with ice shelf cavity ' )
241      !
242      IF(lwp) THEN
243         WRITE(numout,*)
244         IF( nspg == np_EXP )   WRITE(numout,*) '      ===>>   explicit free surface'
245         IF( nspg == np_TS  )   WRITE(numout,*) '      ===>>   free surface with time splitting scheme'
246         IF( nspg == np_NO  )   WRITE(numout,*) '      ===>>   No surface surface pressure gradient trend in momentum Eqs.'
247      ENDIF
248      !
249      IF( nspg == np_TS ) THEN   ! split-explicit scheme initialisation
250         CALL dyn_spg_ts_init          ! do it first: set nn_baro used to allocate some arrays later on
251         IF( dyn_spg_ts_alloc() /= 0  )   CALL ctl_stop('STOP', 'dyn_spg_init: failed to allocate dynspg_ts  arrays' )
252         IF( neuler/=0 .AND. ln_bt_fw )   CALL ts_rst( nit000, 'READ' )
253      ENDIF
254      !
255      IF( nn_timing == 1 )  CALL timing_stop('dyn_spg_init')
256      !
257   END SUBROUTINE dyn_spg_init
258
259  !!======================================================================
260END MODULE dynspg
Note: See TracBrowser for help on using the repository browser.