source: trunk/NEMOGCM/NEMO/OPA_SRC/SBC/sbcice_lim.F90 @ 5341

Last change on this file since 5341 was 5341, checked in by davestorkey, 6 years ago

Merge of 2014/dev_r4650_UKMO11_restart_functionality branch into the trunk
as part of 3.6_stable build. See ticket #1347.

  • Property svn:keywords set to Id
File size: 31.0 KB
Line 
1MODULE sbcice_lim
2   !!======================================================================
3   !!                       ***  MODULE  sbcice_lim  ***
4   !! Surface module :  update the ocean surface boundary condition over ice
5   !!       &           covered area using LIM sea-ice model
6   !! Sea-Ice model  :  LIM-3 Sea ice model time-stepping
7   !!=====================================================================
8   !! History :  2.0  ! 2006-12  (M. Vancoppenolle) Original code
9   !!            3.0  ! 2008-02  (C. Talandier)  Surface module from icestp.F90
10   !!             -   ! 2008-04  (G. Madec)  sltyle and lim_ctl routine
11   !!            3.3  ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!            3.4  ! 2011-01  (A Porter)  dynamical allocation
13   !!             -   ! 2012-10  (C. Rousset)  add lim_diahsb
14   !!            3.6  ! 2014-07  (M. Vancoppenolle, G. Madec, O. Marti) revise coupled interface
15   !!----------------------------------------------------------------------
16#if defined key_lim3
17   !!----------------------------------------------------------------------
18   !!   'key_lim3' :                                  LIM 3.0 sea-ice model
19   !!----------------------------------------------------------------------
20   !!   sbc_ice_lim  : sea-ice model time-stepping and update ocean sbc over ice-covered area
21   !!----------------------------------------------------------------------
22   USE oce             ! ocean dynamics and tracers
23   USE dom_oce         ! ocean space and time domain
24   USE ice             ! LIM-3: ice variables
25   USE thd_ice         ! LIM-3: thermodynamical variables
26   USE dom_ice         ! LIM-3: ice domain
27
28   USE sbc_oce         ! Surface boundary condition: ocean fields
29   USE sbc_ice         ! Surface boundary condition: ice   fields
30   USE sbcblk_core     ! Surface boundary condition: CORE bulk
31   USE sbcblk_clio     ! Surface boundary condition: CLIO bulk
32   USE sbccpl          ! Surface boundary condition: coupled interface
33   USE albedo          ! ocean & ice albedo
34
35   USE phycst          ! Define parameters for the routines
36   USE eosbn2          ! equation of state
37   USE limdyn          ! Ice dynamics
38   USE limtrp          ! Ice transport
39   USE limthd          ! Ice thermodynamics
40   USE limitd_me       ! Mechanics on ice thickness distribution
41   USE limsbc          ! sea surface boundary condition
42   USE limdiahsb       ! Ice budget diagnostics
43   USE limwri          ! Ice outputs
44   USE limrst          ! Ice restarts
45   USE limupdate1      ! update of global variables
46   USE limupdate2      ! update of global variables
47   USE limvar          ! Ice variables switch
48
49   USE limmsh          ! LIM mesh
50   USE limistate       ! LIM initial state
51   USE limthd_sal      ! LIM ice thermodynamics: salinity
52
53   USE c1d             ! 1D vertical configuration
54   USE lbclnk          ! lateral boundary condition - MPP link
55   USE lib_mpp         ! MPP library
56   USE wrk_nemo        ! work arrays
57   USE timing          ! Timing
58   USE iom             ! I/O manager library
59   USE in_out_manager  ! I/O manager
60   USE prtctl          ! Print control
61   USE lib_fortran     !
62   USE limctl
63
64#if defined key_bdy 
65   USE bdyice_lim       ! unstructured open boundary data  (bdy_ice_lim routine)
66#endif
67
68   IMPLICIT NONE
69   PRIVATE
70
71   PUBLIC sbc_ice_lim  ! routine called by sbcmod.F90
72   PUBLIC sbc_lim_init ! routine called by sbcmod.F90
73   
74   !! * Substitutions
75#  include "domzgr_substitute.h90"
76#  include "vectopt_loop_substitute.h90"
77   !!----------------------------------------------------------------------
78   !! NEMO/OPA 4.0 , UCL NEMO Consortium (2011)
79   !! $Id$
80   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
81   !!----------------------------------------------------------------------
82CONTAINS
83
84   !!======================================================================
85
86   SUBROUTINE sbc_ice_lim( kt, kblk )
87      !!---------------------------------------------------------------------
88      !!                  ***  ROUTINE sbc_ice_lim  ***
89      !!                   
90      !! ** Purpose :   update the ocean surface boundary condition via the
91      !!                Louvain la Neuve Sea Ice Model time stepping
92      !!
93      !! ** Method  :   ice model time stepping
94      !!              - call the ice dynamics routine
95      !!              - call the ice advection/diffusion routine
96      !!              - call the ice thermodynamics routine
97      !!              - call the routine that computes mass and
98      !!                heat fluxes at the ice/ocean interface
99      !!              - save the outputs
100      !!              - save the outputs for restart when necessary
101      !!
102      !! ** Action  : - time evolution of the LIM sea-ice model
103      !!              - update all sbc variables below sea-ice:
104      !!                utau, vtau, taum, wndm, qns , qsr, emp , sfx
105      !!---------------------------------------------------------------------
106      INTEGER, INTENT(in) ::   kt      ! ocean time step
107      INTEGER, INTENT(in) ::   kblk    ! type of bulk (=3 CLIO, =4 CORE, =5 COUPLED)
108      !!
109      INTEGER  ::   jl                 ! dummy loop index
110      REAL(wp), POINTER, DIMENSION(:,:,:)   ::   zalb_os, zalb_cs  ! ice albedo under overcast/clear sky
111      REAL(wp), POINTER, DIMENSION(:,:,:)   ::   zalb_ice          ! mean ice albedo (for coupled)
112      !!----------------------------------------------------------------------
113
114      IF( nn_timing == 1 )  CALL timing_start('sbc_ice_lim')
115
116      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN     !  Ice time-step only
117         !-----------------------!                                           
118         ! --- Bulk Formulae --- !                                           
119         !-----------------------!
120         u_oce(:,:) = ssu_m(:,:) * umask(:,:,1)      ! mean surface ocean current at ice velocity point
121         v_oce(:,:) = ssv_m(:,:) * vmask(:,:,1)      ! (C-grid dynamics :  U- & V-points as the ocean)
122         
123         ! masked sea surface freezing temperature [Kelvin] (set to rt0 over land)
124         t_bo(:,:) = ( eos_fzp( sss_m ) + rt0 ) * tmask(:,:,1) + rt0 * ( 1._wp - tmask(:,:,1) ) 
125         !                                                                                     
126         ! Ice albedo
127         CALL wrk_alloc( jpi,jpj,jpl, zalb_os, zalb_cs, zalb_ice )
128         CALL albedo_ice( t_su, ht_i, ht_s, zalb_cs, zalb_os )  ! cloud-sky and overcast-sky ice albedos
129
130         ! CORE and COUPLED bulk formulations
131         SELECT CASE( kblk )
132         CASE( jp_core , jp_cpl )
133
134            ! albedo depends on cloud fraction because of non-linear spectral effects
135            zalb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
136            ! In CLIO the cloud fraction is read in the climatology and the all-sky albedo
137            ! (zalb_ice) is computed within the bulk routine
138           
139         END SELECT
140         
141         ! Mask sea ice surface temperature (set to rt0 over land)
142         DO jl = 1, jpl
143            t_su(:,:,jl) = t_su(:,:,jl) * tmask(:,:,1) + rt0 * ( 1._wp - tmask(:,:,1) )
144         END DO
145     
146         ! Bulk formulae  - provides the following fields:
147         ! utau_ice, vtau_ice : surface ice stress                     (U- & V-points)   [N/m2]
148         ! qsr_ice , qns_ice  : solar & non solar heat flux over ice   (T-point)         [W/m2]
149         ! qla_ice            : latent heat flux over ice              (T-point)         [W/m2]
150         ! dqns_ice, dqla_ice : non solar & latent heat sensistivity   (T-point)         [W/m2]
151         ! tprecip , sprecip  : total & solid precipitation            (T-point)         [Kg/m2/s]
152         ! fr1_i0  , fr2_i0   : 1sr & 2nd fraction of qsr penetration in ice             [%]
153         !
154         SELECT CASE( kblk )
155         CASE( jp_clio )                                       ! CLIO bulk formulation
156            CALL blk_ice_clio( t_su , zalb_cs    , zalb_os    , zalb_ice  ,               &
157               &                      utau_ice   , vtau_ice   , qns_ice   , qsr_ice   ,   &
158               &                      qla_ice    , dqns_ice   , dqla_ice  ,               &
159               &                      tprecip    , sprecip    ,                           &
160               &                      fr1_i0     , fr2_i0     , cp_ice_msh, jpl  )
161            !         
162            IF( nn_limflx /= 2 )   CALL ice_lim_flx( t_su, zalb_ice, qns_ice, qsr_ice ,   &
163               &                                           dqns_ice, qla_ice, dqla_ice, nn_limflx )
164
165         CASE( jp_core )                                       ! CORE bulk formulation
166            CALL blk_ice_core( t_su , u_ice     , v_ice     , zalb_ice   ,               &
167               &                      utau_ice  , vtau_ice  , qns_ice    , qsr_ice   ,   &
168               &                      qla_ice   , dqns_ice  , dqla_ice   ,               &
169               &                      tprecip   , sprecip   ,                            &
170               &                      fr1_i0    , fr2_i0    , cp_ice_msh, jpl  )
171               !
172            IF( nn_limflx /= 2 )   CALL ice_lim_flx( t_su, zalb_ice, qns_ice, qsr_ice ,   &
173               &                                           dqns_ice, qla_ice, dqla_ice, nn_limflx )
174            !
175         CASE ( jp_cpl )
176           
177            CALL sbc_cpl_ice_tau( utau_ice , vtau_ice )
178
179         END SELECT
180         
181         !------------------------------!
182         ! --- LIM-3 main time-step --- !
183         !------------------------------!
184         numit = numit + nn_fsbc                     ! Ice model time step
185         !                                                   
186         CALL sbc_lim_bef                   ! Store previous ice values
187
188         CALL sbc_lim_diag0                 ! set diag of mass, heat and salt fluxes to 0
189         
190         CALL lim_rst_opn( kt )             ! Open Ice restart file
191         !
192         ! ----------------------------------------------
193         ! ice dynamics and transport (except in 1D case)
194         ! ----------------------------------------------
195         IF( .NOT. lk_c1d ) THEN
196           
197            CALL lim_dyn( kt )              ! Ice dynamics    ( rheology/dynamics )
198           
199            CALL lim_trp( kt )              ! Ice transport   ( Advection/diffusion )
200           
201            IF( nn_monocat /= 2 ) CALL lim_itd_me  ! Mechanical redistribution ! (ridging/rafting)
202
203#if defined key_bdy
204            CALL bdy_ice_lim( kt )         ! bdy ice thermo
205            IF( ln_icectl )   CALL lim_prt( kt, iiceprt, jiceprt, 1, ' - ice thermo bdy - ' )
206#endif
207            CALL lim_update1( kt )
208           
209         ENDIF
210         
211         CALL sbc_lim_bef                  ! Store previous ice values
212 
213         ! ----------------------------------------------
214         ! ice thermodynamics
215         ! ----------------------------------------------
216         CALL lim_var_agg(1)
217         
218         ! previous lead fraction and ice volume for flux calculations
219         pfrld(:,:)   = 1._wp - at_i(:,:)
220         phicif(:,:)  = vt_i(:,:)
221         
222         SELECT CASE( kblk )
223         CASE ( jp_cpl )
224            CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=zalb_ice, psst=sst_m, pist=t_su    )
225            IF( nn_limflx == 2 )   CALL ice_lim_flx( t_su, zalb_ice, qns_ice, qsr_ice ,   &
226               &                                           dqns_ice, qla_ice, dqla_ice, nn_limflx )
227            ! Latent heat flux is forced to 0 in coupled: it is included in qns (non-solar heat flux)
228            qla_ice  (:,:,:) = 0._wp
229            dqla_ice (:,:,:) = 0._wp
230         END SELECT
231         !
232         CALL lim_thd( kt )                         ! Ice thermodynamics
233         
234         CALL lim_update2( kt )                     ! Corrections
235         !
236         CALL lim_sbc_flx( kt )                     ! Update surface ocean mass, heat and salt fluxes
237         !
238         IF(ln_limdiaout) CALL lim_diahsb           ! Diagnostics and outputs
239         
240         CALL lim_wri( 1 )                          ! Ice outputs
241         
242         IF( kt == nit000 .AND. ln_rstart )   &
243            &             CALL iom_close( numrir )  ! close input ice restart file
244         !
245         IF( lrst_ice )   CALL lim_rst_write( kt )  ! Ice restart file
246         !
247         IF( ln_icectl )  CALL lim_ctl( kt )        ! alerts in case of model crash
248         !
249         CALL wrk_dealloc( jpi,jpj,jpl, zalb_os, zalb_cs, zalb_ice )
250         !
251      ENDIF   ! End sea-ice time step only
252
253      !--------------------------------!
254      ! --- at all ocean time step --- !
255      !--------------------------------!
256      ! Update surface ocean stresses (only in ice-dynamic case)
257      !    otherwise the atm.-ocean stresses are used everywhere
258      IF( ln_limdyn )     CALL lim_sbc_tau( kt, ub(:,:,1), vb(:,:,1) )  ! using before instantaneous surf. currents
259!!gm   remark, the ocean-ice stress is not saved in ice diag call above .....  find a solution!!!
260      !
261      IF( nn_timing == 1 )  CALL timing_stop('sbc_ice_lim')
262      !
263   END SUBROUTINE sbc_ice_lim
264   
265
266   SUBROUTINE sbc_lim_init
267      !!----------------------------------------------------------------------
268      !!                  ***  ROUTINE sbc_lim_init  ***
269      !!
270      !! ** purpose :   Allocate all the dynamic arrays of the LIM-3 modules
271      !!----------------------------------------------------------------------
272      INTEGER :: ierr
273      !!----------------------------------------------------------------------
274      IF(lwp) WRITE(numout,*)
275      IF(lwp) WRITE(numout,*) 'sbc_ice_lim : update ocean surface boudary condition' 
276      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   via Louvain la Neuve Ice Model (LIM-3) time stepping'
277      !
278                                       ! Open the reference and configuration namelist files and namelist output file
279      CALL ctl_opn( numnam_ice_ref, 'namelist_ice_ref',    'OLD',     'FORMATTED', 'SEQUENTIAL', -1, numout, lwp ) 
280      CALL ctl_opn( numnam_ice_cfg, 'namelist_ice_cfg',    'OLD',     'FORMATTED', 'SEQUENTIAL', -1, numout, lwp )
281      IF(lwm) CALL ctl_opn( numoni, 'output.namelist.ice', 'UNKNOWN', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, 1 )
282
283      CALL ice_run                     ! set some ice run parameters
284      !
285      !                                ! Allocate the ice arrays
286      ierr =        ice_alloc        ()      ! ice variables
287      ierr = ierr + dom_ice_alloc    ()      ! domain
288      ierr = ierr + sbc_ice_alloc    ()      ! surface forcing
289      ierr = ierr + thd_ice_alloc    ()      ! thermodynamics
290      ierr = ierr + lim_itd_me_alloc ()      ! ice thickness distribution - mechanics
291      !
292      IF( lk_mpp    )   CALL mpp_sum( ierr )
293      IF( ierr /= 0 )   CALL ctl_stop('STOP', 'sbc_lim_init : unable to allocate ice arrays')
294      !
295      !                                ! adequation jpk versus ice/snow layers/categories
296      IF( jpl > jpk .OR. (nlay_i+1) > jpk .OR. nlay_s > jpk )   &
297         &      CALL ctl_stop( 'STOP',                          &
298         &     'sbc_lim_init: the 3rd dimension of workspace arrays is too small.',   &
299         &     'use more ocean levels or less ice/snow layers/categories.' )
300      !
301      CALL lim_itd_init                ! ice thickness distribution initialization
302      !
303      CALL lim_thd_init                ! set ice thermodynics parameters
304      !
305      CALL lim_thd_sal_init            ! set ice salinity parameters
306      !
307      CALL lim_msh                     ! ice mesh initialization
308      !
309      CALL lim_itd_me_init             ! ice thickness distribution initialization for mecanical deformation
310      !                                ! Initial sea-ice state
311      IF( .NOT. ln_rstart ) THEN              ! start from rest: sea-ice deduced from sst
312         numit = 0
313         numit = nit000 - 1
314         CALL lim_istate
315      ELSE                                    ! start from a restart file
316         CALL lim_rst_read
317         numit = nit000 - 1
318      ENDIF
319      CALL lim_var_agg(1)
320      CALL lim_var_glo2eqv
321      !
322      CALL lim_sbc_init                 ! ice surface boundary condition   
323      !
324      fr_i(:,:)     = at_i(:,:)         ! initialisation of sea-ice fraction
325      tn_ice(:,:,:) = t_su(:,:,:)       ! initialisation of surface temp for coupled simu
326      !
327      nstart = numit  + nn_fsbc     
328      nitrun = nitend - nit000 + 1 
329      nlast  = numit  + nitrun 
330      !
331      IF( nstock == 0 )   nstock = nlast + 1
332      !
333   END SUBROUTINE sbc_lim_init
334
335
336   SUBROUTINE ice_run
337      !!-------------------------------------------------------------------
338      !!                  ***  ROUTINE ice_run ***
339      !!                 
340      !! ** Purpose :   Definition some run parameter for ice model
341      !!
342      !! ** Method  :   Read the namicerun namelist and check the parameter
343      !!              values called at the first timestep (nit000)
344      !!
345      !! ** input   :   Namelist namicerun
346      !!-------------------------------------------------------------------
347      INTEGER  ::   ios                 ! Local integer output status for namelist read
348      NAMELIST/namicerun/ jpl, nlay_i, nlay_s, cn_icerst_in, cn_icerst_indir, cn_icerst_out, cn_icerst_outdir,  &
349         &                ln_limdyn, rn_amax, ln_limdiahsb, ln_limdiaout, ln_icectl, iiceprt, jiceprt 
350      !!-------------------------------------------------------------------
351      !                   
352      REWIND( numnam_ice_ref )              ! Namelist namicerun in reference namelist : Parameters for ice
353      READ  ( numnam_ice_ref, namicerun, IOSTAT = ios, ERR = 901)
354901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicerun in reference namelist', lwp )
355
356      REWIND( numnam_ice_cfg )              ! Namelist namicerun in configuration namelist : Parameters for ice
357      READ  ( numnam_ice_cfg, namicerun, IOSTAT = ios, ERR = 902 )
358902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicerun in configuration namelist', lwp )
359      IF(lwm) WRITE ( numoni, namicerun )
360      !
361      !
362      IF(lwp) THEN                        ! control print
363         WRITE(numout,*)
364         WRITE(numout,*) 'ice_run : ice share parameters for dynamics/advection/thermo of sea-ice'
365         WRITE(numout,*) ' ~~~~~~'
366         WRITE(numout,*) '   number of ice  categories                               = ', jpl
367         WRITE(numout,*) '   number of ice  layers                                   = ', nlay_i
368         WRITE(numout,*) '   number of snow layers                                   = ', nlay_s
369         WRITE(numout,*) '   switch for ice dynamics (1) or not (0)      ln_limdyn   = ', ln_limdyn
370         WRITE(numout,*) '   maximum ice concentration                               = ', rn_amax 
371         WRITE(numout,*) '   Diagnose heat/salt budget or not          ln_limdiahsb  = ', ln_limdiahsb
372         WRITE(numout,*) '   Output   heat/salt budget or not          ln_limdiaout  = ', ln_limdiaout
373         WRITE(numout,*) '   control prints in ocean.out for (i,j)=(iiceprt,jiceprt) = ', ln_icectl
374         WRITE(numout,*) '   i-index for control prints (ln_icectl=true)             = ', iiceprt
375         WRITE(numout,*) '   j-index for control prints (ln_icectl=true)             = ', jiceprt
376      ENDIF
377      !
378      ! sea-ice timestep and inverse
379      rdt_ice   = nn_fsbc * rdttra(1) 
380      r1_rdtice = 1._wp / rdt_ice 
381
382      ! inverse of nlay_i and nlay_s
383      r1_nlay_i = 1._wp / REAL( nlay_i, wp )
384      r1_nlay_s = 1._wp / REAL( nlay_s, wp )
385      !
386#if defined key_bdy
387      IF( lwp .AND. ln_limdiahsb )  CALL ctl_warn('online conservation check activated but it does not work with BDY')
388#endif
389      !
390   END SUBROUTINE ice_run
391
392
393   SUBROUTINE lim_itd_init
394      !!------------------------------------------------------------------
395      !!                ***  ROUTINE lim_itd_init ***
396      !!
397      !! ** Purpose :   Initializes the ice thickness distribution
398      !! ** Method  :   ...
399      !! ** input   :   Namelist namiceitd
400      !!-------------------------------------------------------------------
401      INTEGER  ::   ios                 ! Local integer output status for namelist read
402      NAMELIST/namiceitd/ nn_catbnd, rn_himean
403      !
404      INTEGER  ::   jl                   ! dummy loop index
405      REAL(wp) ::   zc1, zc2, zc3, zx1   ! local scalars
406      REAL(wp) ::   zhmax, znum, zden, zalpha !
407      !!------------------------------------------------------------------
408      !
409      REWIND( numnam_ice_ref )              ! Namelist namiceitd in reference namelist : Parameters for ice
410      READ  ( numnam_ice_ref, namiceitd, IOSTAT = ios, ERR = 903)
411903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namiceitd in reference namelist', lwp )
412
413      REWIND( numnam_ice_cfg )              ! Namelist namiceitd in configuration namelist : Parameters for ice
414      READ  ( numnam_ice_cfg, namiceitd, IOSTAT = ios, ERR = 904 )
415904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namiceitd in configuration namelist', lwp )
416      IF(lwm) WRITE ( numoni, namiceitd )
417      !
418      !
419      IF(lwp) THEN                        ! control print
420         WRITE(numout,*)
421         WRITE(numout,*) 'ice_itd : ice cat distribution'
422         WRITE(numout,*) ' ~~~~~~'
423         WRITE(numout,*) '   shape of ice categories distribution                          nn_catbnd = ', nn_catbnd
424         WRITE(numout,*) '   mean ice thickness in the domain (only active if nn_catbnd=2) rn_himean = ', rn_himean
425      ENDIF
426
427      !----------------------------------
428      !- Thickness categories boundaries
429      !----------------------------------
430      IF(lwp) WRITE(numout,*)
431      IF(lwp) WRITE(numout,*) 'lim_itd_init : Initialization of ice cat distribution '
432      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
433
434      hi_max(:) = 0._wp
435
436      SELECT CASE ( nn_catbnd  )       
437                                   !----------------------
438         CASE (1)                  ! tanh function (CICE)
439                                   !----------------------
440         zc1 =  3._wp / REAL( jpl, wp )
441         zc2 = 10._wp * zc1
442         zc3 =  3._wp
443
444         DO jl = 1, jpl
445            zx1 = REAL( jl-1, wp ) / REAL( jpl, wp )
446            hi_max(jl) = hi_max(jl-1) + zc1 + zc2 * (1._wp + TANH( zc3 * (zx1 - 1._wp ) ) )
447         END DO
448
449                                   !----------------------
450         CASE (2)                  ! h^(-alpha) function
451                                   !----------------------
452         zalpha = 0.05             ! exponent of the transform function
453
454         zhmax  = 3.*rn_himean
455
456         DO jl = 1, jpl 
457            znum = jpl * ( zhmax+1 )**zalpha
458            zden = ( jpl - jl ) * ( zhmax+1 )**zalpha + jl
459            hi_max(jl) = ( znum / zden )**(1./zalpha) - 1
460         END DO
461
462      END SELECT
463
464      DO jl = 1, jpl
465         hi_mean(jl) = ( hi_max(jl) + hi_max(jl-1) ) * 0.5_wp
466      END DO
467
468      ! Set hi_max(jpl) to a big value to ensure that all ice is thinner than hi_max(jpl)
469      hi_max(jpl) = 99._wp
470
471      IF(lwp) WRITE(numout,*) ' Thickness category boundaries '
472      IF(lwp) WRITE(numout,*) ' hi_max ', hi_max(0:jpl)
473      !
474   END SUBROUTINE lim_itd_init
475
476   
477   SUBROUTINE ice_lim_flx( ptn_ice, palb_ice, pqns_ice, pqsr_ice,   &
478         &                          pdqn_ice, pqla_ice, pdql_ice, k_limflx )
479      !!---------------------------------------------------------------------
480      !!                  ***  ROUTINE ice_lim_flx  ***
481      !!                   
482      !! ** Purpose :   update the ice surface boundary condition by averaging and / or
483      !!                redistributing fluxes on ice categories                   
484      !!
485      !! ** Method  :   average then redistribute
486      !!
487      !! ** Action  :   
488      !!---------------------------------------------------------------------
489      INTEGER                   , INTENT(in   ) ::   k_limflx   ! =-1 do nothing; =0 average ;
490                                                                ! =1 average and redistribute ; =2 redistribute
491      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   ptn_ice    ! ice surface temperature
492      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   palb_ice   ! ice albedo
493      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pqns_ice   ! non solar flux
494      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pqsr_ice   ! net solar flux
495      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdqn_ice   ! non solar flux sensitivity
496      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pqla_ice   ! latent heat flux
497      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdql_ice   ! latent heat flux sensitivity
498      !
499      INTEGER  ::   jl      ! dummy loop index
500      !
501      REAL(wp), POINTER, DIMENSION(:,:) :: zalb_m    ! Mean albedo over all categories
502      REAL(wp), POINTER, DIMENSION(:,:) :: ztem_m    ! Mean temperature over all categories
503      !
504      REAL(wp), POINTER, DIMENSION(:,:) :: z_qsr_m   ! Mean solar heat flux over all categories
505      REAL(wp), POINTER, DIMENSION(:,:) :: z_qns_m   ! Mean non solar heat flux over all categories
506      REAL(wp), POINTER, DIMENSION(:,:) :: z_qla_m   ! Mean latent heat flux over all categories
507      REAL(wp), POINTER, DIMENSION(:,:) :: z_dqn_m   ! Mean d(qns)/dT over all categories
508      REAL(wp), POINTER, DIMENSION(:,:) :: z_dql_m   ! Mean d(qla)/dT over all categories
509      !!----------------------------------------------------------------------
510
511      IF( nn_timing == 1 )  CALL timing_start('ice_lim_flx')
512      !
513      !
514      SELECT CASE( k_limflx )                              !==  averaged on all ice categories  ==!
515      CASE( 0 , 1 )
516         CALL wrk_alloc( jpi,jpj, z_qsr_m, z_qns_m, z_qla_m, z_dqn_m, z_dql_m)
517         !
518         z_qns_m(:,:) = fice_ice_ave ( pqns_ice (:,:,:) )
519         z_qsr_m(:,:) = fice_ice_ave ( pqsr_ice (:,:,:) )
520         z_dqn_m(:,:) = fice_ice_ave ( pdqn_ice (:,:,:) )
521         z_qla_m(:,:) = fice_ice_ave ( pqla_ice (:,:,:) )
522         z_dql_m(:,:) = fice_ice_ave ( pdql_ice (:,:,:) )
523         DO jl = 1, jpl
524            pdqn_ice(:,:,jl) = z_dqn_m(:,:)
525            pdql_ice(:,:,jl) = z_dql_m(:,:)
526         END DO
527         !
528         DO jl = 1, jpl
529            pqns_ice(:,:,jl) = z_qns_m(:,:)
530            pqsr_ice(:,:,jl) = z_qsr_m(:,:)
531            pqla_ice(:,:,jl) = z_qla_m(:,:)
532         END DO
533         !
534         CALL wrk_dealloc( jpi,jpj, z_qsr_m, z_qns_m, z_qla_m, z_dqn_m, z_dql_m)
535      END SELECT
536
537      SELECT CASE( k_limflx )                              !==  redistribution on all ice categories  ==!
538      CASE( 1 , 2 )
539         CALL wrk_alloc( jpi,jpj, zalb_m, ztem_m )
540         !
541         zalb_m(:,:) = fice_ice_ave ( palb_ice (:,:,:) ) 
542         ztem_m(:,:) = fice_ice_ave ( ptn_ice  (:,:,:) ) 
543         DO jl = 1, jpl
544            pqns_ice(:,:,jl) = pqns_ice(:,:,jl) + pdqn_ice(:,:,jl) * (ptn_ice(:,:,jl) - ztem_m(:,:))
545            pqla_ice(:,:,jl) = pqla_ice(:,:,jl) + pdql_ice(:,:,jl) * (ptn_ice(:,:,jl) - ztem_m(:,:))
546            pqsr_ice(:,:,jl) = pqsr_ice(:,:,jl) * ( 1._wp - palb_ice(:,:,jl) ) / ( 1._wp - zalb_m(:,:) ) 
547         END DO
548         !
549         CALL wrk_dealloc( jpi,jpj, zalb_m, ztem_m )
550      END SELECT
551      !
552      IF( nn_timing == 1 )  CALL timing_stop('ice_lim_flx')
553      !
554   END SUBROUTINE ice_lim_flx
555
556   SUBROUTINE sbc_lim_bef
557      !!----------------------------------------------------------------------
558      !!                  ***  ROUTINE sbc_lim_bef  ***
559      !!
560      !! ** purpose :  store ice variables at "before" time step
561      !!----------------------------------------------------------------------
562      a_i_b  (:,:,:)   = a_i  (:,:,:)     ! ice area
563      e_i_b  (:,:,:,:) = e_i  (:,:,:,:)   ! ice thermal energy
564      v_i_b  (:,:,:)   = v_i  (:,:,:)     ! ice volume
565      v_s_b  (:,:,:)   = v_s  (:,:,:)     ! snow volume
566      e_s_b  (:,:,:,:) = e_s  (:,:,:,:)   ! snow thermal energy
567      smv_i_b(:,:,:)   = smv_i(:,:,:)     ! salt content
568      oa_i_b (:,:,:)   = oa_i (:,:,:)     ! areal age content
569      u_ice_b(:,:)     = u_ice(:,:)
570      v_ice_b(:,:)     = v_ice(:,:)
571     
572   END SUBROUTINE sbc_lim_bef
573
574   SUBROUTINE sbc_lim_diag0
575      !!----------------------------------------------------------------------
576      !!                  ***  ROUTINE sbc_lim_diag0  ***
577      !!
578      !! ** purpose :  set ice-ocean and ice-atm. fluxes to zeros at the beggining
579      !!               of the time step
580      !!----------------------------------------------------------------------
581      sfx    (:,:) = 0._wp   ;
582      sfx_bri(:,:) = 0._wp   ; 
583      sfx_sni(:,:) = 0._wp   ;   sfx_opw(:,:) = 0._wp
584      sfx_bog(:,:) = 0._wp   ;   sfx_dyn(:,:) = 0._wp
585      sfx_bom(:,:) = 0._wp   ;   sfx_sum(:,:) = 0._wp
586      sfx_res(:,:) = 0._wp
587     
588      wfx_snw(:,:) = 0._wp   ;   wfx_ice(:,:) = 0._wp
589      wfx_sni(:,:) = 0._wp   ;   wfx_opw(:,:) = 0._wp
590      wfx_bog(:,:) = 0._wp   ;   wfx_dyn(:,:) = 0._wp
591      wfx_bom(:,:) = 0._wp   ;   wfx_sum(:,:) = 0._wp
592      wfx_res(:,:) = 0._wp   ;   wfx_sub(:,:) = 0._wp
593      wfx_spr(:,:) = 0._wp   ;   
594     
595      hfx_in (:,:) = 0._wp   ;   hfx_out(:,:) = 0._wp
596      hfx_thd(:,:) = 0._wp   ;   
597      hfx_snw(:,:) = 0._wp   ;   hfx_opw(:,:) = 0._wp
598      hfx_bog(:,:) = 0._wp   ;   hfx_dyn(:,:) = 0._wp
599      hfx_bom(:,:) = 0._wp   ;   hfx_sum(:,:) = 0._wp
600      hfx_res(:,:) = 0._wp   ;   hfx_sub(:,:) = 0._wp
601      hfx_spr(:,:) = 0._wp   ;   hfx_dif(:,:) = 0._wp 
602      hfx_err(:,:) = 0._wp   ;   hfx_err_rem(:,:) = 0._wp
603      hfx_err_dif(:,:) = 0._wp   ;
604
605      afx_tot(:,:) = 0._wp   ;
606      afx_dyn(:,:) = 0._wp   ;   afx_thd(:,:) = 0._wp
607
608      diag_heat(:,:) = 0._wp ;   diag_smvi(:,:) = 0._wp ;
609      diag_vice(:,:) = 0._wp ;   diag_vsnw(:,:) = 0._wp ;
610     
611   END SUBROUTINE sbc_lim_diag0
612     
613   FUNCTION fice_cell_ave ( ptab )
614      !!--------------------------------------------------------------------------
615      !! * Compute average over categories, for grid cell (ice covered and free ocean)
616      !!--------------------------------------------------------------------------
617      REAL (wp), DIMENSION (jpi,jpj) :: fice_cell_ave
618      REAL (wp), DIMENSION (jpi,jpj,jpl), INTENT (in) :: ptab
619      INTEGER :: jl ! Dummy loop index
620     
621      fice_cell_ave (:,:) = 0.0_wp
622     
623      DO jl = 1, jpl
624         fice_cell_ave (:,:) = fice_cell_ave (:,:) + a_i (:,:,jl) * ptab (:,:,jl)
625      END DO
626     
627   END FUNCTION fice_cell_ave
628   
629   
630   FUNCTION fice_ice_ave ( ptab )
631      !!--------------------------------------------------------------------------
632      !! * Compute average over categories, for ice covered part of grid cell
633      !!--------------------------------------------------------------------------
634      REAL (kind=wp), DIMENSION (jpi,jpj) :: fice_ice_ave
635      REAL (kind=wp), DIMENSION (jpi,jpj,jpl), INTENT(in) :: ptab
636
637      fice_ice_ave (:,:) = 0.0_wp
638      WHERE ( at_i (:,:) > 0.0_wp ) fice_ice_ave (:,:) = fice_cell_ave ( ptab (:,:,:)) / at_i (:,:)
639
640   END FUNCTION fice_ice_ave
641
642
643#else
644   !!----------------------------------------------------------------------
645   !!   Default option           Dummy module      NO LIM 3.0 sea-ice model
646   !!----------------------------------------------------------------------
647CONTAINS
648   SUBROUTINE sbc_ice_lim ( kt, kblk )     ! Dummy routine
649      WRITE(*,*) 'sbc_ice_lim: You should not have seen this print! error?', kt, kblk
650   END SUBROUTINE sbc_ice_lim
651   SUBROUTINE sbc_lim_init                 ! Dummy routine
652   END SUBROUTINE sbc_lim_init
653#endif
654
655   !!======================================================================
656END MODULE sbcice_lim
Note: See TracBrowser for help on using the repository browser.