New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcapr.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/SBC/sbcapr.F90 @ 2528

Last change on this file since 2528 was 2528, checked in by rblod, 13 years ago

Update NEMOGCM from branch nemo_v3_3_beta
File size: 9.6 KB
Line 
1MODULE sbcapr
2   !!======================================================================
3   !!                       ***  MODULE  sbcapr  ***
4   !! Surface module :   atmospheric pressure forcing
5   !!======================================================================
6   !! History :  3.3  !   2010-09  (J. Chanut, C. Bricaud, G. Madec)  Original code
7   !!----------------------------------------------------------------------
8   
9   !!----------------------------------------------------------------------
10   !!   sbc_apr        : read atmospheric pressure in netcdf files
11   !!----------------------------------------------------------------------
12   USE bdy_par         ! Unstructured boundary parameters
13   USE obc_par         ! open boundary condition parameters
14   USE dom_oce         ! ocean space and time domain
15   USE sbc_oce         ! surface boundary condition
16   USE dynspg_oce      ! surface pressure gradient variables
17   USE phycst          ! physical constants
18   USE fldread         ! read input fields
19   USE in_out_manager  ! I/O manager
20   USE lib_fortran     ! distribued memory computing library
21   USE iom
22   USE restart
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   sbc_apr    ! routine called in sbcmod
28   
29   !                                         !!* namsbc_apr namelist (Atmospheric PRessure) *
30   LOGICAL, PUBLIC ::   ln_apr_obc = .FALSE.  !: inverse barometer added to OBC ssh data
31   LOGICAL, PUBLIC ::   ln_apr_bdy = .FALSE.  !: inverse barometer added to BDY ssh data
32   LOGICAL, PUBLIC ::   ln_ref_apr = .FALSE.  !: ref. pressure: global mean Patm (F) or a constant (F)
33
34   REAL(wp), ALLOCATABLE, PUBLIC, DIMENSION(:,:) ::   ssh_ib    ! Inverse barometer now    sea surface height     [m]
35   REAL(wp), ALLOCATABLE, PUBLIC, DIMENSION(:,:) ::   ssh_ibb   ! Inverse barometer before sea surface height     [m]
36   REAL(wp), ALLOCATABLE, PUBLIC, DIMENSION(:,:) ::   apr       ! atmospheric pressure at kt                   [N/m2]
37   
38   REAL(wp) ::   rpref = 101000._wp   ! reference atmospheric pressure          [N/m2]
39   REAL(wp) ::   tarea                ! whole domain mean masked ocean surface
40   REAL(wp) ::   r1_grau              ! = 1.e0 / (grav * rau0)
41
42   
43   TYPE(FLD), ALLOCATABLE, DIMENSION(:)   ::   sf_apr   ! structure of input fields (file informations, fields read)
44
45   !! * Substitutions
46#  include "domzgr_substitute.h90"
47   !!----------------------------------------------------------------------
48   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
49   !! $Id $
50   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
51   !!----------------------------------------------------------------------
52CONTAINS
53
54   SUBROUTINE sbc_apr( kt )
55      !!---------------------------------------------------------------------
56      !!                     ***  ROUTINE sbc_apr  ***
57      !!
58      !! ** Purpose :   read atmospheric pressure fields in netcdf files.
59      !!
60      !! ** Method  : - Read namelist namsbc_apr
61      !!              - Read Patm fields in netcdf files
62      !!              - Compute reference atmospheric pressure
63      !!              - Compute inverse barometer ssh
64      !! ** action  :   apr      : atmospheric pressure at kt
65      !!                ssh_ib   : inverse barometer ssh at kt
66      !!---------------------------------------------------------------------
67      INTEGER, INTENT(in)::   kt   ! ocean time step
68      !!
69      INTEGER            ::   ierror  ! local integer
70      REAL(wp)           ::   zpref   ! local scalar
71      !!
72      CHARACTER(len=100) ::  cn_dir   ! Root directory for location of ssr files
73      TYPE(FLD_N)        ::  sn_apr   ! informations about the fields to be read
74      !!
75      NAMELIST/namsbc_apr/ cn_dir, sn_apr, ln_ref_apr
76      !!----------------------------------------------------------------------
77      !
78      !
79      !                                         ! -------------------- !
80      IF( kt == nit000 ) THEN                   ! First call kt=nit000 !
81         !                                      ! -------------------- !
82         !                                            !* set file information (default values)
83         ! ... default values (NB: frequency positive => hours, negative => months)
84         !            !   file   ! frequency !  variable  ! time intep !  clim   ! 'yearly' or ! weights  ! rotation !
85         !            !   name   !  (hours)  !   name     !   (T/F)    !  (T/F)  !  'monthly'  ! filename ! pairs    !
86         sn_apr = FLD_N( 'patm'  ,    24     ,  'patm'    ,  .false.   , .true.  ,   'yearly'  , ''       , ''       )
87         cn_dir  = './'          ! directory in which the Patm data are
88
89         REWIND( numnam )                             !* read in namlist namsbc_apr
90         READ  ( numnam, namsbc_apr ) 
91         !
92         ALLOCATE( sf_apr(1), STAT=ierror )           !* allocate and fill sf_sst (forcing structure) with sn_sst
93         IF( ierror > 0 ) THEN
94            CALL ctl_stop( 'sbc_apr: unable to allocate sf_apr structure' )   ;   RETURN
95         ENDIF
96         CALL fld_fill( sf_apr, (/ sn_apr /), cn_dir, 'sbc_apr', 'Atmospheric pressure ', 'namsbc_apr' )
97                                ALLOCATE( sf_apr(1)%fnow(jpi,jpj,1)   )
98         IF( sn_apr%ln_tint )   ALLOCATE( sf_apr(1)%fdta(jpi,jpj,1,2) )
99                                ALLOCATE( ssh_ib(jpi,jpj) , ssh_ibb(jpi,jpj) )
100                                ALLOCATE( apr (jpi,jpj) )
101         !
102         IF(lwp) THEN                                 !* control print
103            WRITE(numout,*)
104            WRITE(numout,*) '   Namelist namsbc_apr : Atmospheric PRessure as extrenal forcing'
105            WRITE(numout,*) '      ref. pressure: global mean Patm (T) or a constant (F)  ln_ref_apr = ', ln_ref_apr
106         ENDIF
107         !
108         IF( ln_ref_apr ) THEN                        !* Compute whole inner domain mean masked ocean surface
109            tarea = glob_sum( e1t(:,:) * e2t(:,:) )
110            IF(lwp) WRITE(numout,*) '         Variable ref. Patm computed over a ocean surface of ', tarea*1e-6, 'km2'
111         ELSE
112            IF(lwp) WRITE(numout,*) '         Reference Patm used : ', rpref, ' N/m2'
113         ENDIF
114         !
115         r1_grau = 1.e0 / (grav * rau0)               !* constant for optimization
116         !
117         !                                            !* control check
118         IF( ln_apr_obc .OR. ln_apr_bdy   )   &
119            CALL ctl_stop( 'sbc_apr: inverse barometer added to OBC or BDY ssh data not yet implemented ' )
120         IF( ln_apr_obc .AND. .NOT. lk_obc )   &
121            CALL ctl_stop( 'sbc_apr: add inverse barometer to OBC requires to use key_obc' )
122         IF( ln_apr_bdy .AND. .NOT. lk_bdy )   &
123            CALL ctl_stop( 'sbc_apr: add inverse barometer to OBC requires to use key_bdy' )
124         IF( ( ln_apr_obc .OR. ln_apr_bdy ) .AND. .NOT. lk_dynspg_ts )   &
125            CALL ctl_stop( 'sbc_apr: use inverse barometer ssh at open boundary ONLY possible with time-splitting' )
126         IF( ( ln_apr_obc .OR. ln_apr_bdy ) .AND. .NOT. ln_apr_dyn   )   &
127            CALL ctl_stop( 'sbc_apr: use inverse barometer ssh at open boundary ONLY requires ln_apr_dyn=T' )
128      ENDIF
129
130      !                                         ! ========================== !
131      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN      !    At each sbc time-step   !
132         !                                      ! ===========+++============ !
133         !
134         IF( kt /= nit000 )   ssh_ibb(:,:) = ssh_ib(:,:)    !* Swap of ssh_ib fields
135         !
136         CALL fld_read( kt, nn_fsbc, sf_apr )               !* input Patm provided at kt + nn_fsbc/2
137         !
138         !                                                  !* update the reference atmospheric pressure (if necessary)
139         IF( ln_ref_apr )   rpref = glob_sum( sf_apr(1)%fnow(:,:,1) * e1t(:,:) * e2t(:,:) ) / tarea
140         !
141         !                                                  !* Patm related forcing at kt
142         ssh_ib(:,:) = - ( sf_apr(1)%fnow(:,:,1) - rpref ) * r1_grau    ! equivalent ssh (inverse barometer)
143         apr   (:,:) =     sf_apr(1)%fnow(:,:,1)                        ! atmospheric pressure
144         !
145         CALL iom_put( "ssh_ib", ssh_ib )                   !* output the inverse barometer ssh
146      ENDIF
147
148      !                                         ! ---------------------------------------- !
149      IF( kt == nit000 ) THEN                   !   set the forcing field at nit000 - 1    !
150         !                                      ! ---------------------------------------- !
151         !                                            !* Restart: read in restart file
152         IF( ln_rstart .AND. iom_varid( numror, 'ssh_ibb', ldstop = .FALSE. ) > 0 ) THEN
153            IF(lwp) WRITE(numout,*) 'sbc_apr:   ssh_ibb read in the restart file'
154            CALL iom_get( numror, jpdom_autoglo, 'ssh_ibb', ssh_ibb )   ! before inv. barometer ssh
155            !
156         ELSE                                         !* no restart: set from nit000 values
157            IF(lwp) WRITE(numout,*) 'sbc_apr:   ssh_ibb set to nit000 values'
158            ssh_ibb(:,:) = ssh_ib(:,:)
159         ENDIF
160      ENDIF
161      !                                         ! ---------------------------------------- !
162      IF( lrst_oce ) THEN                       !      Write in the ocean restart file     !
163         !                                      ! ---------------------------------------- !
164         IF(lwp) WRITE(numout,*)
165         IF(lwp) WRITE(numout,*) 'sbc_apr : ssh_ib written in ocean restart file at it= ', kt,' date= ', ndastp
166         IF(lwp) WRITE(numout,*) '~~~~'
167         CALL iom_rstput( kt, nitrst, numrow, 'ssh_ibb' , ssh_ib )
168      ENDIF
169      !
170   END SUBROUTINE sbc_apr
171     
172   !!======================================================================
173END MODULE sbcapr
Note: See TracBrowser for help on using the repository browser.