New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
ldfdyn_c3d.h90 in trunk/NEMOGCM/NEMO/OPA_SRC/LDF – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/LDF/ldfdyn_c3d.h90 @ 2715

Last change on this file since 2715 was 2715, checked in by rblod, 13 years ago

First attempt to put dynamic allocation on the trunk
  • Property svn:keywords set to Id
File size: 18.8 KB
Line 
1   !!----------------------------------------------------------------------
2   !!                        ***  ldfdyn_c3d.h90  ***
3   !!----------------------------------------------------------------------
4
5   !!----------------------------------------------------------------------
6   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
7   !! $Id$
8   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   'key_dynldf_c3d'             3D lateral eddy viscosity coefficients
13   !!----------------------------------------------------------------------
14
15   SUBROUTINE ldf_dyn_c3d( ld_print )
16      !!----------------------------------------------------------------------
17      !!                  ***  ROUTINE ldf_dyn_c3d  ***
18      !!                   
19      !! ** Purpose :   initializations of the horizontal ocean physics
20      !!
21      !! ** Method  :   3D eddy viscosity coef. ( longitude, latitude, depth )
22      !!       laplacian operator   : ahm1, ahm2 defined at T- and F-points
23      !!                              ahm2, ahm4 never used
24      !!       bilaplacian operator : ahm1, ahm2 never used
25      !!                           :  ahm3, ahm4 defined at U- and V-points
26      !!       ??? explanation of the default is missing
27      !!----------------------------------------------------------------------
28      USE ldftra_oce, ONLY :   aht0
29      USE wrk_nemo  , ONLY:   wrk_in_use, wrk_not_released
30      USE wrk_nemo  , ONLY:   zcoef => wrk_1d_2
31      !!
32      LOGICAL, INTENT (in) ::   ld_print   ! If true, output arrays on numout
33      !!
34      INTEGER  ::   ji, jj, jk   ! dummy loop indices
35      REAL(wp) ::   zr = 0.2     ! maximum of the reduction factor at the bottom ocean ( 0 < zr < 1 )
36      REAL(wp) ::   zh = 500.    ! depth of at which start the reduction ( > dept(1) )
37      REAL(wp) ::   zd_max       ! maximum grid spacing over the global domain
38      REAL(wp) ::   za00, zc, zd, zetmax, zefmax, zeumax, zevmax   ! local scalars
39      !!----------------------------------------------------------------------
40
41      IF( wrk_in_use(1,2) ) THEN
42         CALL ctl_stop('ldf_dyn_c3d: requested workspace array unavailable')   ;   RETURN
43      ENDIF
44
45      IF(lwp) WRITE(numout,*)
46      IF(lwp) WRITE(numout,*) 'ldf_dyn_c3d : 3D lateral eddy viscosity coefficient'
47      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
48
49     
50      ! Set ahm1 and ahm2  ( T- and F- points) (used for laplacian operators
51      ! =================                       whatever its orientation is)
52      IF( ln_dynldf_lap ) THEN
53         ! define ahm1 and ahm2 at the right grid point position
54         ! (USER: modify ahm1 and ahm2 following your desiderata)
55
56         zd_max = MAX( MAXVAL( e1t(:,:) ), MAXVAL( e2t(:,:) ) )
57         IF( lk_mpp )   CALL mpp_max( zd_max )   ! max over the global domain
58
59         IF(lwp) WRITE(numout,*) '              laplacian operator: ahm proportional to e1'
60         IF(lwp) WRITE(numout,*) '              maximum grid-spacing = ', zd_max, ' maximum value for ahm = ', ahm0
61
62         za00 = ahm0 / zd_max
63
64         IF( ln_dynldf_iso ) THEN
65            IF(lwp) WRITE(numout,*) '              Caution, as implemented now, the isopycnal part of momentum'
66            IF(lwp) WRITE(numout,*) '                 mixing use aht0 as eddy viscosity coefficient. Thus, it is'
67            IF(lwp) WRITE(numout,*) '                 uniform and you must be sure that your ahm is greater than'
68            IF(lwp) WRITE(numout,*) '                 aht0 everywhere in the model domain.'
69         ENDIF
70
71         CALL ldf_zpf( .TRUE. , 1000., 500., 0.25, fsdept(:,:,:), ahm1 )   ! vertical profile
72         CALL ldf_zpf( .TRUE. , 1000., 500., 0.25, fsdept(:,:,:), ahm2 )   ! vertical profile
73         DO jk = 1,jpk
74            DO jj = 1, jpj
75               DO ji = 1, jpi
76                  zetmax = MAX( e1t(ji,jj), e2t(ji,jj) )
77                  zefmax = MAX( e1f(ji,jj), e2f(ji,jj) )
78                  ahm1(ji,jj,jk) = za00 * zetmax * ahm1(ji,jj,jk)
79                  ahm2(ji,jj,jk) = za00 * zefmax * ahm2(ji,jj,jk)
80               END DO
81            END DO
82         END DO
83
84
85         ! Special case for ORCA R1, R2 and R4 configurations (overwrite the value of ahm1 ahm2)
86         ! ==============================================
87         IF( cp_cfg == "orca" .AND. ( jp_cfg == 1 .OR. jp_cfg == 2 .OR. jp_cfg == 4 ) ) THEN
88            IF(lwp) WRITE(numout,*)
89            IF(lwp) WRITE(numout,*) '              ORCA R1, R2 or R4: overwrite the previous definition of ahm'
90            IF(lwp) WRITE(numout,*) '              ================='
91            CALL ldf_dyn_c3d_orca( ld_print )
92         ENDIF
93
94      ENDIF
95     
96      ! Control print
97      IF(lwp .AND. ld_print ) THEN
98         WRITE(numout,*)
99         WRITE(numout,*) '         3D ahm1 array (k=1)'
100         CALL prihre( ahm1(:,:,1), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1.e-3, numout )
101         WRITE(numout,*)
102         WRITE(numout,*) '         3D ahm2 array (k=1)'
103         CALL prihre( ahm2(:,:,1), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1.e-3, numout )
104      ENDIF
105
106
107      ! ahm3 and ahm4 at U- and V-points (used for bilaplacian operator
108      ! ================================  whatever its orientation is)
109      ! (USER: modify ahm3 and ahm4 following your desiderata)
110      ! Here: ahm is proportional to the cube of the maximum of the gridspacing
111      !       in the to horizontal direction
112
113      IF( ln_dynldf_bilap ) THEN
114
115         zd_max = MAX( MAXVAL( e1u(:,:) ), MAXVAL( e2u(:,:) ) )
116         IF( lk_mpp )   CALL mpp_max( zd_max )   ! max over the global domain
117
118         IF(lwp) WRITE(numout,*) '              bi-laplacian operator: ahm proportional to e1**3 '
119         IF(lwp) WRITE(numout,*) '              maximum grid-spacing = ', zd_max, ' maximum value for ahm = ', ahm0
120
121         za00 = ahm0_blp / ( zd_max * zd_max * zd_max )
122         DO jj = 1, jpj
123            DO ji = 1, jpi
124               zeumax = MAX( e1u(ji,jj), e2u(ji,jj) )
125               zevmax = MAX( e1v(ji,jj), e2v(ji,jj) )
126               ahm3(ji,jj,1) = za00 * zeumax * zeumax * zeumax
127               ahm4(ji,jj,1) = za00 * zevmax * zevmax * zevmax
128            END DO
129         END DO
130
131         zh = MAX( zh, fsdept(1,1,1) )   ! at least the first reach ahm0
132         IF( ln_zco ) THEN               ! z-coordinate, same profile everywhere
133            IF(lwp) WRITE(numout,'(36x," ahm ", 7x)')
134            DO jk = 1, jpk
135               IF( fsdept(1,1,jk) <= zh ) THEN
136                  zcoef(jk) = 1.e0
137               ELSE
138                  zcoef(jk) = 1.e0 + ( zr - 1.e0 )   &
139                     &               * (  1. - EXP( ( fsdept(1,1,jk   ) - zh ) / zh )  )   &
140                     &               / (  1. - EXP( ( fsdept(1,1,jpkm1) - zh ) / zh )  )
141               ENDIF
142               ahm3(:,:,jk) = ahm3(:,:,1) * zcoef(jk)
143               ahm4(:,:,jk) = ahm4(:,:,1) * zcoef(jk)
144               IF(lwp) WRITE(numout,'(34x,E7.2,8x,i3)') zcoef(jk) * ahm0, jk
145            END DO
146         ELSE                            ! partial steps or s-ccordinate
147            zc = MAXVAL( fsdept(:,:,jpkm1) )
148            IF( lk_mpp )   CALL mpp_max( zc )   ! max over the global domain
149
150            zc = 1. / (  1. - EXP( ( zc - zh ) / zh )  )
151            DO jk = 2, jpkm1
152               DO jj = 1, jpj
153                  DO ji = 1, jpi
154                     IF( fsdept(ji,jj,jk) <= zh ) THEN
155                        ahm3(ji,jj,jk) = ahm3(ji,jj,1)
156                        ahm4(ji,jj,jk) = ahm4(ji,jj,1)
157                     ELSE
158                        zd = 1.e0 + ( zr - 1.e0 ) * (  1. - EXP( ( fsdept(ji,jj,jk) - zh ) / zh )  ) * zc
159                        ahm3(ji,jj,jk) = ahm3(ji,jj,1) * zd
160                        ahm4(ji,jj,jk) = ahm4(ji,jj,1) * zd
161                     ENDIF
162                  END DO
163               END DO
164            END DO
165            ahm3(:,:,jpk) = ahm3(:,:,jpkm1)
166            ahm4(:,:,jpk) = ahm4(:,:,jpkm1)
167            IF(lwp) WRITE(numout,'(36x," ahm ", 7x)')
168            DO jk = 1, jpk
169               IF(lwp) WRITE(numout,'(30x,E10.2,8x,i3)') ahm3(1,1,jk), jk
170            END DO
171         ENDIF
172
173         ! Control print
174         IF( lwp .AND. ld_print ) THEN
175            WRITE(numout,*)
176            WRITE(numout,*) 'inildf: ahm3 array at level 1'
177            CALL prihre(ahm3(:,:,1  ),jpi,jpj,1,jpi,1,1,jpj,1,1.e-3,numout)
178            WRITE(numout,*)
179            WRITE(numout,*) 'inildf: ahm4 array at level 1'
180            CALL prihre(ahm4(:,:,jpk),jpi,jpj,1,jpi,1,1,jpj,1,1.e-3,numout)
181         ENDIF
182      ENDIF
183      !
184      IF( wrk_not_released(1,2) )   CALL ctl_stop('ldf_dyn_c3d: failed to release workspace array')
185      !
186   END SUBROUTINE ldf_dyn_c3d
187
188
189   SUBROUTINE ldf_dyn_c3d_orca( ld_print )
190      !!----------------------------------------------------------------------
191      !!                  ***  ROUTINE ldf_dyn_c3d  ***
192      !!                   
193      !! ** Purpose :   ORCA R1, R2 and R4 only
194      !!
195      !! ** Method  :   blah blah blah ....
196      !!----------------------------------------------------------------------
197      USE ldftra_oce, ONLY:   aht0
198      USE wrk_nemo  , ONLY:   wrk_in_use, wrk_not_released, iwrk_in_use, iwrk_not_released
199      USE wrk_nemo  , ONLY:   icof  => iwrk_2d_1
200      USE wrk_nemo  , ONLY:   zahm0 =>  wrk_2d_1
201      USE wrk_nemo  , ONLY:   zcoef =>  wrk_1d_1
202      !!
203      LOGICAL, INTENT(in) ::   ld_print   ! If true, output arrays on numout
204      !!
205      INTEGER ::   ji, jj, jk, jn      ! dummy loop indices
206      INTEGER ::   ii0, ii1, ij0, ij1  ! local integers
207      INTEGER ::   inum, iim, ijm      !
208      INTEGER ::   ifreq, il1, il2, ij, ii
209      INTEGER, DIMENSION(jpidta, jpjdta) ::   idata
210
211      REAL(wp) ::   zahmeq, zcoff, zcoft, zmsk   ! local scalars
212      REAL(wp) ::   zemax , zemin, zeref, zahmm
213      CHARACTER (len=15) ::   clexp
214      !!----------------------------------------------------------------------
215
216      IF( iwrk_in_use(2,1) .OR. wrk_in_use(2,1) .OR. wrk_in_use(1,1) ) THEN
217         CALL ctl_stop('ldf_dyn_c3d_orca: requested workspace arrays are unavailable')   ;   RETURN
218      ENDIF
219
220      IF(lwp) WRITE(numout,*)
221      IF(lwp) WRITE(numout,*) 'ldfdyn_c3d_orca : 3D eddy viscosity coefficient'
222      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~'
223      IF(lwp) WRITE(numout,*) '        orca R1, R2 or R4 configuration: reduced in the surface Eq. strip '
224
225      ! Read 2d integer array to specify western boundary increase in the
226      ! ===================== equatorial strip (20N-20S) defined at t-points
227
228      CALL ctl_opn( inum, 'ahmcoef', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp )
229      READ(inum,9101) clexp, iim, ijm
230      READ(inum,'(/)')
231      ifreq = 40
232      il1 = 1
233      DO jn = 1, jpidta/ifreq+1
234         READ(inum,'(/)')
235         il2 = MIN( jpidta, il1+ifreq-1 )
236         READ(inum,9201) ( ii, ji = il1, il2, 5 )
237         READ(inum,'(/)')
238         DO jj = jpjdta, 1, -1
239            READ(inum,9202) ij, ( idata(ji,jj), ji = il1, il2 )
240         END DO
241         il1 = il1 + ifreq
242      END DO
243     
244      DO jj = 1, nlcj
245         DO ji = 1, nlci
246            icof(ji,jj) = idata( mig(ji), mjg(jj) )
247         END DO
248      END DO
249      DO jj = nlcj+1, jpj
250         DO ji = 1, nlci
251            icof(ji,jj) = icof(ji,nlcj)
252         END DO
253      END DO
254      DO jj = 1, jpj
255         DO ji = nlci+1, jpi
256            icof(ji,jj) = icof(nlci,jj)
257         END DO
258      END DO
259     
2609101  FORMAT(1x,a15,2i8)
2619201  FORMAT(3x,13(i3,12x))
2629202  FORMAT(i3,41i3)
263     
264      ! Set ahm1 and ahm2
265      ! =================
266     
267      ! define ahm1 and ahm2 at the right grid point position
268      ! (USER: modify ahm1 and ahm2 following your desiderata)
269      ! biharmonic : ahm1 (ahm2) defined at u- (v-) point
270      ! harmonic   : ahm1 (ahm2) defined at t- (f-) point
271     
272      ! first level : as for 2D coefficients
273     
274      ! Decrease ahm to zahmeq m2/s in the tropics
275      ! (from 90 to 20 degre: ahm = constant
276      ! from 20 to  2.5 degre: ahm = decrease in (1-cos)/2
277      ! from  2.5 to  0 degre: ahm = constant
278      ! symmetric in the south hemisphere)
279     
280      IF( jp_cfg == 4 )   THEN
281         zahmeq = 5.0 * aht0
282         zahmm  = min( 160000.0, ahm0)
283         zemax = MAXVAL ( e1t(:,:) * e2t(:,:), tmask(:,:,1) .GE. 0.5 )
284         zemin = MINVAL ( e1t(:,:) * e2t(:,:), tmask(:,:,1) .GE. 0.5 )
285         zeref = MAXVAL ( e1t(:,:) * e2t(:,:),   &
286             &   tmask(:,:,1) .GE. 0.5 .AND. ABS(gphit(:,:)) .GT. 50. )
287 
288         DO jj = 1, jpj
289           DO ji = 1, jpi
290              zmsk = e1t(ji,jj) * e2t(ji,jj)
291              IF( abs(gphit(ji,jj)) .LE. 15 ) THEN
292                 zahm0(ji,jj) = ahm0
293              ELSE
294                 IF( zmsk .GE. zeref ) THEN
295                    zahm0(ji,jj) = ahm0
296                 ELSE
297                    zahm0(ji,jj) = zahmm + (ahm0-zahmm)*(1.0 -   &
298                        &          cos((rpi*0.5*(zmsk-zemin)/(zeref-zemin))))
299                 ENDIF
300              ENDIF
301           END DO
302         END DO
303      ENDIF
304
305      IF( jp_cfg == 2 )   THEN
306         zahmeq     = aht0
307         zahmm      = ahm0
308         zahm0(:,:) = ahm0
309      ENDIF
310
311      IF( jp_cfg == 1 )   THEN
312         zahmeq     = aht0  ! reduced to aht0 on equator; set to ahm0 if no tropical reduction is required
313         zahmm      = ahm0
314         zahm0(:,:) = ahm0
315      ENDIF
316
317      DO jj = 1, jpj
318         DO ji = 1, jpi
319            IF( ABS(gphif(ji,jj)) >= 20.) THEN
320               ahm2(ji,jj,1) =  zahm0(ji,jj)
321            ELSEIF( ABS(gphif(ji,jj)) <= 2.5) THEN
322               ahm2(ji,jj,1) =  zahmeq
323            ELSE
324               ahm2(ji,jj,1) = zahmeq + (zahm0(ji,jj)-zahmeq)/2.   &
325                  &            *(1.-COS( rad*(ABS(gphif(ji,jj))-2.5)*180./17.5 ) )
326            ENDIF
327            IF( ABS(gphit(ji,jj)) >= 20.) THEN
328               ahm1(ji,jj,1) =  zahm0(ji,jj)
329            ELSEIF( ABS(gphit(ji,jj)) <= 2.5) THEN
330               ahm1(ji,jj,1) =  zahmeq
331            ELSE
332               ahm1(ji,jj,1) = zahmeq + (zahm0(ji,jj)-zahmeq)/2.   &
333                  &            *(1.-COS( rad*(ABS(gphit(ji,jj))-2.5)*180./17.5 ) )
334            ENDIF
335         END DO
336      END DO
337     
338      ! increase along western boundaries of equatorial strip
339      ! t-point
340      DO jj = 1, jpjm1
341         DO ji = 1, jpim1
342            zcoft = float( icof(ji,jj) ) / 100.
343            ahm1(ji,jj,1) = zcoft * zahm0(ji,jj) + (1.-zcoft) * ahm1(ji,jj,1)
344         END DO
345      END DO
346      ! f-point
347      icof(:,:) = icof(:,:) * tmask(:,:,1)
348      DO jj = 1, jpjm1
349         DO ji = 1, jpim1   ! NO vector opt.
350            zmsk = tmask(ji,jj+1,1) + tmask(ji+1,jj+1,1) + tmask(ji,jj,1) + tmask(ji,jj+1,1)
351            IF( zmsk == 0. ) THEN
352               zcoff = 1.
353            ELSE
354               zcoff = FLOAT( icof(ji,jj+1) + icof(ji+1,jj+1) + icof(ji,jj) + icof(ji,jj+1) )   &
355                     / (zmsk * 100.)
356            ENDIF
357            ahm2(ji,jj,1) = zcoff * zahm0(ji,jj) + (1.-zcoff) * ahm2(ji,jj,1)
358         END DO
359      END DO
360
361      ! other level: re-increase the coef in the deep ocean
362      !==================================================================
363      ! Prior to v3.3, zcoeff was hardwired according to k-index jk.
364      !
365      ! From v3.3 onwards this has been generalised to a function of
366      ! depth so that it can be used with any number of levels.
367      !
368      ! The function has been chosen to match the original values (shown
369      ! in the following comments) when using the standard 31 ORCA levels. 
370      !     DO jk = 1, 21
371      !        zcoef(jk) = 1._wp
372      !     END DO
373      !     zcoef(22) = 2._wp
374      !     zcoef(23) = 3._wp
375      !     zcoef(24) = 5._wp
376      !     zcoef(25) = 7._wp
377      !     zcoef(26) = 9._wp
378      !     DO jk = 27, jpk
379      !        zcoef(jk) = 10._wp
380      !     END DO
381      !==================================================================
382
383       IF(lwp) THEN
384          WRITE(numout,*)
385          WRITE(numout,*) '         1D zcoef array '
386          WRITE(numout,*) '         ~~~~~~~~~~~~~~ '
387          WRITE(numout,*)
388          WRITE(numout,*) '    jk        zcoef '
389       ENDIF
390
391      DO jk=1, jpk
392         zcoef(jk) = 1.0_wp + NINT(9.0_wp*(gdept_0(jk)-800.0_wp)/(3000.0_wp-800.0_wp))
393         zcoef(jk) = MIN(10.0_wp, MAX(1.0_wp, zcoef(jk)))
394         IF(lwp) WRITE(numout,'(4x,i3,6x,f7.3)') jk,zcoef(jk)
395      END DO
396
397      DO jk = 2, jpk
398         ahm1(:,:,jk) = MIN( zahm0(:,:), zcoef(jk) * ahm1(:,:,1) )
399         ahm2(:,:,jk) = MIN( zahm0(:,:), zcoef(jk) * ahm2(:,:,1) )
400      END DO
401
402      IF( jp_cfg == 4 )   THEN         ! Limit AHM in Gibraltar strait
403         ij0 = 50   ;   ij1 = 53
404         ii0 = 69   ;   ii1 = 71
405         DO jk = 1, jpk
406            ahm1(mi0(ii0):mi1(ii1),mj0(ij0):mj1(ij1),jk) = MIN( zahmm, ahm1(mi0(ii0):mi1(ii1),mj0(ij0):mj1(ij1),jk) )
407            ahm2(mi0(ii0):mi1(ii1),mj0(ij0):mj1(ij1),jk) = MIN( zahmm, ahm2(mi0(ii0):mi1(ii1),mj0(ij0):mj1(ij1),jk) )
408         END DO
409      ENDIF
410      CALL lbc_lnk( ahm1, 'T', 1. )   ! Lateral boundary conditions (unchanged sign)
411      CALL lbc_lnk( ahm2, 'F', 1. )
412
413
414      IF(lwp) THEN                    ! Control print
415         WRITE(numout,*)
416         WRITE(numout,*) '         3D ahm1 array (k=1)'
417         CALL prihre( ahm1(:,:,1), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1.e-3, numout )
418         WRITE(numout,*)
419         WRITE(numout,*) '         3D ahm2 array (k=1)'
420         CALL prihre( ahm2(:,:,1), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1.e-3, numout )
421         WRITE(numout,*)
422         WRITE(numout,*) '         3D ahm2 array (k=jpk)'
423         CALL prihre( ahm2(:,:,jpk), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1.e-3, numout )
424      ENDIF
425
426
427      ! Set ahm3 and ahm4
428      ! =================
429
430      ! define ahm3 and ahm4 at the right grid point position
431      ! initialization to a constant value
432      !     (USER: modify ahm3 and ahm4 following your desiderata)
433      !     harmonic isopycnal or geopotential:
434      !                          ahm3 (ahm4) defined at u- (v-) point
435      DO jk = 1, jpk
436         DO jj = 2, jpj
437            DO ji = 2, jpi
438               ahm3(ji,jj,jk) = 0.5 * ( ahm2(ji,jj,jk) + ahm2(ji  ,jj-1,jk) )
439               ahm4(ji,jj,jk) = 0.5 * ( ahm2(ji,jj,jk) + ahm2(ji-1,jj  ,jk) )
440            END DO
441         END DO
442      END DO
443      ahm3 ( :, 1, :) = ahm3 ( :, 2, :)
444      ahm4 ( :, 1, :) = ahm4 ( :, 2, :)
445     
446      CALL lbc_lnk( ahm3, 'U', 1. )    ! Lateral boundary conditions (unchanged sign)
447      CALL lbc_lnk( ahm4, 'V', 1. )
448
449      ! Control print
450
451      IF( lwp .AND. ld_print ) THEN
452         WRITE(numout,*)
453         WRITE(numout,*) '         ahm3 array level 1'
454         CALL prihre(ahm3(:,:,1),jpi,jpj,1,jpi,1,1,jpj,1,1.e-3,numout)
455         WRITE(numout,*)
456         WRITE(numout,*) '         ahm4 array level 1'
457         CALL prihre(ahm4(:,:,1),jpi,jpj,1,jpi,1,1,jpj,1,1.e-3,numout)
458      ENDIF
459
460      IF( iwrk_not_released(2,1) .OR.   &
461           wrk_not_released(2,1) .OR.   &
462           wrk_not_released(1,1)   ) CALL ctl_stop('ldf_dyn_c3d_orca: failed to release workspace arrays')
463      !
464   END SUBROUTINE ldf_dyn_c3d_orca
Note: See TracBrowser for help on using the repository browser.