New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

traadv.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

Context Navigation

source: trunk/NEMOGCM/NEMO/OPA_SRC/TRA/traadv.F90 @ 7698

Last change on this file since 7698 was 7698, checked in by mocavero, 7 years ago
update trunk with OpenMP parallelization
Property svn:keywords set to `Id`
File size: 18.5 KB

Line
1	MODULE traadv
2	!!==============================================================================
3	!! * MODULE traadv *
4	!! Ocean active tracers: advection trend
5	!!==============================================================================
6	!! History : 2.0 ! 2005-11 (G. Madec) Original code
7	!! 3.3 ! 2010-09 (C. Ethe, G. Madec) merge TRC-TRA + switch from velocity to transport
8	!! 3.6 ! 2011-06 (G. Madec) Addition of Mixed Layer Eddy parameterisation
9	!! 3.7 ! 2014-05 (G. Madec) Add 2nd/4th order cases for CEN and FCT schemes
10	!! - ! 2014-12 (G. Madec) suppression of cross land advection option
11	!! 3.6 ! 2015-06 (E. Clementi) Addition of Stokes drift in case of wave coupling
12	!!----------------------------------------------------------------------
13
14	!!----------------------------------------------------------------------
15	!! tra_adv : compute ocean tracer advection trend
16	!! tra_adv_ctl : control the different options of advection scheme
17	!!----------------------------------------------------------------------
18	USE oce ! ocean dynamics and active tracers
19	USE dom_oce ! ocean space and time domain
20	USE domvvl ! variable vertical scale factors
21	USE traadv_cen ! centered scheme (tra_adv_cen routine)
22	USE traadv_fct ! FCT scheme (tra_adv_fct routine)
23	USE traadv_mus ! MUSCL scheme (tra_adv_mus routine)
24	USE traadv_ubs ! UBS scheme (tra_adv_ubs routine)
25	USE traadv_qck ! QUICKEST scheme (tra_adv_qck routine)
26	USE traadv_mle ! ML eddy induced velocity (tra_adv_mle routine)
27	USE ldftra ! lateral diffusion: eddy diffusivity & EIV coeff.
28	USE ldfslp ! Lateral diffusion: slopes of neutral surfaces
29	USE trd_oce ! trends: ocean variables
30	USE trdtra ! trends manager: tracers
31	!
32	USE in_out_manager ! I/O manager
33	USE iom ! I/O module
34	USE prtctl ! Print control
35	USE lib_mpp ! MPP library
36	USE wrk_nemo ! Memory Allocation
37	USE timing ! Timing
38	USE sbcwave ! wave module
39	USE sbc_oce ! surface boundary condition: ocean
40	USE diaptr ! Poleward heat transport
41
42	IMPLICIT NONE
43	PRIVATE
44
45	PUBLIC tra_adv ! routine called by step module
46	PUBLIC tra_adv_init ! routine called by opa module
47
48	! !!* Namelist namtra_adv *
49	LOGICAL :: ln_traadv_cen ! centered scheme flag
50	INTEGER :: nn_cen_h, nn_cen_v ! =2/4 : horizontal and vertical choices of the order of CEN scheme
51	LOGICAL :: ln_traadv_fct ! FCT scheme flag
52	INTEGER :: nn_fct_h, nn_fct_v ! =2/4 : horizontal and vertical choices of the order of FCT scheme
53	INTEGER :: nn_fct_zts ! >=1 : 2nd order FCT with vertical sub-timestepping
54	LOGICAL :: ln_traadv_mus ! MUSCL scheme flag
55	LOGICAL :: ln_mus_ups ! use upstream scheme in vivcinity of river mouths
56	LOGICAL :: ln_traadv_ubs ! UBS scheme flag
57	INTEGER :: nn_ubs_v ! =2/4 : vertical choice of the order of UBS scheme
58	LOGICAL :: ln_traadv_qck ! QUICKEST scheme flag
59
60	INTEGER :: nadv ! choice of the type of advection scheme
61	!
62	! ! associated indices:
63	INTEGER, PARAMETER :: np_NO_adv = 0 ! no T-S advection
64	INTEGER, PARAMETER :: np_CEN = 1 ! 2nd/4th order centered scheme
65	INTEGER, PARAMETER :: np_FCT = 2 ! 2nd/4th order Flux Corrected Transport scheme
66	INTEGER, PARAMETER :: np_FCT_zts = 3 ! 2nd order FCT scheme with vertical sub-timestepping
67	INTEGER, PARAMETER :: np_MUS = 4 ! MUSCL scheme
68	INTEGER, PARAMETER :: np_UBS = 5 ! 3rd order Upstream Biased Scheme
69	INTEGER, PARAMETER :: np_QCK = 6 ! QUICK scheme
70
71	!! * Substitutions
72	# include "vectopt_loop_substitute.h90"
73	!!----------------------------------------------------------------------
74	!! NEMO/OPA 3.7 , NEMO Consortium (2014)
75	!! $Id$
76	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
77	!!----------------------------------------------------------------------
78	CONTAINS
79
80	SUBROUTINE tra_adv( kt )
81	!!----------------------------------------------------------------------
82	!! * ROUTINE tra_adv *
83	!!
84	!! ** Purpose : compute the ocean tracer advection trend.
85	!!
86	!! ** Method : - Update (ua,va) with the advection term following nadv
87	!!----------------------------------------------------------------------
88	INTEGER, INTENT( in ) :: kt ! ocean time-step index
89	!
90	INTEGER :: ji, jj, jk ! dummy loop index
91	REAL(wp), POINTER, DIMENSION(:,:,:) :: zun, zvn, zwn
92	REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdt, ztrds ! 3D workspace
93	!!----------------------------------------------------------------------
94	!
95	IF( nn_timing == 1 ) CALL timing_start('tra_adv')
96	!
97	CALL wrk_alloc( jpi,jpj,jpk, zun, zvn, zwn )
98	!
99	! ! set time step
100	!$OMP PARALLEL DO schedule(static) private(jk, jj, ji)
101	DO jk = 1, jpk
102	DO jj = 1, jpj
103	DO ji = 1, jpi
104	zun(ji,jj,jk) = 0.0
105	zvn(ji,jj,jk) = 0.0
106	zwn(ji,jj,jk) = 0.0
107	END DO
108	END DO
109	END DO
110	!
111	IF( neuler == 0 .AND. kt == nit000 ) THEN ! at nit000
112	r2dt = rdt ! = rdt (restarting with Euler time stepping)
113	ELSEIF( kt <= nit000 + 1) THEN ! at nit000 or nit000+1
114	r2dt = 2._wp * rdt ! = 2 rdt (leapfrog)
115	ENDIF
116	!
117	! !== effective transport ==!
118	IF( ln_wave .AND. ln_sdw ) THEN
119	!$OMP PARALLEL DO schedule(static) private(jk, jj, ji)
120	DO jk = 1, jpkm1 ! eulerian transport + Stokes Drift
121	DO jj = 1, jpj
122	DO ji = 1, jpi
123	zun(ji,jj,jk) = e2u(ji,jj) * e3u_n(ji,jj,jk) * ( un(ji,jj,jk) + usd(ji,jj,jk) )
124	zvn(ji,jj,jk) = e1v(ji,jj) * e3v_n(ji,jj,jk) * ( vn(ji,jj,jk) + vsd(ji,jj,jk) )
125	zwn(ji,jj,jk) = e1e2t(ji,jj) * ( wn(ji,jj,jk) + wsd(ji,jj,jk) )
126	END DO
127	END DO
128	END DO
129	ELSE
130	!$OMP PARALLEL DO schedule(static) private(jk, jj, ji)
131	DO jk = 1, jpkm1
132	DO jj = 1, jpj
133	DO ji = 1, jpi
134	zun(ji,jj,jk) = e2u (ji,jj) * e3u_n(ji,jj,jk) * un(ji,jj,jk) ! eulerian transport only
135	zvn(ji,jj,jk) = e1v (ji,jj) * e3v_n(ji,jj,jk) * vn(ji,jj,jk)
136	zwn(ji,jj,jk) = e1e2t(ji,jj) * wn(ji,jj,jk)
137	END DO
138	END DO
139	END DO
140	ENDIF
141	!
142	IF( ln_vvl_ztilde .OR. ln_vvl_layer ) THEN ! add z-tilde and/or vvl corrections
143	!$OMP PARALLEL DO schedule(static) private(jk, jj, ji)
144	DO jk = 1, jpk
145	DO jj = 1, jpj
146	DO ji = 1, jpi
147	zun(ji,jj,jk) = zun(ji,jj,jk) + un_td(ji,jj,jk)
148	zvn(ji,jj,jk) = zvn(ji,jj,jk) + vn_td(ji,jj,jk)
149	END DO
150	END DO
151	END DO
152	ENDIF
153	!
154	!$OMP PARALLEL DO schedule(static) private(jj, ji)
155	DO jj = 1, jpj
156	DO ji = 1, jpi
157	zun(ji,jj,jpk) = 0._wp ! no transport trough the bottom
158	zvn(ji,jj,jpk) = 0._wp
159	zwn(ji,jj,jpk) = 0._wp
160	END DO
161	END DO
162	!
163	IF( ln_ldfeiv .AND. .NOT. ln_traldf_triad ) &
164	& CALL ldf_eiv_trp( kt, nit000, zun, zvn, zwn, 'TRA' ) ! add the eiv transport (if necessary)
165	!
166	IF( ln_mle ) CALL tra_adv_mle( kt, nit000, zun, zvn, zwn, 'TRA' ) ! add the mle transport (if necessary)
167	!
168	CALL iom_put( "uocetr_eff", zun ) ! output effective transport
169	CALL iom_put( "vocetr_eff", zvn )
170	CALL iom_put( "wocetr_eff", zwn )
171	!
172	!!gm ???
173	IF( ln_diaptr ) CALL dia_ptr( zvn ) ! diagnose the effective MSF
174	!!gm ???
175	!
176	IF( l_trdtra ) THEN !* Save ta and sa trends
177	CALL wrk_alloc( jpi, jpj, jpk, ztrdt, ztrds )
178	!$OMP PARALLEL DO schedule(static) private(jk, jj, ji)
179	DO jk = 1, jpk
180	DO jj = 1, jpj
181	DO ji = 1, jpi
182	ztrdt(ji,jj,jk) = tsa(ji,jj,jk,jp_tem)
183	ztrds(ji,jj,jk) = tsa(ji,jj,jk,jp_sal)
184	END DO
185	END DO
186	END DO
187	ENDIF
188	!
189	SELECT CASE ( nadv ) !== compute advection trend and add it to general trend ==!
190	!
191	CASE ( np_CEN ) ! Centered scheme : 2nd / 4th order
192	CALL tra_adv_cen ( kt, nit000, 'TRA', zun, zvn, zwn , tsn, tsa, jpts, nn_cen_h, nn_cen_v )
193	CASE ( np_FCT ) ! FCT scheme : 2nd / 4th order
194	CALL tra_adv_fct ( kt, nit000, 'TRA', r2dt, zun, zvn, zwn, tsb, tsn, tsa, jpts, nn_fct_h, nn_fct_v )
195	CASE ( np_FCT_zts ) ! 2nd order FCT with vertical time-splitting
196	CALL tra_adv_fct_zts( kt, nit000, 'TRA', r2dt, zun, zvn, zwn, tsb, tsn, tsa, jpts , nn_fct_zts )
197	CASE ( np_MUS ) ! MUSCL
198	CALL tra_adv_mus ( kt, nit000, 'TRA', r2dt, zun, zvn, zwn, tsb, tsa, jpts , ln_mus_ups )
199	CASE ( np_UBS ) ! UBS
200	CALL tra_adv_ubs ( kt, nit000, 'TRA', r2dt, zun, zvn, zwn, tsb, tsn, tsa, jpts , nn_ubs_v )
201	CASE ( np_QCK ) ! QUICKEST
202	CALL tra_adv_qck ( kt, nit000, 'TRA', r2dt, zun, zvn, zwn, tsb, tsn, tsa, jpts )
203	!
204	END SELECT
205	!
206	IF( l_trdtra ) THEN ! save the advective trends for further diagnostics
207	!$OMP PARALLEL DO schedule(static) private(jk, jj, ji)
208	DO jk = 1, jpkm1
209	DO jj = 1, jpj
210	DO ji = 1, jpi
211	ztrdt(ji,jj,jk) = tsa(ji,jj,jk,jp_tem) - ztrdt(ji,jj,jk)
212	ztrds(ji,jj,jk) = tsa(ji,jj,jk,jp_sal) - ztrds(ji,jj,jk)
213	END DO
214	END DO
215	END DO
216	CALL trd_tra( kt, 'TRA', jp_tem, jptra_totad, ztrdt )
217	CALL trd_tra( kt, 'TRA', jp_sal, jptra_totad, ztrds )
218	CALL wrk_dealloc( jpi, jpj, jpk, ztrdt, ztrds )
219	ENDIF
220	! ! print mean trends (used for debugging)
221	IF(ln_ctl) CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv - Ta: ', mask1=tmask, &
222	& tab3d_2=tsa(:,:,:,jp_sal), clinfo2= ' Sa: ', mask2=tmask, clinfo3='tra' )
223	!
224	IF( nn_timing == 1 ) CALL timing_stop( 'tra_adv' )
225	!
226	CALL wrk_dealloc( jpi,jpj,jpk, zun, zvn, zwn )
227	!
228	END SUBROUTINE tra_adv
229
230
231	SUBROUTINE tra_adv_init
232	!!---------------------------------------------------------------------
233	!! * ROUTINE tra_adv_init *
234	!!
235	!! ** Purpose : Control the consistency between namelist options for
236	!! tracer advection schemes and set nadv
237	!!----------------------------------------------------------------------
238	INTEGER :: ioptio, ios ! Local integers
239	!
240	NAMELIST/namtra_adv/ ln_traadv_cen, nn_cen_h, nn_cen_v, & ! CEN
241	& ln_traadv_fct, nn_fct_h, nn_fct_v, nn_fct_zts, & ! FCT
242	& ln_traadv_mus, ln_mus_ups, & ! MUSCL
243	& ln_traadv_ubs, nn_ubs_v, & ! UBS
244	& ln_traadv_qck ! QCK
245	!!----------------------------------------------------------------------
246	!
247	! !== Namelist ==!
248	REWIND( numnam_ref ) ! Namelist namtra_adv in reference namelist : Tracer advection scheme
249	READ ( numnam_ref, namtra_adv, IOSTAT = ios, ERR = 901)
250	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_adv in reference namelist', lwp )
251	!
252	REWIND( numnam_cfg ) ! Namelist namtra_adv in configuration namelist : Tracer advection scheme
253	READ ( numnam_cfg, namtra_adv, IOSTAT = ios, ERR = 902 )
254	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_adv in configuration namelist', lwp )
255	IF(lwm) WRITE( numond, namtra_adv )
256	!
257	IF(lwp) THEN ! Namelist print
258	WRITE(numout,*)
259	WRITE(numout,*) 'tra_adv_init : choice/control of the tracer advection scheme'
260	WRITE(numout,*) '~~~~~~~~~~~'
261	WRITE(numout,*) ' Namelist namtra_adv : chose a advection scheme for tracers'
262	WRITE(numout,*) ' centered scheme ln_traadv_cen = ', ln_traadv_cen
263	WRITE(numout,*) ' horizontal 2nd/4th order nn_cen_h = ', nn_fct_h
264	WRITE(numout,*) ' vertical 2nd/4th order nn_cen_v = ', nn_fct_v
265	WRITE(numout,*) ' Flux Corrected Transport scheme ln_traadv_fct = ', ln_traadv_fct
266	WRITE(numout,*) ' horizontal 2nd/4th order nn_fct_h = ', nn_fct_h
267	WRITE(numout,*) ' vertical 2nd/4th order nn_fct_v = ', nn_fct_v
268	WRITE(numout,*) ' 2nd order + vertical sub-timestepping nn_fct_zts = ', nn_fct_zts
269	WRITE(numout,*) ' MUSCL scheme ln_traadv_mus = ', ln_traadv_mus
270	WRITE(numout,*) ' + upstream scheme near river mouths ln_mus_ups = ', ln_mus_ups
271	WRITE(numout,*) ' UBS scheme ln_traadv_ubs = ', ln_traadv_ubs
272	WRITE(numout,*) ' vertical 2nd/4th order nn_ubs_v = ', nn_ubs_v
273	WRITE(numout,*) ' QUICKEST scheme ln_traadv_qck = ', ln_traadv_qck
274	ENDIF
275	!
276	ioptio = 0 !== Parameter control ==!
277	IF( ln_traadv_cen ) ioptio = ioptio + 1
278	IF( ln_traadv_fct ) ioptio = ioptio + 1
279	IF( ln_traadv_mus ) ioptio = ioptio + 1
280	IF( ln_traadv_ubs ) ioptio = ioptio + 1
281	IF( ln_traadv_qck ) ioptio = ioptio + 1
282	!
283	IF( ioptio == 0 ) THEN
284	nadv = np_NO_adv
285	CALL ctl_warn( 'tra_adv_init: You are running without tracer advection.' )
286	ENDIF
287	IF( ioptio /= 1 ) CALL ctl_stop( 'tra_adv_init: Choose ONE advection scheme in namelist namtra_adv' )
288	!
289	IF( ln_traadv_cen .AND. ( nn_cen_h /= 2 .AND. nn_cen_h /= 4 ) & ! Centered
290	.AND. ( nn_cen_v /= 2 .AND. nn_cen_v /= 4 ) ) THEN
291	CALL ctl_stop( 'tra_adv_init: CEN scheme, choose 2nd or 4th order' )
292	ENDIF
293	IF( ln_traadv_fct .AND. ( nn_fct_h /= 2 .AND. nn_fct_h /= 4 ) & ! FCT
294	.AND. ( nn_fct_v /= 2 .AND. nn_fct_v /= 4 ) ) THEN
295	CALL ctl_stop( 'tra_adv_init: FCT scheme, choose 2nd or 4th order' )
296	ENDIF
297	IF( ln_traadv_fct .AND. nn_fct_zts > 0 ) THEN
298	IF( nn_fct_h == 4 ) THEN
299	nn_fct_h = 2
300	CALL ctl_stop( 'tra_adv_init: force 2nd order FCT scheme, 4th order does not exist with sub-timestepping' )
301	ENDIF
302	IF( .NOT.ln_linssh ) THEN
303	CALL ctl_stop( 'tra_adv_init: vertical sub-timestepping not allow in non-linear free surface' )
304	ENDIF
305	IF( nn_fct_zts == 1 ) CALL ctl_warn( 'tra_adv_init: FCT with ONE sub-timestep = FCT without sub-timestep' )
306	ENDIF
307	IF( ln_traadv_ubs .AND. ( nn_ubs_v /= 2 .AND. nn_ubs_v /= 4 ) ) THEN ! UBS
308	CALL ctl_stop( 'tra_adv_init: UBS scheme, choose 2nd or 4th order' )
309	ENDIF
310	IF( ln_traadv_ubs .AND. nn_ubs_v == 4 ) THEN
311	CALL ctl_warn( 'tra_adv_init: UBS scheme, only 2nd FCT scheme available on the vertical. It will be used' )
312	ENDIF
313	IF( ln_isfcav ) THEN ! ice-shelf cavities
314	IF( ln_traadv_cen .AND. nn_cen_v == 4 .OR. & ! NO 4th order with ISF
315	& ln_traadv_fct .AND. nn_fct_v == 4 ) CALL ctl_stop( 'tra_adv_init: 4th order COMPACT scheme not allowed with ISF' )
316	ENDIF
317	!
318	! !== used advection scheme ==!
319	! ! set nadv
320	IF( ln_traadv_cen ) nadv = np_CEN
321	IF( ln_traadv_fct ) nadv = np_FCT
322	IF( ln_traadv_fct .AND. nn_fct_zts > 0 ) nadv = np_FCT_zts
323	IF( ln_traadv_mus ) nadv = np_MUS
324	IF( ln_traadv_ubs ) nadv = np_UBS
325	IF( ln_traadv_qck ) nadv = np_QCK
326	!
327	IF(lwp) THEN ! Print the choice
328	WRITE(numout,*)
329	SELECT CASE ( nadv )
330	CASE( np_NO_adv ) ; WRITE(numout,*) ' ===>> NO T-S advection'
331	CASE( np_CEN ) ; WRITE(numout,*) ' ===>> CEN scheme is used. Horizontal order: ', nn_cen_h, &
332	& ' Vertical order: ', nn_cen_v
333	CASE( np_FCT ) ; WRITE(numout,*) ' ===>> FCT scheme is used. Horizontal order: ', nn_fct_h, &
334	& ' Vertical order: ', nn_fct_v
335	CASE( np_FCT_zts ) ; WRITE(numout,*) ' ===>> use 2nd order FCT with ', nn_fct_zts,'vertical sub-timestepping'
336	CASE( np_MUS ) ; WRITE(numout,*) ' ===>> MUSCL scheme is used'
337	CASE( np_UBS ) ; WRITE(numout,*) ' ===>> UBS scheme is used'
338	CASE( np_QCK ) ; WRITE(numout,*) ' ===>> QUICKEST scheme is used'
339	END SELECT
340	ENDIF
341	!
342	CALL tra_adv_mle_init !== initialisation of the Mixed Layer Eddy parametrisation (MLE) ==!
343	!
344	END SUBROUTINE tra_adv_init
345
346	!!======================================================================
347	END MODULE traadv

Note: See TracBrowser for help on using the repository browser.

Download in other formats: