New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

sbcice_lim.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

Context Navigation

source: trunk/NEMOGCM/NEMO/OPA_SRC/SBC/sbcice_lim.F90 @ 5410

Last change on this file since 5410 was 5410, checked in by clem, 9 years ago
change sbccpl for EC-Earth purpose, ie more options for sn_snd_temp ('oce and ice'), sn_snd_alb ('ice') and sn_snd_thick (add 1-cat case for 'ice and snow'). Plus few cleaning in sbcice_lim
Property svn:keywords set to `Id`
File size: 31.5 KB

Line
1	MODULE sbcice_lim
2	!!======================================================================
3	!! * MODULE sbcice_lim *
4	!! Surface module : update the ocean surface boundary condition over ice
5	!! & covered area using LIM sea-ice model
6	!! Sea-Ice model : LIM-3 Sea ice model time-stepping
7	!!=====================================================================
8	!! History : 2.0 ! 2006-12 (M. Vancoppenolle) Original code
9	!! 3.0 ! 2008-02 (C. Talandier) Surface module from icestp.F90
10	!! - ! 2008-04 (G. Madec) sltyle and lim_ctl routine
11	!! 3.3 ! 2010-11 (G. Madec) ice-ocean stress always computed at each ocean time-step
12	!! 3.4 ! 2011-01 (A Porter) dynamical allocation
13	!! - ! 2012-10 (C. Rousset) add lim_diahsb
14	!! 3.6 ! 2014-07 (M. Vancoppenolle, G. Madec, O. Marti) revise coupled interface
15	!!----------------------------------------------------------------------
16	#if defined key_lim3
17	!!----------------------------------------------------------------------
18	!! 'key_lim3' : LIM 3.0 sea-ice model
19	!!----------------------------------------------------------------------
20	!! sbc_ice_lim : sea-ice model time-stepping and update ocean sbc over ice-covered area
21	!!----------------------------------------------------------------------
22	USE oce ! ocean dynamics and tracers
23	USE dom_oce ! ocean space and time domain
24	USE ice ! LIM-3: ice variables
25	USE thd_ice ! LIM-3: thermodynamical variables
26	USE dom_ice ! LIM-3: ice domain
27
28	USE sbc_oce ! Surface boundary condition: ocean fields
29	USE sbc_ice ! Surface boundary condition: ice fields
30	USE sbcblk_core ! Surface boundary condition: CORE bulk
31	USE sbcblk_clio ! Surface boundary condition: CLIO bulk
32	USE sbccpl ! Surface boundary condition: coupled interface
33	USE albedo ! ocean & ice albedo
34
35	USE phycst ! Define parameters for the routines
36	USE eosbn2 ! equation of state
37	USE limdyn ! Ice dynamics
38	USE limtrp ! Ice transport
39	USE limthd ! Ice thermodynamics
40	USE limitd_me ! Mechanics on ice thickness distribution
41	USE limsbc ! sea surface boundary condition
42	USE limdiahsb ! Ice budget diagnostics
43	USE limwri ! Ice outputs
44	USE limrst ! Ice restarts
45	USE limupdate1 ! update of global variables
46	USE limupdate2 ! update of global variables
47	USE limvar ! Ice variables switch
48
49	USE limmsh ! LIM mesh
50	USE limistate ! LIM initial state
51	USE limthd_sal ! LIM ice thermodynamics: salinity
52
53	USE c1d ! 1D vertical configuration
54	USE lbclnk ! lateral boundary condition - MPP link
55	USE lib_mpp ! MPP library
56	USE wrk_nemo ! work arrays
57	USE timing ! Timing
58	USE iom ! I/O manager library
59	USE in_out_manager ! I/O manager
60	USE prtctl ! Print control
61	USE lib_fortran !
62	USE limctl
63
64	#if defined key_bdy
65	USE bdyice_lim ! unstructured open boundary data (bdy_ice_lim routine)
66	#endif
67
68	IMPLICIT NONE
69	PRIVATE
70
71	PUBLIC sbc_ice_lim ! routine called by sbcmod.F90
72	PUBLIC sbc_lim_init ! routine called by sbcmod.F90
73
74	!! * Substitutions
75	# include "domzgr_substitute.h90"
76	# include "vectopt_loop_substitute.h90"
77	!!----------------------------------------------------------------------
78	!! NEMO/OPA 4.0 , UCL NEMO Consortium (2011)
79	!! $Id$
80	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
81	!!----------------------------------------------------------------------
82	CONTAINS
83
84	!!======================================================================
85
86	SUBROUTINE sbc_ice_lim( kt, kblk )
87	!!---------------------------------------------------------------------
88	!! * ROUTINE sbc_ice_lim *
89	!!
90	!! ** Purpose : update the ocean surface boundary condition via the
91	!! Louvain la Neuve Sea Ice Model time stepping
92	!!
93	!! ** Method : ice model time stepping
94	!! - call the ice dynamics routine
95	!! - call the ice advection/diffusion routine
96	!! - call the ice thermodynamics routine
97	!! - call the routine that computes mass and
98	!! heat fluxes at the ice/ocean interface
99	!! - save the outputs
100	!! - save the outputs for restart when necessary
101	!!
102	!! ** Action : - time evolution of the LIM sea-ice model
103	!! - update all sbc variables below sea-ice:
104	!! utau, vtau, taum, wndm, qns , qsr, emp , sfx
105	!!---------------------------------------------------------------------
106	INTEGER, INTENT(in) :: kt ! ocean time step
107	INTEGER, INTENT(in) :: kblk ! type of bulk (=3 CLIO, =4 CORE, =5 COUPLED)
108	!!
109	INTEGER :: jl ! dummy loop index
110	REAL(wp), POINTER, DIMENSION(:,:,:) :: zalb_os, zalb_cs ! ice albedo under overcast/clear sky
111	REAL(wp), POINTER, DIMENSION(:,:,:) :: zalb_ice ! mean ice albedo (for coupled)
112	REAL(wp), POINTER, DIMENSION(:,: ) :: zutau_ice, zvtau_ice
113	!!----------------------------------------------------------------------
114
115	IF( nn_timing == 1 ) CALL timing_start('sbc_ice_lim')
116
117	!-----------------------!
118	! --- Ice time step --- !
119	!-----------------------!
120	IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
121
122	! mean surface ocean current at ice velocity point (C-grid dynamics : U- & V-points as the ocean)
123	u_oce(:,:) = ssu_m(:,:) * umask(:,:,1)
124	v_oce(:,:) = ssv_m(:,:) * vmask(:,:,1)
125
126	! masked sea surface freezing temperature [Kelvin] (set to rt0 over land)
127	t_bo(:,:) = ( eos_fzp( sss_m ) + rt0 ) * tmask(:,:,1) + rt0 * ( 1._wp - tmask(:,:,1) )
128
129	! Mask sea ice surface temperature (set to rt0 over land)
130	DO jl = 1, jpl
131	t_su(:,:,jl) = t_su(:,:,jl) * tmask(:,:,1) + rt0 * ( 1._wp - tmask(:,:,1) )
132	END DO
133	!
134	!------------------------------------------------!
135	! --- Dynamical coupling with the atmosphere --- !
136	!------------------------------------------------!
137	! It provides the following fields:
138	! utau_ice, vtau_ice : surface ice stress (U- & V-points) [N/m2]
139	!-----------------------------------------------------------------
140	SELECT CASE( kblk )
141	CASE( jp_clio ) ; CALL blk_ice_clio_tau ! CLIO bulk formulation
142	CASE( jp_core ) ; CALL blk_ice_core_tau ! CORE bulk formulation
143	CASE( jp_purecpl ) ; CALL sbc_cpl_ice_tau( utau_ice , vtau_ice ) ! Coupled formulation
144	END SELECT
145
146	IF( ln_mixcpl) THEN ! Case of a mixed Bulk/Coupled formulation
147	CALL wrk_alloc( jpi,jpj , zutau_ice, zvtau_ice)
148	CALL sbc_cpl_ice_tau( zutau_ice , zvtau_ice )
149	utau_ice(:,:) = utau_ice(:,:) * xcplmask(:,:,0) + zutau_ice(:,:) * ( 1. - xcplmask(:,:,0) )
150	vtau_ice(:,:) = vtau_ice(:,:) * xcplmask(:,:,0) + zvtau_ice(:,:) * ( 1. - xcplmask(:,:,0) )
151	CALL wrk_dealloc( jpi,jpj , zutau_ice, zvtau_ice)
152	ENDIF
153
154	!-------------------------------------------------------!
155	! --- ice dynamics and transport (except in 1D case) ---!
156	!-------------------------------------------------------!
157	numit = numit + nn_fsbc ! Ice model time step
158	!
159	CALL sbc_lim_bef ! Store previous ice values
160	CALL sbc_lim_diag0 ! set diag of mass, heat and salt fluxes to 0
161	CALL lim_rst_opn( kt ) ! Open Ice restart file
162	!
163	IF( .NOT. lk_c1d ) THEN
164	!
165	CALL lim_dyn( kt ) ! Ice dynamics ( rheology/dynamics )
166	!
167	CALL lim_trp( kt ) ! Ice transport ( Advection/diffusion )
168	!
169	IF( nn_monocat /= 2 ) CALL lim_itd_me ! Mechanical redistribution ! (ridging/rafting)
170	!
171	#if defined key_bdy
172	CALL bdy_ice_lim( kt ) ! bdy ice thermo
173	IF( ln_icectl ) CALL lim_prt( kt, iiceprt, jiceprt, 1, ' - ice thermo bdy - ' )
174	#endif
175	!
176	CALL lim_update1( kt ) ! Corrections
177	!
178	ENDIF
179
180	! previous lead fraction and ice volume for flux calculations
181	CALL sbc_lim_bef
182	CALL lim_var_glo2eqv ! ht_i and ht_s for ice albedo calculation
183	CALL lim_var_agg(1) ! at_i for coupling (via pfrld)
184	pfrld(:,:) = 1._wp - at_i(:,:)
185	phicif(:,:) = vt_i(:,:)
186
187	!------------------------------------------------------!
188	! --- Thermodynamical coupling with the atmosphere --- !
189	!------------------------------------------------------!
190	! It provides the following fields:
191	! qsr_ice , qns_ice : solar & non solar heat flux over ice (T-point) [W/m2]
192	! qla_ice : latent heat flux over ice (T-point) [W/m2]
193	! dqns_ice, dqla_ice : non solar & latent heat sensistivity (T-point) [W/m2]
194	! tprecip , sprecip : total & solid precipitation (T-point) [Kg/m2/s]
195	! fr1_i0 , fr2_i0 : 1sr & 2nd fraction of qsr penetration in ice [%]
196	!----------------------------------------------------------------------------------------
197	CALL wrk_alloc( jpi,jpj,jpl, zalb_os, zalb_cs, zalb_ice )
198	CALL albedo_ice( t_su, ht_i, ht_s, zalb_cs, zalb_os ) ! cloud-sky and overcast-sky ice albedos
199
200	SELECT CASE( kblk )
201	CASE( jp_clio ) ! CLIO bulk formulation
202	! In CLIO the cloud fraction is read in the climatology and the all-sky albedo
203	! (zalb_ice) is computed within the bulk routine
204	CALL blk_ice_clio_flx( t_su, zalb_cs, zalb_os, zalb_ice )
205	IF( ln_mixcpl ) CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=zalb_ice, psst=sst_m, pist=t_su )
206	IF( nn_limflx /= 2 ) CALL ice_lim_flx( t_su, zalb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_limflx )
207	CASE( jp_core ) ! CORE bulk formulation
208	! albedo depends on cloud fraction because of non-linear spectral effects
209	zalb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
210	CALL blk_ice_core_flx( t_su, zalb_ice )
211	IF( ln_mixcpl ) CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=zalb_ice, psst=sst_m, pist=t_su )
212	IF( nn_limflx /= 2 ) CALL ice_lim_flx( t_su, zalb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_limflx )
213	CASE ( jp_purecpl )
214	! albedo depends on cloud fraction because of non-linear spectral effects
215	zalb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
216	CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=zalb_ice, psst=sst_m, pist=t_su )
217	IF( nn_limflx == 2 ) CALL ice_lim_flx( t_su, zalb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_limflx )
218	! Latent heat flux is forced to 0 in coupled: it is included in qns (non-solar heat flux)
219	evap_ice (:,:,:) = 0._wp
220	devap_ice (:,:,:) = 0._wp
221	END SELECT
222	CALL wrk_dealloc( jpi,jpj,jpl, zalb_os, zalb_cs, zalb_ice )
223
224	!----------------------------!
225	! --- ice thermodynamics --- !
226	!----------------------------!
227	CALL lim_thd( kt ) ! Ice thermodynamics
228	!
229	CALL lim_update2( kt ) ! Corrections
230	!
231	CALL lim_sbc_flx( kt ) ! Update surface ocean mass, heat and salt fluxes
232	!
233	IF(ln_limdiaout) CALL lim_diahsb ! Diagnostics and outputs
234	!
235	CALL lim_wri( 1 ) ! Ice outputs
236	!
237	IF( kt == nit000 .AND. ln_rstart ) &
238	& CALL iom_close( numrir ) ! close input ice restart file
239	!
240	IF( lrst_ice ) CALL lim_rst_write( kt ) ! Ice restart file
241	!
242	IF( ln_icectl ) CALL lim_ctl( kt ) ! alerts in case of model crash
243	!
244	ENDIF ! End sea-ice time step only
245
246	!-------------------------!
247	! --- Ocean time step --- !
248	!-------------------------!
249	! Update surface ocean stresses (only in ice-dynamic case) otherwise the atm.-ocean stresses are used everywhere
250	IF( ln_limdyn ) CALL lim_sbc_tau( kt, ub(:,:,1), vb(:,:,1) ) ! using before instantaneous surf. currents
251	!!gm remark, the ocean-ice stress is not saved in ice diag call above ..... find a solution!!!
252	!
253	IF( nn_timing == 1 ) CALL timing_stop('sbc_ice_lim')
254	!
255	END SUBROUTINE sbc_ice_lim
256
257
258	SUBROUTINE sbc_lim_init
259	!!----------------------------------------------------------------------
260	!! * ROUTINE sbc_lim_init *
261	!!
262	!! ** purpose : Allocate all the dynamic arrays of the LIM-3 modules
263	!!----------------------------------------------------------------------
264	INTEGER :: ierr
265	!!----------------------------------------------------------------------
266	IF(lwp) WRITE(numout,*)
267	IF(lwp) WRITE(numout,*) 'sbc_ice_lim : update ocean surface boudary condition'
268	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ via Louvain la Neuve Ice Model (LIM-3) time stepping'
269	!
270	! Open the reference and configuration namelist files and namelist output file
271	CALL ctl_opn( numnam_ice_ref, 'namelist_ice_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp )
272	CALL ctl_opn( numnam_ice_cfg, 'namelist_ice_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp )
273	IF(lwm) CALL ctl_opn( numoni, 'output.namelist.ice', 'UNKNOWN', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, 1 )
274
275	CALL ice_run ! set some ice run parameters
276	!
277	! ! Allocate the ice arrays
278	ierr = ice_alloc () ! ice variables
279	ierr = ierr + dom_ice_alloc () ! domain
280	ierr = ierr + sbc_ice_alloc () ! surface forcing
281	ierr = ierr + thd_ice_alloc () ! thermodynamics
282	ierr = ierr + lim_itd_me_alloc () ! ice thickness distribution - mechanics
283	!
284	IF( lk_mpp ) CALL mpp_sum( ierr )
285	IF( ierr /= 0 ) CALL ctl_stop('STOP', 'sbc_lim_init : unable to allocate ice arrays')
286	!
287	! ! adequation jpk versus ice/snow layers/categories
288	IF( jpl > jpk .OR. (nlay_i+1) > jpk .OR. nlay_s > jpk ) &
289	& CALL ctl_stop( 'STOP', &
290	& 'sbc_lim_init: the 3rd dimension of workspace arrays is too small.', &
291	& 'use more ocean levels or less ice/snow layers/categories.' )
292	!
293	CALL lim_itd_init ! ice thickness distribution initialization
294	!
295	CALL lim_thd_init ! set ice thermodynics parameters
296	!
297	CALL lim_thd_sal_init ! set ice salinity parameters
298	!
299	CALL lim_msh ! ice mesh initialization
300	!
301	CALL lim_itd_me_init ! ice thickness distribution initialization for mecanical deformation
302	! ! Initial sea-ice state
303	IF( .NOT. ln_rstart ) THEN ! start from rest: sea-ice deduced from sst
304	numit = 0
305	numit = nit000 - 1
306	CALL lim_istate
307	ELSE ! start from a restart file
308	CALL lim_rst_read
309	numit = nit000 - 1
310	ENDIF
311	CALL lim_var_agg(1)
312	CALL lim_var_glo2eqv
313	!
314	CALL lim_sbc_init ! ice surface boundary condition
315	!
316	fr_i(:,:) = at_i(:,:) ! initialisation of sea-ice fraction
317	tn_ice(:,:,:) = t_su(:,:,:) ! initialisation of surface temp for coupled simu
318	!
319	nstart = numit + nn_fsbc
320	nitrun = nitend - nit000 + 1
321	nlast = numit + nitrun
322	!
323	IF( nstock == 0 ) nstock = nlast + 1
324	!
325	END SUBROUTINE sbc_lim_init
326
327
328	SUBROUTINE ice_run
329	!!-------------------------------------------------------------------
330	!! * ROUTINE ice_run *
331	!!
332	!! ** Purpose : Definition some run parameter for ice model
333	!!
334	!! ** Method : Read the namicerun namelist and check the parameter
335	!! values called at the first timestep (nit000)
336	!!
337	!! ** input : Namelist namicerun
338	!!-------------------------------------------------------------------
339	INTEGER :: ios ! Local integer output status for namelist read
340	NAMELIST/namicerun/ jpl, nlay_i, nlay_s, cn_icerst_in, cn_icerst_indir, cn_icerst_out, cn_icerst_outdir, &
341	& ln_limdyn, rn_amax, ln_limdiahsb, ln_limdiaout, ln_icectl, iiceprt, jiceprt
342	!!-------------------------------------------------------------------
343	!
344	REWIND( numnam_ice_ref ) ! Namelist namicerun in reference namelist : Parameters for ice
345	READ ( numnam_ice_ref, namicerun, IOSTAT = ios, ERR = 901)
346	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicerun in reference namelist', lwp )
347
348	REWIND( numnam_ice_cfg ) ! Namelist namicerun in configuration namelist : Parameters for ice
349	READ ( numnam_ice_cfg, namicerun, IOSTAT = ios, ERR = 902 )
350	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicerun in configuration namelist', lwp )
351	IF(lwm) WRITE ( numoni, namicerun )
352	!
353	!
354	IF(lwp) THEN ! control print
355	WRITE(numout,*)
356	WRITE(numout,*) 'ice_run : ice share parameters for dynamics/advection/thermo of sea-ice'
357	WRITE(numout,*) ' ~~~~~~'
358	WRITE(numout,*) ' number of ice categories = ', jpl
359	WRITE(numout,*) ' number of ice layers = ', nlay_i
360	WRITE(numout,*) ' number of snow layers = ', nlay_s
361	WRITE(numout,*) ' switch for ice dynamics (1) or not (0) ln_limdyn = ', ln_limdyn
362	WRITE(numout,*) ' maximum ice concentration = ', rn_amax
363	WRITE(numout,*) ' Diagnose heat/salt budget or not ln_limdiahsb = ', ln_limdiahsb
364	WRITE(numout,*) ' Output heat/salt budget or not ln_limdiaout = ', ln_limdiaout
365	WRITE(numout,*) ' control prints in ocean.out for (i,j)=(iiceprt,jiceprt) = ', ln_icectl
366	WRITE(numout,*) ' i-index for control prints (ln_icectl=true) = ', iiceprt
367	WRITE(numout,*) ' j-index for control prints (ln_icectl=true) = ', jiceprt
368	ENDIF
369	!
370	! sea-ice timestep and inverse
371	rdt_ice = nn_fsbc * rdttra(1)
372	r1_rdtice = 1._wp / rdt_ice
373
374	! inverse of nlay_i and nlay_s
375	r1_nlay_i = 1._wp / REAL( nlay_i, wp )
376	r1_nlay_s = 1._wp / REAL( nlay_s, wp )
377	!
378	#if defined key_bdy
379	IF( lwp .AND. ln_limdiahsb ) CALL ctl_warn('online conservation check activated but it does not work with BDY')
380	#endif
381	!
382	END SUBROUTINE ice_run
383
384
385	SUBROUTINE lim_itd_init
386	!!------------------------------------------------------------------
387	!! * ROUTINE lim_itd_init *
388	!!
389	!! ** Purpose : Initializes the ice thickness distribution
390	!! ** Method : ...
391	!! ** input : Namelist namiceitd
392	!!-------------------------------------------------------------------
393	INTEGER :: ios ! Local integer output status for namelist read
394	NAMELIST/namiceitd/ nn_catbnd, rn_himean
395	!
396	INTEGER :: jl ! dummy loop index
397	REAL(wp) :: zc1, zc2, zc3, zx1 ! local scalars
398	REAL(wp) :: zhmax, znum, zden, zalpha !
399	!!------------------------------------------------------------------
400	!
401	REWIND( numnam_ice_ref ) ! Namelist namiceitd in reference namelist : Parameters for ice
402	READ ( numnam_ice_ref, namiceitd, IOSTAT = ios, ERR = 903)
403	903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namiceitd in reference namelist', lwp )
404
405	REWIND( numnam_ice_cfg ) ! Namelist namiceitd in configuration namelist : Parameters for ice
406	READ ( numnam_ice_cfg, namiceitd, IOSTAT = ios, ERR = 904 )
407	904 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namiceitd in configuration namelist', lwp )
408	IF(lwm) WRITE ( numoni, namiceitd )
409	!
410	!
411	IF(lwp) THEN ! control print
412	WRITE(numout,*)
413	WRITE(numout,*) 'ice_itd : ice cat distribution'
414	WRITE(numout,*) ' ~~~~~~'
415	WRITE(numout,*) ' shape of ice categories distribution nn_catbnd = ', nn_catbnd
416	WRITE(numout,*) ' mean ice thickness in the domain (only active if nn_catbnd=2) rn_himean = ', rn_himean
417	ENDIF
418
419	!----------------------------------
420	!- Thickness categories boundaries
421	!----------------------------------
422	IF(lwp) WRITE(numout,*)
423	IF(lwp) WRITE(numout,*) 'lim_itd_init : Initialization of ice cat distribution '
424	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
425
426	hi_max(:) = 0._wp
427
428	SELECT CASE ( nn_catbnd )
429	!----------------------
430	CASE (1) ! tanh function (CICE)
431	!----------------------
432	zc1 = 3._wp / REAL( jpl, wp )
433	zc2 = 10._wp * zc1
434	zc3 = 3._wp
435
436	DO jl = 1, jpl
437	zx1 = REAL( jl-1, wp ) / REAL( jpl, wp )
438	hi_max(jl) = hi_max(jl-1) + zc1 + zc2 * (1._wp + TANH( zc3 * (zx1 - 1._wp ) ) )
439	END DO
440
441	!----------------------
442	CASE (2) ! h^(-alpha) function
443	!----------------------
444	zalpha = 0.05 ! exponent of the transform function
445
446	zhmax = 3.*rn_himean
447
448	DO jl = 1, jpl
449	znum = jpl * ( zhmax+1 )**zalpha
450	zden = ( jpl - jl ) * ( zhmax+1 )**zalpha + jl
451	hi_max(jl) = ( znum / zden )**(1./zalpha) - 1
452	END DO
453
454	END SELECT
455
456	DO jl = 1, jpl
457	hi_mean(jl) = ( hi_max(jl) + hi_max(jl-1) ) * 0.5_wp
458	END DO
459
460	! Set hi_max(jpl) to a big value to ensure that all ice is thinner than hi_max(jpl)
461	hi_max(jpl) = 99._wp
462
463	IF(lwp) WRITE(numout,*) ' Thickness category boundaries '
464	IF(lwp) WRITE(numout,*) ' hi_max ', hi_max(0:jpl)
465	!
466	END SUBROUTINE lim_itd_init
467
468
469	SUBROUTINE ice_lim_flx( ptn_ice, palb_ice, pqns_ice, pqsr_ice, pdqn_ice, pevap_ice, pdevap_ice, k_limflx )
470	!!---------------------------------------------------------------------
471	!! * ROUTINE ice_lim_flx *
472	!!
473	!! ** Purpose : update the ice surface boundary condition by averaging and / or
474	!! redistributing fluxes on ice categories
475	!!
476	!! ** Method : average then redistribute
477	!!
478	!! ** Action :
479	!!---------------------------------------------------------------------
480	INTEGER , INTENT(in ) :: k_limflx ! =-1 do nothing; =0 average ;
481	! =1 average and redistribute ; =2 redistribute
482	REAL(wp), DIMENSION(:,:,:), INTENT(in ) :: ptn_ice ! ice surface temperature
483	REAL(wp), DIMENSION(:,:,:), INTENT(in ) :: palb_ice ! ice albedo
484	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pqns_ice ! non solar flux
485	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pqsr_ice ! net solar flux
486	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pdqn_ice ! non solar flux sensitivity
487	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pevap_ice ! sublimation
488	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pdevap_ice ! sublimation sensitivity
489	!
490	INTEGER :: jl ! dummy loop index
491	!
492	REAL(wp), POINTER, DIMENSION(:,:) :: zalb_m ! Mean albedo over all categories
493	REAL(wp), POINTER, DIMENSION(:,:) :: ztem_m ! Mean temperature over all categories
494	!
495	REAL(wp), POINTER, DIMENSION(:,:) :: z_qsr_m ! Mean solar heat flux over all categories
496	REAL(wp), POINTER, DIMENSION(:,:) :: z_qns_m ! Mean non solar heat flux over all categories
497	REAL(wp), POINTER, DIMENSION(:,:) :: z_evap_m ! Mean sublimation over all categories
498	REAL(wp), POINTER, DIMENSION(:,:) :: z_dqn_m ! Mean d(qns)/dT over all categories
499	REAL(wp), POINTER, DIMENSION(:,:) :: z_devap_m ! Mean d(evap)/dT over all categories
500	!!----------------------------------------------------------------------
501
502	IF( nn_timing == 1 ) CALL timing_start('ice_lim_flx')
503	!
504	!
505	SELECT CASE( k_limflx ) !== averaged on all ice categories ==!
506	CASE( 0 , 1 )
507	CALL wrk_alloc( jpi,jpj, z_qsr_m, z_qns_m, z_evap_m, z_dqn_m, z_devap_m)
508	!
509	z_qns_m (:,:) = fice_ice_ave ( pqns_ice (:,:,:) )
510	z_qsr_m (:,:) = fice_ice_ave ( pqsr_ice (:,:,:) )
511	z_dqn_m (:,:) = fice_ice_ave ( pdqn_ice (:,:,:) )
512	z_evap_m (:,:) = fice_ice_ave ( pevap_ice (:,:,:) )
513	z_devap_m(:,:) = fice_ice_ave ( pdevap_ice (:,:,:) )
514	DO jl = 1, jpl
515	pdqn_ice (:,:,jl) = z_dqn_m(:,:)
516	pdevap_ice(:,:,jl) = z_devap_m(:,:)
517	END DO
518	!
519	DO jl = 1, jpl
520	pqns_ice (:,:,jl) = z_qns_m(:,:)
521	pqsr_ice (:,:,jl) = z_qsr_m(:,:)
522	pevap_ice(:,:,jl) = z_evap_m(:,:)
523	END DO
524	!
525	CALL wrk_dealloc( jpi,jpj, z_qsr_m, z_qns_m, z_evap_m, z_dqn_m, z_devap_m)
526	END SELECT
527
528	SELECT CASE( k_limflx ) !== redistribution on all ice categories ==!
529	CASE( 1 , 2 )
530	CALL wrk_alloc( jpi,jpj, zalb_m, ztem_m )
531	!
532	zalb_m(:,:) = fice_ice_ave ( palb_ice (:,:,:) )
533	ztem_m(:,:) = fice_ice_ave ( ptn_ice (:,:,:) )
534	DO jl = 1, jpl
535	pqns_ice (:,:,jl) = pqns_ice (:,:,jl) + pdqn_ice (:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
536	pevap_ice(:,:,jl) = pevap_ice(:,:,jl) + pdevap_ice(:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
537	pqsr_ice (:,:,jl) = pqsr_ice (:,:,jl) * ( 1._wp - palb_ice(:,:,jl) ) / ( 1._wp - zalb_m(:,:) )
538	END DO
539	!
540	CALL wrk_dealloc( jpi,jpj, zalb_m, ztem_m )
541	END SELECT
542	!
543	IF( nn_timing == 1 ) CALL timing_stop('ice_lim_flx')
544	!
545	END SUBROUTINE ice_lim_flx
546
547	SUBROUTINE sbc_lim_bef
548	!!----------------------------------------------------------------------
549	!! * ROUTINE sbc_lim_bef *
550	!!
551	!! ** purpose : store ice variables at "before" time step
552	!!----------------------------------------------------------------------
553	a_i_b (:,:,:) = a_i (:,:,:) ! ice area
554	e_i_b (:,:,:,:) = e_i (:,:,:,:) ! ice thermal energy
555	v_i_b (:,:,:) = v_i (:,:,:) ! ice volume
556	v_s_b (:,:,:) = v_s (:,:,:) ! snow volume
557	e_s_b (:,:,:,:) = e_s (:,:,:,:) ! snow thermal energy
558	smv_i_b(:,:,:) = smv_i(:,:,:) ! salt content
559	oa_i_b (:,:,:) = oa_i (:,:,:) ! areal age content
560	u_ice_b(:,:) = u_ice(:,:)
561	v_ice_b(:,:) = v_ice(:,:)
562
563	END SUBROUTINE sbc_lim_bef
564
565	SUBROUTINE sbc_lim_diag0
566	!!----------------------------------------------------------------------
567	!! * ROUTINE sbc_lim_diag0 *
568	!!
569	!! ** purpose : set ice-ocean and ice-atm. fluxes to zeros at the beggining
570	!! of the time step
571	!!----------------------------------------------------------------------
572	sfx (:,:) = 0._wp ;
573	sfx_bri(:,:) = 0._wp ;
574	sfx_sni(:,:) = 0._wp ; sfx_opw(:,:) = 0._wp
575	sfx_bog(:,:) = 0._wp ; sfx_dyn(:,:) = 0._wp
576	sfx_bom(:,:) = 0._wp ; sfx_sum(:,:) = 0._wp
577	sfx_res(:,:) = 0._wp
578
579	wfx_snw(:,:) = 0._wp ; wfx_ice(:,:) = 0._wp
580	wfx_sni(:,:) = 0._wp ; wfx_opw(:,:) = 0._wp
581	wfx_bog(:,:) = 0._wp ; wfx_dyn(:,:) = 0._wp
582	wfx_bom(:,:) = 0._wp ; wfx_sum(:,:) = 0._wp
583	wfx_res(:,:) = 0._wp ; wfx_sub(:,:) = 0._wp
584	wfx_spr(:,:) = 0._wp ;
585
586	hfx_thd(:,:) = 0._wp ;
587	hfx_snw(:,:) = 0._wp ; hfx_opw(:,:) = 0._wp
588	hfx_bog(:,:) = 0._wp ; hfx_dyn(:,:) = 0._wp
589	hfx_bom(:,:) = 0._wp ; hfx_sum(:,:) = 0._wp
590	hfx_res(:,:) = 0._wp ; hfx_sub(:,:) = 0._wp
591	hfx_spr(:,:) = 0._wp ; hfx_dif(:,:) = 0._wp
592	hfx_err(:,:) = 0._wp ; hfx_err_rem(:,:) = 0._wp
593	hfx_err_dif(:,:) = 0._wp ;
594
595	afx_tot(:,:) = 0._wp ;
596	afx_dyn(:,:) = 0._wp ; afx_thd(:,:) = 0._wp
597
598	diag_heat(:,:) = 0._wp ; diag_smvi(:,:) = 0._wp ;
599	diag_vice(:,:) = 0._wp ; diag_vsnw(:,:) = 0._wp ;
600
601	END SUBROUTINE sbc_lim_diag0
602
603
604	FUNCTION fice_cell_ave ( ptab )
605	!!--------------------------------------------------------------------------
606	!! * Compute average over categories, for grid cell (ice covered and free ocean)
607	!!--------------------------------------------------------------------------
608	REAL (wp), DIMENSION (jpi,jpj) :: fice_cell_ave
609	REAL (wp), DIMENSION (jpi,jpj,jpl), INTENT (in) :: ptab
610	INTEGER :: jl ! Dummy loop index
611
612	fice_cell_ave (:,:) = 0.0_wp
613	DO jl = 1, jpl
614	fice_cell_ave (:,:) = fice_cell_ave (:,:) + a_i (:,:,jl) * ptab (:,:,jl)
615	END DO
616
617	END FUNCTION fice_cell_ave
618
619
620	FUNCTION fice_ice_ave ( ptab )
621	!!--------------------------------------------------------------------------
622	!! * Compute average over categories, for ice covered part of grid cell
623	!!--------------------------------------------------------------------------
624	REAL (kind=wp), DIMENSION (jpi,jpj) :: fice_ice_ave
625	REAL (kind=wp), DIMENSION (jpi,jpj,jpl), INTENT(in) :: ptab
626
627	fice_ice_ave (:,:) = 0.0_wp
628	WHERE ( at_i (:,:) > 0.0_wp ) fice_ice_ave (:,:) = fice_cell_ave ( ptab (:,:,:)) / at_i (:,:)
629
630	END FUNCTION fice_ice_ave
631
632
633	#else
634	!!----------------------------------------------------------------------
635	!! Default option Dummy module NO LIM 3.0 sea-ice model
636	!!----------------------------------------------------------------------
637	CONTAINS
638	SUBROUTINE sbc_ice_lim ( kt, kblk ) ! Dummy routine
639	WRITE(,) 'sbc_ice_lim: You should not have seen this print! error?', kt, kblk
640	END SUBROUTINE sbc_ice_lim
641	SUBROUTINE sbc_lim_init ! Dummy routine
642	END SUBROUTINE sbc_lim_init
643	#endif
644
645	!!======================================================================
646	END MODULE sbcice_lim

Note: See TracBrowser for help on using the repository browser.

Download in other formats: