source: trunk/NEMOGCM/NEMO/OPA_SRC/IOM/iom_nf90.F90 @ 7881

Last change on this file since 7881 was 7646, checked in by timgraham, 4 years ago

Merge of dev_merge_2016 into trunk. UPDATE TO ARCHFILES NEEDED for XIOS2.
LIM_SRC_s/limrhg.F90 to follow in next commit due to change of kind (I'm unable to do it in this commit).
Merged using the following steps:

1) svn merge —reintegrate svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/trunk .
2) Resolve minor conflicts in sette.sh and namelist_cfg for ORCA2LIM3 (due to a change in trunk after branch was created)
3) svn commit
4) svn switch svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/trunk
5) svn merge svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/branches/2016/dev_merge_2016 .
6) At this stage I checked out a clean copy of the branch to compare against what is about to be committed to the trunk.
6) svn commit #Commit code to the trunk

In this commit I have also reverted a change to Fcheck_archfile.sh which was causing problems on the Paris machine.

  • Property svn:keywords set to Id
File size: 47.6 KB
Line 
1MODULE iom_nf90
2   !!=====================================================================
3   !!                    ***  MODULE  iom_nf90 ***
4   !! Input/Output manager :  Library to read input files with NF90 (only fliocom module)
5   !!====================================================================
6   !! History :  9.0  ! 05 12  (J. Belier) Original code
7   !!            9.0  ! 06 02  (S. Masson) Adaptation to NEMO
8   !!             "   ! 07 07  (D. Storkey) Changes to iom_nf90_gettime
9   !!            3.6  ! 2015-15  (J. Harle) Added procedure to read REAL attributes
10   !!--------------------------------------------------------------------
11   !!gm  caution add !DIR nec: improved performance to be checked as well as no result changes
12
13   !!--------------------------------------------------------------------
14   !!   iom_open       : open a file read only
15   !!   iom_close      : close a file or all files opened by iom
16   !!   iom_get        : read a field (interfaced to several routines)
17   !!   iom_gettime    : read the time axis kvid in the file
18   !!   iom_varid      : get the id of a variable in a file
19   !!   iom_rstput     : write a field in a restart file (interfaced to several routines)
20   !!--------------------------------------------------------------------
21   USE dom_oce         ! ocean space and time domain
22   USE lbclnk          ! lateal boundary condition / mpp exchanges
23   USE iom_def         ! iom variables definitions
24   USE netcdf          ! NetCDF library
25   USE in_out_manager  ! I/O manager
26   USE lib_mpp         ! MPP library
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC iom_nf90_open, iom_nf90_close, iom_nf90_varid, iom_nf90_get, iom_nf90_gettime, iom_nf90_rstput
32   PUBLIC iom_nf90_getatt, iom_nf90_putatt
33
34   INTERFACE iom_nf90_get
35      MODULE PROCEDURE iom_nf90_g0d, iom_nf90_g123d
36   END INTERFACE
37   INTERFACE iom_nf90_getatt
38      MODULE PROCEDURE iom_nf90_giatt, iom_nf90_gratt, iom_nf90_gcatt
39   END INTERFACE
40   INTERFACE iom_nf90_putatt
41      MODULE PROCEDURE iom_nf90_piatt, iom_nf90_pratt, iom_nf90_pcatt
42   END INTERFACE
43   INTERFACE iom_nf90_rstput
44      MODULE PROCEDURE iom_nf90_rp0123d
45   END INTERFACE
46
47   !!----------------------------------------------------------------------
48   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
49   !! $Id$
50   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
51   !!----------------------------------------------------------------------
52
53CONTAINS
54
55   SUBROUTINE iom_nf90_open( cdname, kiomid, ldwrt, ldok, kdompar )
56      !!---------------------------------------------------------------------
57      !!                   ***  SUBROUTINE  iom_open  ***
58      !!
59      !! ** Purpose : open an input file with NF90
60      !!---------------------------------------------------------------------
61      CHARACTER(len=*)       , INTENT(inout)           ::   cdname      ! File name
62      INTEGER                , INTENT(  out)           ::   kiomid      ! nf90 identifier of the opened file
63      LOGICAL                , INTENT(in   )           ::   ldwrt       ! read or write the file?
64      LOGICAL                , INTENT(in   )           ::   ldok        ! check the existence
65      INTEGER, DIMENSION(2,5), INTENT(in   ), OPTIONAL ::   kdompar     ! domain parameters:
66
67      CHARACTER(LEN=256) ::   clinfo           ! info character
68      CHARACTER(LEN=256) ::   cltmp            ! temporary character
69      INTEGER            ::   iln              ! lengths of character
70      INTEGER            ::   istop            ! temporary storage of nstop
71      INTEGER            ::   if90id           ! nf90 identifier of the opened file
72      INTEGER            ::   idmy             ! dummy variable
73      INTEGER            ::   jl               ! loop variable
74      INTEGER            ::   ichunk           ! temporary storage of nn_chunksz
75      INTEGER            ::   imode            ! creation mode flag: NF90_CLOBBER or NF90_NOCLOBBER or NF90_HDF5
76      INTEGER            ::   ihdf5            ! local variable for retrieval of value for NF90_HDF5
77      LOGICAL            ::   llclobber        ! local definition of ln_clobber
78      !---------------------------------------------------------------------
79
80      clinfo = '                    iom_nf90_open ~~~  '
81      istop = nstop   ! store the actual value of nstop
82      IF( nn_chunksz > 0 ) THEN   ;   ichunk = nn_chunksz
83      ELSE                        ;   ichunk = NF90_SIZEHINT_DEFAULT
84      ENDIF
85      !
86      llclobber = ldwrt .AND. ln_clobber
87      IF( ldok .AND. .NOT. llclobber ) THEN      ! Open existing file...
88         !                 ! =============
89         IF( ldwrt ) THEN  ! ... in write mode
90            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in WRITE mode'
91            IF( snc4set%luse ) THEN
92               CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_WRITE  , if90id ), clinfo)
93            ELSE
94               CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_WRITE  , if90id, chunksize = ichunk ), clinfo)
95            ENDIF
96            CALL iom_nf90_check(NF90_SET_FILL( if90id, NF90_NOFILL, idmy                          ), clinfo)
97         ELSE              ! ... in read mode
98            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in READ mode'
99            CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_NOWRITE, if90id, chunksize = ichunk ), clinfo)
100         ENDIF
101      ELSE                                       ! the file does not exist (or we overwrite it)
102         !                 ! =============
103         iln = INDEX( cdname, '.nc' )
104         IF( ldwrt ) THEN  ! the file should be open in write mode so we create it...
105            IF( jpnij > 1 ) THEN
106               WRITE(cltmp,'(a,a,i4.4,a)') cdname(1:iln-1), '_', narea-1, '.nc'
107               cdname = TRIM(cltmp)
108            ENDIF
109            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' create new file: '//TRIM(cdname)//' in WRITE mode'
110
111            IF( llclobber ) THEN   ;   imode = IOR( NF90_64BIT_OFFSET, NF90_CLOBBER   )
112            ELSE                   ;   imode = IOR( NF90_64BIT_OFFSET, NF90_NOCLOBBER ) 
113            ENDIF
114            IF( snc4set%luse ) THEN
115               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' creating file: '//TRIM(cdname)//' in hdf5 (netcdf4) mode'
116               CALL GET_NF90_SYMBOL("NF90_HDF5", ihdf5)
117               IF( llclobber ) THEN   ;   imode = IOR(ihdf5, NF90_CLOBBER)
118               ELSE                   ;   imode = IOR(ihdf5, NF90_NOCLOBBER)
119               ENDIF
120               CALL iom_nf90_check(NF90_CREATE( TRIM(cdname), imode, if90id ), clinfo)
121            ELSE
122               CALL iom_nf90_check(NF90_CREATE( TRIM(cdname), imode, if90id, chunksize = ichunk ), clinfo)
123            ENDIF
124            CALL iom_nf90_check(NF90_SET_FILL( if90id, NF90_NOFILL, idmy                     ), clinfo)
125            ! define dimensions
126            CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'x', kdompar(1,1)  , idmy ), clinfo)
127            CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'y', kdompar(2,1)  , idmy ), clinfo)
128            CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'z', jpk           , idmy ), clinfo)
129            CALL iom_nf90_check(NF90_DEF_DIM( if90id, 't', NF90_UNLIMITED, idmy ), clinfo)
130            ! global attributes
131            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_number_total'   , jpnij              ), clinfo)
132            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_number'         , narea-1            ), clinfo)
133            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_dimensions_ids' , (/1     , 2     /) ), clinfo)
134            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_size_global'    , (/jpiglo, jpjglo/) ), clinfo)
135            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_size_local'     , kdompar(:,1)       ), clinfo)
136            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_position_first' , kdompar(:,2)       ), clinfo)
137            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_position_last'  , kdompar(:,3)       ), clinfo)
138            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_halo_size_start', kdompar(:,4)       ), clinfo)
139            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_halo_size_end'  , kdompar(:,5)       ), clinfo)
140            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_type'           , 'BOX'              ), clinfo)
141         ELSE              ! the file should be open for read mode so it must exist...
142            CALL ctl_stop( TRIM(clinfo), ' should be impossible case...' )
143         ENDIF
144      ENDIF
145      ! start to fill file informations
146      ! =============
147      IF( istop == nstop ) THEN   ! no error within this routine
148!does not work with some compilers         kiomid = MINLOC(iom_file(:)%nfid, dim = 1)
149         kiomid = 0
150         DO jl = jpmax_files, 1, -1
151            IF( iom_file(jl)%nfid == 0 )   kiomid = jl
152         ENDDO
153         iom_file(kiomid)%name   = TRIM(cdname)
154         iom_file(kiomid)%nfid   = if90id
155         iom_file(kiomid)%iolib  = jpnf90
156         iom_file(kiomid)%nvars  = 0
157         iom_file(kiomid)%irec   = -1   ! useless for NetCDF files, used to know if the file is in define mode
158         CALL iom_nf90_check(NF90_Inquire(if90id, unlimitedDimId = iom_file(kiomid)%iduld), clinfo)
159         IF ( iom_file(kiomid)%iduld .GE. 0 ) THEN
160           CALL iom_nf90_check(NF90_Inquire_Dimension(if90id, iom_file(kiomid)%iduld,     & 
161        &                                               name = iom_file(kiomid)%uldname,  &
162        &                                               len  = iom_file(kiomid)%lenuld ), clinfo )
163         ENDIF
164         IF(lwp) WRITE(numout,*) '                   ---> '//TRIM(cdname)//' OK'
165      ELSE
166         kiomid = 0               ! return error flag
167      ENDIF
168      !
169   END SUBROUTINE iom_nf90_open
170
171
172   SUBROUTINE iom_nf90_close( kiomid )
173      !!--------------------------------------------------------------------
174      !!                   ***  SUBROUTINE  iom_nf90_close  ***
175      !!
176      !! ** Purpose : close an input file with NF90
177      !!--------------------------------------------------------------------
178      INTEGER, INTENT(in) ::   kiomid   ! iom identifier of the file to be closed
179      CHARACTER(LEN=100)  ::   clinfo   ! info character
180      !---------------------------------------------------------------------
181      !
182      clinfo = '      iom_nf90_close    , file: '//TRIM(iom_file(kiomid)%name)
183      CALL iom_nf90_check(NF90_CLOSE(iom_file(kiomid)%nfid), clinfo)
184      !   
185   END SUBROUTINE iom_nf90_close
186
187
188   FUNCTION iom_nf90_varid ( kiomid, cdvar, kiv, kdimsz, kndims ) 
189      !!-----------------------------------------------------------------------
190      !!                  ***  FUNCTION  iom_varid  ***
191      !!
192      !! ** Purpose : get the id of a variable in a file with NF90
193      !!-----------------------------------------------------------------------
194      INTEGER              , INTENT(in   )           ::   kiomid   ! file Identifier
195      CHARACTER(len=*)     , INTENT(in   )           ::   cdvar    ! name of the variable
196      INTEGER              , INTENT(in   )           ::   kiv   !
197      INTEGER, DIMENSION(:), INTENT(  out), OPTIONAL ::   kdimsz   ! size of the dimensions
198      INTEGER,               INTENT(  out), OPTIONAL ::   kndims   ! size of the dimensions
199      !
200      INTEGER                        ::   iom_nf90_varid   ! iom variable Id
201      INTEGER                        ::   if90id           ! nf90 file identifier
202      INTEGER                        ::   ji               ! dummy loop index
203      INTEGER                        ::   ivarid           ! NetCDF  variable Id
204      INTEGER                        ::   i_nvd            ! number of dimension of the variable
205      INTEGER, DIMENSION(jpmax_dims) ::   idimid           ! dimension ids of the variable
206      LOGICAL                        ::   llok             ! ok  test
207      CHARACTER(LEN=100)             ::   clinfo           ! info character
208      !!-----------------------------------------------------------------------
209      clinfo = '          iom_nf90_varid, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
210      iom_nf90_varid = 0                    ! default definition
211      IF( PRESENT(kdimsz) ) kdimsz(:) = 0   ! default definition
212      if90id = iom_file(kiomid)%nfid        ! get back NetCDF file id
213      !
214      llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr   ! does the variable exist in the file
215      IF( llok ) THEN
216         iom_nf90_varid = kiv
217         iom_file(kiomid)%nvars       = kiv
218         iom_file(kiomid)%nvid(kiv)   = ivarid
219         iom_file(kiomid)%cn_var(kiv) = TRIM(cdvar)
220         CALL iom_nf90_check(NF90_Inquire_Variable(if90id, ivarid, ndims = i_nvd), clinfo)   ! number of dimensions
221         iom_file(kiomid)%ndims(kiv)  = i_nvd
222         CALL iom_nf90_check(NF90_Inquire_Variable(if90id, ivarid, dimids = idimid(1:i_nvd)), clinfo)   ! dimensions ids
223         iom_file(kiomid)%luld(kiv) = .FALSE.   ! default value
224         iom_file(kiomid)%dimsz(:,kiv) = 0      ! reset dimsz in case previously used
225         DO ji = 1, i_nvd                       ! dimensions size
226            CALL iom_nf90_check(NF90_Inquire_Dimension(if90id, idimid(ji), len = iom_file(kiomid)%dimsz(ji,kiv)), clinfo)   
227            IF( idimid(ji) == iom_file(kiomid)%iduld ) iom_file(kiomid)%luld(kiv) = .TRUE.   ! unlimited dimension?
228         END DO
229         !---------- Deal with scale_factor and add_offset
230         llok = NF90_Inquire_attribute(if90id, ivarid, 'scale_factor') == nf90_noerr
231         IF( llok) THEN
232            CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, 'scale_factor', iom_file(kiomid)%scf(kiv)), clinfo)
233         ELSE
234            iom_file(kiomid)%scf(kiv) = 1.
235         END IF
236         llok = NF90_Inquire_attribute(if90id, ivarid, 'add_offset') == nf90_noerr
237         IF( llok ) THEN
238            CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, 'add_offset', iom_file(kiomid)%ofs(kiv)), clinfo)
239         ELSE
240            iom_file(kiomid)%ofs(kiv) = 0.
241         END IF
242         ! return the simension size
243         IF( PRESENT(kdimsz) ) THEN
244            IF( i_nvd == SIZE(kdimsz) ) THEN
245               kdimsz(:) = iom_file(kiomid)%dimsz(1:i_nvd,kiv)
246            ELSE
247               WRITE(ctmp1,*) i_nvd, SIZE(kdimsz)
248               CALL ctl_stop( TRIM(clinfo), 'error in kdimsz size'//TRIM(ctmp1) )
249            ENDIF
250         ENDIF
251         IF( PRESENT(kndims) )  kndims = iom_file(kiomid)%ndims(kiv)
252      ELSE 
253         iom_nf90_varid = -1   !   variable not found, return error code: -1
254      ENDIF
255      !
256   END FUNCTION iom_nf90_varid
257
258   !!----------------------------------------------------------------------
259   !!                   INTERFACE iom_nf90_get
260   !!----------------------------------------------------------------------
261
262   SUBROUTINE iom_nf90_g0d( kiomid, kvid, pvar, kstart )
263      !!-----------------------------------------------------------------------
264      !!                  ***  ROUTINE  iom_nf90_g0d  ***
265      !!
266      !! ** Purpose : read a scalar with NF90
267      !!-----------------------------------------------------------------------
268      INTEGER ,               INTENT(in   )            ::   kiomid   ! Identifier of the file
269      INTEGER ,               INTENT(in   )            ::   kvid     ! variable id
270      REAL(wp),               INTENT(  out)            ::   pvar     ! read field
271      INTEGER , DIMENSION(1), INTENT(in   ), OPTIONAL  ::   kstart   ! start position of the reading in each axis
272      !
273      CHARACTER(LEN=100)      ::   clinfo   ! info character
274      !---------------------------------------------------------------------
275      clinfo = 'iom_nf90_g0d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
276      CALL iom_nf90_check(NF90_GET_VAR(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), pvar, start = kstart), clinfo )
277      !
278   END SUBROUTINE iom_nf90_g0d
279
280
281   SUBROUTINE iom_nf90_g123d( kiomid, kvid, knbdim, kstart, kcount, kx1, kx2, ky1, ky2,   &
282         &                    pv_r1d, pv_r2d, pv_r3d )
283      !!-----------------------------------------------------------------------
284      !!                  ***  ROUTINE  iom_nf90_g123d  ***
285      !!
286      !! ** Purpose : read a 1D/2D/3D variable with NF90
287      !!
288      !! ** Method : read ONE record at each CALL
289      !!-----------------------------------------------------------------------
290      INTEGER                    , INTENT(in   )           ::   kiomid    ! iom identifier of the file
291      INTEGER                    , INTENT(in   )           ::   kvid      ! Name of the variable
292      INTEGER                    , INTENT(in   )           ::   knbdim    ! number of dimensions of the variable
293      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kstart    ! start position of the reading in each axis
294      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kcount    ! number of points to be read in each axis
295      INTEGER ,                    INTENT(in   )           ::   kx1, kx2, ky1, ky2   ! subdomain indexes
296      REAL(wp), DIMENSION(:)     , INTENT(  out), OPTIONAL ::   pv_r1d    ! read field (1D case)
297      REAL(wp), DIMENSION(:,:)   , INTENT(  out), OPTIONAL ::   pv_r2d    ! read field (2D case)
298      REAL(wp), DIMENSION(:,:,:) , INTENT(  out), OPTIONAL ::   pv_r3d    ! read field (3D case)
299      !
300      CHARACTER(LEN=100) ::   clinfo               ! info character
301      INTEGER            ::   if90id               ! nf90 identifier of the opened file
302      INTEGER            ::   ivid                 ! nf90 variable id
303      !---------------------------------------------------------------------
304      clinfo = 'iom_nf90_g123d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
305      if90id = iom_file(kiomid)%nfid         ! get back NetCDF file id
306      ivid   = iom_file(kiomid)%nvid(kvid)   ! get back NetCDF var id
307      !
308      IF(     PRESENT(pv_r1d) ) THEN
309         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r1d(:                ), start = kstart(1:knbdim),   &
310            &                                                                       count = kcount(1:knbdim)), clinfo )
311      ELSEIF( PRESENT(pv_r2d) ) THEN
312         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r2d(kx1:kx2,ky1:ky2  ), start = kstart(1:knbdim),   &
313            &                                                                       count = kcount(1:knbdim)), clinfo )
314      ELSEIF( PRESENT(pv_r3d) ) THEN
315         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r3d(kx1:kx2,ky1:ky2,:), start = kstart(1:knbdim),   &
316            &                                                                       count = kcount(1:knbdim)), clinfo )
317      ENDIF
318      !
319   END SUBROUTINE iom_nf90_g123d
320
321   !!----------------------------------------------------------------------
322   !!                   INTERFACE iom_nf90_getatt
323   !!----------------------------------------------------------------------
324
325   SUBROUTINE iom_nf90_giatt( kiomid, cdatt, pv_i0d, cdvar)
326      !!-----------------------------------------------------------------------
327      !!                  ***  ROUTINE  iom_nf90_giatt  ***
328      !!
329      !! ** Purpose : read an integer attribute with NF90
330      !!              (either a global attribute (default) or a variable
331      !!               attribute if optional variable name is supplied (cdvar))
332      !!-----------------------------------------------------------------------
333      INTEGER         , INTENT(in   ) ::   kiomid   ! Identifier of the file
334      CHARACTER(len=*), INTENT(in   ) ::   cdatt    ! attribute name
335      INTEGER         , INTENT(  out) ::   pv_i0d   ! read field
336      CHARACTER(len=*), INTENT(in   ), OPTIONAL     &
337                      &               ::   cdvar    ! name of the variable
338      !
339      INTEGER                         ::   if90id   ! temporary integer
340      INTEGER                         ::   ivarid   ! NetCDF variable Id
341      LOGICAL                         ::   llok     ! temporary logical
342      CHARACTER(LEN=100)              ::   clinfo   ! info character
343      !---------------------------------------------------------------------
344      !
345      if90id = iom_file(kiomid)%nfid
346      IF( PRESENT(cdvar) ) THEN
347         ! check the variable exists in the file
348         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr
349         IF( llok ) THEN
350            ! check the variable has the attribute required
351            llok = NF90_Inquire_attribute(if90id, ivarid, cdatt) == nf90_noerr
352         ELSE
353            CALL ctl_warn('iom_nf90_getatt: no variable '//cdvar//' found')
354         ENDIF
355      ELSE
356         llok = NF90_Inquire_attribute(if90id, NF90_GLOBAL, cdatt) == nf90_noerr
357         ivarid = NF90_GLOBAL
358      ENDIF
359!
360      IF( llok) THEN
361         clinfo = 'iom_nf90_getatt, file: '//TRIM(iom_file(kiomid)%name)//', giatt: '//TRIM(cdatt)
362         CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values=pv_i0d), clinfo)
363      ELSE
364         CALL ctl_warn('iom_nf90_getatt: no attribute '//cdatt//' found')
365         pv_i0d = -999
366      ENDIF
367      !
368   END SUBROUTINE iom_nf90_giatt
369
370   SUBROUTINE iom_nf90_gratt( kiomid, cdatt, pv_r0d, cdvar)
371      !!-----------------------------------------------------------------------
372      !!                  ***  ROUTINE  iom_nf90_gratt  ***
373      !!
374      !! ** Purpose : read a real attribute with NF90
375      !!              (either a global attribute (default) or a variable
376      !!               attribute if optional variable name is supplied (cdvar))
377      !!-----------------------------------------------------------------------
378      INTEGER         , INTENT(in   ) ::   kiomid   ! Identifier of the file
379      CHARACTER(len=*), INTENT(in   ) ::   cdatt    ! attribute name
380      REAL(wp)        , INTENT(  out) ::   pv_r0d   ! read field
381      CHARACTER(len=*), INTENT(in   ), OPTIONAL     &
382                      &               ::   cdvar    ! name of the variable
383      !
384      INTEGER                         ::   if90id   ! temporary integer
385      INTEGER                         ::   ivarid   ! NetCDF variable Id
386      LOGICAL                         ::   llok     ! temporary logical
387      CHARACTER(LEN=100)              ::   clinfo   ! info character
388      !---------------------------------------------------------------------
389      !
390      if90id = iom_file(kiomid)%nfid
391      IF( PRESENT(cdvar) ) THEN
392         ! check the variable exists in the file
393         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr
394         IF( llok ) THEN
395            ! check the variable has the attribute required
396            llok = NF90_Inquire_attribute(if90id, ivarid, cdatt) == nf90_noerr
397         ELSE
398            CALL ctl_warn('iom_nf90_getatt: no variable '//cdvar//' found')
399         ENDIF
400      ELSE
401         llok = NF90_Inquire_attribute(if90id, NF90_GLOBAL, cdatt) == nf90_noerr
402         ivarid = NF90_GLOBAL
403      ENDIF
404!
405      IF( llok) THEN
406         clinfo = 'iom_nf90_getatt, file: '//TRIM(iom_file(kiomid)%name)//', gratt: '//TRIM(cdatt)
407         CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values=pv_r0d), clinfo)
408      ELSE
409         CALL ctl_warn('iom_nf90_getatt: no attribute '//cdatt//' found')
410         pv_r0d = -999._wp
411      ENDIF
412      !
413   END SUBROUTINE iom_nf90_gratt
414
415   SUBROUTINE iom_nf90_gcatt( kiomid, cdatt, pv_c0d, cdvar)
416      !!-----------------------------------------------------------------------
417      !!                  ***  ROUTINE  iom_nf90_gcatt  ***
418      !!
419      !! ** Purpose : read a character attribute with NF90
420      !!              (either a global attribute (default) or a variable
421      !!               attribute if optional variable name is supplied (cdvar))
422      !!-----------------------------------------------------------------------
423      INTEGER         , INTENT(in   ) ::   kiomid   ! Identifier of the file
424      CHARACTER(len=*), INTENT(in   ) ::   cdatt    ! attribute name
425      CHARACTER(len=*), INTENT(  out) ::   pv_c0d   ! read field
426      CHARACTER(len=*), INTENT(in   ), OPTIONAL     &
427                      &               ::   cdvar    ! name of the variable
428      !
429      INTEGER                         ::   if90id   ! temporary integer
430      INTEGER                         ::   ivarid   ! NetCDF variable Id
431      LOGICAL                         ::   llok     ! temporary logical
432      CHARACTER(LEN=100)              ::   clinfo   ! info character
433      !---------------------------------------------------------------------
434      !
435      if90id = iom_file(kiomid)%nfid
436      IF( PRESENT(cdvar) ) THEN
437         ! check the variable exists in the file
438         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr
439         IF( llok ) THEN
440            ! check the variable has the attribute required
441            llok = NF90_Inquire_attribute(if90id, ivarid, cdatt) == nf90_noerr
442         ELSE
443            CALL ctl_warn('iom_nf90_getatt: no variable '//cdvar//' found')
444         ENDIF
445      ELSE
446         llok = NF90_Inquire_attribute(if90id, NF90_GLOBAL, cdatt) == nf90_noerr
447         ivarid = NF90_GLOBAL
448      ENDIF
449!
450      IF( llok) THEN
451         clinfo = 'iom_nf90_getatt, file: '//TRIM(iom_file(kiomid)%name)//', gcatt: '//TRIM(cdatt)
452         CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values=pv_c0d), clinfo)
453      ELSE
454         CALL ctl_warn('iom_nf90_getatt: no attribute '//cdatt//' found')
455         pv_c0d = '!'
456      ENDIF
457      !
458   END SUBROUTINE iom_nf90_gcatt
459
460   !!----------------------------------------------------------------------
461   !!                   INTERFACE iom_nf90_putatt
462   !!----------------------------------------------------------------------
463
464   SUBROUTINE iom_nf90_piatt( kiomid, cdatt, pv_i0d, cdvar)
465      !!-----------------------------------------------------------------------
466      !!                  ***  ROUTINE  iom_nf90_piatt  ***
467      !!
468      !! ** Purpose : write an integer attribute with NF90
469      !!              (either a global attribute (default) or a variable
470      !!               attribute if optional variable name is supplied (cdvar))
471      !!-----------------------------------------------------------------------
472      INTEGER         , INTENT(in   ) ::   kiomid   ! Identifier of the file
473      CHARACTER(len=*), INTENT(in   ) ::   cdatt    ! attribute name
474      INTEGER         , INTENT(in   ) ::   pv_i0d   ! write field
475      CHARACTER(len=*), INTENT(in   ), OPTIONAL     &
476                      &               ::   cdvar    ! name of the variable
477      !
478      INTEGER                         ::   if90id   ! temporary integer
479      INTEGER                         ::   ivarid   ! NetCDF variable Id
480      LOGICAL                         ::   llok     ! temporary logical
481      LOGICAL                         ::   lenddef  ! temporary logical
482      CHARACTER(LEN=100)              ::   clinfo   ! info character
483      !---------------------------------------------------------------------
484      !
485      if90id = iom_file(kiomid)%nfid
486      lenddef = .false.
487      IF( PRESENT(cdvar) ) THEN
488         ! check the variable exists in the file
489         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr
490         IF( .NOT. llok ) THEN
491            CALL ctl_warn('iom_nf90_putatt: no variable '//cdvar//' found')
492         ENDIF
493      ELSE
494         llok = .true.
495         ivarid = NF90_GLOBAL
496      ENDIF
497!
498      IF( llok) THEN
499         clinfo = 'iom_nf90_putatt, file: '//TRIM(iom_file(kiomid)%name)//', piatt: '//TRIM(cdatt)
500         IF( iom_file(kiomid)%irec /= -1 ) THEN   
501            ! trick: irec used to know if the file is in define mode or not
502            ! if it is not then temporarily put it into define mode
503            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)
504            lenddef = .true.
505         ENDIF
506         !
507         CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values=pv_i0d), clinfo)
508         !
509         IF( lenddef ) THEN   
510            ! file was in data mode on entry; put it back in that mode
511            CALL iom_nf90_check(NF90_ENDDEF( if90id ), clinfo)
512         ENDIF
513      ELSE
514         CALL ctl_warn('iom_nf90_putatt: no attribute '//cdatt//' written')
515      ENDIF
516      !
517   END SUBROUTINE iom_nf90_piatt
518
519   SUBROUTINE iom_nf90_pratt( kiomid, cdatt, pv_r0d, cdvar)
520      !!-----------------------------------------------------------------------
521      !!                  ***  ROUTINE  iom_nf90_pratt  ***
522      !!
523      !! ** Purpose : write a real attribute with NF90
524      !!              (either a global attribute (default) or a variable
525      !!               attribute if optional variable name is supplied (cdvar))
526      !!-----------------------------------------------------------------------
527      INTEGER         , INTENT(in   ) ::   kiomid   ! Identifier of the file
528      CHARACTER(len=*), INTENT(in   ) ::   cdatt    ! attribute name
529      REAL(wp)        , INTENT(in   ) ::   pv_r0d   ! write field
530      CHARACTER(len=*), INTENT(in   ), OPTIONAL     &
531                      &               ::   cdvar    ! name of the variable
532      !
533      INTEGER                         ::   if90id   ! temporary integer
534      INTEGER                         ::   ivarid   ! NetCDF variable Id
535      LOGICAL                         ::   llok     ! temporary logical
536      LOGICAL                         ::   lenddef  ! temporary logical
537      CHARACTER(LEN=100)              ::   clinfo   ! info character
538      !---------------------------------------------------------------------
539      !
540      if90id = iom_file(kiomid)%nfid
541      lenddef = .false.
542      IF( PRESENT(cdvar) ) THEN
543         ! check the variable exists in the file
544         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr
545         IF( .NOT. llok ) THEN
546            CALL ctl_warn('iom_nf90_putatt: no variable '//cdvar//' found')
547         ENDIF
548      ELSE
549         llok = .true.
550         ivarid = NF90_GLOBAL
551      ENDIF
552!
553      IF( llok) THEN
554         clinfo = 'iom_nf90_putatt, file: '//TRIM(iom_file(kiomid)%name)//', pratt: '//TRIM(cdatt)
555         IF( iom_file(kiomid)%irec /= -1 ) THEN   
556            ! trick: irec used to know if the file is in define mode or not
557            ! if it is not then temporarily put it into define mode
558            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)
559            lenddef = .true.
560         ENDIF
561         !
562         CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values=pv_r0d), clinfo)
563         !
564         IF( lenddef ) THEN   
565            ! file was in data mode on entry; put it back in that mode
566            CALL iom_nf90_check(NF90_ENDDEF( if90id ), clinfo)
567         ENDIF
568      ELSE
569         CALL ctl_warn('iom_nf90_putatt: no attribute '//cdatt//' written')
570      ENDIF
571      !
572   END SUBROUTINE iom_nf90_pratt
573
574   SUBROUTINE iom_nf90_pcatt( kiomid, cdatt, pv_c0d, cdvar)
575      !!-----------------------------------------------------------------------
576      !!                  ***  ROUTINE  iom_nf90_pcatt  ***
577      !!
578      !! ** Purpose : write a character attribute with NF90
579      !!              (either a global attribute (default) or a variable
580      !!               attribute if optional variable name is supplied (cdvar))
581      !!-----------------------------------------------------------------------
582      INTEGER         , INTENT(in   ) ::   kiomid   ! Identifier of the file
583      CHARACTER(len=*), INTENT(in   ) ::   cdatt    ! attribute name
584      CHARACTER(len=*), INTENT(in   ) ::   pv_c0d   ! write field
585      CHARACTER(len=*), INTENT(in   ), OPTIONAL     &
586                      &               ::   cdvar    ! name of the variable
587      !
588      INTEGER                         ::   if90id   ! temporary integer
589      INTEGER                         ::   ivarid   ! NetCDF variable Id
590      LOGICAL                         ::   llok     ! temporary logical
591      LOGICAL                         ::   lenddef  ! temporary logical
592      CHARACTER(LEN=100)              ::   clinfo   ! info character
593      !---------------------------------------------------------------------
594      !
595      if90id = iom_file(kiomid)%nfid
596      lenddef = .false.
597      IF( PRESENT(cdvar) ) THEN
598         ! check the variable exists in the file
599         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr
600         IF( .NOT. llok ) THEN
601            CALL ctl_warn('iom_nf90_putatt: no variable '//cdvar//' found')
602         ENDIF
603      ELSE
604         llok = .true.
605         ivarid = NF90_GLOBAL
606      ENDIF
607!
608      IF( llok) THEN
609         clinfo = 'iom_nf90_putatt, file: '//TRIM(iom_file(kiomid)%name)//', pcatt: '//TRIM(cdatt)
610         IF( iom_file(kiomid)%irec /= -1 ) THEN   
611            ! trick: irec used to know if the file is in define mode or not
612            ! if it is not then temporarily put it into define mode
613            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)
614            lenddef = .true.
615         ENDIF
616         !
617         CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values=pv_c0d), clinfo)
618         !
619         IF( lenddef ) THEN   
620            ! file was in data mode on entry; put it back in that mode
621            CALL iom_nf90_check(NF90_ENDDEF( if90id ), clinfo)
622         ENDIF
623      ELSE
624         CALL ctl_warn('iom_nf90_putatt: no attribute '//cdatt//' written')
625      ENDIF
626      !
627   END SUBROUTINE iom_nf90_pcatt
628
629
630   SUBROUTINE iom_nf90_gettime( kiomid, kvid, ptime, cdunits, cdcalendar )
631      !!--------------------------------------------------------------------
632      !!                   ***  SUBROUTINE iom_gettime  ***
633      !!
634      !! ** Purpose : read the time axis kvid in the file with NF90
635      !!--------------------------------------------------------------------
636      INTEGER                   , INTENT(in   ) ::   kiomid     ! file Identifier
637      INTEGER                   , INTENT(in   ) ::   kvid       ! variable id
638      REAL(wp), DIMENSION(:)    , INTENT(  out) ::   ptime      ! the time axis
639      CHARACTER(len=*), OPTIONAL, INTENT(  out) ::   cdunits    ! units attribute
640      CHARACTER(len=*), OPTIONAL, INTENT(  out) ::   cdcalendar ! calendar attribute
641      !
642      CHARACTER(LEN=100) ::   clinfo     ! info character
643      !---------------------------------------------------------------------
644      clinfo = 'iom_nf90_gettime, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
645      CALL iom_nf90_check(NF90_GET_VAR(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), ptime(:),   &
646            &                           start=(/ 1 /), count=(/ iom_file(kiomid)%dimsz(1, kvid) /)), clinfo)
647      IF ( PRESENT(cdunits) ) THEN
648         CALL iom_nf90_check(NF90_GET_ATT(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), "units", &
649            &                           values=cdunits), clinfo)
650      ENDIF
651      IF ( PRESENT(cdcalendar) ) THEN
652         CALL iom_nf90_check(NF90_GET_ATT(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), "calendar", &
653            &                           values=cdcalendar), clinfo)
654      ENDIF
655      !
656   END SUBROUTINE iom_nf90_gettime
657
658
659   SUBROUTINE iom_nf90_rp0123d( kt, kwrite, kiomid, cdvar , kvid  , ktype,   &
660         &                               pv_r0d, pv_r1d, pv_r2d, pv_r3d )
661      !!--------------------------------------------------------------------
662      !!                   ***  SUBROUTINE  iom_nf90_rstput  ***
663      !!
664      !! ** Purpose : read the time axis cdvar in the file
665      !!--------------------------------------------------------------------
666      INTEGER                     , INTENT(in)           ::   kt       ! ocean time-step
667      INTEGER                     , INTENT(in)           ::   kwrite   ! writing time-step
668      INTEGER                     , INTENT(in)           ::   kiomid   ! Identifier of the file
669      CHARACTER(len=*)            , INTENT(in)           ::   cdvar    ! variable name
670      INTEGER                     , INTENT(in)           ::   kvid     ! variable id
671      INTEGER                     , INTENT(in), OPTIONAL ::   ktype    ! variable type (default R8)
672      REAL(wp)                    , INTENT(in), OPTIONAL ::   pv_r0d   ! written Od field
673      REAL(wp), DIMENSION(      :), INTENT(in), OPTIONAL ::   pv_r1d   ! written 1d field
674      REAL(wp), DIMENSION(:, :   ), INTENT(in), OPTIONAL ::   pv_r2d   ! written 2d field
675      REAL(wp), DIMENSION(:, :, :), INTENT(in), OPTIONAL ::   pv_r3d   ! written 3d field
676      !
677      INTEGER               :: idims                ! number of dimension
678      INTEGER               :: idvar                ! variable id
679      INTEGER               :: jd                   ! dimension loop counter   
680      INTEGER               :: ix1, ix2, iy1, iy2   ! subdomain indexes   
681      INTEGER, DIMENSION(4) :: idimsz               ! dimensions size 
682      INTEGER, DIMENSION(4) :: idimid               ! dimensions id
683      CHARACTER(LEN=256)    :: clinfo               ! info character
684      CHARACTER(LEN= 12), DIMENSION(4) :: cltmp     ! temporary character
685      INTEGER               :: if90id               ! nf90 file identifier
686      INTEGER               :: idmy                 ! dummy variable
687      INTEGER               :: itype                ! variable type
688      INTEGER, DIMENSION(4) :: ichunksz             ! NetCDF4 chunk sizes. Will be computed using
689                                                    ! nn_nchunks_[i,j,k,t] namelist parameters
690      INTEGER               :: ichunkalg, ishuffle,&
691                               ideflate, ideflate_level
692                                                    ! NetCDF4 internally fixed parameters
693      LOGICAL               :: lchunk               ! logical switch to activate chunking and compression
694                                                    ! when appropriate (currently chunking is applied to 4d fields only)
695      !---------------------------------------------------------------------
696      !
697      clinfo = '          iom_nf90_rp0123d, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
698      if90id = iom_file(kiomid)%nfid
699      !
700      ! define dimension variables if it is not already done
701      ! ==========================
702      IF( iom_file(kiomid)%nvars == 0 ) THEN
703         ! are we in define mode?
704         IF( iom_file(kiomid)%irec /= -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
705            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = -1
706         ENDIF
707         ! define the dimension variables if it is not already done
708         cltmp = (/ 'nav_lon     ', 'nav_lat     ', 'nav_lev     ', 'time_counter' /)
709         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(1)), NF90_FLOAT , (/ 1, 2 /), iom_file(kiomid)%nvid(1) ), clinfo)
710         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(2)), NF90_FLOAT , (/ 1, 2 /), iom_file(kiomid)%nvid(2) ), clinfo)
711         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(3)), NF90_FLOAT , (/ 3    /), iom_file(kiomid)%nvid(3) ), clinfo)
712         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(4)), NF90_DOUBLE, (/ 4    /), iom_file(kiomid)%nvid(4) ), clinfo)
713         ! update informations structure related the dimension variable we just added...
714         iom_file(kiomid)%nvars       = 4
715         iom_file(kiomid)%luld(1:4)   = (/ .FALSE., .FALSE., .FALSE., .TRUE. /)
716         iom_file(kiomid)%cn_var(1:4) = cltmp
717         iom_file(kiomid)%ndims(1:4)  = (/ 2, 2, 1, 1 /) 
718         ! trick: defined to 0 to say that dimension variables are defined but not yet written
719         iom_file(kiomid)%dimsz(1, 1)  = 0   
720         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' define dimension variables done'
721      ENDIF
722      ! define the data if it is not already done
723      ! ===============
724      IF( kvid <= 0 ) THEN
725         !
726         ! NetCDF4 chunking and compression fixed settings
727         ichunkalg = 0
728         ishuffle = 1
729         ideflate = 1
730         ideflate_level = 1
731         !
732         idvar = iom_file(kiomid)%nvars + 1
733         ! are we in define mode?
734         IF( iom_file(kiomid)%irec /= -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
735            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = -1
736         ENDIF
737         ! variable definition
738         IF(     PRESENT(pv_r0d) ) THEN   ;   idims = 0
739         ELSEIF( PRESENT(pv_r1d) ) THEN   ;   idims = 2   ;   idimid(1:idims) = (/    3,4/)
740         ELSEIF( PRESENT(pv_r2d) ) THEN   ;   idims = 3   ;   idimid(1:idims) = (/1,2  ,4/)
741         ELSEIF( PRESENT(pv_r3d) ) THEN   ;   idims = 4   ;   idimid(1:idims) = (/1,2,3,4/)
742         ENDIF
743         IF( PRESENT(ktype) ) THEN   ! variable external type
744            SELECT CASE (ktype)
745            CASE (jp_r8)  ;   itype = NF90_DOUBLE
746            CASE (jp_r4)  ;   itype = NF90_FLOAT
747            CASE (jp_i4)  ;   itype = NF90_INT
748            CASE (jp_i2)  ;   itype = NF90_SHORT
749            CASE (jp_i1)  ;   itype = NF90_BYTE
750            CASE DEFAULT   ;   CALL ctl_stop( TRIM(clinfo)//' unknown variable type' )
751            END SELECT
752         ELSE
753            itype = NF90_DOUBLE
754         ENDIF
755         IF( PRESENT(pv_r0d) ) THEN
756            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cdvar), itype,                    &
757                 &                            iom_file(kiomid)%nvid(idvar) ), clinfo)
758         ELSE
759            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cdvar), itype, idimid(1:idims),   &
760                 &                            iom_file(kiomid)%nvid(idvar) ), clinfo)
761         ENDIF
762         lchunk = .false.
763         IF( snc4set%luse .AND. idims.eq.4 ) lchunk = .true.
764         ! update informations structure related the new variable we want to add...
765         iom_file(kiomid)%nvars         = idvar
766         iom_file(kiomid)%cn_var(idvar) = TRIM(cdvar)
767         iom_file(kiomid)%scf(idvar)    = 1.
768         iom_file(kiomid)%ofs(idvar)    = 0.
769         iom_file(kiomid)%ndims(idvar)  = idims
770         IF( .NOT. PRESENT(pv_r0d) ) THEN   ;   iom_file(kiomid)%luld(idvar) = .TRUE.
771         ELSE                               ;   iom_file(kiomid)%luld(idvar) = .FALSE.
772         ENDIF
773         DO jd = 1, idims
774            CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, idimid(jd), len = iom_file(kiomid)%dimsz(jd,idvar) ), clinfo)
775            IF ( lchunk ) ichunksz(jd) = iom_file(kiomid)%dimsz(jd,idvar)
776         END DO
777         IF ( lchunk ) THEN
778            ! Calculate chunk sizes by partitioning each dimension as requested in namnc4 namelist
779            ! Disallow very small chunk sizes and prevent chunk sizes larger than each individual dimension
780            ichunksz(1) = MIN( ichunksz(1),MAX( (ichunksz(1)-1)/snc4set%ni + 1 ,16 ) ) ! Suggested default nc4set%ni=4
781            ichunksz(2) = MIN( ichunksz(2),MAX( (ichunksz(2)-1)/snc4set%nj + 1 ,16 ) ) ! Suggested default nc4set%nj=2
782            ichunksz(3) = MIN( ichunksz(3),MAX( (ichunksz(3)-1)/snc4set%nk + 1 , 1 ) ) ! Suggested default nc4set%nk=6
783            ichunksz(4) = 1                                                            ! Do not allow chunks to span the
784                                                                                       ! unlimited dimension
785            CALL iom_nf90_check(SET_NF90_DEF_VAR_CHUNKING(if90id, idvar, ichunkalg, ichunksz), clinfo)
786            CALL iom_nf90_check(SET_NF90_DEF_VAR_DEFLATE(if90id, idvar, ishuffle, ideflate, ideflate_level), clinfo)
787            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' chunked ok. Chunks sizes: ', ichunksz
788         ENDIF
789         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' defined ok'
790      ELSE
791         idvar = kvid
792      ENDIF
793
794      ! time step kwrite : write the variable
795      IF( kt == kwrite ) THEN
796         ! are we in write mode?
797         IF( iom_file(kiomid)%irec == -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
798            CALL iom_nf90_check(NF90_ENDDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = 0
799         ENDIF
800         ! on what kind of domain must the data be written?
801         IF( PRESENT(pv_r2d) .OR. PRESENT(pv_r3d) ) THEN
802            idimsz(1:2) = iom_file(kiomid)%dimsz(1:2,idvar)
803            IF(     idimsz(1) == (nlei - nldi + 1) .AND. idimsz(2) == (nlej - nldj + 1) ) THEN
804               ix1 = nldi   ;   ix2 = nlei   ;   iy1 = nldj   ;   iy2 = nlej
805            ELSEIF( idimsz(1) == nlci              .AND. idimsz(2) == nlcj              ) THEN
806               ix1 = 1      ;   ix2 = nlci   ;   iy1 = 1      ;   iy2 = nlcj
807            ELSEIF( idimsz(1) == jpi               .AND. idimsz(2) == jpj               ) THEN
808               ix1 = 1      ;   ix2 = jpi    ;   iy1 = 1      ;   iy2 = jpj
809            ELSE
810               CALL ctl_stop( 'iom_nf90_rp0123d: should have been an impossible case...' )
811            ENDIF
812
813            ! write dimension variables if it is not already done
814            ! =============
815            ! trick: is defined to 0 => dimension variable are defined but not yet written
816            IF( iom_file(kiomid)%dimsz(1, 1) == 0 ) THEN
817               CALL iom_nf90_check(NF90_INQ_VARID( if90id, 'nav_lon'     , idmy ), clinfo)
818               CALL iom_nf90_check(NF90_PUT_VAR( if90id, idmy, glamt(ix1:ix2, iy1:iy2) ), clinfo)
819               CALL iom_nf90_check(NF90_INQ_VARID( if90id, 'nav_lat'     , idmy ), clinfo)
820               CALL iom_nf90_check(NF90_PUT_VAR( if90id, idmy, gphit(ix1:ix2, iy1:iy2) ), clinfo)
821               CALL iom_nf90_check(NF90_INQ_VARID( if90id, 'nav_lev'     , idmy ), clinfo)
822               CALL iom_nf90_check(NF90_PUT_VAR( if90id, idmy, gdept_1d                ), clinfo)
823               ! +++ WRONG VALUE: to be improved but not really useful...
824               CALL iom_nf90_check(NF90_INQ_VARID( if90id, 'time_counter', idmy ), clinfo)
825               CALL iom_nf90_check(NF90_PUT_VAR( if90id, idmy, kt                      ), clinfo)   
826               ! update the values of the variables dimensions size
827               CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, 1, len = iom_file(kiomid)%dimsz(1,1) ), clinfo)
828               CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, 2, len = iom_file(kiomid)%dimsz(2,1) ), clinfo)
829               iom_file(kiomid)%dimsz(1:2, 2) = iom_file(kiomid)%dimsz(1:2, 1)
830               CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, 3, len = iom_file(kiomid)%dimsz(1,3) ), clinfo)
831               iom_file(kiomid)%dimsz(1  , 4) = 1   ! unlimited dimension
832               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' write dimension variables done'
833            ENDIF
834         ENDIF
835
836         ! write the data
837         ! =============
838         IF(     PRESENT(pv_r0d) ) THEN
839            CALL iom_nf90_check(NF90_PUT_VAR( if90id, idvar, pv_r0d                      ), clinfo)
840         ELSEIF( PRESENT(pv_r1d) ) THEN
841            CALL iom_nf90_check(NF90_PUT_VAR( if90id, idvar, pv_r1d(                  :) ), clinfo)
842         ELSEIF( PRESENT(pv_r2d) ) THEN
843            CALL iom_nf90_check(NF90_PUT_VAR( if90id, idvar, pv_r2d(ix1:ix2, iy1:iy2   ) ), clinfo)
844         ELSEIF( PRESENT(pv_r3d) ) THEN
845            CALL iom_nf90_check(NF90_PUT_VAR( if90id, idvar, pv_r3d(ix1:ix2, iy1:iy2, :) ), clinfo)
846         ENDIF
847         ! add 1 to the size of the temporal dimension (not really useful...)
848         IF( iom_file(kiomid)%luld(idvar) )   iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar)    &
849               &                            = iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar) + 1
850         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' written ok'
851      ENDIF
852      !     
853   END SUBROUTINE iom_nf90_rp0123d
854
855
856   SUBROUTINE iom_nf90_check( kstatus, cdinfo )
857      !!--------------------------------------------------------------------
858      !!                   ***  SUBROUTINE iom_nf90_check  ***
859      !!
860      !! ** Purpose :   check nf90 errors
861      !!--------------------------------------------------------------------
862      INTEGER,          INTENT(in) :: kstatus
863      CHARACTER(LEN=*), INTENT(in) :: cdinfo
864      !---------------------------------------------------------------------
865      IF(kstatus /= nf90_noerr)   CALL ctl_stop( 'iom_nf90_check : '//TRIM(nf90_strerror(kstatus)), TRIM(cdinfo) )
866   END SUBROUTINE iom_nf90_check
867
868   !!======================================================================
869END MODULE iom_nf90
Note: See TracBrowser for help on using the repository browser.