New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssr.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/SBC/sbcssr.F90 @ 6140

Last change on this file since 6140 was 6140, checked in by timgraham, 8 years ago

Merge of branches/2015/dev_merge_2015 back into trunk. Merge excludes NEMOGCM/TOOLS/OBSTOOLS/ for now due to issues with the change of file type. Will sort these manually with further commits.

Branch merged as follows:
In the working copy of branch ran:
svn merge svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/trunk@HEAD
Small conflicts due to bug fixes applied to trunk since the dev_merge_2015 was copied. Bug fixes were applied to the branch as well so these were easy to resolve.
Branch committed at this stage

In working copy run:
svn switch svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/trunk
to switch working copy

Run:
svn merge --reintegrate svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/branches/2015/dev_merge_2015
to merge the branch into the trunk and then commit - no conflicts at this stage.

  • Property svn:keywords set to Id
File size: 12.2 KB
Line 
1MODULE sbcssr
2   !!======================================================================
3   !!                       ***  MODULE  sbcssr  ***
4   !! Surface module :  heat and fresh water fluxes a restoring term toward observed SST/SSS
5   !!======================================================================
6   !! History :  3.0  !  2006-06  (G. Madec)  Original code
7   !!            3.2  !  2009-04  (B. Lemaire)  Introduce iom_put
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   sbc_ssr       : add to sbc a restoring term toward SST/SSS climatology
12   !!   sbc_ssr_init  : initialisation of surface restoring
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers
15   USE dom_oce        ! ocean space and time domain
16   USE sbc_oce        ! surface boundary condition
17   USE phycst         ! physical constants
18   USE sbcrnf         ! surface boundary condition : runoffs
19   !
20   USE fldread        ! read input fields
21   USE in_out_manager ! I/O manager
22   USE iom            ! I/O manager
23   USE lib_mpp        ! distribued memory computing library
24   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
25   USE timing         ! Timing
26   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   sbc_ssr        ! routine called in sbcmod
32   PUBLIC   sbc_ssr_init   ! routine called in sbcmod
33
34   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   erp   !: evaporation damping   [kg/m2/s]
35   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   qrp   !: heat flux damping        [w/m2]
36
37   !                                   !!* Namelist namsbc_ssr *
38   INTEGER, PUBLIC ::   nn_sstr         ! SST/SSS restoring indicator
39   INTEGER, PUBLIC ::   nn_sssr         ! SST/SSS restoring indicator
40   REAL(wp)        ::   rn_dqdt         ! restoring factor on SST and SSS
41   REAL(wp)        ::   rn_deds         ! restoring factor on SST and SSS
42   LOGICAL         ::   ln_sssr_bnd     ! flag to bound erp term
43   REAL(wp)        ::   rn_sssr_bnd     ! ABS(Max./Min.) value of erp term [mm/day]
44
45   REAL(wp) , ALLOCATABLE, DIMENSION(:) ::   buffer   ! Temporary buffer for exchange
46   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_sst   ! structure of input SST (file informations, fields read)
47   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_sss   ! structure of input SSS (file informations, fields read)
48
49   !!----------------------------------------------------------------------
50   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
51   !! $Id$
52   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
53   !!----------------------------------------------------------------------
54CONTAINS
55
56   SUBROUTINE sbc_ssr( kt )
57      !!---------------------------------------------------------------------
58      !!                     ***  ROUTINE sbc_ssr  ***
59      !!
60      !! ** Purpose :   Add to heat and/or freshwater fluxes a damping term
61      !!                toward observed SST and/or SSS.
62      !!
63      !! ** Method  : - Read namelist namsbc_ssr
64      !!              - Read observed SST and/or SSS
65      !!              - at each nscb time step
66      !!                   add a retroaction term on qns    (nn_sstr = 1)
67      !!                   add a damping term on sfx        (nn_sssr = 1)
68      !!                   add a damping term on emp        (nn_sssr = 2)
69      !!---------------------------------------------------------------------
70      INTEGER, INTENT(in   ) ::   kt   ! ocean time step
71      !!
72      INTEGER  ::   ji, jj   ! dummy loop indices
73      REAL(wp) ::   zerp     ! local scalar for evaporation damping
74      REAL(wp) ::   zqrp     ! local scalar for heat flux damping
75      REAL(wp) ::   zsrp     ! local scalar for unit conversion of rn_deds factor
76      REAL(wp) ::   zerp_bnd ! local scalar for unit conversion of rn_epr_max factor
77      INTEGER  ::   ierror   ! return error code
78      !!
79      CHARACTER(len=100) ::  cn_dir          ! Root directory for location of ssr files
80      TYPE(FLD_N) ::   sn_sst, sn_sss        ! informations about the fields to be read
81      !!----------------------------------------------------------------------
82      !
83      IF( nn_timing == 1 )  CALL timing_start('sbc_ssr')
84      !
85      IF( nn_sstr + nn_sssr /= 0 ) THEN
86         !
87         IF( nn_sstr == 1)   CALL fld_read( kt, nn_fsbc, sf_sst )   ! Read SST data and provides it at kt
88         IF( nn_sssr >= 1)   CALL fld_read( kt, nn_fsbc, sf_sss )   ! Read SSS data and provides it at kt
89         !
90         !                                         ! ========================= !
91         IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN      !    Add restoring term     !
92            !                                      ! ========================= !
93            !
94            IF( nn_sstr == 1 ) THEN                                   !* Temperature restoring term
95               DO jj = 1, jpj
96                  DO ji = 1, jpi
97                     zqrp = rn_dqdt * ( sst_m(ji,jj) - sf_sst(1)%fnow(ji,jj,1) )
98                     qns(ji,jj) = qns(ji,jj) + zqrp
99                     qrp(ji,jj) = zqrp
100                  END DO
101               END DO
102               CALL iom_put( "qrp", qrp )                             ! heat flux damping
103            ENDIF
104            !
105            IF( nn_sssr == 1 ) THEN                                   !* Salinity damping term (salt flux only (sfx))
106               zsrp = rn_deds / rday                                  ! from [mm/day] to [kg/m2/s]
107               DO jj = 1, jpj
108                  DO ji = 1, jpi
109                     zerp = zsrp * ( 1. - 2.*rnfmsk(ji,jj) )   &      ! No damping in vicinity of river mouths
110                        &        * ( sss_m(ji,jj) - sf_sss(1)%fnow(ji,jj,1) ) 
111                     sfx(ji,jj) = sfx(ji,jj) + zerp                 ! salt flux
112                     erp(ji,jj) = zerp / MAX( sss_m(ji,jj), 1.e-20 ) ! converted into an equivalent volume flux (diagnostic only)
113                  END DO
114               END DO
115               CALL iom_put( "erp", erp )                             ! freshwater flux damping
116               !
117            ELSEIF( nn_sssr == 2 ) THEN                               !* Salinity damping term (volume flux (emp) and associated heat flux (qns)
118               zsrp = rn_deds / rday                                  ! from [mm/day] to [kg/m2/s]
119               zerp_bnd = rn_sssr_bnd / rday                          !       -              -   
120               DO jj = 1, jpj
121                  DO ji = 1, jpi                           
122                     zerp = zsrp * ( 1. - 2.*rnfmsk(ji,jj) )   &      ! No damping in vicinity of river mouths
123                        &        * ( sss_m(ji,jj) - sf_sss(1)%fnow(ji,jj,1) )   &
124                        &        / MAX(  sss_m(ji,jj), 1.e-20   )
125                     IF( ln_sssr_bnd )   zerp = SIGN( 1., zerp ) * MIN( zerp_bnd, ABS(zerp) )
126                     emp(ji,jj) = emp (ji,jj) + zerp
127                     qns(ji,jj) = qns(ji,jj) - zerp * rcp * sst_m(ji,jj)
128                     erp(ji,jj) = zerp
129                  END DO
130               END DO
131               CALL iom_put( "erp", erp )                             ! freshwater flux damping
132            ENDIF
133            !
134         ENDIF
135         !
136      ENDIF
137      !
138      IF( nn_timing == 1 )  CALL timing_stop('sbc_ssr')
139      !
140   END SUBROUTINE sbc_ssr
141
142 
143   SUBROUTINE sbc_ssr_init
144      !!---------------------------------------------------------------------
145      !!                  ***  ROUTINE sbc_ssr_init  ***
146      !!
147      !! ** Purpose :   initialisation of surface damping term
148      !!
149      !! ** Method  : - Read namelist namsbc_ssr
150      !!              - Read observed SST and/or SSS if required
151      !!---------------------------------------------------------------------
152      INTEGER  ::   ji, jj   ! dummy loop indices
153      REAL(wp) ::   zerp     ! local scalar for evaporation damping
154      REAL(wp) ::   zqrp     ! local scalar for heat flux damping
155      REAL(wp) ::   zsrp     ! local scalar for unit conversion of rn_deds factor
156      REAL(wp) ::   zerp_bnd ! local scalar for unit conversion of rn_epr_max factor
157      INTEGER  ::   ierror   ! return error code
158      !!
159      CHARACTER(len=100) ::  cn_dir          ! Root directory for location of ssr files
160      TYPE(FLD_N) ::   sn_sst, sn_sss        ! informations about the fields to be read
161      NAMELIST/namsbc_ssr/ cn_dir, nn_sstr, nn_sssr, rn_dqdt, rn_deds, sn_sst, sn_sss, ln_sssr_bnd, rn_sssr_bnd
162      INTEGER     ::  ios
163      !!----------------------------------------------------------------------
164      !
165 
166      REWIND( numnam_ref )              ! Namelist namsbc_ssr in reference namelist :
167      READ  ( numnam_ref, namsbc_ssr, IOSTAT = ios, ERR = 901)
168901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_ssr in reference namelist', lwp )
169
170      REWIND( numnam_cfg )              ! Namelist namsbc_ssr in configuration namelist :
171      READ  ( numnam_cfg, namsbc_ssr, IOSTAT = ios, ERR = 902 )
172902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_ssr in configuration namelist', lwp )
173      IF(lwm) WRITE ( numond, namsbc_ssr )
174
175      IF(lwp) THEN                 !* control print
176         WRITE(numout,*)
177         WRITE(numout,*) 'sbc_ssr : SST and/or SSS damping term '
178         WRITE(numout,*) '~~~~~~~ '
179         WRITE(numout,*) '   Namelist namsbc_ssr :'
180         WRITE(numout,*) '      SST restoring term (Yes=1)             nn_sstr     = ', nn_sstr
181         WRITE(numout,*) '      SSS damping term (Yes=1, salt flux)    nn_sssr     = ', nn_sssr
182         WRITE(numout,*) '                       (Yes=2, volume flux) '
183         WRITE(numout,*) '      dQ/dT (restoring magnitude on SST)     rn_dqdt     = ', rn_dqdt, ' W/m2/K'
184         WRITE(numout,*) '      dE/dS (restoring magnitude on SST)     rn_deds     = ', rn_deds, ' mm/day'
185         WRITE(numout,*) '      flag to bound erp term                 ln_sssr_bnd = ', ln_sssr_bnd
186         WRITE(numout,*) '      ABS(Max./Min.) erp threshold           rn_sssr_bnd = ', rn_sssr_bnd, ' mm/day'
187      ENDIF
188      !
189      !                            !* Allocate erp and qrp array
190      ALLOCATE( qrp(jpi,jpj), erp(jpi,jpj), STAT=ierror )
191      IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate erp and qrp array' )
192      !
193      IF( nn_sstr == 1 ) THEN      !* set sf_sst structure & allocate arrays
194         !
195         ALLOCATE( sf_sst(1), STAT=ierror )
196         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sst structure' )
197         ALLOCATE( sf_sst(1)%fnow(jpi,jpj,1), STAT=ierror )
198         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sst now array' )
199         !
200         ! fill sf_sst with sn_sst and control print
201         CALL fld_fill( sf_sst, (/ sn_sst /), cn_dir, 'sbc_ssr', 'SST restoring term toward SST data', 'namsbc_ssr' )
202         IF( sf_sst(1)%ln_tint )   ALLOCATE( sf_sst(1)%fdta(jpi,jpj,1,2), STAT=ierror )
203         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sst data array' )
204         !
205      ENDIF
206      !
207      IF( nn_sssr >= 1 ) THEN      !* set sf_sss structure & allocate arrays
208         !
209         ALLOCATE( sf_sss(1), STAT=ierror )
210         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sss structure' )
211         ALLOCATE( sf_sss(1)%fnow(jpi,jpj,1), STAT=ierror )
212         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sss now array' )
213         !
214         ! fill sf_sss with sn_sss and control print
215         CALL fld_fill( sf_sss, (/ sn_sss /), cn_dir, 'sbc_ssr', 'SSS restoring term toward SSS data', 'namsbc_ssr' )
216         IF( sf_sss(1)%ln_tint )   ALLOCATE( sf_sss(1)%fdta(jpi,jpj,1,2), STAT=ierror )
217         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sss data array' )
218         !
219      ENDIF
220      !
221      !                            !* Initialize qrp and erp if no restoring
222      IF( nn_sstr /= 1                   )   qrp(:,:) = 0._wp
223      IF( nn_sssr /= 1 .OR. nn_sssr /= 2 )   erp(:,:) = 0._wp
224      !
225   END SUBROUTINE sbc_ssr_init
226     
227   !!======================================================================
228END MODULE sbcssr
Note: See TracBrowser for help on using the repository browser.