source: trunk/NEMOGCM/NEMO/OPA_SRC/SBC/sbcapr.F90 @ 8524

Last change on this file since 8524 was 8524, checked in by cbricaud, 3 years ago

bugfix in trunk for ticket #1922

  • Property svn:keywords set to Id
File size: 9.3 KB
Line 
1MODULE sbcapr
2   !!======================================================================
3   !!                       ***  MODULE  sbcapr  ***
4   !! Surface module :   atmospheric pressure forcing
5   !!======================================================================
6   !! History :  3.3  !   2010-09  (J. Chanut, C. Bricaud, G. Madec)  Original code
7   !!----------------------------------------------------------------------
8   
9   !!----------------------------------------------------------------------
10   !!   sbc_apr        : read atmospheric pressure in netcdf files
11   !!----------------------------------------------------------------------
12   USE dom_oce         ! ocean space and time domain
13   USE sbc_oce         ! surface boundary condition
14   USE phycst          ! physical constants
15   !
16   USE fldread         ! read input fields
17   USE in_out_manager  ! I/O manager
18   USE lib_fortran     ! distribued memory computing library
19   USE iom             ! IOM library
20   USE lib_mpp         ! MPP library
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   sbc_apr       ! routine called in sbcmod
26   PUBLIC   sbc_apr_init  ! routine called in sbcmod
27   
28   !                                !!* namsbc_apr namelist (Atmospheric PRessure) *
29   LOGICAL, PUBLIC ::   ln_apr_obc   !: inverse barometer added to OBC ssh data
30   LOGICAL, PUBLIC ::   ln_ref_apr   !: ref. pressure: global mean Patm (F) or a constant (F)
31   REAL(wp)        ::   rn_pref      !  reference atmospheric pressure   [N/m2]
32
33   REAL(wp), ALLOCATABLE, SAVE, PUBLIC, DIMENSION(:,:) ::   ssh_ib    ! Inverse barometer now    sea surface height   [m]
34   REAL(wp), ALLOCATABLE, SAVE, PUBLIC, DIMENSION(:,:) ::   ssh_ibb   ! Inverse barometer before sea surface height   [m]
35   REAL(wp), ALLOCATABLE, SAVE, PUBLIC, DIMENSION(:,:) ::   apr       ! atmospheric pressure at kt                 [N/m2]
36   
37   REAL(wp) ::   tarea                ! whole domain mean masked ocean surface
38   REAL(wp) ::   r1_grau              ! = 1.e0 / (grav * rau0)
39   
40   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_apr   ! structure of input fields (file informations, fields read)
41
42   !!----------------------------------------------------------------------
43   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
44   !! $Id$
45   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE sbc_apr_init
50      !!---------------------------------------------------------------------
51      !!                     ***  ROUTINE sbc_apr  ***
52      !!
53      !! ** Purpose :   read atmospheric pressure fields in netcdf files.
54      !!
55      !! ** Method  : - Read namelist namsbc_apr
56      !!              - Read Patm fields in netcdf files
57      !!              - Compute reference atmospheric pressure
58      !!              - Compute inverse barometer ssh
59      !! ** action  :   apr      : atmospheric pressure at kt
60      !!                ssh_ib   : inverse barometer ssh at kt
61      !!---------------------------------------------------------------------
62      INTEGER            ::   ierror  ! local integer
63      INTEGER            ::   ios     ! Local integer output status for namelist read
64      !!
65      CHARACTER(len=100) ::  cn_dir   ! Root directory for location of ssr files
66      TYPE(FLD_N)        ::  sn_apr   ! informations about the fields to be read
67      !!
68      NAMELIST/namsbc_apr/ cn_dir, sn_apr, ln_ref_apr, rn_pref, ln_apr_obc
69      !!----------------------------------------------------------------------
70      REWIND( numnam_ref )              ! Namelist namsbc_apr in reference namelist : File for atmospheric pressure forcing
71      READ  ( numnam_ref, namsbc_apr, IOSTAT = ios, ERR = 901)
72901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_apr in reference namelist', lwp )
73
74      REWIND( numnam_cfg )              ! Namelist namsbc_apr in configuration namelist : File for atmospheric pressure forcing
75      READ  ( numnam_cfg, namsbc_apr, IOSTAT = ios, ERR = 902 )
76902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_apr in configuration namelist', lwp )
77      IF(lwm) WRITE ( numond, namsbc_apr )
78      !
79      ALLOCATE( sf_apr(1), STAT=ierror )           !* allocate and fill sf_sst (forcing structure) with sn_sst
80      IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_apr: unable to allocate sf_apr structure' )
81      !
82      CALL fld_fill( sf_apr, (/ sn_apr /), cn_dir, 'sbc_apr', 'Atmospheric pressure ', 'namsbc_apr' )
83                                ALLOCATE( sf_apr(1)%fnow(jpi,jpj,1)   )
84      IF( sn_apr%ln_tint )   ALLOCATE( sf_apr(1)%fdta(jpi,jpj,1,2) )
85                             ALLOCATE( ssh_ib(jpi,jpj) , ssh_ibb(jpi,jpj) )
86                             ALLOCATE( apr (jpi,jpj) )
87      !
88      IF( lwp )THEN                                 !* control print
89         WRITE(numout,*)
90         WRITE(numout,*) '   Namelist namsbc_apr : Atmospheric PRessure as extrenal forcing'
91         WRITE(numout,*) '      ref. pressure: global mean Patm (T) or a constant (F)  ln_ref_apr = ', ln_ref_apr
92      ENDIF
93      !
94      IF( ln_ref_apr ) THEN                        !* Compute whole inner domain mean masked ocean surface
95         tarea = glob_sum( e1e2t(:,:) )
96         IF(lwp) WRITE(numout,*) '         Variable ref. Patm computed over a ocean surface of ', tarea*1e-6, 'km2'
97      ELSE
98         IF(lwp) WRITE(numout,*) '         Reference Patm used : ', rn_pref, ' N/m2'
99      ENDIF
100      !
101      r1_grau = 1.e0 / (grav * rau0)               !* constant for optimization
102      !
103      !                                            !* control check
104      IF ( ln_apr_obc  ) THEN
105         IF(lwp) WRITE(numout,*) '         Inverse barometer added to OBC ssh data'
106      ENDIF
107!jc: stop below should rather be a warning
108      IF( ln_apr_obc .AND. .NOT.ln_apr_dyn   )   &
109            CALL ctl_warn( 'sbc_apr: use inverse barometer ssh at open boundary ONLY requires ln_apr_dyn=T' )
110      !
111   END SUBROUTINE sbc_apr_init
112
113   SUBROUTINE sbc_apr( kt )
114      !!---------------------------------------------------------------------
115      !!                     ***  ROUTINE sbc_apr  ***
116      !!
117      !! ** Purpose :   read atmospheric pressure fields in netcdf files.
118      !!
119      !! ** Method  : - Read namelist namsbc_apr
120      !!              - Read Patm fields in netcdf files
121      !!              - Compute reference atmospheric pressure
122      !!              - Compute inverse barometer ssh
123      !! ** action  :   apr      : atmospheric pressure at kt
124      !!                ssh_ib   : inverse barometer ssh at kt
125      !!---------------------------------------------------------------------
126      INTEGER, INTENT(in)::   kt   ! ocean time step
127      !
128      !!----------------------------------------------------------------------
129
130      !                                         ! ========================== !
131      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN      !    At each sbc time-step   !
132         !                                      ! ===========+++============ !
133         !
134         IF( kt /= nit000 )   ssh_ibb(:,:) = ssh_ib(:,:)    !* Swap of ssh_ib fields
135         !
136         CALL fld_read( kt, nn_fsbc, sf_apr )               !* input Patm provided at kt + nn_fsbc/2
137         !
138         !                                                  !* update the reference atmospheric pressure (if necessary)
139         IF( ln_ref_apr )   rn_pref = glob_sum( sf_apr(1)%fnow(:,:,1) * e1e2t(:,:) ) / tarea
140         !
141         !                                                  !* Patm related forcing at kt
142         ssh_ib(:,:) = - ( sf_apr(1)%fnow(:,:,1) - rn_pref ) * r1_grau    ! equivalent ssh (inverse barometer)
143         apr   (:,:) =     sf_apr(1)%fnow(:,:,1)                        ! atmospheric pressure
144         !
145         CALL iom_put( "ssh_ib", ssh_ib )                   !* output the inverse barometer ssh
146      ENDIF
147
148      !                                         ! ---------------------------------------- !
149      IF( kt == nit000 ) THEN                   !   set the forcing field at nit000 - 1    !
150         !                                      ! ---------------------------------------- !
151         !                                            !* Restart: read in restart file
152         IF( ln_rstart .AND. iom_varid( numror, 'ssh_ibb', ldstop = .FALSE. ) > 0 ) THEN
153            IF(lwp) WRITE(numout,*) 'sbc_apr:   ssh_ibb read in the restart file'
154            CALL iom_get( numror, jpdom_autoglo, 'ssh_ibb', ssh_ibb )   ! before inv. barometer ssh
155            !
156         ELSE                                         !* no restart: set from nit000 values
157            IF(lwp) WRITE(numout,*) 'sbc_apr:   ssh_ibb set to nit000 values'
158            ssh_ibb(:,:) = ssh_ib(:,:)
159         ENDIF
160      ENDIF
161      !                                         ! ---------------------------------------- !
162      IF( lrst_oce ) THEN                       !      Write in the ocean restart file     !
163         !                                      ! ---------------------------------------- !
164         IF(lwp) WRITE(numout,*)
165         IF(lwp) WRITE(numout,*) 'sbc_apr : ssh_ib written in ocean restart file at it= ', kt,' date= ', ndastp
166         IF(lwp) WRITE(numout,*) '~~~~'
167         CALL iom_rstput( kt, nitrst, numrow, 'ssh_ibb' , ssh_ib )
168      ENDIF
169      !
170   END SUBROUTINE sbc_apr
171     
172   !!======================================================================
173END MODULE sbcapr
Note: See TracBrowser for help on using the repository browser.