New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcapr.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/SBC/sbcapr.F90 @ 7881

Last change on this file since 7881 was 6140, checked in by timgraham, 8 years ago

Merge of branches/2015/dev_merge_2015 back into trunk. Merge excludes NEMOGCM/TOOLS/OBSTOOLS/ for now due to issues with the change of file type. Will sort these manually with further commits.

Branch merged as follows:
In the working copy of branch ran:
svn merge svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/trunk@HEAD
Small conflicts due to bug fixes applied to trunk since the dev_merge_2015 was copied. Bug fixes were applied to the branch as well so these were easy to resolve.
Branch committed at this stage

In working copy run:
svn switch svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/trunk
to switch working copy

Run:
svn merge --reintegrate svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/branches/2015/dev_merge_2015
to merge the branch into the trunk and then commit - no conflicts at this stage.

  • Property svn:keywords set to Id
File size: 8.8 KB
Line 
1MODULE sbcapr
2   !!======================================================================
3   !!                       ***  MODULE  sbcapr  ***
4   !! Surface module :   atmospheric pressure forcing
5   !!======================================================================
6   !! History :  3.3  !   2010-09  (J. Chanut, C. Bricaud, G. Madec)  Original code
7   !!----------------------------------------------------------------------
8   
9   !!----------------------------------------------------------------------
10   !!   sbc_apr        : read atmospheric pressure in netcdf files
11   !!----------------------------------------------------------------------
12   USE dom_oce         ! ocean space and time domain
13   USE sbc_oce         ! surface boundary condition
14   USE phycst          ! physical constants
15   !
16   USE fldread         ! read input fields
17   USE in_out_manager  ! I/O manager
18   USE lib_fortran     ! distribued memory computing library
19   USE iom             ! IOM library
20   USE lib_mpp         ! MPP library
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   sbc_apr    ! routine called in sbcmod
26   
27   !                                !!* namsbc_apr namelist (Atmospheric PRessure) *
28   LOGICAL, PUBLIC ::   ln_apr_obc   !: inverse barometer added to OBC ssh data
29   LOGICAL, PUBLIC ::   ln_ref_apr   !: ref. pressure: global mean Patm (F) or a constant (F)
30   REAL(wp)        ::   rn_pref      !  reference atmospheric pressure   [N/m2]
31
32   REAL(wp), ALLOCATABLE, SAVE, PUBLIC, DIMENSION(:,:) ::   ssh_ib    ! Inverse barometer now    sea surface height   [m]
33   REAL(wp), ALLOCATABLE, SAVE, PUBLIC, DIMENSION(:,:) ::   ssh_ibb   ! Inverse barometer before sea surface height   [m]
34   REAL(wp), ALLOCATABLE, SAVE, PUBLIC, DIMENSION(:,:) ::   apr       ! atmospheric pressure at kt                 [N/m2]
35   
36   REAL(wp) ::   tarea                ! whole domain mean masked ocean surface
37   REAL(wp) ::   r1_grau              ! = 1.e0 / (grav * rau0)
38   
39   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_apr   ! structure of input fields (file informations, fields read)
40
41   !!----------------------------------------------------------------------
42   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
43   !! $Id$
44   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE sbc_apr( kt )
49      !!---------------------------------------------------------------------
50      !!                     ***  ROUTINE sbc_apr  ***
51      !!
52      !! ** Purpose :   read atmospheric pressure fields in netcdf files.
53      !!
54      !! ** Method  : - Read namelist namsbc_apr
55      !!              - Read Patm fields in netcdf files
56      !!              - Compute reference atmospheric pressure
57      !!              - Compute inverse barometer ssh
58      !! ** action  :   apr      : atmospheric pressure at kt
59      !!                ssh_ib   : inverse barometer ssh at kt
60      !!---------------------------------------------------------------------
61      INTEGER, INTENT(in)::   kt   ! ocean time step
62      !
63      INTEGER            ::   ierror  ! local integer
64      INTEGER            ::   ios     ! Local integer output status for namelist read
65      !!
66      CHARACTER(len=100) ::  cn_dir   ! Root directory for location of ssr files
67      TYPE(FLD_N)        ::  sn_apr   ! informations about the fields to be read
68      !!
69      NAMELIST/namsbc_apr/ cn_dir, sn_apr, ln_ref_apr, rn_pref, ln_apr_obc
70      !!----------------------------------------------------------------------
71      !
72      !                                         ! -------------------- !
73      IF( kt == nit000 ) THEN                   ! First call kt=nit000 !
74         !                                      ! -------------------- !
75         REWIND( numnam_ref )              ! Namelist namsbc_apr in reference namelist : File for atmospheric pressure forcing
76         READ  ( numnam_ref, namsbc_apr, IOSTAT = ios, ERR = 901)
77901      IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_apr in reference namelist', lwp )
78
79         REWIND( numnam_cfg )              ! Namelist namsbc_apr in configuration namelist : File for atmospheric pressure forcing
80         READ  ( numnam_cfg, namsbc_apr, IOSTAT = ios, ERR = 902 )
81902      IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_apr in configuration namelist', lwp )
82         IF(lwm) WRITE ( numond, namsbc_apr )
83         !
84         ALLOCATE( sf_apr(1), STAT=ierror )           !* allocate and fill sf_sst (forcing structure) with sn_sst
85         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_apr: unable to allocate sf_apr structure' )
86         !
87         CALL fld_fill( sf_apr, (/ sn_apr /), cn_dir, 'sbc_apr', 'Atmospheric pressure ', 'namsbc_apr' )
88                                ALLOCATE( sf_apr(1)%fnow(jpi,jpj,1)   )
89         IF( sn_apr%ln_tint )   ALLOCATE( sf_apr(1)%fdta(jpi,jpj,1,2) )
90                                ALLOCATE( ssh_ib(jpi,jpj) , ssh_ibb(jpi,jpj) )
91                                ALLOCATE( apr (jpi,jpj) )
92         !
93         IF(lwp) THEN                                 !* control print
94            WRITE(numout,*)
95            WRITE(numout,*) '   Namelist namsbc_apr : Atmospheric PRessure as extrenal forcing'
96            WRITE(numout,*) '      ref. pressure: global mean Patm (T) or a constant (F)  ln_ref_apr = ', ln_ref_apr
97         ENDIF
98         !
99         IF( ln_ref_apr ) THEN                        !* Compute whole inner domain mean masked ocean surface
100            tarea = glob_sum( e1e2t(:,:) )
101            IF(lwp) WRITE(numout,*) '         Variable ref. Patm computed over a ocean surface of ', tarea*1e-6, 'km2'
102         ELSE
103            IF(lwp) WRITE(numout,*) '         Reference Patm used : ', rn_pref, ' N/m2'
104         ENDIF
105         !
106         r1_grau = 1.e0 / (grav * rau0)               !* constant for optimization
107         !
108         !                                            !* control check
109         IF ( ln_apr_obc  ) THEN
110            IF(lwp) WRITE(numout,*) '         Inverse barometer added to OBC ssh data'
111         ENDIF
112!jc: stop below should rather be a warning
113         IF( ln_apr_obc .AND. .NOT.ln_apr_dyn   )   &
114            CALL ctl_stop( 'sbc_apr: use inverse barometer ssh at open boundary ONLY requires ln_apr_dyn=T' )
115      ENDIF
116
117      !                                         ! ========================== !
118      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN      !    At each sbc time-step   !
119         !                                      ! ===========+++============ !
120         !
121         IF( kt /= nit000 )   ssh_ibb(:,:) = ssh_ib(:,:)    !* Swap of ssh_ib fields
122         !
123         CALL fld_read( kt, nn_fsbc, sf_apr )               !* input Patm provided at kt + nn_fsbc/2
124         !
125         !                                                  !* update the reference atmospheric pressure (if necessary)
126         IF( ln_ref_apr )   rn_pref = glob_sum( sf_apr(1)%fnow(:,:,1) * e1e2t(:,:) ) / tarea
127         !
128         !                                                  !* Patm related forcing at kt
129         ssh_ib(:,:) = - ( sf_apr(1)%fnow(:,:,1) - rn_pref ) * r1_grau    ! equivalent ssh (inverse barometer)
130         apr   (:,:) =     sf_apr(1)%fnow(:,:,1)                        ! atmospheric pressure
131         !
132         CALL iom_put( "ssh_ib", ssh_ib )                   !* output the inverse barometer ssh
133      ENDIF
134
135      !                                         ! ---------------------------------------- !
136      IF( kt == nit000 ) THEN                   !   set the forcing field at nit000 - 1    !
137         !                                      ! ---------------------------------------- !
138         !                                            !* Restart: read in restart file
139         IF( ln_rstart .AND. iom_varid( numror, 'ssh_ibb', ldstop = .FALSE. ) > 0 ) THEN
140            IF(lwp) WRITE(numout,*) 'sbc_apr:   ssh_ibb read in the restart file'
141            CALL iom_get( numror, jpdom_autoglo, 'ssh_ibb', ssh_ibb )   ! before inv. barometer ssh
142            !
143         ELSE                                         !* no restart: set from nit000 values
144            IF(lwp) WRITE(numout,*) 'sbc_apr:   ssh_ibb set to nit000 values'
145            ssh_ibb(:,:) = ssh_ib(:,:)
146         ENDIF
147      ENDIF
148      !                                         ! ---------------------------------------- !
149      IF( lrst_oce ) THEN                       !      Write in the ocean restart file     !
150         !                                      ! ---------------------------------------- !
151         IF(lwp) WRITE(numout,*)
152         IF(lwp) WRITE(numout,*) 'sbc_apr : ssh_ib written in ocean restart file at it= ', kt,' date= ', ndastp
153         IF(lwp) WRITE(numout,*) '~~~~'
154         CALL iom_rstput( kt, nitrst, numrow, 'ssh_ibb' , ssh_ib )
155      ENDIF
156      !
157   END SUBROUTINE sbc_apr
158     
159   !!======================================================================
160END MODULE sbcapr
Note: See TracBrowser for help on using the repository browser.