New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_mus.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_mus.F90 @ 6140

Last change on this file since 6140 was 6140, checked in by timgraham, 8 years ago

Merge of branches/2015/dev_merge_2015 back into trunk. Merge excludes NEMOGCM/TOOLS/OBSTOOLS/ for now due to issues with the change of file type. Will sort these manually with further commits.

Branch merged as follows:
In the working copy of branch ran:
svn merge svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/trunk@HEAD
Small conflicts due to bug fixes applied to trunk since the dev_merge_2015 was copied. Bug fixes were applied to the branch as well so these were easy to resolve.
Branch committed at this stage

In working copy run:
svn switch svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/trunk
to switch working copy

Run:
svn merge --reintegrate svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/branches/2015/dev_merge_2015
to merge the branch into the trunk and then commit - no conflicts at this stage.

  • Property svn:keywords set to Id
File size: 14.9 KB
RevLine 
[5770]1MODULE traadv_mus
[503]2   !!======================================================================
[5770]3   !!                       ***  MODULE  traadv_mus  ***
[2528]4   !! Ocean  tracers:  horizontal & vertical advective trend
[503]5   !!======================================================================
[2528]6   !! History :       !  2000-06  (A.Estublier)  for passive tracers
7   !!                 !  2001-08  (E.Durand, G.Madec)  adapted for T & S
8   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.2  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
[3680]10   !!            3.4  !  2012-06  (P. Oddo, M. Vichi) include the upstream where needed
[5770]11   !!            3.7  !  2015-09  (G. Madec) add the ice-shelf cavities boundary condition
[503]12   !!----------------------------------------------------------------------
[3]13
14   !!----------------------------------------------------------------------
[5770]15   !!   tra_adv_mus   : update the tracer trend with the horizontal
[3]16   !!                   and vertical advection trends using MUSCL scheme
17   !!----------------------------------------------------------------------
[3625]18   USE oce            ! ocean dynamics and active tracers
[4990]19   USE trc_oce        ! share passive tracers/Ocean variables
[3625]20   USE dom_oce        ! ocean space and time domain
[4990]21   USE trd_oce        ! trends: ocean variables
22   USE trdtra         ! tracers trends manager
[5147]23   USE sbcrnf         ! river runoffs
[3625]24   USE diaptr         ! poleward transport diagnostics
[4990]25   !
[3625]26   USE wrk_nemo       ! Memory Allocation
27   USE timing         ! Timing
28   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
[4990]29   USE in_out_manager ! I/O manager
30   USE lib_mpp        ! distribued memory computing
31   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
[3]32
33   IMPLICIT NONE
34   PRIVATE
35
[5770]36   PUBLIC   tra_adv_mus   ! routine called by traadv.F90
[4990]37   
38   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   upsmsk   !: mixed upstream/centered scheme near some straits
39   !                                                           !  and in closed seas (orca 2 and 4 configurations)
40   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   xind     !: mixed upstream/centered index
41   
[3]42   !! * Substitutions
43#  include "vectopt_loop_substitute.h90"
44   !!----------------------------------------------------------------------
[2528]45   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
[1152]46   !! $Id$
[2528]47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
[3]48   !!----------------------------------------------------------------------
49CONTAINS
50
[5770]51   SUBROUTINE tra_adv_mus( kt, kit000, cdtype, p2dt, pun, pvn, pwn,             &
52      &                                              ptb, pta, kjpt, ld_msc_ups )
[3]53      !!----------------------------------------------------------------------
[5770]54      !!                    ***  ROUTINE tra_adv_mus  ***
[216]55      !!
[5770]56      !! ** Purpose :   Compute the now trend due to total advection of tracers
57      !!              using a MUSCL scheme (Monotone Upstream-centered Scheme for
58      !!              Conservation Laws) and add it to the general tracer trend.
[3]59      !!
[216]60      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
[5770]61      !!              ld_msc_ups=T :
[3]62      !!
[6140]63      !! ** Action : - update pta  with the now advective tracer trends
64      !!             - send trends to trdtra module for further diagnostcs (l_trdtra=T)
65      !!             - htr_adv, str_adv : poleward advective heat and salt transport (ln_diaptr=T)
[3]66      !!
[503]67      !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
68      !!              IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
69      !!----------------------------------------------------------------------
[2528]70      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
[3294]71      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
[2528]72      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
73      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
[3718]74      LOGICAL                              , INTENT(in   ) ::   ld_msc_ups      ! use upstream scheme within muscl
[6140]75      REAL(wp)                             , INTENT(in   ) ::   p2dt            ! tracer time-step
[2528]76      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
77      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb             ! before tracer field
78      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
[2715]79      !
[5770]80      INTEGER  ::   ji, jj, jk, jn       ! dummy loop indices
81      INTEGER  ::   ierr                 ! local integer
82      REAL(wp) ::   zu, z0u, zzwx, zw    ! local scalars
83      REAL(wp) ::   zv, z0v, zzwy, z0w   !   -      -
[6140]84      REAL(wp) ::   zalpha               !   -      -
[4990]85      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zslpx, zslpy   ! 3D workspace
86      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zwx  , zwy     ! -      -
[3]87      !!----------------------------------------------------------------------
[3294]88      !
[5770]89      IF( nn_timing == 1 )  CALL timing_start('tra_adv_mus')
[3294]90      !
[5770]91      CALL wrk_alloc( jpi,jpj,jpk,   zslpx, zslpy, zwx, zwy )
[3294]92      !
93      IF( kt == kit000 )  THEN
[2528]94         IF(lwp) WRITE(numout,*)
95         IF(lwp) WRITE(numout,*) 'tra_adv : MUSCL advection scheme on ', cdtype
[3718]96         IF(lwp) WRITE(numout,*) '        : mixed up-stream           ', ld_msc_ups
[2528]97         IF(lwp) WRITE(numout,*) '~~~~~~~'
[3680]98         IF(lwp) WRITE(numout,*)
[2528]99         !
[5770]100         ! Upstream / MUSCL scheme indicator
[3680]101         !
[5770]102         ALLOCATE( xind(jpi,jpj,jpk), STAT=ierr )
103         xind(:,:,:) = 1._wp              ! set equal to 1 where up-stream is not needed
104         !
105         IF( ld_msc_ups ) THEN            ! define the upstream indicator (if asked)
106            ALLOCATE( upsmsk(jpi,jpj), STAT=ierr )
[3718]107            upsmsk(:,:) = 0._wp                             ! not upstream by default
[5770]108            !
[4990]109            DO jk = 1, jpkm1
110               xind(:,:,jk) = 1._wp                              &                 ! =>1 where up-stream is not needed
111                  &         - MAX ( rnfmsk(:,:) * rnfmsk_z(jk),  &                 ! =>0 near runoff mouths (& closed sea outflows)
[5770]112                  &                 upsmsk(:,:)                ) * tmask(:,:,jk)   ! =>0 in some user defined area
[3718]113            END DO
[3680]114         ENDIF 
[3718]115         !
116      ENDIF 
[4990]117      !     
[6140]118      DO jn = 1, kjpt            !==  loop over the tracers  ==!
119         !
120         !                          !* Horizontal advective fluxes
121         !
122         !                                !-- first guess of the slopes
123         zwx(:,:,jpk) = 0._wp                   ! bottom values
124         zwy(:,:,jpk) = 0._wp 
125         DO jk = 1, jpkm1                       ! interior values
[2528]126            DO jj = 1, jpjm1     
127               DO ji = 1, fs_jpim1   ! vector opt.
128                  zwx(ji,jj,jk) = umask(ji,jj,jk) * ( ptb(ji+1,jj,jk,jn) - ptb(ji,jj,jk,jn) )
129                  zwy(ji,jj,jk) = vmask(ji,jj,jk) * ( ptb(ji,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
130               END DO
131           END DO
[3]132         END DO
[6140]133         CALL lbc_lnk( zwx, 'U', -1. )          ! lateral boundary conditions   (changed sign)
[2528]134         CALL lbc_lnk( zwy, 'V', -1. )
[6140]135         !                                !-- Slopes of tracer
136         zslpx(:,:,jpk) = 0._wp                 ! bottom values
137         zslpy(:,:,jpk) = 0._wp
138         DO jk = 1, jpkm1                       ! interior values
[2528]139            DO jj = 2, jpj
140               DO ji = fs_2, jpi   ! vector opt.
141                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji-1,jj  ,jk) )   &
142                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji-1,jj  ,jk) ) )
143                  zslpy(ji,jj,jk) =                    ( zwy(ji,jj,jk) + zwy(ji  ,jj-1,jk) )   &
144                     &            * ( 0.25 + SIGN( 0.25, zwy(ji,jj,jk) * zwy(ji  ,jj-1,jk) ) )
145               END DO
[3]146            END DO
147         END DO
[503]148         !
[6140]149         DO jk = 1, jpkm1                 !-- Slopes limitation
[2528]150            DO jj = 2, jpj
151               DO ji = fs_2, jpi   ! vector opt.
152                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji  ,jj,jk) ),   &
153                     &                                                 2.*ABS( zwx  (ji-1,jj,jk) ),   &
154                     &                                                 2.*ABS( zwx  (ji  ,jj,jk) ) )
155                  zslpy(ji,jj,jk) = SIGN( 1., zslpy(ji,jj,jk) ) * MIN(    ABS( zslpy(ji,jj  ,jk) ),   &
156                     &                                                 2.*ABS( zwy  (ji,jj-1,jk) ),   &
157                     &                                                 2.*ABS( zwy  (ji,jj  ,jk) ) )
[503]158               END DO
[2528]159           END DO
[5770]160         END DO
161         !
[6140]162         DO jk = 1, jpkm1                 !-- MUSCL horizontal advective fluxes
[503]163            DO jj = 2, jpjm1
164               DO ji = fs_2, fs_jpim1   ! vector opt.
[2528]165                  ! MUSCL fluxes
166                  z0u = SIGN( 0.5, pun(ji,jj,jk) )
167                  zalpha = 0.5 - z0u
[6140]168                  zu  = z0u - 0.5 * pun(ji,jj,jk) * p2dt * r1_e1e2u(ji,jj) / e3u_n(ji,jj,jk)
[4990]169                  zzwx = ptb(ji+1,jj,jk,jn) + xind(ji,jj,jk) * zu * zslpx(ji+1,jj,jk)
170                  zzwy = ptb(ji  ,jj,jk,jn) + xind(ji,jj,jk) * zu * zslpx(ji  ,jj,jk)
[2528]171                  zwx(ji,jj,jk) = pun(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
172                  !
173                  z0v = SIGN( 0.5, pvn(ji,jj,jk) )
174                  zalpha = 0.5 - z0v
[6140]175                  zv  = z0v - 0.5 * pvn(ji,jj,jk) * p2dt * r1_e1e2v(ji,jj) / e3v_n(ji,jj,jk)
[4990]176                  zzwx = ptb(ji,jj+1,jk,jn) + xind(ji,jj,jk) * zv * zslpy(ji,jj+1,jk)
177                  zzwy = ptb(ji,jj  ,jk,jn) + xind(ji,jj,jk) * zv * zslpy(ji,jj  ,jk)
[2528]178                  zwy(ji,jj,jk) = pvn(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
[503]179               END DO
180            END DO
181         END DO
[5770]182         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )   ! lateral boundary conditions   (changed sign)
[503]183         !
[6140]184         DO jk = 1, jpkm1                 !-- Tracer advective trend
[2528]185            DO jj = 2, jpjm1     
186               DO ji = fs_2, fs_jpim1   ! vector opt.
[5770]187                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) - ( zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )       &
188                  &                                     + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  ) )     &
[6140]189                  &                                   * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
[3]190               END DO
[2528]191           END DO
192         END DO       
[6140]193         !                                ! trend diagnostics
[4990]194         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR.   &
195            &( cdtype == 'TRC' .AND. l_trdtrc )      )  THEN
196            CALL trd_tra( kt, cdtype, jn, jptra_xad, zwx, pun, ptb(:,:,:,jn) )
197            CALL trd_tra( kt, cdtype, jn, jptra_yad, zwy, pvn, ptb(:,:,:,jn) )
[2528]198         END IF
[6140]199         !                                ! "Poleward" heat and salt transports
[5147]200         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
201            IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) )
202            IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) )
[457]203         ENDIF
[6140]204         !
205         !                          !* Vertical advective fluxes
206         !
[5770]207         !                                !-- first guess of the slopes
208         zwx(:,:, 1 ) = 0._wp                   ! surface & bottom boundary conditions
[6140]209         zwx(:,:,jpk) = 0._wp
210         DO jk = 2, jpkm1                       ! interior values
[2528]211            zwx(:,:,jk) = tmask(:,:,jk) * ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) )
[3]212         END DO
[5770]213         !                                !-- Slopes of tracer
214         zslpx(:,:,1) = 0._wp                   ! surface values
215         DO jk = 2, jpkm1                       ! interior value
[2528]216            DO jj = 1, jpj
217               DO ji = 1, jpi
[6140]218                  zslpx(ji,jj,jk) =                     ( zwx(ji,jj,jk) + zwx(ji,jj,jk+1) )  &
219                     &            * (  0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji,jj,jk+1) )  )
[2528]220               END DO
[3]221            END DO
222         END DO
[6140]223         DO jk = 2, jpkm1                 !-- Slopes limitation
224            DO jj = 1, jpj                      ! interior values
[2528]225               DO ji = 1, jpi
226                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji,jj,jk  ) ),   &
227                     &                                                 2.*ABS( zwx  (ji,jj,jk+1) ),   &
228                     &                                                 2.*ABS( zwx  (ji,jj,jk  ) )  )
229               END DO
[3]230            END DO
231         END DO
[6140]232         DO jk = 1, jpk-2                 !-- vertical advective flux
[2528]233            DO jj = 2, jpjm1     
234               DO ji = fs_2, fs_jpim1   ! vector opt.
235                  z0w = SIGN( 0.5, pwn(ji,jj,jk+1) )
236                  zalpha = 0.5 + z0w
[6140]237                  zw  = z0w - 0.5 * pwn(ji,jj,jk+1) * p2dt * r1_e1e2t(ji,jj) / e3w_n(ji,jj,jk+1)
[4990]238                  zzwx = ptb(ji,jj,jk+1,jn) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk+1)
239                  zzwy = ptb(ji,jj,jk  ,jn) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk  )
[5770]240                  zwx(ji,jj,jk+1) = pwn(ji,jj,jk+1) * ( zalpha * zzwx + (1.-zalpha) * zzwy ) * wmask(ji,jj,jk)
[2528]241               END DO
[3]242            END DO
243         END DO
[6140]244         IF( ln_linssh ) THEN                   ! top values, linear free surface only
245            IF( ln_isfcav ) THEN                      ! ice-shelf cavities (top of the ocean)
[5770]246               DO jj = 1, jpj
247                  DO ji = 1, jpi
248                     zwx(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)
249                  END DO
250               END DO   
[6140]251            ELSE                                      ! no cavities: only at the ocean surface
[5770]252               zwx(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)
253            ENDIF
254         ENDIF
255         !
[6140]256         DO jk = 1, jpkm1                 !-- vertical advective trend
[2528]257            DO jj = 2, jpjm1     
[503]258               DO ji = fs_2, fs_jpim1   ! vector opt.
[6140]259                  pta(ji,jj,jk,jn) =  pta(ji,jj,jk,jn) - ( zwx(ji,jj,jk) - zwx(ji,jj,jk+1) ) * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
[503]260               END DO
261            END DO
262         END DO
[6140]263         !                                ! send trends for diagnostic
[4990]264         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR.     &
265            &( cdtype == 'TRC' .AND. l_trdtrc )      )   &
266            CALL trd_tra( kt, cdtype, jn, jptra_zad, zwx, pwn, ptb(:,:,:,jn) )
[503]267         !
[6140]268      END DO                     ! end of tracer loop
[503]269      !
[5770]270      CALL wrk_dealloc( jpi,jpj,jpk,   zslpx, zslpy, zwx, zwy )
[2715]271      !
[5770]272      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_mus')
[3294]273      !
[5770]274   END SUBROUTINE tra_adv_mus
[3]275
276   !!======================================================================
[5770]277END MODULE traadv_mus
Note: See TracBrowser for help on using the repository browser.