New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_eiv.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_eiv.F90 @ 2528

Last change on this file since 2528 was 2528, checked in by rblod, 13 years ago

Update NEMOGCM from branch nemo_v3_3_beta

  • Property svn:keywords set to Id
File size: 9.7 KB
Line 
1MODULE traadv_eiv
2   !!======================================================================
3   !!                    ***  MODULE  traadv_eiv  ***
4   !! Ocean tracers:  advection trend - eddy induced velocity
5   !!======================================================================
6   !! History :  1.0  !  2005-11 (G. Madec)  Original code, from traldf and zdf _iso
7   !!            3.3  !  2010-05 (C. Ethe, G. Madec)  merge TRC-TRA
8   !!----------------------------------------------------------------------
9#if defined key_traldf_eiv   ||   defined key_esopa
10   !!----------------------------------------------------------------------
11   !!   'key_traldf_eiv'                  rotation of the lateral mixing tensor
12   !!----------------------------------------------------------------------
13   !!   tra_ldf_iso : update the tracer trend with the horizontal component
14   !!                 of iso neutral laplacian operator or horizontal
15   !!                 laplacian operator in s-coordinate
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and tracers variables
18   USE dom_oce         ! ocean space and time domain variables
19   USE ldftra_oce      ! ocean active tracers: lateral physics
20   USE ldfslp          ! iso-neutral slopes
21   USE in_out_manager  ! I/O manager
22   USE iom
23   USE trc_oce         ! share passive tracers/Ocean variables
24# if defined key_diaeiv
25   USE phycst          ! physical constants
26   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
27   USE diaar5, ONLY :   lk_diaar5
28# endif 
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   tra_adv_eiv   ! routine called by step.F90
34
35   !! * Substitutions
36#  include "domzgr_substitute.h90"
37#  include "ldftra_substitute.h90"
38#  include "ldfeiv_substitute.h90"
39#  include "vectopt_loop_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
42   !! $Id$
43   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45
46CONTAINS
47
48   SUBROUTINE tra_adv_eiv( kt, pun, pvn, pwn, cdtype )
49      !!----------------------------------------------------------------------
50      !!                  ***  ROUTINE tra_adv_eiv  ***
51      !!
52      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
53      !!      trend and add it to the general trend of tracer equation.
54      !!
55      !! ** Method  :   The eddy induced advection is computed from the slope
56      !!      of iso-neutral surfaces computed in routine ldf_slp as follows:
57      !!         zu_eiv =  1/(e2u e3u)   dk[ aeiu e2u mi(wslpi) ]
58      !!         zv_eiv =  1/(e1v e3v)   dk[ aeiv e1v mj(wslpj)
59      !!         zw_eiv = -1/(e1t e2t) { di[ aeiu e2u mi(wslpi) ]
60      !!                               + dj[ aeiv e1v mj(wslpj) ] }
61      !!      add the eiv component to the model velocity:
62      !!         p.n = p.n + z._eiv
63      !!
64      !! ** Action  : - add to p.n the eiv component
65      !!----------------------------------------------------------------------
66      INTEGER                         , INTENT(in   ) ::   kt       ! ocean time-step index
67      CHARACTER(len=3)                , INTENT(in   ) ::   cdtype   ! =TRA or TRC (tracer indicator)
68      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pun      ! in : 3 ocean velocity components
69      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pvn      ! out: 3 ocean velocity components
70      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pwn      ! increased by the eiv
71      !!
72      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
73      REAL(wp) ::   zuwk, zuwk1, zuwi, zuwi1   ! local scalars
74      REAL(wp) ::   zvwk, zvwk1, zvwj, zvwj1   !   -      -
75      REAL(wp), DIMENSION(jpi,jpj) ::   zu_eiv, zv_eiv, zw_eiv     ! 2D workspace
76# if defined key_diaeiv 
77      REAL(wp) ::   zztmp                      ! local scalar
78      REAL(wp), DIMENSION(jpi,jpj) ::   z2d    ! 2D workspace
79# endif 
80      !!----------------------------------------------------------------------
81
82      IF( kt == nit000 )  THEN
83         IF(lwp) WRITE(numout,*)
84         IF(lwp) WRITE(numout,*) 'tra_adv_eiv : eddy induced advection on ', cdtype,' :'
85         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   add to velocity fields the eiv component'
86# if defined key_diaeiv 
87         IF( cdtype == 'TRA') THEN
88            u_eiv(:,:,:) = 0.e0
89            v_eiv(:,:,:) = 0.e0
90            w_eiv(:,:,:) = 0.e0
91         END IF
92# endif
93      ENDIF
94
95      zu_eiv(:,:) = 0.e0   ;   zv_eiv(:,:) = 0.e0   ;    zw_eiv(:,:) = 0.e0 
96     
97                                                    ! =================
98      DO jk = 1, jpkm1                              !  Horizontal slab
99         !                                          ! =================
100         DO jj = 1, jpjm1
101            DO ji = 1, fs_jpim1   ! vector opt.
102               zuwk = ( wslpi(ji,jj,jk  ) + wslpi(ji+1,jj,jk  ) ) * fsaeiu(ji,jj,jk  ) * umask(ji,jj,jk  )
103               zuwk1= ( wslpi(ji,jj,jk+1) + wslpi(ji+1,jj,jk+1) ) * fsaeiu(ji,jj,jk+1) * umask(ji,jj,jk+1)
104               zvwk = ( wslpj(ji,jj,jk  ) + wslpj(ji,jj+1,jk  ) ) * fsaeiv(ji,jj,jk  ) * vmask(ji,jj,jk  )
105               zvwk1= ( wslpj(ji,jj,jk+1) + wslpj(ji,jj+1,jk+1) ) * fsaeiv(ji,jj,jk+1) * vmask(ji,jj,jk+1)
106
107               zu_eiv(ji,jj) = 0.5 * umask(ji,jj,jk) * ( zuwk - zuwk1 ) 
108               zv_eiv(ji,jj) = 0.5 * vmask(ji,jj,jk) * ( zvwk - zvwk1 ) 
109   
110               pun(ji,jj,jk) = pun(ji,jj,jk) + e2u(ji,jj) * zu_eiv(ji,jj)
111               pvn(ji,jj,jk) = pvn(ji,jj,jk) + e1v(ji,jj) * zv_eiv(ji,jj)
112            END DO
113         END DO
114# if defined key_diaeiv 
115         IF( cdtype == 'TRA') THEN
116            u_eiv(:,:,jk) = zu_eiv(:,:) / fse3u(:,:,jk)
117            v_eiv(:,:,jk) = zv_eiv(:,:) / fse3v(:,:,jk)
118         END IF
119# endif
120         IF( jk >=2 ) THEN                             ! jk=1 zw_eiv=0, not computed
121            DO jj = 2, jpjm1
122               DO ji = fs_2, fs_jpim1   ! vector opt.
123# if defined key_traldf_c2d || defined key_traldf_c3d
124                  zuwi  = ( wslpi(ji,jj,jk)+wslpi(ji-1,jj,jk) ) * fsaeiu(ji-1,jj,jk) * e2u(ji-1,jj) * umask(ji-1,jj,jk)
125                  zuwi1 = ( wslpi(ji,jj,jk)+wslpi(ji+1,jj,jk) ) * fsaeiu(ji  ,jj,jk) * e2u(ji  ,jj) * umask(ji  ,jj,jk)
126                  zvwj  = ( wslpj(ji,jj,jk)+wslpj(ji,jj-1,jk) ) * fsaeiv(ji,jj-1,jk) * e1v(ji,jj-1) * vmask(ji,jj-1,jk)
127                  zvwj1 = ( wslpj(ji,jj,jk)+wslpj(ji,jj+1,jk) ) * fsaeiv(ji,jj  ,jk) * e1v(ji  ,jj) * vmask(ji  ,jj,jk)
128 
129                  zw_eiv(ji,jj) = - 0.5 * tmask(ji,jj,jk) * ( zuwi1 - zuwi + zvwj1 - zvwj ) 
130# else
131                  zuwi  = ( wslpi(ji,jj,jk) + wslpi(ji-1,jj,jk) ) * e2u(ji-1,jj) * umask(ji-1,jj,jk)
132                  zuwi1 = ( wslpi(ji,jj,jk) + wslpi(ji+1,jj,jk) ) * e2u(ji  ,jj) * umask(ji  ,jj,jk)
133                  zvwj  = ( wslpj(ji,jj,jk) + wslpj(ji,jj-1,jk) ) * e1v(ji,jj-1) * vmask(ji,jj-1,jk)
134                  zvwj1 = ( wslpj(ji,jj,jk) + wslpj(ji,jj+1,jk) ) * e1v(ji  ,jj) * vmask(ji  ,jj,jk)
135
136                  zw_eiv(ji,jj) = - 0.5 * tmask(ji,jj,jk) * fsaeiw(ji,jj,jk) * ( zuwi1 - zuwi + zvwj1 - zvwj )
137# endif
138                  pwn(ji,jj,jk) = pwn(ji,jj,jk) + zw_eiv(ji,jj)
139               END DO
140            END DO
141# if defined key_diaeiv 
142            IF( cdtype == 'TRA')  w_eiv(:,:,jk) = zw_eiv(:,:) / ( e1t(:,:) * e2t(:,:) )
143# endif
144         ENDIF
145         !                                          ! =================
146      END DO                                        !    End of slab 
147      !                                             ! =================
148
149# if defined key_diaeiv 
150      IF( cdtype == 'TRA') THEN
151         CALL iom_put( "uoce_eiv", u_eiv )    ! i-eiv current
152         CALL iom_put( "voce_eiv", v_eiv )    ! j-eiv current
153         CALL iom_put( "woce_eiv", w_eiv )    ! vert. eiv current
154         IF( lk_diaar5 ) THEN
155            zztmp = 0.5 * rau0 * rcp 
156            z2d(:,:) = 0.e0 
157            DO jk = 1, jpkm1
158               DO jj = 2, jpjm1
159                  DO ji = fs_2, fs_jpim1   ! vector opt.
160                     z2d(ji,jj) = z2d(ji,jj) + zztmp * u_eiv(ji,jj,jk) &
161                       &         * (tsn(ji,jj,jk,jp_tem)+tsn(ji+1,jj,jk,jp_tem)) * e1u(ji,jj) * fse3u(ji,jj,jk) 
162                  END DO
163               END DO
164            END DO
165            CALL lbc_lnk( z2d, 'U', -1. )
166            CALL iom_put( "ueiv_heattr", z2d )                  ! heat transport in i-direction
167            z2d(:,:) = 0.e0 
168            DO jk = 1, jpkm1
169               DO jj = 2, jpjm1
170                  DO ji = fs_2, fs_jpim1   ! vector opt.
171                     z2d(ji,jj) = z2d(ji,jj) + zztmp * v_eiv(ji,jj,jk) &
172                     &           * (tsn(ji,jj,jk,jp_tem)+tsn(ji,jj+1,jk,jp_tem)) * e2v(ji,jj) * fse3v(ji,jj,jk) 
173                  END DO
174               END DO
175            END DO
176            CALL lbc_lnk( z2d, 'V', -1. )
177            CALL iom_put( "veiv_heattr", z2d )                  !  heat transport in i-direction
178         ENDIF
179    END IF
180# endif 
181      !
182    END SUBROUTINE tra_adv_eiv
183
184#else
185   !!----------------------------------------------------------------------
186   !!   Dummy module :             No rotation of the lateral mixing tensor
187   !!----------------------------------------------------------------------
188CONTAINS
189   SUBROUTINE tra_adv_eiv( kt, pun, pvn, pwn, cdtype )              ! Empty routine
190      INTEGER  ::   kt   
191      CHARACTER(len=3) ::   cdtype
192      REAL, DIMENSION(:,:,:) ::   pun, pvn, pwn
193      WRITE(*,*) 'tra_adv_eiv: You should not have seen this print! error?', kt, cdtype
194      WRITE(*,*) 'tra_adv_eiv: You should not have seen this print! error?', pun(1,1,1), pvn(1,1,1), pwn(1,1,1)
195   END SUBROUTINE tra_adv_eiv
196#endif
197
198   !!==============================================================================
199END MODULE traadv_eiv
Note: See TracBrowser for help on using the repository browser.