New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcice_lim.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/SBC/sbcice_lim.F90 @ 7753

Last change on this file since 7753 was 7753, checked in by mocavero, 7 years ago

Reverting trunk to remove OpenMP

  • Property svn:keywords set to Id
File size: 34.2 KB
Line 
1MODULE sbcice_lim
2   !!======================================================================
3   !!                       ***  MODULE  sbcice_lim  ***
4   !! Surface module :  update the ocean surface boundary condition over ice
5   !!       &           covered area using LIM sea-ice model
6   !! Sea-Ice model  :  LIM-3 Sea ice model time-stepping
7   !!=====================================================================
8   !! History :  2.0  ! 2006-12  (M. Vancoppenolle) Original code
9   !!            3.0  ! 2008-02  (C. Talandier)  Surface module from icestp.F90
10   !!             -   ! 2008-04  (G. Madec)  sltyle and lim_ctl routine
11   !!            3.3  ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!            3.4  ! 2011-01  (A Porter)  dynamical allocation
13   !!             -   ! 2012-10  (C. Rousset)  add lim_diahsb
14   !!            3.6  ! 2014-07  (M. Vancoppenolle, G. Madec, O. Marti) revise coupled interface
15   !!            4.0  ! 2016-06  (L. Brodeau) new unified bulk routine (based on AeroBulk)
16   !!----------------------------------------------------------------------
17#if defined key_lim3
18   !!----------------------------------------------------------------------
19   !!   'key_lim3' :                                  LIM 3.0 sea-ice model
20   !!----------------------------------------------------------------------
21   !!   sbc_ice_lim  : sea-ice model time-stepping and update ocean sbc over ice-covered area
22   !!----------------------------------------------------------------------
23   USE oce             ! ocean dynamics and tracers
24   USE dom_oce         ! ocean space and time domain
25   USE ice             ! LIM-3: ice variables
26   USE thd_ice         ! LIM-3: thermodynamical variables
27   !
28   USE sbc_oce         ! Surface boundary condition: ocean fields
29   USE sbc_ice         ! Surface boundary condition: ice   fields
30   USE usrdef_sbc      ! user defined: surface boundary condition
31   USE sbcblk          ! Surface boundary condition: bulk
32   USE sbccpl          ! Surface boundary condition: coupled interface
33   USE albedo          ! ocean & ice albedo
34   !
35   USE phycst          ! Define parameters for the routines
36   USE eosbn2          ! equation of state
37   USE limdyn          ! Ice dynamics
38   USE limtrp          ! Ice transport
39   USE limhdf          ! Ice horizontal diffusion
40   USE limthd          ! Ice thermodynamics
41   USE limitd_me       ! Mechanics on ice thickness distribution
42   USE limsbc          ! sea surface boundary condition
43   USE limdiahsb       ! Ice budget diagnostics
44   USE limwri          ! Ice outputs
45   USE limrst          ! Ice restarts
46   USE limupdate1      ! update of global variables
47   USE limupdate2      ! update of global variables
48   USE limvar          ! Ice variables switch
49   USE limctl          !
50   USE limistate       ! LIM initial state
51   USE limthd_sal      ! LIM ice thermodynamics: salinity
52   !
53   USE c1d             ! 1D vertical configuration
54   USE in_out_manager  ! I/O manager
55   USE iom             ! I/O manager library
56   USE prtctl          ! Print control
57   USE lib_fortran     !
58   USE lbclnk          ! lateral boundary condition - MPP link
59   USE lib_mpp         ! MPP library
60   USE wrk_nemo        ! work arrays
61   USE timing          ! Timing
62
63   USE bdy_oce   , ONLY: ln_bdy
64   USE bdyice_lim      ! unstructured open boundary data  (bdy_ice_lim routine)
65# if defined key_agrif
66   USE agrif_ice
67   USE agrif_lim3_update
68   USE agrif_lim3_interp
69# endif
70
71   IMPLICIT NONE
72   PRIVATE
73
74   PUBLIC sbc_ice_lim  ! routine called by sbcmod.F90
75   PUBLIC sbc_lim_init ! routine called by sbcmod.F90
76
77   !! * Substitutions
78#  include "vectopt_loop_substitute.h90"
79   !!----------------------------------------------------------------------
80   !! NEMO/OPA 4.0 , UCL NEMO Consortium (2011)
81   !! $Id$
82   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
83   !!----------------------------------------------------------------------
84CONTAINS
85
86   SUBROUTINE sbc_ice_lim( kt, ksbc )
87      !!---------------------------------------------------------------------
88      !!                  ***  ROUTINE sbc_ice_lim  ***
89      !!
90      !! ** Purpose :   update the ocean surface boundary condition via the
91      !!                Louvain la Neuve Sea Ice Model time stepping
92      !!
93      !! ** Method  :   ice model time stepping
94      !!              - call the ice dynamics routine
95      !!              - call the ice advection/diffusion routine
96      !!              - call the ice thermodynamics routine
97      !!              - call the routine that computes mass and
98      !!                heat fluxes at the ice/ocean interface
99      !!              - save the outputs
100      !!              - save the outputs for restart when necessary
101      !!
102      !! ** Action  : - time evolution of the LIM sea-ice model
103      !!              - update all sbc variables below sea-ice:
104      !!                utau, vtau, taum, wndm, qns , qsr, emp , sfx
105      !!---------------------------------------------------------------------
106      INTEGER, INTENT(in) ::   kt      ! ocean time step
107      INTEGER, INTENT(in) ::   ksbc    ! type of sbc flux ( 1 = user defined formulation,
108                                       !                    3 = bulk formulation,
109                                       !                    4 = Pure Coupled formulation)
110      !!
111      INTEGER  ::   jl                 ! dummy loop index
112      REAL(wp), POINTER, DIMENSION(:,:,:)   ::   zalb_os, zalb_cs  ! ice albedo under overcast/clear sky
113      REAL(wp), POINTER, DIMENSION(:,:  )   ::   zutau_ice, zvtau_ice 
114      !!----------------------------------------------------------------------
115
116      IF( nn_timing == 1 )   CALL timing_start('sbc_ice_lim')
117
118      ! clem: it is important to initialize agrif_lim3 variables here and not in sbc_lim_init
119# if defined key_agrif
120      IF( kt == nit000 ) THEN
121         IF( .NOT. Agrif_Root() )   CALL Agrif_InitValues_cont_lim3
122      ENDIF
123# endif
124
125      !-----------------------!
126      ! --- Ice time step --- !
127      !-----------------------!
128      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
129
130# if defined key_agrif
131         IF( .NOT. Agrif_Root() )  lim_nbstep = MOD( lim_nbstep, Agrif_irhot() * Agrif_Parent(nn_fsbc) / nn_fsbc ) + 1
132# endif
133
134         ! mean surface ocean current at ice velocity point (C-grid dynamics :  U- & V-points as the ocean)
135         u_oce(:,:) = ssu_m(:,:) * umask(:,:,1)
136         v_oce(:,:) = ssv_m(:,:) * vmask(:,:,1)
137
138         ! masked sea surface freezing temperature [Kelvin] (set to rt0 over land)
139         CALL eos_fzp( sss_m(:,:) , t_bo(:,:) )
140         t_bo(:,:) = ( t_bo(:,:) + rt0 ) * tmask(:,:,1) + rt0 * ( 1._wp - tmask(:,:,1) )
141
142         ! Mask sea ice surface temperature (set to rt0 over land)
143         DO jl = 1, jpl
144            t_su(:,:,jl) = t_su(:,:,jl) * tmask(:,:,1) + rt0 * ( 1._wp - tmask(:,:,1) )
145         END DO
146         !
147         !------------------------------------------------!
148         ! --- Dynamical coupling with the atmosphere --- !
149         !------------------------------------------------!
150         ! It provides the following fields:
151         ! utau_ice, vtau_ice : surface ice stress (U- & V-points)   [N/m2]
152         !-----------------------------------------------------------------
153                                      CALL sbc_lim_bef         ! Store previous ice values
154         SELECT CASE( ksbc )
155            CASE( jp_usr     )   ;    CALL usrdef_sbc_ice_tau( kt )                 ! user defined formulation
156            CASE( jp_blk     )   ;    CALL blk_ice_tau                              ! Bulk formulation
157            CASE( jp_purecpl )   ;    CALL sbc_cpl_ice_tau( utau_ice , vtau_ice )   ! Coupled   formulation
158         END SELECT
159
160         IF( ln_mixcpl) THEN                                                       ! Case of a mixed Bulk/Coupled formulation
161            CALL wrk_alloc( jpi,jpj    , zutau_ice, zvtau_ice)
162                                      CALL sbc_cpl_ice_tau( zutau_ice , zvtau_ice )
163            utau_ice(:,:) = utau_ice(:,:) * xcplmask(:,:,0) + zutau_ice(:,:) * ( 1. - xcplmask(:,:,0) )
164            vtau_ice(:,:) = vtau_ice(:,:) * xcplmask(:,:,0) + zvtau_ice(:,:) * ( 1. - xcplmask(:,:,0) )
165            CALL wrk_dealloc( jpi,jpj  , zutau_ice, zvtau_ice)
166         ENDIF
167
168         !-------------------------------------------------------!
169         ! --- ice dynamics and transport (except in 1D case) ---!
170         !-------------------------------------------------------!
171         numit = numit + nn_fsbc                  ! Ice model time step
172         !
173                                      CALL sbc_lim_diag0       ! set diag of mass, heat and salt fluxes to 0
174                                      CALL lim_rst_opn( kt )   ! Open Ice restart file
175         !
176         ! --- zap this if no ice dynamics --- !
177         IF( .NOT. lk_c1d .AND. ln_limdyn ) THEN
178            !
179            IF( nn_limdyn /= 0 ) THEN                          ! -- Ice dynamics
180                                      CALL lim_dyn( kt )       !     rheology 
181            ELSE
182               u_ice(:,:) = rn_uice * umask(:,:,1)             !     or prescribed velocity
183               v_ice(:,:) = rn_vice * vmask(:,:,1)
184            ENDIF
185                                      CALL lim_trp( kt )       ! -- Ice transport (Advection/diffusion)
186            IF( nn_limdyn == 2 .AND. nn_monocat /= 2 )  &      ! -- Mechanical redistribution (ridging/rafting)
187               &                      CALL lim_itd_me         
188            IF( nn_limdyn == 2 )      CALL lim_update1( kt )   ! -- Corrections
189            !
190         ENDIF
191
192         ! ---
193#if defined key_agrif
194         IF( .NOT. Agrif_Root() )     CALL agrif_interp_lim3('T')
195#endif
196         IF( ln_limthd .AND. ln_bdy )     CALL bdy_ice_lim( kt )   ! -- bdy ice thermo
197         ! previous lead fraction and ice volume for flux calculations
198                                      CALL sbc_lim_bef                       
199                                      CALL lim_var_glo2eqv     ! ht_i and ht_s for ice albedo calculation
200                                      CALL lim_var_agg(1)      ! at_i for coupling (via pfrld)
201         !
202         pfrld(:,:)   = 1._wp - at_i(:,:)
203         phicif(:,:)  = vt_i(:,:)
204
205         !------------------------------------------------------!
206         ! --- Thermodynamical coupling with the atmosphere --- !
207         !------------------------------------------------------!
208         ! It provides the following fields:
209         ! qsr_ice , qns_ice  : solar & non solar heat flux over ice   (T-point)         [W/m2]
210         ! qla_ice            : latent heat flux over ice              (T-point)         [W/m2]
211         ! dqns_ice, dqla_ice : non solar & latent heat sensistivity   (T-point)         [W/m2]
212         ! tprecip , sprecip  : total & solid precipitation            (T-point)         [Kg/m2/s]
213         ! fr1_i0  , fr2_i0   : 1sr & 2nd fraction of qsr penetration in ice             [%]
214         !----------------------------------------------------------------------------------------
215         CALL wrk_alloc( jpi,jpj,jpl, zalb_os, zalb_cs )
216         
217                                      CALL albedo_ice( t_su, ht_i, ht_s, zalb_cs, zalb_os ) ! cloud-sky and overcast-sky ice albedos
218         SELECT CASE( ksbc )
219            CASE( jp_usr )   ;        CALL usrdef_sbc_ice_flx( kt ) ! user defined formulation
220            CASE( jp_blk )                                          ! bulk formulation
221               ! albedo depends on cloud fraction because of non-linear spectral effects
222               alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
223                                      CALL blk_ice_flx( t_su, alb_ice )
224               IF( ln_mixcpl      )   CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=alb_ice, psst=sst_m, pist=t_su )
225               IF( nn_limflx /= 2 )   CALL ice_lim_flx( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_limflx )
226            CASE ( jp_purecpl )
227               ! albedo depends on cloud fraction because of non-linear spectral effects
228               alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
229                                      CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=alb_ice, psst=sst_m, pist=t_su )
230               IF( nn_limflx == 2 )   CALL ice_lim_flx( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_limflx )
231         END SELECT
232
233         CALL wrk_dealloc( jpi,jpj,jpl, zalb_os, zalb_cs )
234
235         !----------------------------!
236         ! --- ice thermodynamics --- !
237         !----------------------------!
238         ! --- zap this if no ice thermo --- !
239         IF( ln_limthd )              CALL lim_thd( kt )        ! -- Ice thermodynamics     
240         IF( ln_limthd )              CALL lim_update2( kt )    ! -- Corrections
241         ! ---
242# if defined key_agrif
243         IF( .NOT. Agrif_Root() )     CALL agrif_update_lim3( kt )
244# endif
245                                      CALL lim_var_glo2eqv      ! necessary calls (at least for coupling)
246                                      CALL lim_var_agg( 2 )     ! necessary calls (at least for coupling)
247                                      !
248# if defined key_agrif
249!!         IF( .NOT. Agrif_Root() )     CALL Agrif_ChildGrid_To_ParentGrid()  ! clem: should be called at the update frequency only (cf agrif_lim3_update)
250# endif
251                                      CALL lim_sbc_flx( kt )    ! -- Update surface ocean mass, heat and salt fluxes
252# if defined key_agrif
253!!         IF( .NOT. Agrif_Root() )     CALL Agrif_ParentGrid_To_ChildGrid()  ! clem: should be called at the update frequency only (cf agrif_lim3_update)
254# endif
255         IF( ln_limdiahsb )           CALL lim_diahsb( kt )     ! -- Diagnostics and outputs
256         !
257                                      CALL lim_wri( 1 )         ! -- Ice outputs
258         !
259         IF( kt == nit000 .AND. ln_rstart )   &
260            &                         CALL iom_close( numrir )  ! close input ice restart file
261         !
262         IF( lrst_ice )               CALL lim_rst_write( kt )  ! -- Ice restart file
263         !
264         IF( ln_limctl )              CALL lim_ctl( kt )        ! alerts in case of model crash
265         !
266      ENDIF   ! End sea-ice time step only
267
268      !-------------------------!
269      ! --- Ocean time step --- !
270      !-------------------------!
271      ! Update surface ocean stresses (only in ice-dynamic case) otherwise the atm.-ocean stresses are used everywhere
272      !    using before instantaneous surf. currents
273      IF( ln_limdyn )                 CALL lim_sbc_tau( kt, ub(:,:,1), vb(:,:,1) )
274!!gm   remark, the ocean-ice stress is not saved in ice diag call above .....  find a solution!!!
275      !
276      IF( nn_timing == 1 ) CALL timing_stop('sbc_ice_lim')
277      !
278   END SUBROUTINE sbc_ice_lim
279
280
281   SUBROUTINE sbc_lim_init
282      !!----------------------------------------------------------------------
283      !!                  ***  ROUTINE sbc_lim_init  ***
284      !!
285      !! ** purpose :   Allocate all the dynamic arrays of the LIM-3 modules
286      !!----------------------------------------------------------------------
287      INTEGER :: ji, jj, ierr
288      !!----------------------------------------------------------------------
289      IF(lwp) WRITE(numout,*)
290      IF(lwp) WRITE(numout,*) 'sbc_lim_init : update ocean surface boudary condition' 
291      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   via Louvain la Neuve Ice Model (LIM-3) time stepping'
292      !
293      !                                ! Open the reference and configuration namelist files and namelist output file
294      CALL ctl_opn( numnam_ice_ref, 'namelist_ice_ref',    'OLD',     'FORMATTED', 'SEQUENTIAL', -1, numout, lwp )
295      CALL ctl_opn( numnam_ice_cfg, 'namelist_ice_cfg',    'OLD',     'FORMATTED', 'SEQUENTIAL', -1, numout, lwp )
296      IF(lwm) CALL ctl_opn( numoni, 'output.namelist.ice', 'UNKNOWN', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, 1 )
297      !
298      CALL lim_run_init                ! set some ice run parameters
299      !
300      !                                ! Allocate the ice arrays
301      ierr =        ice_alloc        ()      ! ice variables
302      ierr = ierr + sbc_ice_alloc    ()      ! surface forcing
303      ierr = ierr + thd_ice_alloc    ()      ! thermodynamics
304      IF( ln_limdyn )   ierr = ierr + lim_itd_me_alloc ()      ! ice thickness distribution - mechanics
305      !
306      IF( lk_mpp    )   CALL mpp_sum( ierr )
307      IF( ierr /= 0 )   CALL ctl_stop('STOP', 'sbc_lim_init : unable to allocate ice arrays')
308      !
309      CALL lim_dyn_init                ! set ice dynamics parameters
310      !
311      CALL lim_itd_init                ! ice thickness distribution initialization
312      !
313      CALL lim_hdf_init                ! set ice horizontal diffusion computation parameters
314      !
315      CALL lim_thd_init                ! set ice thermodynics parameters
316      !
317      CALL lim_thd_sal_init            ! set ice salinity parameters
318      !
319      IF( ln_limdyn )   CALL lim_itd_me_init             ! ice thickness distribution initialization for mecanical deformation
320      !                                ! Initial sea-ice state
321      IF( .NOT. ln_rstart ) THEN              ! start from rest: sea-ice deduced from sst
322         numit = 0
323         numit = nit000 - 1
324         CALL lim_istate
325      ELSE                                    ! start from a restart file
326         CALL lim_rst_read
327         numit = nit000 - 1
328      ENDIF
329      CALL lim_var_agg(2)
330      CALL lim_var_glo2eqv
331      !
332      CALL lim_sbc_init                 ! ice surface boundary condition
333      !
334      IF( ln_limdiahsb) CALL lim_diahsb_init  ! initialization for diags
335      !
336      fr_i(:,:)     = at_i(:,:)         ! initialisation of sea-ice fraction
337      tn_ice(:,:,:) = t_su(:,:,:)       ! initialisation of surface temp for coupled simu
338      !
339      DO jj = 1, jpj
340         DO ji = 1, jpi
341            IF( gphit(ji,jj) > 0._wp ) THEN  ;  rn_amax_2d(ji,jj) = rn_amax_n  ! NH
342            ELSE                             ;  rn_amax_2d(ji,jj) = rn_amax_s  ! SH
343            ENDIF
344         END DO
345      END DO
346      !
347      nstart = numit  + nn_fsbc
348      nitrun = nitend - nit000 + 1
349      nlast  = numit  + nitrun
350      !
351      IF( nstock == 0 )   nstock = nlast + 1
352      !
353   END SUBROUTINE sbc_lim_init
354
355
356   SUBROUTINE lim_run_init
357      !!-------------------------------------------------------------------
358      !!                  ***  ROUTINE lim_run_init ***
359      !!
360      !! ** Purpose :   Definition some run parameter for ice model
361      !!
362      !! ** Method  :   Read the namicerun namelist and check the parameter
363      !!              values called at the first timestep (nit000)
364      !!
365      !! ** input   :   Namelist namicerun
366      !!-------------------------------------------------------------------
367      INTEGER  ::   ios                 ! Local integer output status for namelist read
368      NAMELIST/namicerun/ jpl, nlay_i, nlay_s, rn_amax_n, rn_amax_s, cn_icerst_in, cn_icerst_indir,   &
369         &                cn_icerst_out, cn_icerst_outdir, ln_limthd, ln_limdyn, nn_limdyn, rn_uice, rn_vice 
370      NAMELIST/namicediag/ ln_limdiachk, ln_limdiahsb, ln_limctl, iiceprt, jiceprt 
371      !!-------------------------------------------------------------------
372      !
373      REWIND( numnam_ice_ref )              ! Namelist namicerun in reference namelist : Parameters for ice
374      READ  ( numnam_ice_ref, namicerun, IOSTAT = ios, ERR = 901)
375901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicerun in reference namelist', lwp )
376
377      REWIND( numnam_ice_cfg )              ! Namelist namicerun in configuration namelist : Parameters for ice
378      READ  ( numnam_ice_cfg, namicerun, IOSTAT = ios, ERR = 902 )
379902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicerun in configuration namelist', lwp )
380      IF(lwm) WRITE ( numoni, namicerun )
381      !
382      REWIND( numnam_ice_ref )              ! Namelist namicediag in reference namelist : Parameters for ice
383      READ  ( numnam_ice_ref, namicediag, IOSTAT = ios, ERR = 903)
384903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicediag in reference namelist', lwp )
385
386      REWIND( numnam_ice_cfg )              ! Namelist namicediag in configuration namelist : Parameters for ice
387      READ  ( numnam_ice_cfg, namicediag, IOSTAT = ios, ERR = 904 )
388904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicediag in configuration namelist', lwp )
389      IF(lwm) WRITE ( numoni, namicediag )
390      !
391      IF(lwp) THEN                        ! control print
392         WRITE(numout,*)
393         WRITE(numout,*) 'lim_run_init : ice share parameters for dynamics/advection/thermo of sea-ice'
394         WRITE(numout,*) ' ~~~~~~'
395         WRITE(numout,*) '   number of ice  categories                               = ', jpl
396         WRITE(numout,*) '   number of ice  layers                                   = ', nlay_i
397         WRITE(numout,*) '   number of snow layers                                   = ', nlay_s
398         WRITE(numout,*) '   maximum ice concentration for NH                        = ', rn_amax_n 
399         WRITE(numout,*) '   maximum ice concentration for SH                        = ', rn_amax_s
400         WRITE(numout,*) '   Ice thermodynamics (T) or not (F)            ln_limthd  = ', ln_limthd
401         WRITE(numout,*) '   Ice dynamics       (T) or not (F)            ln_limdyn  = ', ln_limdyn
402         WRITE(numout,*) '     (ln_limdyn=T) Ice dynamics switch          nn_limdyn  = ', nn_limdyn
403         WRITE(numout,*) '       2: total'
404         WRITE(numout,*) '       1: advection only (no diffusion, no ridging/rafting)'
405         WRITE(numout,*) '       0: advection only (as 1 + prescribed velocity, bypass rheology)'
406         WRITE(numout,*) '     (ln_limdyn=T) prescribed u-vel (case nn_limdyn=0)     = ', rn_uice
407         WRITE(numout,*) '     (ln_limdyn=T) prescribed v-vel (case nn_limdyn=0)     = ', rn_vice
408         WRITE(numout,*)
409         WRITE(numout,*) '...and ice diagnostics'
410         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~'
411         WRITE(numout,*) '   Diagnose online heat/mass/salt budget     ln_limdiachk  = ', ln_limdiachk
412         WRITE(numout,*) '   Output          heat/mass/salt budget     ln_limdiahsb  = ', ln_limdiahsb
413         WRITE(numout,*) '   control prints in ocean.out for (i,j)=(iiceprt,jiceprt) = ', ln_limctl
414         WRITE(numout,*) '   i-index for control prints (ln_limctl=true)             = ', iiceprt
415         WRITE(numout,*) '   j-index for control prints (ln_limctl=true)             = ', jiceprt
416      ENDIF
417      !
418      ! sea-ice timestep and inverse
419      rdt_ice   = REAL(nn_fsbc) * rdt 
420      r1_rdtice = 1._wp / rdt_ice 
421
422      ! inverse of nlay_i and nlay_s
423      r1_nlay_i = 1._wp / REAL( nlay_i, wp )
424      r1_nlay_s = 1._wp / REAL( nlay_s, wp )
425      !
426      IF( lwp .AND. ln_bdy .AND. ln_limdiachk )  &
427      &   CALL ctl_warn('online conservation check activated but it does not work with BDY')
428      !
429      IF( lwp ) WRITE(numout,*) '   ice timestep rdt_ice  = ', rdt_ice
430      !
431   END SUBROUTINE lim_run_init
432
433
434   SUBROUTINE lim_itd_init
435      !!------------------------------------------------------------------
436      !!                ***  ROUTINE lim_itd_init ***
437      !!
438      !! ** Purpose :   Initializes the ice thickness distribution
439      !! ** Method  :   ...
440      !! ** input   :   Namelist namiceitd
441      !!-------------------------------------------------------------------
442      INTEGER  ::   ios                 ! Local integer output status for namelist read
443      NAMELIST/namiceitd/ nn_catbnd, rn_himean
444      !
445      INTEGER  ::   jl                   ! dummy loop index
446      REAL(wp) ::   zc1, zc2, zc3, zx1   ! local scalars
447      REAL(wp) ::   zhmax, znum, zden, zalpha !
448      !!------------------------------------------------------------------
449      !
450      REWIND( numnam_ice_ref )              ! Namelist namiceitd in reference namelist : Parameters for ice
451      READ  ( numnam_ice_ref, namiceitd, IOSTAT = ios, ERR = 905)
452905   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namiceitd in reference namelist', lwp )
453
454      REWIND( numnam_ice_cfg )              ! Namelist namiceitd in configuration namelist : Parameters for ice
455      READ  ( numnam_ice_cfg, namiceitd, IOSTAT = ios, ERR = 906 )
456906   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namiceitd in configuration namelist', lwp )
457      IF(lwm) WRITE ( numoni, namiceitd )
458      !
459      IF(lwp) THEN                        ! control print
460         WRITE(numout,*)
461         WRITE(numout,*) 'lim_itd_init : Initialization of ice cat distribution '
462         WRITE(numout,*) '~~~~~~~~~~~~'
463         WRITE(numout,*) '   shape of ice categories distribution                          nn_catbnd = ', nn_catbnd
464         WRITE(numout,*) '   mean ice thickness in the domain (only active if nn_catbnd=2) rn_himean = ', rn_himean
465      ENDIF
466      !
467      !----------------------------------
468      !- Thickness categories boundaries
469      !----------------------------------
470      !
471      hi_max(:) = 0._wp
472      !
473      SELECT CASE ( nn_catbnd  )    ! type of ice categories distribution
474      !
475      CASE (1)                            !==  tanh function (CICE)  ==!
476         zc1 =  3._wp / REAL( jpl, wp )
477         zc2 = 10._wp * zc1
478         zc3 =  3._wp
479         DO jl = 1, jpl
480            zx1 = REAL( jl-1, wp ) / REAL( jpl, wp )
481            hi_max(jl) = hi_max(jl-1) + zc1 + zc2 * (1._wp + TANH( zc3 * (zx1 - 1._wp ) ) )
482         END DO
483         !
484      CASE (2)                            !==  h^(-alpha) function  ==!
485         zalpha = 0.05_wp
486         zhmax  = 3._wp * rn_himean
487         DO jl = 1, jpl
488            znum = jpl * ( zhmax+1 )**zalpha
489            zden = REAL( jpl-jl , wp ) * ( zhmax + 1._wp )**zalpha + REAL( jl , wp )
490            hi_max(jl) = ( znum / zden )**(1./zalpha) - 1
491         END DO
492         !
493      END SELECT
494      !
495      DO jl = 1, jpl                ! mean thickness by category
496         hi_mean(jl) = ( hi_max(jl) + hi_max(jl-1) ) * 0.5_wp
497      END DO
498      !
499      hi_max(jpl) = 99._wp          ! set to a big value to ensure that all ice is thinner than hi_max(jpl)
500      !
501      IF(lwp) WRITE(numout,*)
502      IF(lwp) WRITE(numout,*) '      Thickness category boundaries '
503      IF(lwp) WRITE(numout,*) '         hi_max ', hi_max(0:jpl)
504      !
505   END SUBROUTINE lim_itd_init
506
507
508   SUBROUTINE ice_lim_flx( ptn_ice, palb_ice, pqns_ice, pqsr_ice, pdqn_ice, pevap_ice, pdevap_ice, k_limflx )
509      !!---------------------------------------------------------------------
510      !!                  ***  ROUTINE ice_lim_flx  ***
511      !!
512      !! ** Purpose :   update the ice surface boundary condition by averaging and / or
513      !!                redistributing fluxes on ice categories
514      !!
515      !! ** Method  :   average then redistribute
516      !!
517      !! ** Action  :
518      !!---------------------------------------------------------------------
519      INTEGER                   , INTENT(in   ) ::   k_limflx   ! =-1 do nothing; =0 average ;
520      !                                                         ! = 1 average and redistribute ; =2 redistribute
521      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   ptn_ice    ! ice surface temperature
522      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   palb_ice   ! ice albedo
523      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pqns_ice   ! non solar flux
524      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pqsr_ice   ! net solar flux
525      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdqn_ice   ! non solar flux sensitivity
526      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pevap_ice  ! sublimation
527      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdevap_ice ! sublimation sensitivity
528      !
529      INTEGER  ::   jl      ! dummy loop index
530      !
531      REAL(wp), POINTER, DIMENSION(:,:) :: zalb_m    ! Mean albedo over all categories
532      REAL(wp), POINTER, DIMENSION(:,:) :: ztem_m    ! Mean temperature over all categories
533      !
534      REAL(wp), POINTER, DIMENSION(:,:) :: z_qsr_m   ! Mean solar heat flux over all categories
535      REAL(wp), POINTER, DIMENSION(:,:) :: z_qns_m   ! Mean non solar heat flux over all categories
536      REAL(wp), POINTER, DIMENSION(:,:) :: z_evap_m  ! Mean sublimation over all categories
537      REAL(wp), POINTER, DIMENSION(:,:) :: z_dqn_m   ! Mean d(qns)/dT over all categories
538      REAL(wp), POINTER, DIMENSION(:,:) :: z_devap_m ! Mean d(evap)/dT over all categories
539      !!----------------------------------------------------------------------
540      !
541      IF( nn_timing == 1 )  CALL timing_start('ice_lim_flx')
542      !
543      SELECT CASE( k_limflx )                              !==  averaged on all ice categories  ==!
544      CASE( 0 , 1 )
545         CALL wrk_alloc( jpi,jpj, z_qsr_m, z_qns_m, z_evap_m, z_dqn_m, z_devap_m)
546         !
547         z_qns_m  (:,:) = fice_ice_ave ( pqns_ice (:,:,:) )
548         z_qsr_m  (:,:) = fice_ice_ave ( pqsr_ice (:,:,:) )
549         z_dqn_m  (:,:) = fice_ice_ave ( pdqn_ice (:,:,:) )
550         z_evap_m (:,:) = fice_ice_ave ( pevap_ice (:,:,:) )
551         z_devap_m(:,:) = fice_ice_ave ( pdevap_ice (:,:,:) )
552         DO jl = 1, jpl
553            pdqn_ice  (:,:,jl) = z_dqn_m(:,:)
554            pdevap_ice(:,:,jl) = z_devap_m(:,:)
555         END DO
556         !
557         DO jl = 1, jpl
558            pqns_ice (:,:,jl) = z_qns_m(:,:)
559            pqsr_ice (:,:,jl) = z_qsr_m(:,:)
560            pevap_ice(:,:,jl) = z_evap_m(:,:)
561         END DO
562         !
563         CALL wrk_dealloc( jpi,jpj, z_qsr_m, z_qns_m, z_evap_m, z_dqn_m, z_devap_m)
564      END SELECT
565      !
566      SELECT CASE( k_limflx )                              !==  redistribution on all ice categories  ==!
567      CASE( 1 , 2 )
568         CALL wrk_alloc( jpi,jpj, zalb_m, ztem_m )
569         !
570         zalb_m(:,:) = fice_ice_ave ( palb_ice (:,:,:) )
571         ztem_m(:,:) = fice_ice_ave ( ptn_ice  (:,:,:) )
572         DO jl = 1, jpl
573            pqns_ice (:,:,jl) = pqns_ice (:,:,jl) + pdqn_ice  (:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
574            pevap_ice(:,:,jl) = pevap_ice(:,:,jl) + pdevap_ice(:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
575            pqsr_ice (:,:,jl) = pqsr_ice (:,:,jl) * ( 1._wp - palb_ice(:,:,jl) ) / ( 1._wp - zalb_m(:,:) )
576         END DO
577         !
578         CALL wrk_dealloc( jpi,jpj, zalb_m, ztem_m )
579      END SELECT
580      !
581      IF( nn_timing == 1 )  CALL timing_stop('ice_lim_flx')
582      !
583   END SUBROUTINE ice_lim_flx
584
585
586   SUBROUTINE sbc_lim_bef
587      !!----------------------------------------------------------------------
588      !!                  ***  ROUTINE sbc_lim_bef  ***
589      !!
590      !! ** purpose :  store ice variables at "before" time step
591      !!----------------------------------------------------------------------
592      a_i_b  (:,:,:)   = a_i  (:,:,:)     ! ice area
593      e_i_b  (:,:,:,:) = e_i  (:,:,:,:)   ! ice thermal energy
594      v_i_b  (:,:,:)   = v_i  (:,:,:)     ! ice volume
595      v_s_b  (:,:,:)   = v_s  (:,:,:)     ! snow volume
596      e_s_b  (:,:,:,:) = e_s  (:,:,:,:)   ! snow thermal energy
597      smv_i_b(:,:,:)   = smv_i(:,:,:)     ! salt content
598      oa_i_b (:,:,:)   = oa_i (:,:,:)     ! areal age content
599      u_ice_b(:,:)     = u_ice(:,:)
600      v_ice_b(:,:)     = v_ice(:,:)
601      !
602      at_i_b (:,:)     = SUM( a_i_b(:,:,:), dim=3 )
603     
604   END SUBROUTINE sbc_lim_bef
605
606
607   SUBROUTINE sbc_lim_diag0
608      !!----------------------------------------------------------------------
609      !!                  ***  ROUTINE sbc_lim_diag0  ***
610      !!
611      !! ** purpose :  set ice-ocean and ice-atm. fluxes to zeros at the beggining
612      !!               of the time step
613      !!----------------------------------------------------------------------
614      sfx    (:,:) = 0._wp   ;
615      sfx_bri(:,:) = 0._wp   ;   sfx_lam(:,:) = 0._wp
616      sfx_sni(:,:) = 0._wp   ;   sfx_opw(:,:) = 0._wp
617      sfx_bog(:,:) = 0._wp   ;   sfx_dyn(:,:) = 0._wp
618      sfx_bom(:,:) = 0._wp   ;   sfx_sum(:,:) = 0._wp
619      sfx_res(:,:) = 0._wp   ;   sfx_sub(:,:) = 0._wp
620      !
621      wfx_snw(:,:) = 0._wp   ;   wfx_ice(:,:) = 0._wp
622      wfx_sni(:,:) = 0._wp   ;   wfx_opw(:,:) = 0._wp
623      wfx_bog(:,:) = 0._wp   ;   wfx_dyn(:,:) = 0._wp
624      wfx_bom(:,:) = 0._wp   ;   wfx_sum(:,:) = 0._wp
625      wfx_res(:,:) = 0._wp   ;   wfx_sub(:,:) = 0._wp
626      wfx_spr(:,:) = 0._wp   ;   wfx_lam(:,:) = 0._wp 
627     
628      hfx_thd(:,:) = 0._wp   ;
629      hfx_snw(:,:) = 0._wp   ;   hfx_opw(:,:) = 0._wp
630      hfx_bog(:,:) = 0._wp   ;   hfx_dyn(:,:) = 0._wp
631      hfx_bom(:,:) = 0._wp   ;   hfx_sum(:,:) = 0._wp
632      hfx_res(:,:) = 0._wp   ;   hfx_sub(:,:) = 0._wp
633      hfx_spr(:,:) = 0._wp   ;   hfx_dif(:,:) = 0._wp
634      hfx_err(:,:) = 0._wp   ;   hfx_err_rem(:,:) = 0._wp
635      hfx_err_dif(:,:) = 0._wp
636      wfx_err_sub(:,:) = 0._wp
637      !
638      afx_tot(:,:) = 0._wp   ;
639      afx_dyn(:,:) = 0._wp   ;   afx_thd(:,:) = 0._wp
640      !
641      diag_heat(:,:) = 0._wp ;   diag_smvi(:,:) = 0._wp
642      diag_vice(:,:) = 0._wp ;   diag_vsnw(:,:) = 0._wp
643
644      tau_icebfr(:,:) = 0._wp; ! landfast ice param only (clem: important to keep the init here)
645     
646   END SUBROUTINE sbc_lim_diag0
647
648
649   FUNCTION fice_cell_ave ( ptab )
650      !!--------------------------------------------------------------------------
651      !! * Compute average over categories, for grid cell (ice covered and free ocean)
652      !!--------------------------------------------------------------------------
653      REAL (wp), DIMENSION (jpi,jpj) :: fice_cell_ave
654      REAL (wp), DIMENSION (jpi,jpj,jpl), INTENT (in) :: ptab
655      INTEGER :: jl ! Dummy loop index
656
657      fice_cell_ave (:,:) = 0._wp
658      DO jl = 1, jpl
659         fice_cell_ave (:,:) = fice_cell_ave (:,:) + a_i (:,:,jl) * ptab (:,:,jl)
660      END DO
661
662   END FUNCTION fice_cell_ave
663
664
665   FUNCTION fice_ice_ave ( ptab )
666      !!--------------------------------------------------------------------------
667      !! * Compute average over categories, for ice covered part of grid cell
668      !!--------------------------------------------------------------------------
669      REAL (kind=wp), DIMENSION (jpi,jpj) :: fice_ice_ave
670      REAL (kind=wp), DIMENSION (jpi,jpj,jpl), INTENT(in) :: ptab
671
672      fice_ice_ave (:,:) = 0.0_wp
673      WHERE ( at_i (:,:) > 0.0_wp ) fice_ice_ave (:,:) = fice_cell_ave ( ptab (:,:,:)) / at_i (:,:)
674
675   END FUNCTION fice_ice_ave
676
677#else
678   !!----------------------------------------------------------------------
679   !!   Default option           Dummy module      NO LIM 3.0 sea-ice model
680   !!----------------------------------------------------------------------
681CONTAINS
682   SUBROUTINE sbc_ice_lim ( kt, ksbc )     ! Dummy routine
683      WRITE(*,*) 'sbc_ice_lim: You should not have seen this print! error?', kt
684   END SUBROUTINE sbc_ice_lim
685   SUBROUTINE sbc_lim_init                 ! Dummy routine
686   END SUBROUTINE sbc_lim_init
687#endif
688
689   !!======================================================================
690END MODULE sbcice_lim
Note: See TracBrowser for help on using the repository browser.