New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
restart.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/IOM – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/IOM/restart.F90 @ 6140

Last change on this file since 6140 was 6140, checked in by timgraham, 8 years ago

Merge of branches/2015/dev_merge_2015 back into trunk. Merge excludes NEMOGCM/TOOLS/OBSTOOLS/ for now due to issues with the change of file type. Will sort these manually with further commits.

Branch merged as follows:
In the working copy of branch ran:
svn merge svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/trunk@HEAD
Small conflicts due to bug fixes applied to trunk since the dev_merge_2015 was copied. Bug fixes were applied to the branch as well so these were easy to resolve.
Branch committed at this stage

In working copy run:
svn switch svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/trunk
to switch working copy

Run:
svn merge --reintegrate svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/branches/2015/dev_merge_2015
to merge the branch into the trunk and then commit - no conflicts at this stage.

  • Property svn:keywords set to Id
File size: 13.4 KB
Line 
1MODULE restart
2   !!======================================================================
3   !!                     ***  MODULE  restart  ***
4   !! Ocean restart :  write the ocean restart file
5   !!======================================================================
6   !! History :  OPA  !  1999-11  (M. Imbard)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec)  F90: Free form
8   !!            2.0  !  2006-07  (S. Masson)  use IOM for restart
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  modified LF-RA
10   !!            - -  !  2010-10  (C. Ethe, G. Madec) TRC-TRA merge (T-S in 4D)
11   !!            3.7  !  2014-01  (G. Madec) suppression of curl and hdiv from the restart
12   !!             -   !  2014-12  (G. Madec) remove KPP scheme
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   rst_opn    : open the ocean restart file
17   !!   rst_write  : write the ocean restart file
18   !!   rst_read   : read the ocean restart file
19   !!----------------------------------------------------------------------
20   USE oce             ! ocean dynamics and tracers
21   USE dom_oce         ! ocean space and time domain
22   USE sbc_ice         ! only lk_lim3
23   USE phycst          ! physical constants
24   USE eosbn2          ! equation of state            (eos bn2 routine)
25   USE trdmxl_oce      ! ocean active mixed layer tracers trends variables
26   !
27   USE in_out_manager  ! I/O manager
28   USE iom             ! I/O module
29   USE diurnal_bulk
30   
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   rst_opn         ! routine called by step module
35   PUBLIC   rst_write       ! routine called by step module
36   PUBLIC   rst_read        ! routine called by istate module
37   PUBLIC   rst_read_open   ! routine called in rst_read and (possibly) in dom_vvl_init
38
39   !! * Substitutions
40#  include "vectopt_loop_substitute.h90"
41   !!----------------------------------------------------------------------
42   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
43   !! $Id$
44   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE rst_opn( kt )
49      !!---------------------------------------------------------------------
50      !!                   ***  ROUTINE rst_opn  ***
51      !!                     
52      !! ** Purpose : + initialization (should be read in the namelist) of nitrst
53      !!              + open the restart when we are one time step before nitrst
54      !!                   - restart header is defined when kt = nitrst-1
55      !!                   - restart data  are written when kt = nitrst
56      !!              + define lrst_oce to .TRUE. when we need to define or write the restart
57      !!----------------------------------------------------------------------
58      INTEGER, INTENT(in) ::   kt     ! ocean time-step
59      !!
60      CHARACTER(LEN=20)   ::   clkt     ! ocean time-step deine as a character
61      CHARACTER(LEN=50)   ::   clname   ! ocean output restart file name
62      CHARACTER(lc)       ::   clpath   ! full path to ocean output restart file
63      !!----------------------------------------------------------------------
64      !
65      IF( kt == nit000 ) THEN   ! default definitions
66         lrst_oce = .FALSE.   
67         IF( ln_rst_list ) THEN
68            nrst_lst = 1
69            nitrst = nstocklist( nrst_lst )
70         ELSE
71            nitrst = nitend
72         ENDIF
73      ENDIF
74
75      ! frequency-based restart dumping (nn_stock)
76      IF( .NOT. ln_rst_list .AND. MOD( kt - 1, nstock ) == 0 ) THEN   
77         ! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
78         nitrst = kt + nstock - 1                  ! define the next value of nitrst for restart writing
79         IF( nitrst > nitend )   nitrst = nitend   ! make sure we write a restart at the end of the run
80      ENDIF
81      ! to get better performances with NetCDF format:
82      ! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
83      ! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
84      IF( kt == nitrst - 1 .OR. nstock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
85         IF( nitrst <= nitend .AND. nitrst > 0 ) THEN 
86            ! beware of the format used to write kt (default is i8.8, that should be large enough...)
87            IF( nitrst > 999999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
88            ELSE                            ;   WRITE(clkt, '(i8.8)') nitrst
89            ENDIF
90            ! create the file
91            clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
92            clpath = TRIM(cn_ocerst_outdir)
93            IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
94            IF(lwp) THEN
95               WRITE(numout,*)
96               SELECT CASE ( jprstlib )
97               CASE DEFAULT         ;   WRITE(numout,*)                            &
98                   '             open ocean restart NetCDF file: ',TRIM(clpath)//clname
99               END SELECT
100               IF ( snc4set%luse )      WRITE(numout,*) '             opened for NetCDF4 chunking and compression'
101               IF( kt == nitrst - 1 ) THEN   ;   WRITE(numout,*) '             kt = nitrst - 1 = ', kt
102               ELSE                          ;   WRITE(numout,*) '             kt = '             , kt
103               ENDIF
104            ENDIF
105            !
106            CALL iom_open( TRIM(clpath)//TRIM(clname), numrow, ldwrt = .TRUE., kiolib = jprstlib )
107            lrst_oce = .TRUE.
108         ENDIF
109      ENDIF
110      !
111   END SUBROUTINE rst_opn
112
113
114   SUBROUTINE rst_write( kt )
115      !!---------------------------------------------------------------------
116      !!                   ***  ROUTINE rstwrite  ***
117      !!                     
118      !! ** Purpose :   Write restart fields in the format corresponding to jprstlib
119      !!
120      !! ** Method  :   Write in numrow when kt == nitrst in NetCDF
121      !!              file, save fields which are necessary for restart
122      !!----------------------------------------------------------------------
123      INTEGER, INTENT(in) ::   kt   ! ocean time-step
124      !!----------------------------------------------------------------------
125
126                     CALL iom_rstput( kt, nitrst, numrow, 'rdt'    , rdt       )   ! dynamics and tracer time step
127
128      IF ( .NOT. ln_diurnal_only ) THEN
129                     CALL iom_rstput( kt, nitrst, numrow, 'ub'     , ub        )     ! before fields
130                     CALL iom_rstput( kt, nitrst, numrow, 'vb'     , vb        )
131                     CALL iom_rstput( kt, nitrst, numrow, 'tb'     , tsb(:,:,:,jp_tem) )
132                     CALL iom_rstput( kt, nitrst, numrow, 'sb'     , tsb(:,:,:,jp_sal) )
133                     CALL iom_rstput( kt, nitrst, numrow, 'sshb'   , sshb      )
134                     !
135                     CALL iom_rstput( kt, nitrst, numrow, 'un'     , un        )     ! now fields
136                     CALL iom_rstput( kt, nitrst, numrow, 'vn'     , vn        )
137                     CALL iom_rstput( kt, nitrst, numrow, 'tn'     , tsn(:,:,:,jp_tem) )
138                     CALL iom_rstput( kt, nitrst, numrow, 'sn'     , tsn(:,:,:,jp_sal) )
139                     CALL iom_rstput( kt, nitrst, numrow, 'sshn'   , sshn      )
140                     CALL iom_rstput( kt, nitrst, numrow, 'rhop'   , rhop      )
141
142                  ! extra variable needed for the ice sheet coupling
143                  IF ( ln_iscpl ) THEN
144                     CALL iom_rstput( kt, nitrst, numrow, 'tmask'  , tmask     ) ! need to extrapolate T/S
145                     CALL iom_rstput( kt, nitrst, numrow, 'umask'  , umask     ) ! need to correct barotropic velocity
146                     CALL iom_rstput( kt, nitrst, numrow, 'vmask'  , vmask     ) ! need to correct barotropic velocity
147                     CALL iom_rstput( kt, nitrst, numrow, 'smask'  , ssmask    ) ! need to correct barotropic velocity
148                     CALL iom_rstput( kt, nitrst, numrow, 'e3t_n', e3t_n(:,:,:) )   ! need to compute temperature correction
149                     CALL iom_rstput( kt, nitrst, numrow, 'e3u_n', e3u_n(:,:,:) )   ! need to compute bt conservation
150                     CALL iom_rstput( kt, nitrst, numrow, 'e3v_n', e3v_n(:,:,:) )   ! need to compute bt conservation
151                     CALL iom_rstput( kt, nitrst, numrow, 'gdepw_n', gdepw_n(:,:,:) ) ! need to compute extrapolation if vvl
152                  END IF
153      ENDIF
154     
155      IF (ln_diurnal) CALL iom_rstput( kt, nitrst, numrow, 'Dsst', x_dsst    ) 
156
157      IF( kt == nitrst ) THEN
158         CALL iom_close( numrow )     ! close the restart file (only at last time step)
159!!gm         IF( .NOT. lk_trdmld )   lrst_oce = .FALSE.
160!!gm  not sure what to do here   ===>>>  ask to Sebastian
161         lrst_oce = .FALSE.
162            IF( ln_rst_list ) THEN
163               nrst_lst = MIN(nrst_lst + 1, SIZE(nstocklist,1))
164               nitrst = nstocklist( nrst_lst )
165            ENDIF
166            lrst_oce = .FALSE.
167      ENDIF
168      !
169   END SUBROUTINE rst_write
170
171
172   SUBROUTINE rst_read_open
173      !!----------------------------------------------------------------------
174      !!                   ***  ROUTINE rst_read_open  ***
175      !!
176      !! ** Purpose :   Open read files for restart (format fixed by jprstlib )
177      !!
178      !! ** Method  :   Use a non-zero, positive value of numror to assess whether or not
179      !!                the file has already been opened
180      !!----------------------------------------------------------------------
181      INTEGER        ::   jlibalt = jprstlib
182      LOGICAL        ::   llok
183      CHARACTER(lc)  ::   clpath   ! full path to ocean output restart file
184      !!----------------------------------------------------------------------
185      !
186      IF( numror <= 0 ) THEN
187         IF(lwp) THEN                                             ! Contol prints
188            WRITE(numout,*)
189            SELECT CASE ( jprstlib )
190            CASE ( jpnf90    )   ;   WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
191            END SELECT
192            IF ( snc4set%luse )      WRITE(numout,*) 'rst_read : configured with NetCDF4 support'
193            WRITE(numout,*) '~~~~~~~~'
194         ENDIF
195
196         clpath = TRIM(cn_ocerst_indir)
197         IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
198         CALL iom_open( TRIM(clpath)//cn_ocerst_in, numror, kiolib = jlibalt )
199      ENDIF
200   END SUBROUTINE rst_read_open
201
202
203   SUBROUTINE rst_read
204      !!----------------------------------------------------------------------
205      !!                   ***  ROUTINE rst_read  ***
206      !!
207      !! ** Purpose :   Read files for restart (format fixed by jprstlib )
208      !!
209      !! ** Method  :   Read in restart.nc file fields which are necessary for restart
210      !!----------------------------------------------------------------------
211      REAL(wp) ::   zrdt
212      INTEGER  ::   jk
213      !!----------------------------------------------------------------------
214
215      CALL rst_read_open           ! open restart for reading (if not already opened)
216
217      ! Check dynamics and tracer time-step consistency and force Euler restart if changed
218      IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 )   THEN
219         CALL iom_get( numror, 'rdt', zrdt )
220         IF( zrdt /= rdt )   neuler = 0
221      ENDIF
222
223      ! Diurnal DSST
224      IF( ln_diurnal ) CALL iom_get( numror, jpdom_autoglo, 'Dsst' , x_dsst  ) 
225      IF ( ln_diurnal_only ) THEN
226         IF(lwp) WRITE( numout, * ) &
227         &   "rst_read:- ln_diurnal_only set, setting rhop=rau0" 
228         rhop = rau0
229         CALL iom_get( numror, jpdom_autoglo, 'tn'     , tsn(:,:,1,jp_tem) ) 
230         RETURN
231      ENDIF 
232     
233      IF( iom_varid( numror, 'ub', ldstop = .FALSE. ) > 0 ) THEN
234         CALL iom_get( numror, jpdom_autoglo, 'ub'     , ub      )   ! before fields
235         CALL iom_get( numror, jpdom_autoglo, 'vb'     , vb      )
236         CALL iom_get( numror, jpdom_autoglo, 'tb'     , tsb(:,:,:,jp_tem) )
237         CALL iom_get( numror, jpdom_autoglo, 'sb'     , tsb(:,:,:,jp_sal) )
238         CALL iom_get( numror, jpdom_autoglo, 'sshb'   , sshb    )
239      ELSE
240         neuler = 0
241      ENDIF
242      !
243      CALL iom_get( numror, jpdom_autoglo, 'un'     , un      )   ! now    fields
244      CALL iom_get( numror, jpdom_autoglo, 'vn'     , vn      )
245      CALL iom_get( numror, jpdom_autoglo, 'tn'     , tsn(:,:,:,jp_tem) )
246      CALL iom_get( numror, jpdom_autoglo, 'sn'     , tsn(:,:,:,jp_sal) )
247      CALL iom_get( numror, jpdom_autoglo, 'sshn'   , sshn    )
248      IF( iom_varid( numror, 'rhop', ldstop = .FALSE. ) > 0 ) THEN
249         CALL iom_get( numror, jpdom_autoglo, 'rhop'   , rhop    )   ! now    potential density
250      ELSE
251         CALL eos( tsn, rhd, rhop, gdept_n(:,:,:) )   
252      ENDIF
253      !
254      IF( neuler == 0 ) THEN                                  ! Euler restart (neuler=0)
255         tsb  (:,:,:,:) = tsn  (:,:,:,:)                             ! all before fields set to now values
256         ub   (:,:,:)   = un   (:,:,:)
257         vb   (:,:,:)   = vn   (:,:,:)
258         sshb (:,:)     = sshn (:,:)
259         !
260         IF( .NOT.ln_linssh ) THEN
261            DO jk = 1, jpk
262               e3t_b(:,:,jk) = e3t_n(:,:,jk)
263            END DO
264         ENDIF
265         !
266      ENDIF
267      !
268   END SUBROUTINE rst_read
269
270   !!=====================================================================
271END MODULE restart
Note: See TracBrowser for help on using the repository browser.