| 1 | MODULE sbcice_lim_2 |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcice_lim_2 *** |
|---|
| 4 | !! Surface module : update surface ocean boundary condition over ice covered area using LIM sea-ice model |
|---|
| 5 | !! Sea-Ice model : LIM-2 Sea ice model time-stepping |
|---|
| 6 | !!====================================================================== |
|---|
| 7 | !! History : 1.0 ! 06-2006 (G. Madec) from icestp_2.F90 |
|---|
| 8 | !! 3.0 ! 08-2008 (S. Masson, E. .... ) coupled interface |
|---|
| 9 | !! 3.3 ! 05-2009 (G.Garric) addition of the lim2_evp case |
|---|
| 10 | !!---------------------------------------------------------------------- |
|---|
| 11 | #if defined key_lim2 |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | !! 'key_lim2' : LIM-2 sea-ice model |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | !! sbc_ice_lim_2 : sea-ice model time-stepping and update ocean sbc over ice-covered area |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | USE oce ! ocean dynamics and tracers |
|---|
| 18 | USE dom_oce ! ocean space and time domain |
|---|
| 19 | USE ice_2 |
|---|
| 20 | USE par_ice_2 |
|---|
| 21 | USE iceini_2 |
|---|
| 22 | USE dom_ice_2 |
|---|
| 23 | |
|---|
| 24 | USE sbc_oce ! Surface boundary condition: ocean fields |
|---|
| 25 | USE sbc_ice ! Surface boundary condition: ice fields |
|---|
| 26 | USE sbcblk_core ! Surface boundary condition: CORE bulk |
|---|
| 27 | USE sbcblk_clio ! Surface boundary condition: CLIO bulk |
|---|
| 28 | USE sbccpl ! Surface boundary condition: coupled interface |
|---|
| 29 | USE albedo |
|---|
| 30 | |
|---|
| 31 | USE phycst ! Define parameters for the routines |
|---|
| 32 | USE eosbn2 ! equation of state |
|---|
| 33 | USE limdyn_2 |
|---|
| 34 | USE limtrp_2 |
|---|
| 35 | USE limdmp_2 |
|---|
| 36 | USE limthd_2 |
|---|
| 37 | USE limsbc_2 ! sea surface boundary condition |
|---|
| 38 | USE limdia_2 |
|---|
| 39 | USE limwri_2 |
|---|
| 40 | USE limrst_2 |
|---|
| 41 | |
|---|
| 42 | USE c1d ! 1D vertical configuration |
|---|
| 43 | |
|---|
| 44 | USE lbclnk ! lateral boundary condition - MPP link |
|---|
| 45 | USE lib_mpp ! MPP library |
|---|
| 46 | USE wrk_nemo ! work arrays |
|---|
| 47 | USE iom ! I/O manager library |
|---|
| 48 | USE in_out_manager ! I/O manager |
|---|
| 49 | USE prtctl ! Print control |
|---|
| 50 | |
|---|
| 51 | IMPLICIT NONE |
|---|
| 52 | PRIVATE |
|---|
| 53 | |
|---|
| 54 | PUBLIC sbc_ice_lim_2 ! routine called by sbcmod.F90 |
|---|
| 55 | |
|---|
| 56 | !! * Substitutions |
|---|
| 57 | # include "domzgr_substitute.h90" |
|---|
| 58 | # include "vectopt_loop_substitute.h90" |
|---|
| 59 | !!---------------------------------------------------------------------- |
|---|
| 60 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
|---|
| 61 | !! $Id$ |
|---|
| 62 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 63 | !!---------------------------------------------------------------------- |
|---|
| 64 | CONTAINS |
|---|
| 65 | |
|---|
| 66 | SUBROUTINE sbc_ice_lim_2( kt, ksbc ) |
|---|
| 67 | !!--------------------------------------------------------------------- |
|---|
| 68 | !! *** ROUTINE sbc_ice_lim_2 *** |
|---|
| 69 | !! |
|---|
| 70 | !! ** Purpose : update the ocean surface boundary condition via the |
|---|
| 71 | !! Louvain la Neuve Sea Ice Model time stepping |
|---|
| 72 | !! |
|---|
| 73 | !! ** Method : ice model time stepping |
|---|
| 74 | !! - call the ice dynamics routine |
|---|
| 75 | !! - call the ice advection/diffusion routine |
|---|
| 76 | !! - call the ice thermodynamics routine |
|---|
| 77 | !! - call the routine that computes mass and |
|---|
| 78 | !! heat fluxes at the ice/ocean interface |
|---|
| 79 | !! - save the outputs |
|---|
| 80 | !! - save the outputs for restart when necessary |
|---|
| 81 | !! |
|---|
| 82 | !! ** Action : - time evolution of the LIM sea-ice model |
|---|
| 83 | !! - update all sbc variables below sea-ice: |
|---|
| 84 | !! utau, vtau, taum, wndm, qns , qsr, emp , emps |
|---|
| 85 | !!--------------------------------------------------------------------- |
|---|
| 86 | INTEGER, INTENT(in) :: kt ! ocean time step |
|---|
| 87 | INTEGER, INTENT(in) :: ksbc ! type of sbc ( =3 CLIO bulk ; =4 CORE bulk ; =5 coupled ) |
|---|
| 88 | !! |
|---|
| 89 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 90 | REAL(wp), DIMENSION(:,:,:), POINTER :: zalb_ice_os ! albedo of the ice under overcast sky |
|---|
| 91 | REAL(wp), DIMENSION(:,:,:), POINTER :: zalb_ice_cs ! albedo of ice under clear sky |
|---|
| 92 | REAL(wp), DIMENSION(:,:,:), POINTER :: zsist ! surface ice temperature (K) |
|---|
| 93 | !!---------------------------------------------------------------------- |
|---|
| 94 | |
|---|
| 95 | CALL wrk_alloc( jpi,jpj,1, zalb_ice_os, zalb_ice_cs, zsist ) |
|---|
| 96 | |
|---|
| 97 | IF( kt == nit000 ) THEN |
|---|
| 98 | IF(lwp) WRITE(numout,*) |
|---|
| 99 | IF(lwp) WRITE(numout,*) 'sbc_ice_lim_2 : update ocean surface boudary condition' |
|---|
| 100 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~ via Louvain la Neuve Ice Model (LIM) time stepping' |
|---|
| 101 | ! |
|---|
| 102 | CALL ice_init_2 |
|---|
| 103 | ENDIF |
|---|
| 104 | |
|---|
| 105 | ! !----------------------! |
|---|
| 106 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN ! Ice time-step only ! |
|---|
| 107 | ! !----------------------! |
|---|
| 108 | ! Bulk Formulea ! |
|---|
| 109 | !----------------! |
|---|
| 110 | ! ... mean surface ocean current at ice dynamics point |
|---|
| 111 | SELECT CASE( cp_ice_msh ) |
|---|
| 112 | CASE( 'I' ) !== B-grid ice dynamics : I-point (i.e. F-point with sea-ice indexation) |
|---|
| 113 | DO jj = 2, jpj |
|---|
| 114 | DO ji = 2, jpi ! NO vector opt. possible |
|---|
| 115 | u_oce(ji,jj) = 0.5_wp * ( ssu_m(ji-1,jj ) + ssu_m(ji-1,jj-1) ) * tmu(ji,jj) |
|---|
| 116 | v_oce(ji,jj) = 0.5_wp * ( ssv_m(ji ,jj-1) + ssv_m(ji-1,jj-1) ) * tmu(ji,jj) |
|---|
| 117 | END DO |
|---|
| 118 | END DO |
|---|
| 119 | CALL lbc_lnk( u_oce, 'I', -1. ) ! I-point (i.e. F-point with ice indices) |
|---|
| 120 | CALL lbc_lnk( v_oce, 'I', -1. ) ! I-point (i.e. F-point with ice indices) |
|---|
| 121 | ! |
|---|
| 122 | CASE( 'C' ) !== C-grid ice dynamics : U & V-points (same as ocean) |
|---|
| 123 | u_oce(:,:) = ssu_m(:,:) ! mean surface ocean current at ice velocity point |
|---|
| 124 | v_oce(:,:) = ssv_m(:,:) |
|---|
| 125 | ! |
|---|
| 126 | END SELECT |
|---|
| 127 | |
|---|
| 128 | ! ... masked sea surface freezing temperature [Kelvin] (set to rt0 over land) |
|---|
| 129 | tfu(:,:) = tfreez( sss_m ) + rt0 |
|---|
| 130 | |
|---|
| 131 | zsist (:,:,1) = sist (:,:) + rt0 * ( 1. - tmask(:,:,1) ) |
|---|
| 132 | |
|---|
| 133 | ! ... ice albedo (clear sky and overcast sky) |
|---|
| 134 | CALL albedo_ice( zsist, reshape( hicif, (/jpi,jpj,1/) ), & |
|---|
| 135 | reshape( hsnif, (/jpi,jpj,1/) ), & |
|---|
| 136 | zalb_ice_cs, zalb_ice_os ) |
|---|
| 137 | |
|---|
| 138 | ! ... Sea-ice surface boundary conditions output from bulk formulae : |
|---|
| 139 | ! - utau_ice ! surface ice stress i-component (I-point) [N/m2] |
|---|
| 140 | ! - vtau_ice ! surface ice stress j-component (I-point) [N/m2] |
|---|
| 141 | ! - qns_ice ! non solar heat flux over ice (T-point) [W/m2] |
|---|
| 142 | ! - qsr_ice ! solar heat flux over ice (T-point) [W/m2] |
|---|
| 143 | ! - qla_ice ! latent heat flux over ice (T-point) [W/m2] |
|---|
| 144 | ! - dqns_ice ! non solar heat sensistivity (T-point) [W/m2] |
|---|
| 145 | ! - dqla_ice ! latent heat sensistivity (T-point) [W/m2] |
|---|
| 146 | ! - tprecip ! total precipitation (T-point) [Kg/m2/s] |
|---|
| 147 | ! - sprecip ! solid precipitation (T-point) [Kg/m2/s] |
|---|
| 148 | ! - fr1_i0 ! 1sr fraction of qsr penetration in ice [%] |
|---|
| 149 | ! - fr2_i0 ! 2nd fraction of qsr penetration in ice [%] |
|---|
| 150 | ! |
|---|
| 151 | SELECT CASE( ksbc ) |
|---|
| 152 | CASE( 3 ) ! CLIO bulk formulation |
|---|
| 153 | CALL blk_ice_clio( zsist, zalb_ice_cs, zalb_ice_os, & |
|---|
| 154 | & utau_ice , vtau_ice , qns_ice , qsr_ice, & |
|---|
| 155 | & qla_ice , dqns_ice , dqla_ice , & |
|---|
| 156 | & tprecip , sprecip , & |
|---|
| 157 | & fr1_i0 , fr2_i0 , cp_ice_msh , jpl ) |
|---|
| 158 | |
|---|
| 159 | CASE( 4 ) ! CORE bulk formulation |
|---|
| 160 | CALL blk_ice_core( zsist, u_ice , v_ice , zalb_ice_cs, & |
|---|
| 161 | & utau_ice , vtau_ice , qns_ice , qsr_ice, & |
|---|
| 162 | & qla_ice , dqns_ice , dqla_ice , & |
|---|
| 163 | & tprecip , sprecip , & |
|---|
| 164 | & fr1_i0 , fr2_i0 , cp_ice_msh , jpl ) |
|---|
| 165 | CASE( 5 ) ! Coupled formulation : atmosphere-ice stress only (fluxes provided after ice dynamics) |
|---|
| 166 | CALL sbc_cpl_ice_tau( utau_ice , vtau_ice ) |
|---|
| 167 | END SELECT |
|---|
| 168 | |
|---|
| 169 | CALL iom_put( 'utau_ice', utau_ice ) ! Wind stress over ice along i-axis at I-point |
|---|
| 170 | CALL iom_put( 'vtau_ice', vtau_ice ) ! Wind stress over ice along j-axis at I-point |
|---|
| 171 | |
|---|
| 172 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
|---|
| 173 | CALL prt_ctl_info( 'Ice Forcings ' ) |
|---|
| 174 | CALL prt_ctl( tab2d_1=tprecip ,clinfo1=' sbc_ice_lim: precip : ', tab2d_2=sprecip , clinfo2=' Snow : ' ) |
|---|
| 175 | CALL prt_ctl( tab2d_1=utau_ice,clinfo1=' sbc_ice_lim: utau_ice: ', tab2d_2=vtau_ice, clinfo2=' vtau_ice: ' ) |
|---|
| 176 | CALL prt_ctl( tab2d_1=sst_m ,clinfo1=' sbc_ice_lim: sst : ', tab2d_2=sss_m , clinfo2=' sss : ' ) |
|---|
| 177 | CALL prt_ctl( tab2d_1=u_oce ,clinfo1=' sbc_ice_lim: u_io : ', tab2d_2=v_oce , clinfo2=' v_io : ' ) |
|---|
| 178 | CALL prt_ctl( tab2d_1=hsnif ,clinfo1=' sbc_ice_lim: hsnif 1: ', tab2d_2=hicif , clinfo2=' hicif : ' ) |
|---|
| 179 | CALL prt_ctl( tab2d_1=frld ,clinfo1=' sbc_ice_lim: frld 1: ', tab2d_2=sist , clinfo2=' sist : ' ) |
|---|
| 180 | ENDIF |
|---|
| 181 | |
|---|
| 182 | ! ---------------- ! |
|---|
| 183 | ! Ice model step ! |
|---|
| 184 | ! ---------------- ! |
|---|
| 185 | numit = numit + nn_fsbc ! Ice model time step |
|---|
| 186 | |
|---|
| 187 | CALL lim_rst_opn_2 ( kt ) ! Open Ice restart file |
|---|
| 188 | IF( .NOT. lk_c1d ) THEN ! Ice dynamics & transport (except in 1D case) |
|---|
| 189 | CALL lim_dyn_2 ( kt ) ! Ice dynamics ( rheology/dynamics ) |
|---|
| 190 | CALL lim_trp_2 ( kt ) ! Ice transport ( Advection/diffusion ) |
|---|
| 191 | IF( ln_limdmp ) CALL lim_dmp_2 ( kt ) ! Ice damping |
|---|
| 192 | END IF |
|---|
| 193 | #if defined key_coupled |
|---|
| 194 | ! ! Ice surface fluxes in coupled mode |
|---|
| 195 | IF( ksbc == 5 ) THEN |
|---|
| 196 | a_i(:,:,1)=fr_i |
|---|
| 197 | CALL sbc_cpl_ice_flx( frld, & |
|---|
| 198 | ! optional arguments, used only in 'mixed oce-ice' case |
|---|
| 199 | & palbi = zalb_ice_cs, psst = sst_m, pist = zsist ) |
|---|
| 200 | sprecip(:,:) = - emp_ice(:,:) ! Ugly patch, WARNING, in coupled mode, sublimation included in snow (parsub = 0.) |
|---|
| 201 | ENDIF |
|---|
| 202 | #endif |
|---|
| 203 | CALL lim_thd_2 ( kt ) ! Ice thermodynamics |
|---|
| 204 | CALL lim_sbc_flx_2 ( kt ) ! update surface ocean mass, heat & salt fluxes |
|---|
| 205 | |
|---|
| 206 | IF( ( MOD( kt+nn_fsbc-1, ninfo ) == 0 .OR. ntmoy == 1 ) .AND. .NOT. lk_mpp ) & |
|---|
| 207 | & CALL lim_dia_2 ( kt ) ! Ice Diagnostics |
|---|
| 208 | # if ! defined key_iomput |
|---|
| 209 | CALL lim_wri_2 ( kt ) ! Ice outputs |
|---|
| 210 | # endif |
|---|
| 211 | IF( lrst_ice ) CALL lim_rst_write_2( kt ) ! Ice restart file |
|---|
| 212 | ! |
|---|
| 213 | ENDIF ! End sea-ice time step only |
|---|
| 214 | ! |
|---|
| 215 | ! !--------------------------! |
|---|
| 216 | ! ! at all ocean time step ! |
|---|
| 217 | ! !--------------------------! |
|---|
| 218 | ! |
|---|
| 219 | ! ! Update surface ocean stresses (only in ice-dynamic case) |
|---|
| 220 | ! ! otherwise the atm.-ocean stresses are used everywhere |
|---|
| 221 | IF( ln_limdyn ) CALL lim_sbc_tau_2( kt, ub(:,:,1), vb(:,:,1) ) ! using before instantaneous surf. currents |
|---|
| 222 | ! |
|---|
| 223 | CALL wrk_dealloc( jpi,jpj,1, zalb_ice_os, zalb_ice_cs, zsist ) |
|---|
| 224 | ! |
|---|
| 225 | END SUBROUTINE sbc_ice_lim_2 |
|---|
| 226 | |
|---|
| 227 | #else |
|---|
| 228 | !!---------------------------------------------------------------------- |
|---|
| 229 | !! Default option Dummy module NO LIM 2.0 sea-ice model |
|---|
| 230 | !!---------------------------------------------------------------------- |
|---|
| 231 | CONTAINS |
|---|
| 232 | SUBROUTINE sbc_ice_lim_2 ( kt, ksbc ) ! Dummy routine |
|---|
| 233 | INTEGER, INTENT(in) :: kt, ksbc |
|---|
| 234 | WRITE(*,*) 'sbc_ice_lim_2: You should not have seen this print! error?', kt, ksbc |
|---|
| 235 | END SUBROUTINE sbc_ice_lim_2 |
|---|
| 236 | #endif |
|---|
| 237 | |
|---|
| 238 | !!====================================================================== |
|---|
| 239 | END MODULE sbcice_lim_2 |
|---|
