| 1 | MODULE sbcmod |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcmod *** |
|---|
| 4 | !! Surface module : provide to the ocean its surface boundary condition |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 3.0 ! 2006-07 (G. Madec) Original code |
|---|
| 7 | !! 3.1 ! 2008-08 (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface |
|---|
| 8 | !! 3.3 ! 2010-04 (M. Leclair, G. Madec) Forcing averaged over 2 time steps |
|---|
| 9 | !! 3.3 ! 2010-10 (S. Masson) add diurnal cycle |
|---|
| 10 | !! 3.3 ! 2010-09 (D. Storkey) add ice boundary conditions (BDY) |
|---|
| 11 | !! - ! 2010-11 (G. Madec) ice-ocean stress always computed at each ocean time-step |
|---|
| 12 | !! - ! 2010-10 (J. Chanut, C. Bricaud, G. Madec) add the surface pressure forcing |
|---|
| 13 | !! 3.4 ! 2011-11 (C. Harris) CICE added as an option |
|---|
| 14 | !! 3.5 ! 2012-11 (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes |
|---|
| 15 | !! 3.6 ! 2014-11 (P. Mathiot, C. Harris) add ice shelves melting |
|---|
| 16 | !! 4.0 ! 2016-06 (L. Brodeau) new general bulk formulation |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | |
|---|
| 19 | !!---------------------------------------------------------------------- |
|---|
| 20 | !! sbc_init : read namsbc namelist |
|---|
| 21 | !! sbc : surface ocean momentum, heat and freshwater boundary conditions |
|---|
| 22 | !! sbc_final : Finalize CICE ice model (if used) |
|---|
| 23 | !!---------------------------------------------------------------------- |
|---|
| 24 | USE oce ! ocean dynamics and tracers |
|---|
| 25 | USE dom_oce ! ocean space and time domain |
|---|
| 26 | USE phycst ! physical constants |
|---|
| 27 | USE sbc_oce ! Surface boundary condition: ocean fields |
|---|
| 28 | USE trc_oce ! shared ocean-passive tracers variables |
|---|
| 29 | USE sbc_ice ! Surface boundary condition: ice fields |
|---|
| 30 | USE sbcdcy ! surface boundary condition: diurnal cycle |
|---|
| 31 | USE sbcssm ! surface boundary condition: sea-surface mean variables |
|---|
| 32 | USE sbcflx ! surface boundary condition: flux formulation |
|---|
| 33 | USE sbcblk ! surface boundary condition: bulk formulation |
|---|
| 34 | USE sbcice_if ! surface boundary condition: ice-if sea-ice model |
|---|
| 35 | USE sbcice_lim ! surface boundary condition: LIM 3.0 sea-ice model |
|---|
| 36 | USE sbcice_lim_2 ! surface boundary condition: LIM 2.0 sea-ice model |
|---|
| 37 | USE sbcice_cice ! surface boundary condition: CICE sea-ice model |
|---|
| 38 | USE sbccpl ! surface boundary condition: coupled formulation |
|---|
| 39 | USE cpl_oasis3 ! OASIS routines for coupling |
|---|
| 40 | USE sbcssr ! surface boundary condition: sea surface restoring |
|---|
| 41 | USE sbcrnf ! surface boundary condition: runoffs |
|---|
| 42 | USE sbcisf ! surface boundary condition: ice shelf |
|---|
| 43 | USE sbcfwb ! surface boundary condition: freshwater budget |
|---|
| 44 | USE icbstp ! Icebergs |
|---|
| 45 | USE traqsr ! active tracers: light penetration |
|---|
| 46 | USE sbcwave ! Wave module |
|---|
| 47 | USE bdy_oce , ONLY: ln_bdy |
|---|
| 48 | USE usrdef_sbc ! user defined: surface boundary condition |
|---|
| 49 | USE usrdef_closea ! user defined: closed sea |
|---|
| 50 | ! |
|---|
| 51 | USE prtctl ! Print control (prt_ctl routine) |
|---|
| 52 | USE iom ! IOM library |
|---|
| 53 | USE in_out_manager ! I/O manager |
|---|
| 54 | USE lib_mpp ! MPP library |
|---|
| 55 | USE timing ! Timing |
|---|
| 56 | |
|---|
| 57 | USE diurnal_bulk, ONLY: ln_diurnal_only ! diurnal SST diagnostic |
|---|
| 58 | |
|---|
| 59 | IMPLICIT NONE |
|---|
| 60 | PRIVATE |
|---|
| 61 | |
|---|
| 62 | PUBLIC sbc ! routine called by step.F90 |
|---|
| 63 | PUBLIC sbc_init ! routine called by opa.F90 |
|---|
| 64 | |
|---|
| 65 | INTEGER :: nsbc ! type of surface boundary condition (deduced from namsbc informations) |
|---|
| 66 | |
|---|
| 67 | !!---------------------------------------------------------------------- |
|---|
| 68 | !! NEMO/OPA 4.0 , NEMO-consortium (2016) |
|---|
| 69 | !! $Id$ |
|---|
| 70 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 71 | !!---------------------------------------------------------------------- |
|---|
| 72 | CONTAINS |
|---|
| 73 | |
|---|
| 74 | SUBROUTINE sbc_init |
|---|
| 75 | !!--------------------------------------------------------------------- |
|---|
| 76 | !! *** ROUTINE sbc_init *** |
|---|
| 77 | !! |
|---|
| 78 | !! ** Purpose : Initialisation of the ocean surface boundary computation |
|---|
| 79 | !! |
|---|
| 80 | !! ** Method : Read the namsbc namelist and set derived parameters |
|---|
| 81 | !! Call init routines for all other SBC modules that have one |
|---|
| 82 | !! |
|---|
| 83 | !! ** Action : - read namsbc parameters |
|---|
| 84 | !! - nsbc: type of sbc |
|---|
| 85 | !!---------------------------------------------------------------------- |
|---|
| 86 | INTEGER :: ios, icpt ! local integer |
|---|
| 87 | LOGICAL :: ll_purecpl, ll_opa, ll_not_nemo ! local logical |
|---|
| 88 | !! |
|---|
| 89 | NAMELIST/namsbc/ nn_fsbc , & |
|---|
| 90 | & ln_usr , ln_flx , ln_blk , & |
|---|
| 91 | & ln_cpl , ln_mixcpl, nn_components, nn_limflx, & |
|---|
| 92 | & nn_ice , nn_ice_embd, & |
|---|
| 93 | & ln_traqsr, ln_dm2dc , & |
|---|
| 94 | & ln_rnf , nn_fwb , ln_ssr , ln_isf , ln_apr_dyn , & |
|---|
| 95 | & ln_wave , ln_cdgw , ln_sdw , ln_tauoc , ln_stcor , & |
|---|
| 96 | & nn_lsm |
|---|
| 97 | !!---------------------------------------------------------------------- |
|---|
| 98 | ! |
|---|
| 99 | IF(lwp) THEN |
|---|
| 100 | WRITE(numout,*) |
|---|
| 101 | WRITE(numout,*) 'sbc_init : surface boundary condition setting' |
|---|
| 102 | WRITE(numout,*) '~~~~~~~~ ' |
|---|
| 103 | ENDIF |
|---|
| 104 | ! |
|---|
| 105 | ! !** read Surface Module namelist |
|---|
| 106 | REWIND( numnam_ref ) !* Namelist namsbc in reference namelist : Surface boundary |
|---|
| 107 | READ ( numnam_ref, namsbc, IOSTAT = ios, ERR = 901) |
|---|
| 108 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in reference namelist', lwp ) |
|---|
| 109 | ! |
|---|
| 110 | REWIND( numnam_cfg ) !* Namelist namsbc in configuration namelist : Parameters of the run |
|---|
| 111 | READ ( numnam_cfg, namsbc, IOSTAT = ios, ERR = 902 ) |
|---|
| 112 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in configuration namelist', lwp ) |
|---|
| 113 | IF(lwm) WRITE( numond, namsbc ) |
|---|
| 114 | ! |
|---|
| 115 | ! !* overwrite namelist parameter using CPP key information |
|---|
| 116 | #if defined key_agrif |
|---|
| 117 | IF( Agrif_Root() ) THEN ! AGRIF zoom (cf r1242: possibility to run without ice in fine grid) |
|---|
| 118 | IF( lk_lim2 ) nn_ice = 2 |
|---|
| 119 | IF( lk_lim3 ) nn_ice = 3 |
|---|
| 120 | IF( lk_cice ) nn_ice = 4 |
|---|
| 121 | ENDIF |
|---|
| 122 | #else |
|---|
| 123 | IF( lk_lim2 ) nn_ice = 2 |
|---|
| 124 | IF( lk_lim3 ) nn_ice = 3 |
|---|
| 125 | IF( lk_cice ) nn_ice = 4 |
|---|
| 126 | #endif |
|---|
| 127 | ! |
|---|
| 128 | IF(lwp) THEN !* Control print |
|---|
| 129 | WRITE(numout,*) ' Namelist namsbc (partly overwritten with CPP key setting)' |
|---|
| 130 | WRITE(numout,*) ' frequency update of sbc (and ice) nn_fsbc = ', nn_fsbc |
|---|
| 131 | WRITE(numout,*) ' Type of air-sea fluxes : ' |
|---|
| 132 | WRITE(numout,*) ' user defined formulation ln_usr = ', ln_usr |
|---|
| 133 | WRITE(numout,*) ' flux formulation ln_flx = ', ln_flx |
|---|
| 134 | WRITE(numout,*) ' bulk formulation ln_blk = ', ln_blk |
|---|
| 135 | WRITE(numout,*) ' Type of coupling (Ocean/Ice/Atmosphere) : ' |
|---|
| 136 | WRITE(numout,*) ' ocean-atmosphere coupled formulation ln_cpl = ', ln_cpl |
|---|
| 137 | WRITE(numout,*) ' mixed forced-coupled formulation ln_mixcpl = ', ln_mixcpl |
|---|
| 138 | !!gm lk_oasis is controlled by key_oasis3 ===>>> It shoud be removed from the namelist |
|---|
| 139 | WRITE(numout,*) ' OASIS coupling (with atm or sas) lk_oasis = ', lk_oasis |
|---|
| 140 | WRITE(numout,*) ' components of your executable nn_components = ', nn_components |
|---|
| 141 | WRITE(numout,*) ' Multicategory heat flux formulation (LIM3) nn_limflx = ', nn_limflx |
|---|
| 142 | WRITE(numout,*) ' Sea-ice : ' |
|---|
| 143 | WRITE(numout,*) ' ice management in the sbc (=0/1/2/3) nn_ice = ', nn_ice |
|---|
| 144 | WRITE(numout,*) ' ice-ocean embedded/levitating (=0/1/2) nn_ice_embd = ', nn_ice_embd |
|---|
| 145 | WRITE(numout,*) ' Misc. options of sbc : ' |
|---|
| 146 | WRITE(numout,*) ' Light penetration in temperature Eq. ln_traqsr = ', ln_traqsr |
|---|
| 147 | WRITE(numout,*) ' daily mean to diurnal cycle qsr ln_dm2dc = ', ln_dm2dc |
|---|
| 148 | WRITE(numout,*) ' Sea Surface Restoring on SST and/or SSS ln_ssr = ', ln_ssr |
|---|
| 149 | WRITE(numout,*) ' FreshWater Budget control (=0/1/2) nn_fwb = ', nn_fwb |
|---|
| 150 | WRITE(numout,*) ' Patm gradient added in ocean & ice Eqs. ln_apr_dyn = ', ln_apr_dyn |
|---|
| 151 | WRITE(numout,*) ' runoff / runoff mouths ln_rnf = ', ln_rnf |
|---|
| 152 | WRITE(numout,*) ' iceshelf formulation ln_isf = ', ln_isf |
|---|
| 153 | WRITE(numout,*) ' closed sea (=0/1) (set in namdom) nn_closea = ', nn_closea |
|---|
| 154 | WRITE(numout,*) ' nb of iterations if land-sea-mask applied nn_lsm = ', nn_lsm |
|---|
| 155 | WRITE(numout,*) ' surface wave ln_wave = ', ln_wave |
|---|
| 156 | WRITE(numout,*) ' Stokes drift corr. to vert. velocity ln_sdw = ', ln_sdw |
|---|
| 157 | WRITE(numout,*) ' wave modified ocean stress ln_tauoc = ', ln_tauoc |
|---|
| 158 | WRITE(numout,*) ' Stokes coriolis term ln_stcor = ', ln_stcor |
|---|
| 159 | WRITE(numout,*) ' neutral drag coefficient (CORE, MFS) ln_cdgw = ', ln_cdgw |
|---|
| 160 | ENDIF |
|---|
| 161 | ! |
|---|
| 162 | IF( .NOT.ln_usr ) THEN ! the model calendar needs some specificities (except in user defined case) |
|---|
| 163 | IF( MOD( rday , rdt ) /= 0. ) CALL ctl_stop( 'the time step must devide the number of second of in a day' ) |
|---|
| 164 | IF( MOD( rday , 2. ) /= 0. ) CALL ctl_stop( 'the number of second of in a day must be an even number' ) |
|---|
| 165 | IF( MOD( rdt , 2. ) /= 0. ) CALL ctl_stop( 'the time step (in second) must be an even number' ) |
|---|
| 166 | ENDIF |
|---|
| 167 | ! !** check option consistency |
|---|
| 168 | ! |
|---|
| 169 | IF(lwp) WRITE(numout,*) !* Single / Multi - executable (NEMO / OPA+SAS) |
|---|
| 170 | SELECT CASE( nn_components ) |
|---|
| 171 | CASE( jp_iam_nemo ) |
|---|
| 172 | IF(lwp) WRITE(numout,*) ' NEMO configured as a single executable (i.e. including both OPA and Surface module' |
|---|
| 173 | CASE( jp_iam_opa ) |
|---|
| 174 | IF(lwp) WRITE(numout,*) ' Multi executable configuration. Here, OPA component' |
|---|
| 175 | IF( .NOT.lk_oasis ) CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' ) |
|---|
| 176 | IF( ln_cpl ) CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_cpl = T in OPA' ) |
|---|
| 177 | IF( ln_mixcpl ) CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' ) |
|---|
| 178 | CASE( jp_iam_sas ) |
|---|
| 179 | IF(lwp) WRITE(numout,*) ' Multi executable configuration. Here, SAS component' |
|---|
| 180 | IF( .NOT.lk_oasis ) CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' ) |
|---|
| 181 | IF( ln_mixcpl ) CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' ) |
|---|
| 182 | CASE DEFAULT |
|---|
| 183 | CALL ctl_stop( 'sbc_init : unsupported value for nn_components' ) |
|---|
| 184 | END SELECT |
|---|
| 185 | ! !* coupled options |
|---|
| 186 | IF( ln_cpl ) THEN |
|---|
| 187 | IF( .NOT. lk_oasis ) CALL ctl_stop( 'sbc_init : coupled mode with an atmosphere model (ln_cpl=T)', & |
|---|
| 188 | & ' required to defined key_oasis3' ) |
|---|
| 189 | ENDIF |
|---|
| 190 | IF( ln_mixcpl ) THEN |
|---|
| 191 | IF( .NOT. lk_oasis ) CALL ctl_stop( 'sbc_init : mixed forced-coupled mode (ln_mixcpl=T) ', & |
|---|
| 192 | & ' required to defined key_oasis3' ) |
|---|
| 193 | IF( .NOT.ln_cpl ) CALL ctl_stop( 'sbc_init : mixed forced-coupled mode (ln_mixcpl=T) requires ln_cpl = T' ) |
|---|
| 194 | IF( nn_components /= jp_iam_nemo ) & |
|---|
| 195 | & CALL ctl_stop( 'sbc_init : the mixed forced-coupled mode (ln_mixcpl=T) ', & |
|---|
| 196 | & ' not yet working with sas-opa coupling via oasis' ) |
|---|
| 197 | ENDIF |
|---|
| 198 | ! !* sea-ice |
|---|
| 199 | SELECT CASE( nn_ice ) |
|---|
| 200 | CASE( 0 ) !- no ice in the domain |
|---|
| 201 | CASE( 1 ) !- Ice-cover climatology ("Ice-if" model) |
|---|
| 202 | CASE( 2 ) !- LIM2 ice model |
|---|
| 203 | IF( .NOT.( ln_blk .OR. ln_cpl ) ) CALL ctl_stop( 'sbc_init : LIM2 sea-ice model requires ln_blk or ln_cpl = T' ) |
|---|
| 204 | CASE( 3 ) !- LIM3 ice model |
|---|
| 205 | IF( .NOT.( ln_blk .OR. ln_cpl ) ) CALL ctl_stop( 'sbc_init : LIM3 sea-ice model requires ln_blk or ln_cpl = T' ) |
|---|
| 206 | IF( nn_ice_embd == 0 ) CALL ctl_stop( 'sbc_init : LIM3 sea-ice models require nn_ice_embd = 1 or 2' ) |
|---|
| 207 | CASE( 4 ) !- CICE ice model |
|---|
| 208 | IF( .NOT.( ln_blk .OR. ln_cpl ) ) CALL ctl_stop( 'sbc_init : CICE sea-ice model requires ln_blk or ln_cpl = T' ) |
|---|
| 209 | IF( nn_ice_embd == 0 ) CALL ctl_stop( 'sbc_init : CICE sea-ice models require nn_ice_embd = 1 or 2' ) |
|---|
| 210 | IF( lk_agrif ) CALL ctl_stop( 'sbc_init : CICE sea-ice model not currently available with AGRIF' ) |
|---|
| 211 | CASE DEFAULT !- not supported |
|---|
| 212 | END SELECT |
|---|
| 213 | ! |
|---|
| 214 | IF( nn_ice == 3 ) THEN !- LIM3 case: multi-category flux option |
|---|
| 215 | IF(lwp) WRITE(numout,*) |
|---|
| 216 | SELECT CASE( nn_limflx ) ! LIM3 Multi-category heat flux formulation |
|---|
| 217 | CASE ( -1 ) |
|---|
| 218 | IF(lwp) WRITE(numout,*) ' LIM3: use per-category fluxes (nn_limflx = -1) ' |
|---|
| 219 | IF( ln_cpl ) CALL ctl_stop( 'sbc_init : the chosen nn_limflx for LIM3 in coupled mode must be 0 or 2' ) |
|---|
| 220 | CASE ( 0 ) |
|---|
| 221 | IF(lwp) WRITE(numout,*) ' LIM3: use average per-category fluxes (nn_limflx = 0) ' |
|---|
| 222 | CASE ( 1 ) |
|---|
| 223 | IF(lwp) WRITE(numout,*) ' LIM3: use average then redistribute per-category fluxes (nn_limflx = 1) ' |
|---|
| 224 | IF( ln_cpl ) CALL ctl_stop( 'sbc_init : the chosen nn_limflx for LIM3 in coupled mode must be 0 or 2' ) |
|---|
| 225 | CASE ( 2 ) |
|---|
| 226 | IF(lwp) WRITE(numout,*) ' LIM3: Redistribute a single flux over categories (nn_limflx = 2) ' |
|---|
| 227 | IF( .NOT.ln_cpl ) CALL ctl_stop( 'sbc_init : the chosen nn_limflx for LIM3 in forced mode cannot be 2' ) |
|---|
| 228 | CASE DEFAULT |
|---|
| 229 | CALL ctl_stop( 'sbcmod: LIM3 option, nn_limflx, should be between -1 and 2' ) |
|---|
| 230 | END SELECT |
|---|
| 231 | ELSE ! other sea-ice model |
|---|
| 232 | IF( nn_limflx >= 0 ) CALL ctl_warn( 'sbc_init : multi-category flux option (nn_limflx) only available in LIM3' ) |
|---|
| 233 | ENDIF |
|---|
| 234 | ! |
|---|
| 235 | ! !** allocate and set required variables |
|---|
| 236 | ! |
|---|
| 237 | ! !* allocate sbc arrays |
|---|
| 238 | IF( sbc_oce_alloc() /= 0 ) CALL ctl_stop( 'sbc_init : unable to allocate sbc_oce arrays' ) |
|---|
| 239 | ! |
|---|
| 240 | IF( .NOT.ln_isf ) THEN !* No ice-shelf in the domain : allocate and set to zero |
|---|
| 241 | IF( sbc_isf_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_isf arrays' ) |
|---|
| 242 | fwfisf (:,:) = 0._wp ; risf_tsc (:,:,:) = 0._wp |
|---|
| 243 | fwfisf_b(:,:) = 0._wp ; risf_tsc_b(:,:,:) = 0._wp |
|---|
| 244 | END IF |
|---|
| 245 | IF( nn_ice == 0 ) THEN !* No sea-ice in the domain : ice fraction is always zero |
|---|
| 246 | IF( nn_components /= jp_iam_opa ) fr_i(:,:) = 0._wp ! except for OPA in SAS-OPA coupled case |
|---|
| 247 | ENDIF |
|---|
| 248 | ! |
|---|
| 249 | sfx (:,:) = 0._wp !* salt flux due to freezing/melting |
|---|
| 250 | fmmflx(:,:) = 0._wp !* freezing minus melting flux |
|---|
| 251 | |
|---|
| 252 | taum(:,:) = 0._wp !* wind stress module (needed in GLS in case of reduced restart) |
|---|
| 253 | |
|---|
| 254 | ! ! Choice of the Surface Boudary Condition (set nsbc) |
|---|
| 255 | IF( ln_dm2dc ) THEN !* daily mean to diurnal cycle |
|---|
| 256 | nday_qsr = -1 ! allow initialization at the 1st call |
|---|
| 257 | IF( .NOT.( ln_flx .OR. ln_blk ) .AND. nn_components /= jp_iam_opa ) & |
|---|
| 258 | & CALL ctl_stop( 'qsr diurnal cycle from daily values requires a flux or bulk formulation' ) |
|---|
| 259 | ENDIF |
|---|
| 260 | ! !* Choice of the Surface Boudary Condition |
|---|
| 261 | ! (set nsbc) |
|---|
| 262 | ! |
|---|
| 263 | ll_purecpl = ln_cpl .AND. .NOT.ln_mixcpl |
|---|
| 264 | ll_opa = nn_components == jp_iam_opa |
|---|
| 265 | ll_not_nemo = nn_components /= jp_iam_nemo |
|---|
| 266 | icpt = 0 |
|---|
| 267 | ! |
|---|
| 268 | IF( ln_usr ) THEN ; nsbc = jp_usr ; icpt = icpt + 1 ; ENDIF ! user defined formulation |
|---|
| 269 | IF( ln_flx ) THEN ; nsbc = jp_flx ; icpt = icpt + 1 ; ENDIF ! flux formulation |
|---|
| 270 | IF( ln_blk ) THEN ; nsbc = jp_blk ; icpt = icpt + 1 ; ENDIF ! bulk formulation |
|---|
| 271 | IF( ll_purecpl ) THEN ; nsbc = jp_purecpl ; icpt = icpt + 1 ; ENDIF ! Pure Coupled formulation |
|---|
| 272 | IF( ll_opa ) THEN ; nsbc = jp_none ; icpt = icpt + 1 ; ENDIF ! opa coupling via SAS module |
|---|
| 273 | ! |
|---|
| 274 | IF( icpt /= 1 ) CALL ctl_stop( 'sbc_init : choose ONE and only ONE sbc option' ) |
|---|
| 275 | ! |
|---|
| 276 | IF(lwp) THEN !- print the choice of surface flux formulation |
|---|
| 277 | WRITE(numout,*) |
|---|
| 278 | SELECT CASE( nsbc ) |
|---|
| 279 | CASE( jp_usr ) ; WRITE(numout,*) ' user defined formulation' |
|---|
| 280 | CASE( jp_flx ) ; WRITE(numout,*) ' ===>> flux formulation' |
|---|
| 281 | CASE( jp_blk ) ; WRITE(numout,*) ' ===>> bulk formulation' |
|---|
| 282 | CASE( jp_purecpl ) ; WRITE(numout,*) ' ===>> pure coupled formulation' |
|---|
| 283 | !!gm abusive use of jp_none ?? ===>>> need to be check and changed by adding a jp_sas parameter |
|---|
| 284 | CASE( jp_none ) ; WRITE(numout,*) ' ===>> OPA coupled to SAS via oasis' |
|---|
| 285 | IF( ln_mixcpl ) WRITE(numout,*) ' + forced-coupled mixed formulation' |
|---|
| 286 | END SELECT |
|---|
| 287 | IF( ll_not_nemo ) WRITE(numout,*) ' + OASIS coupled SAS' |
|---|
| 288 | ENDIF |
|---|
| 289 | ! |
|---|
| 290 | ! !* OASIS initialization |
|---|
| 291 | ! |
|---|
| 292 | IF( lk_oasis ) CALL sbc_cpl_init( nn_ice ) ! Must be done before: (1) first time step |
|---|
| 293 | ! ! (2) the use of nn_fsbc |
|---|
| 294 | ! nn_fsbc initialization if OPA-SAS coupling via OASIS |
|---|
| 295 | ! SAS time-step has to be declared in OASIS (mandatory) -> nn_fsbc has to be modified accordingly |
|---|
| 296 | IF( nn_components /= jp_iam_nemo ) THEN |
|---|
| 297 | IF( nn_components == jp_iam_opa ) nn_fsbc = cpl_freq('O_SFLX') / NINT(rdt) |
|---|
| 298 | IF( nn_components == jp_iam_sas ) nn_fsbc = cpl_freq('I_SFLX') / NINT(rdt) |
|---|
| 299 | ! |
|---|
| 300 | IF(lwp)THEN |
|---|
| 301 | WRITE(numout,*) |
|---|
| 302 | WRITE(numout,*)" OPA-SAS coupled via OASIS : nn_fsbc re-defined from OASIS namcouple ", nn_fsbc |
|---|
| 303 | WRITE(numout,*) |
|---|
| 304 | ENDIF |
|---|
| 305 | ENDIF |
|---|
| 306 | ! |
|---|
| 307 | ! !* check consistency between model timeline and nn_fsbc |
|---|
| 308 | IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR. & |
|---|
| 309 | MOD( nstock , nn_fsbc) /= 0 ) THEN |
|---|
| 310 | WRITE(ctmp1,*) 'sbc_init : experiment length (', nitend - nit000 + 1, ') or nstock (', nstock, & |
|---|
| 311 | & ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')' |
|---|
| 312 | CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' ) |
|---|
| 313 | ENDIF |
|---|
| 314 | ! |
|---|
| 315 | IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 ) & |
|---|
| 316 | & CALL ctl_warn( 'sbc_init : nn_fsbc is NOT a multiple of the number of time steps in a day' ) |
|---|
| 317 | ! |
|---|
| 318 | IF( ln_dm2dc .AND. NINT(rday) / ( nn_fsbc * NINT(rdt) ) < 8 ) & |
|---|
| 319 | & CALL ctl_warn( 'sbc_init : diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' ) |
|---|
| 320 | ! |
|---|
| 321 | |
|---|
| 322 | ! !** associated modules : initialization |
|---|
| 323 | ! |
|---|
| 324 | CALL sbc_ssm_init ! Sea-surface mean fields initialization |
|---|
| 325 | ! |
|---|
| 326 | IF( ln_blk ) CALL sbc_blk_init ! bulk formulae initialization |
|---|
| 327 | |
|---|
| 328 | IF( ln_ssr ) CALL sbc_ssr_init ! Sea-Surface Restoring initialization |
|---|
| 329 | ! |
|---|
| 330 | CALL sbc_rnf_init ! Runof initialization |
|---|
| 331 | ! |
|---|
| 332 | IF( nn_ice == 3 ) CALL sbc_lim_init ! LIM3 initialization |
|---|
| 333 | ! |
|---|
| 334 | IF( nn_ice == 4 ) CALL cice_sbc_init( nsbc ) ! CICE initialization |
|---|
| 335 | ! |
|---|
| 336 | IF( ln_wave ) CALL sbc_wave_init ! surface wave initialisation |
|---|
| 337 | ! |
|---|
| 338 | END SUBROUTINE sbc_init |
|---|
| 339 | |
|---|
| 340 | |
|---|
| 341 | SUBROUTINE sbc( kt ) |
|---|
| 342 | !!--------------------------------------------------------------------- |
|---|
| 343 | !! *** ROUTINE sbc *** |
|---|
| 344 | !! |
|---|
| 345 | !! ** Purpose : provide at each time-step the ocean surface boundary |
|---|
| 346 | !! condition (momentum, heat and freshwater fluxes) |
|---|
| 347 | !! |
|---|
| 348 | !! ** Method : blah blah to be written ????????? |
|---|
| 349 | !! CAUTION : never mask the surface stress field (tke sbc) |
|---|
| 350 | !! |
|---|
| 351 | !! ** Action : - set the ocean surface boundary condition at before and now |
|---|
| 352 | !! time step, i.e. |
|---|
| 353 | !! utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b |
|---|
| 354 | !! utau , vtau , qns , qsr , emp , sfx , qrp , erp |
|---|
| 355 | !! - updte the ice fraction : fr_i |
|---|
| 356 | !!---------------------------------------------------------------------- |
|---|
| 357 | INTEGER, INTENT(in) :: kt ! ocean time step |
|---|
| 358 | ! |
|---|
| 359 | LOGICAL :: ll_sas, ll_opa ! local logical |
|---|
| 360 | !!--------------------------------------------------------------------- |
|---|
| 361 | ! |
|---|
| 362 | IF( nn_timing == 1 ) CALL timing_start('sbc') |
|---|
| 363 | ! |
|---|
| 364 | ! ! ---------------------------------------- ! |
|---|
| 365 | IF( kt /= nit000 ) THEN ! Swap of forcing fields ! |
|---|
| 366 | ! ! ---------------------------------------- ! |
|---|
| 367 | utau_b(:,:) = utau(:,:) ! Swap the ocean forcing fields |
|---|
| 368 | vtau_b(:,:) = vtau(:,:) ! (except at nit000 where before fields |
|---|
| 369 | qns_b (:,:) = qns (:,:) ! are set at the end of the routine) |
|---|
| 370 | emp_b (:,:) = emp (:,:) |
|---|
| 371 | sfx_b (:,:) = sfx (:,:) |
|---|
| 372 | IF ( ln_rnf ) THEN |
|---|
| 373 | rnf_b (:,: ) = rnf (:,: ) |
|---|
| 374 | rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:) |
|---|
| 375 | ENDIF |
|---|
| 376 | ENDIF |
|---|
| 377 | ! ! ---------------------------------------- ! |
|---|
| 378 | ! ! forcing field computation ! |
|---|
| 379 | ! ! ---------------------------------------- ! |
|---|
| 380 | ! |
|---|
| 381 | ll_sas = nn_components == jp_iam_sas ! component flags |
|---|
| 382 | ll_opa = nn_components == jp_iam_opa |
|---|
| 383 | ! |
|---|
| 384 | IF( .NOT.ll_sas ) CALL sbc_ssm ( kt ) ! mean ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m) |
|---|
| 385 | IF( ln_wave ) CALL sbc_wave( kt ) ! surface waves |
|---|
| 386 | |
|---|
| 387 | ! |
|---|
| 388 | ! !== sbc formulation ==! |
|---|
| 389 | ! |
|---|
| 390 | SELECT CASE( nsbc ) ! Compute ocean surface boundary condition |
|---|
| 391 | ! ! (i.e. utau,vtau, qns, qsr, emp, sfx) |
|---|
| 392 | CASE( jp_usr ) ; CALL usrdef_sbc_oce( kt ) ! user defined formulation |
|---|
| 393 | CASE( jp_flx ) ; CALL sbc_flx ( kt ) ! flux formulation |
|---|
| 394 | CASE( jp_blk ) |
|---|
| 395 | IF( ll_sas ) CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! OPA-SAS coupling: SAS receiving fields from OPA |
|---|
| 396 | CALL sbc_blk ( kt ) ! bulk formulation for the ocean |
|---|
| 397 | ! |
|---|
| 398 | CASE( jp_purecpl ) ; CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! pure coupled formulation |
|---|
| 399 | CASE( jp_none ) |
|---|
| 400 | IF( ll_opa ) CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! OPA-SAS coupling: OPA receiving fields from SAS |
|---|
| 401 | END SELECT |
|---|
| 402 | IF ( ln_wave .AND. ln_tauoc) THEN ! Wave stress subctracted |
|---|
| 403 | utau(:,:) = utau(:,:)*tauoc_wave(:,:) |
|---|
| 404 | vtau(:,:) = vtau(:,:)*tauoc_wave(:,:) |
|---|
| 405 | taum(:,:) = taum(:,:)*tauoc_wave(:,:) |
|---|
| 406 | ! |
|---|
| 407 | SELECT CASE( nsbc ) |
|---|
| 408 | CASE( 0,1,2,3,5,-1 ) ; |
|---|
| 409 | IF(lwp .AND. kt == nit000 ) WRITE(numout,*) 'WARNING: You are subtracting the wave stress to the ocean. & |
|---|
| 410 | & If not requested select ln_tauoc=.false' |
|---|
| 411 | END SELECT |
|---|
| 412 | ! |
|---|
| 413 | END IF |
|---|
| 414 | IF( ln_mixcpl ) CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! forced-coupled mixed formulation after forcing |
|---|
| 415 | |
|---|
| 416 | ! |
|---|
| 417 | ! !== Misc. Options ==! |
|---|
| 418 | ! |
|---|
| 419 | SELECT CASE( nn_ice ) ! Update heat and freshwater fluxes over sea-ice areas |
|---|
| 420 | CASE( 1 ) ; CALL sbc_ice_if ( kt ) ! Ice-cover climatology ("Ice-if" model) |
|---|
| 421 | CASE( 2 ) ; CALL sbc_ice_lim_2( kt, nsbc ) ! LIM-2 ice model |
|---|
| 422 | CASE( 3 ) ; CALL sbc_ice_lim ( kt, nsbc ) ! LIM-3 ice model |
|---|
| 423 | CASE( 4 ) ; CALL sbc_ice_cice ( kt, nsbc ) ! CICE ice model |
|---|
| 424 | END SELECT |
|---|
| 425 | |
|---|
| 426 | IF( ln_icebergs ) CALL icb_stp( kt ) ! compute icebergs |
|---|
| 427 | |
|---|
| 428 | IF( ln_isf ) CALL sbc_isf( kt ) ! compute iceshelves |
|---|
| 429 | |
|---|
| 430 | IF( ln_rnf ) CALL sbc_rnf( kt ) ! add runoffs to fresh water fluxes |
|---|
| 431 | |
|---|
| 432 | IF( ln_ssr ) CALL sbc_ssr( kt ) ! add SST/SSS damping term |
|---|
| 433 | |
|---|
| 434 | IF( nn_fwb /= 0 ) CALL sbc_fwb( kt, nn_fwb, nn_fsbc ) ! control the freshwater budget |
|---|
| 435 | |
|---|
| 436 | ! treatment of closed sea in the model domain (update freshwater fluxes) |
|---|
| 437 | ! Should not be ran if ln_diurnal_only |
|---|
| 438 | IF( .NOT.ln_diurnal_only .AND. nn_closea == 1 ) CALL sbc_clo( kt, cn_cfg, nn_cfg ) |
|---|
| 439 | |
|---|
| 440 | !RBbug do not understand why see ticket 667 |
|---|
| 441 | !clem: it looks like it is necessary for the north fold (in certain circumstances). Don't know why. |
|---|
| 442 | CALL lbc_lnk( emp, 'T', 1. ) |
|---|
| 443 | ! |
|---|
| 444 | IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 ! |
|---|
| 445 | ! ! ---------------------------------------- ! |
|---|
| 446 | IF( ln_rstart .AND. & !* Restart: read in restart file |
|---|
| 447 | & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 448 | IF(lwp) WRITE(numout,*) ' nit000-1 surface forcing fields red in the restart file' |
|---|
| 449 | CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b ) ! before i-stress (U-point) |
|---|
| 450 | CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b ) ! before j-stress (V-point) |
|---|
| 451 | CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b ) ! before non solar heat flux (T-point) |
|---|
| 452 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 453 | ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b ) ! before solar heat flux (T-point) |
|---|
| 454 | CALL iom_get( numror, jpdom_autoglo, 'emp_b', emp_b ) ! before freshwater flux (T-point) |
|---|
| 455 | ! To ensure restart capability with 3.3x/3.4 restart files !! to be removed in v3.6 |
|---|
| 456 | IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 457 | CALL iom_get( numror, jpdom_autoglo, 'sfx_b', sfx_b ) ! before salt flux (T-point) |
|---|
| 458 | ELSE |
|---|
| 459 | sfx_b (:,:) = sfx(:,:) |
|---|
| 460 | ENDIF |
|---|
| 461 | ELSE !* no restart: set from nit000 values |
|---|
| 462 | IF(lwp) WRITE(numout,*) ' nit000-1 surface forcing fields set to nit000' |
|---|
| 463 | utau_b(:,:) = utau(:,:) |
|---|
| 464 | vtau_b(:,:) = vtau(:,:) |
|---|
| 465 | qns_b (:,:) = qns (:,:) |
|---|
| 466 | emp_b (:,:) = emp (:,:) |
|---|
| 467 | sfx_b (:,:) = sfx (:,:) |
|---|
| 468 | ENDIF |
|---|
| 469 | ENDIF |
|---|
| 470 | ! ! ---------------------------------------- ! |
|---|
| 471 | IF( lrst_oce ) THEN ! Write in the ocean restart file ! |
|---|
| 472 | ! ! ---------------------------------------- ! |
|---|
| 473 | IF(lwp) WRITE(numout,*) |
|---|
| 474 | IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ', & |
|---|
| 475 | & 'at it= ', kt,' date= ', ndastp |
|---|
| 476 | IF(lwp) WRITE(numout,*) '~~~~' |
|---|
| 477 | CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau ) |
|---|
| 478 | CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau ) |
|---|
| 479 | CALL iom_rstput( kt, nitrst, numrow, 'qns_b' , qns ) |
|---|
| 480 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 481 | ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b' , qsr ) |
|---|
| 482 | CALL iom_rstput( kt, nitrst, numrow, 'emp_b' , emp ) |
|---|
| 483 | CALL iom_rstput( kt, nitrst, numrow, 'sfx_b' , sfx ) |
|---|
| 484 | ENDIF |
|---|
| 485 | ! ! ---------------------------------------- ! |
|---|
| 486 | ! ! Outputs and control print ! |
|---|
| 487 | ! ! ---------------------------------------- ! |
|---|
| 488 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN |
|---|
| 489 | CALL iom_put( "empmr" , emp - rnf ) ! upward water flux |
|---|
| 490 | CALL iom_put( "empbmr" , emp_b - rnf ) ! before upward water flux ( needed to recalculate the time evolution of ssh in offline ) |
|---|
| 491 | CALL iom_put( "saltflx", sfx ) ! downward salt flux (includes virtual salt flux beneath ice in linear free surface case) |
|---|
| 492 | CALL iom_put( "fmmflx", fmmflx ) ! Freezing-melting water flux |
|---|
| 493 | CALL iom_put( "qt" , qns + qsr ) ! total heat flux |
|---|
| 494 | CALL iom_put( "qns" , qns ) ! solar heat flux |
|---|
| 495 | CALL iom_put( "qsr" , qsr ) ! solar heat flux |
|---|
| 496 | IF( nn_ice > 0 .OR. ll_opa ) CALL iom_put( "ice_cover", fr_i ) ! ice fraction |
|---|
| 497 | CALL iom_put( "taum" , taum ) ! wind stress module |
|---|
| 498 | CALL iom_put( "wspd" , wndm ) ! wind speed module over free ocean or leads in presence of sea-ice |
|---|
| 499 | ENDIF |
|---|
| 500 | ! |
|---|
| 501 | CALL iom_put( "utau", utau ) ! i-wind stress (stress can be updated at each time step in sea-ice) |
|---|
| 502 | CALL iom_put( "vtau", vtau ) ! j-wind stress |
|---|
| 503 | ! |
|---|
| 504 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
|---|
| 505 | CALL prt_ctl(tab2d_1=fr_i , clinfo1=' fr_i - : ', mask1=tmask, ovlap=1 ) |
|---|
| 506 | CALL prt_ctl(tab2d_1=(emp-rnf + fwfisf), clinfo1=' emp-rnf - : ', mask1=tmask, ovlap=1 ) |
|---|
| 507 | CALL prt_ctl(tab2d_1=(sfx-rnf + fwfisf), clinfo1=' sfx-rnf - : ', mask1=tmask, ovlap=1 ) |
|---|
| 508 | CALL prt_ctl(tab2d_1=qns , clinfo1=' qns - : ', mask1=tmask, ovlap=1 ) |
|---|
| 509 | CALL prt_ctl(tab2d_1=qsr , clinfo1=' qsr - : ', mask1=tmask, ovlap=1 ) |
|---|
| 510 | CALL prt_ctl(tab3d_1=tmask , clinfo1=' tmask - : ', mask1=tmask, ovlap=1, kdim=jpk ) |
|---|
| 511 | CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst - : ', mask1=tmask, ovlap=1, kdim=1 ) |
|---|
| 512 | CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss - : ', mask1=tmask, ovlap=1, kdim=1 ) |
|---|
| 513 | CALL prt_ctl(tab2d_1=utau , clinfo1=' utau - : ', mask1=umask, & |
|---|
| 514 | & tab2d_2=vtau , clinfo2=' vtau - : ', mask2=vmask, ovlap=1 ) |
|---|
| 515 | ENDIF |
|---|
| 516 | |
|---|
| 517 | IF( kt == nitend ) CALL sbc_final ! Close down surface module if necessary |
|---|
| 518 | ! |
|---|
| 519 | IF( nn_timing == 1 ) CALL timing_stop('sbc') |
|---|
| 520 | ! |
|---|
| 521 | END SUBROUTINE sbc |
|---|
| 522 | |
|---|
| 523 | |
|---|
| 524 | SUBROUTINE sbc_final |
|---|
| 525 | !!--------------------------------------------------------------------- |
|---|
| 526 | !! *** ROUTINE sbc_final *** |
|---|
| 527 | !! |
|---|
| 528 | !! ** Purpose : Finalize CICE (if used) |
|---|
| 529 | !!--------------------------------------------------------------------- |
|---|
| 530 | ! |
|---|
| 531 | IF( nn_ice == 4 ) CALL cice_sbc_final |
|---|
| 532 | ! |
|---|
| 533 | END SUBROUTINE sbc_final |
|---|
| 534 | |
|---|
| 535 | !!====================================================================== |
|---|
| 536 | END MODULE sbcmod |
|---|
