New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_eiv.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_eiv.F90 @ 2715

Last change on this file since 2715 was 2715, checked in by rblod, 13 years ago

First attempt to put dynamic allocation on the trunk
  • Property svn:keywords set to Id
File size: 10.3 KB
Line 
1MODULE traadv_eiv
2   !!======================================================================
3   !!                    ***  MODULE  traadv_eiv  ***
4   !! Ocean tracers:  advection trend - eddy induced velocity
5   !!======================================================================
6   !! History :  1.0  !  2005-11 (G. Madec)  Original code, from traldf and zdf _iso
7   !!            3.3  !  2010-05 (C. Ethe, G. Madec)  merge TRC-TRA
8   !!----------------------------------------------------------------------
9#if defined key_traldf_eiv   ||   defined key_esopa
10   !!----------------------------------------------------------------------
11   !!   'key_traldf_eiv'                  rotation of the lateral mixing tensor
12   !!----------------------------------------------------------------------
13   !!   tra_ldf_iso : update the tracer trend with the horizontal component
14   !!                 of iso neutral laplacian operator or horizontal
15   !!                 laplacian operator in s-coordinate
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and tracers variables
18   USE dom_oce         ! ocean space and time domain variables
19   USE ldftra_oce      ! ocean active tracers: lateral physics
20   USE ldfslp          ! iso-neutral slopes
21   USE in_out_manager  ! I/O manager
22   USE iom
23   USE trc_oce         ! share passive tracers/Ocean variables
24# if defined key_diaeiv
25   USE phycst          ! physical constants
26   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
27   USE diaar5, ONLY:   lk_diaar5
28# endif 
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   tra_adv_eiv   ! routine called by step.F90
34
35   !! * Substitutions
36#  include "domzgr_substitute.h90"
37#  include "ldftra_substitute.h90"
38#  include "ldfeiv_substitute.h90"
39#  include "vectopt_loop_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
42   !! $Id$
43   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE tra_adv_eiv( kt, pun, pvn, pwn, cdtype )
48      !!----------------------------------------------------------------------
49      !!                  ***  ROUTINE tra_adv_eiv  ***
50      !!
51      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
52      !!      trend and add it to the general trend of tracer equation.
53      !!
54      !! ** Method  :   The eddy induced advection is computed from the slope
55      !!      of iso-neutral surfaces computed in routine ldf_slp as follows:
56      !!         zu_eiv =  1/(e2u e3u)   dk[ aeiu e2u mi(wslpi) ]
57      !!         zv_eiv =  1/(e1v e3v)   dk[ aeiv e1v mj(wslpj)
58      !!         zw_eiv = -1/(e1t e2t) { di[ aeiu e2u mi(wslpi) ]
59      !!                               + dj[ aeiv e1v mj(wslpj) ] }
60      !!      add the eiv component to the model velocity:
61      !!         p.n = p.n + z._eiv
62      !!
63      !! ** Action  : - add to p.n the eiv component
64      !!----------------------------------------------------------------------
65      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
66      USE wrk_nemo, ONLY:   zu_eiv => wrk_2d_1 , zv_eiv => wrk_2d_2 , zw_eiv => wrk_2d_3   ! 2D workspace
67# if defined key_diaeiv 
68      USE wrk_nemo, ONLY:   z2d => wrk_2d_4   ! 2D workspace
69#endif
70      INTEGER                         , INTENT(in   ) ::   kt       ! ocean time-step index
71      CHARACTER(len=3)                , INTENT(in   ) ::   cdtype   ! =TRA or TRC (tracer indicator)
72      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pun      ! in : 3 ocean velocity components
73      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pvn      ! out: 3 ocean velocity components
74      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pwn      ! increased by the eiv
75      !!
76      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
77      REAL(wp) ::   zuwk, zuwk1, zuwi, zuwi1   ! local scalars
78      REAL(wp) ::   zvwk, zvwk1, zvwj, zvwj1   !   -      -
79# if defined key_diaeiv 
80      REAL(wp) ::   zztmp                      ! local scalar
81# endif 
82      !!----------------------------------------------------------------------
83
84# if defined key_diaeiv 
85      IF( wrk_in_use(2, 1,2,3,4) ) THEN
86# else
87      IF( wrk_in_use(2, 1,2,3)   ) THEN
88# endif
89         CALL ctl_stop('tra_adv_eiv: requested workspace arrays are unavailable')   ;   RETURN
90      ENDIF
91
92      IF( kt == nit000 )  THEN
93         IF(lwp) WRITE(numout,*)
94         IF(lwp) WRITE(numout,*) 'tra_adv_eiv : eddy induced advection on ', cdtype,' :'
95         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   add to velocity fields the eiv component'
96# if defined key_diaeiv 
97         IF( cdtype == 'TRA') THEN
98            u_eiv(:,:,:) = 0.e0
99            v_eiv(:,:,:) = 0.e0
100            w_eiv(:,:,:) = 0.e0
101         END IF
102# endif
103      ENDIF
104
105      zu_eiv(:,:) = 0.e0   ;   zv_eiv(:,:) = 0.e0   ;    zw_eiv(:,:) = 0.e0 
106     
107                                                    ! =================
108      DO jk = 1, jpkm1                              !  Horizontal slab
109         !                                          ! =================
110         DO jj = 1, jpjm1
111            DO ji = 1, fs_jpim1   ! vector opt.
112               zuwk = ( wslpi(ji,jj,jk  ) + wslpi(ji+1,jj,jk  ) ) * fsaeiu(ji,jj,jk  ) * umask(ji,jj,jk  )
113               zuwk1= ( wslpi(ji,jj,jk+1) + wslpi(ji+1,jj,jk+1) ) * fsaeiu(ji,jj,jk+1) * umask(ji,jj,jk+1)
114               zvwk = ( wslpj(ji,jj,jk  ) + wslpj(ji,jj+1,jk  ) ) * fsaeiv(ji,jj,jk  ) * vmask(ji,jj,jk  )
115               zvwk1= ( wslpj(ji,jj,jk+1) + wslpj(ji,jj+1,jk+1) ) * fsaeiv(ji,jj,jk+1) * vmask(ji,jj,jk+1)
116
117               zu_eiv(ji,jj) = 0.5 * umask(ji,jj,jk) * ( zuwk - zuwk1 ) 
118               zv_eiv(ji,jj) = 0.5 * vmask(ji,jj,jk) * ( zvwk - zvwk1 ) 
119   
120               pun(ji,jj,jk) = pun(ji,jj,jk) + e2u(ji,jj) * zu_eiv(ji,jj)
121               pvn(ji,jj,jk) = pvn(ji,jj,jk) + e1v(ji,jj) * zv_eiv(ji,jj)
122            END DO
123         END DO
124# if defined key_diaeiv 
125         IF( cdtype == 'TRA') THEN
126            u_eiv(:,:,jk) = zu_eiv(:,:) / fse3u(:,:,jk)
127            v_eiv(:,:,jk) = zv_eiv(:,:) / fse3v(:,:,jk)
128         END IF
129# endif
130         IF( jk >=2 ) THEN                             ! jk=1 zw_eiv=0, not computed
131            DO jj = 2, jpjm1
132               DO ji = fs_2, fs_jpim1   ! vector opt.
133# if defined key_traldf_c2d || defined key_traldf_c3d
134                  zuwi  = ( wslpi(ji,jj,jk)+wslpi(ji-1,jj,jk) ) * fsaeiu(ji-1,jj,jk) * e2u(ji-1,jj) * umask(ji-1,jj,jk)
135                  zuwi1 = ( wslpi(ji,jj,jk)+wslpi(ji+1,jj,jk) ) * fsaeiu(ji  ,jj,jk) * e2u(ji  ,jj) * umask(ji  ,jj,jk)
136                  zvwj  = ( wslpj(ji,jj,jk)+wslpj(ji,jj-1,jk) ) * fsaeiv(ji,jj-1,jk) * e1v(ji,jj-1) * vmask(ji,jj-1,jk)
137                  zvwj1 = ( wslpj(ji,jj,jk)+wslpj(ji,jj+1,jk) ) * fsaeiv(ji,jj  ,jk) * e1v(ji  ,jj) * vmask(ji  ,jj,jk)
138 
139                  zw_eiv(ji,jj) = - 0.5 * tmask(ji,jj,jk) * ( zuwi1 - zuwi + zvwj1 - zvwj ) 
140# else
141                  zuwi  = ( wslpi(ji,jj,jk) + wslpi(ji-1,jj,jk) ) * e2u(ji-1,jj) * umask(ji-1,jj,jk)
142                  zuwi1 = ( wslpi(ji,jj,jk) + wslpi(ji+1,jj,jk) ) * e2u(ji  ,jj) * umask(ji  ,jj,jk)
143                  zvwj  = ( wslpj(ji,jj,jk) + wslpj(ji,jj-1,jk) ) * e1v(ji,jj-1) * vmask(ji,jj-1,jk)
144                  zvwj1 = ( wslpj(ji,jj,jk) + wslpj(ji,jj+1,jk) ) * e1v(ji  ,jj) * vmask(ji  ,jj,jk)
145
146                  zw_eiv(ji,jj) = - 0.5 * tmask(ji,jj,jk) * fsaeiw(ji,jj,jk) * ( zuwi1 - zuwi + zvwj1 - zvwj )
147# endif
148                  pwn(ji,jj,jk) = pwn(ji,jj,jk) + zw_eiv(ji,jj)
149               END DO
150            END DO
151# if defined key_diaeiv 
152            IF( cdtype == 'TRA')  w_eiv(:,:,jk) = zw_eiv(:,:) / ( e1t(:,:) * e2t(:,:) )
153# endif
154         ENDIF
155         !                                          ! =================
156      END DO                                        !    End of slab 
157      !                                             ! =================
158
159# if defined key_diaeiv 
160      IF( cdtype == 'TRA') THEN
161         CALL iom_put( "uoce_eiv", u_eiv )    ! i-eiv current
162         CALL iom_put( "voce_eiv", v_eiv )    ! j-eiv current
163         CALL iom_put( "woce_eiv", w_eiv )    ! vert. eiv current
164         IF( lk_diaar5 ) THEN
165            zztmp = 0.5 * rau0 * rcp 
166            z2d(:,:) = 0.e0 
167            DO jk = 1, jpkm1
168               DO jj = 2, jpjm1
169                  DO ji = fs_2, fs_jpim1   ! vector opt.
170                     z2d(ji,jj) = z2d(ji,jj) + zztmp * u_eiv(ji,jj,jk) &
171                       &         * (tsn(ji,jj,jk,jp_tem)+tsn(ji+1,jj,jk,jp_tem)) * e1u(ji,jj) * fse3u(ji,jj,jk) 
172                  END DO
173               END DO
174            END DO
175            CALL lbc_lnk( z2d, 'U', -1. )
176            CALL iom_put( "ueiv_heattr", z2d )                  ! heat transport in i-direction
177            z2d(:,:) = 0.e0 
178            DO jk = 1, jpkm1
179               DO jj = 2, jpjm1
180                  DO ji = fs_2, fs_jpim1   ! vector opt.
181                     z2d(ji,jj) = z2d(ji,jj) + zztmp * v_eiv(ji,jj,jk) &
182                     &           * (tsn(ji,jj,jk,jp_tem)+tsn(ji,jj+1,jk,jp_tem)) * e2v(ji,jj) * fse3v(ji,jj,jk) 
183                  END DO
184               END DO
185            END DO
186            CALL lbc_lnk( z2d, 'V', -1. )
187            CALL iom_put( "veiv_heattr", z2d )                  !  heat transport in i-direction
188         ENDIF
189    END IF
190# endif 
191      !
192# if defined key_diaeiv 
193      IF( wrk_not_released(2, 1,2,3,4) )   CALL ctl_stop('tra_adv_eiv: failed to release workspace arrays')
194# else
195      IF( wrk_not_released(2, 1,2,3)   )   CALL ctl_stop('tra_adv_eiv: failed to release workspace arrays')
196# endif
197      !
198    END SUBROUTINE tra_adv_eiv
199
200#else
201   !!----------------------------------------------------------------------
202   !!   Dummy module :             No rotation of the lateral mixing tensor
203   !!----------------------------------------------------------------------
204CONTAINS
205   SUBROUTINE tra_adv_eiv( kt, pun, pvn, pwn, cdtype )              ! Empty routine
206      INTEGER  ::   kt   
207      CHARACTER(len=3) ::   cdtype
208      REAL, DIMENSION(:,:,:) ::   pun, pvn, pwn
209      WRITE(*,*) 'tra_adv_eiv: You should not have seen this print! error?', kt, cdtype, pun(1,1,1), pvn(1,1,1), pwn(1,1,1)
210   END SUBROUTINE tra_adv_eiv
211#endif
212
213   !!==============================================================================
214END MODULE traadv_eiv
Note: See TracBrowser for help on using the repository browser.