New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_muscl.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_muscl.F90 @ 2528

Last change on this file since 2528 was 2528, checked in by rblod, 13 years ago

Update NEMOGCM from branch nemo_v3_3_beta
  • Property svn:keywords set to Id
File size: 13.3 KB
Line 
1MODULE traadv_muscl
2   !!======================================================================
3   !!                       ***  MODULE  traadv_muscl  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!======================================================================
6   !! History :       !  2000-06  (A.Estublier)  for passive tracers
7   !!                 !  2001-08  (E.Durand, G.Madec)  adapted for T & S
8   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.2  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   tra_adv_muscl : update the tracer trend with the horizontal
14   !!                   and vertical advection trends using MUSCL scheme
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean dynamics and active tracers
17   USE dom_oce         ! ocean space and time domain
18   USE trdmod_oce      ! tracers trends
19   USE trdtra      ! tracers trends
20   USE in_out_manager  ! I/O manager
21   USE dynspg_oce      ! choice/control of key cpp for surface pressure gradient
22   USE trabbl          ! tracers: bottom boundary layer
23   USE lib_mpp         ! distribued memory computing
24   USE lbclnk          ! ocean lateral boundary condition (or mpp link)
25   USE diaptr          ! poleward transport diagnostics
26   USE trc_oce         ! share passive tracers/Ocean variables
27
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   tra_adv_muscl  ! routine called by step.F90
33
34   LOGICAL  :: l_trd       ! flag to compute trends
35
36   !! * Substitutions
37#  include "domzgr_substitute.h90"
38#  include "vectopt_loop_substitute.h90"
39   !!----------------------------------------------------------------------
40   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
41   !! $Id$
42   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
43   !!----------------------------------------------------------------------
44CONTAINS
45
46   SUBROUTINE tra_adv_muscl( kt, cdtype, p2dt, pun, pvn, pwn, &
47      &                                        ptb, pta, kjpt )
48      !!----------------------------------------------------------------------
49      !!                    ***  ROUTINE tra_adv_muscl  ***
50      !!
51      !! ** Purpose :   Compute the now trend due to total advection of T and
52      !!      S using a MUSCL scheme (Monotone Upstream-centered Scheme for
53      !!      Conservation Laws) and add it to the general tracer trend.
54      !!
55      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
56      !!
57      !! ** Action  : - update (ta,sa) with the now advective tracer trends
58      !!              - save trends
59      !!
60      !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
61      !!              IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
62      !!----------------------------------------------------------------------
63      USE oce         , zwx => ua   ! use ua as workspace
64      USE oce         , zwy => va   ! use va as workspace
65      !!
66      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
67      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
68      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
69      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
70      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
71      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb             ! before tracer field
72      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
73      !!
74      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
75      REAL(wp) ::   zu, z0u, zzwx    ! local scalar
76      REAL(wp) ::   zv, z0v, zzwy    !   -      -
77      REAL(wp) ::   zw, z0w          !   -      -
78      REAL(wp) ::   ztra, zbtr, zdt, zalpha
79      REAL(wp), DIMENSION (jpi,jpj,jpk) :: zslpx, zslpy   ! 3D workspace
80      !!----------------------------------------------------------------------
81
82      IF( kt == nit000 )  THEN
83         IF(lwp) WRITE(numout,*)
84         IF(lwp) WRITE(numout,*) 'tra_adv : MUSCL advection scheme on ', cdtype
85         IF(lwp) WRITE(numout,*) '~~~~~~~'
86         !
87         l_trd = .FALSE.
88         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
89      ENDIF
90
91      !                                                     ! ===========
92      DO jn = 1, kjpt                                       ! tracer loop
93         !                                                  ! ===========
94         ! I. Horizontal advective fluxes
95         ! ------------------------------
96         ! first guess of the slopes
97         zwx(:,:,jpk) = 0.e0   ;   zwy(:,:,jpk) = 0.e0        ! bottom values
98         ! interior values
99         DO jk = 1, jpkm1
100            DO jj = 1, jpjm1     
101               DO ji = 1, fs_jpim1   ! vector opt.
102                  zwx(ji,jj,jk) = umask(ji,jj,jk) * ( ptb(ji+1,jj,jk,jn) - ptb(ji,jj,jk,jn) )
103                  zwy(ji,jj,jk) = vmask(ji,jj,jk) * ( ptb(ji,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
104               END DO
105           END DO
106         END DO
107         !
108         CALL lbc_lnk( zwx, 'U', -1. )                        ! lateral boundary conditions on zwx, zwy   (changed sign)
109         CALL lbc_lnk( zwy, 'V', -1. )
110         !                                             !-- Slopes of tracer
111         zslpx(:,:,jpk) = 0.e0   ;   zslpy(:,:,jpk) = 0.e0    ! bottom values
112         DO jk = 1, jpkm1                                     ! interior values
113            DO jj = 2, jpj
114               DO ji = fs_2, jpi   ! vector opt.
115                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji-1,jj  ,jk) )   &
116                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji-1,jj  ,jk) ) )
117                  zslpy(ji,jj,jk) =                    ( zwy(ji,jj,jk) + zwy(ji  ,jj-1,jk) )   &
118                     &            * ( 0.25 + SIGN( 0.25, zwy(ji,jj,jk) * zwy(ji  ,jj-1,jk) ) )
119               END DO
120            END DO
121         END DO
122         !
123         DO jk = 1, jpkm1                                     ! Slopes limitation
124            DO jj = 2, jpj
125               DO ji = fs_2, jpi   ! vector opt.
126                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji  ,jj,jk) ),   &
127                     &                                                 2.*ABS( zwx  (ji-1,jj,jk) ),   &
128                     &                                                 2.*ABS( zwx  (ji  ,jj,jk) ) )
129                  zslpy(ji,jj,jk) = SIGN( 1., zslpy(ji,jj,jk) ) * MIN(    ABS( zslpy(ji,jj  ,jk) ),   &
130                     &                                                 2.*ABS( zwy  (ji,jj-1,jk) ),   &
131                     &                                                 2.*ABS( zwy  (ji,jj  ,jk) ) )
132               END DO
133           END DO
134         END DO             ! interior values
135
136         !                                             !-- MUSCL horizontal advective fluxes
137         DO jk = 1, jpkm1                                     ! interior values
138            zdt  = p2dt(jk)
139            DO jj = 2, jpjm1
140               DO ji = fs_2, fs_jpim1   ! vector opt.
141                  ! MUSCL fluxes
142                  z0u = SIGN( 0.5, pun(ji,jj,jk) )
143                  zalpha = 0.5 - z0u
144                  zu  = z0u - 0.5 * pun(ji,jj,jk) * zdt / ( e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk) )
145                  zzwx = ptb(ji+1,jj,jk,jn) + zu * zslpx(ji+1,jj,jk)
146                  zzwy = ptb(ji  ,jj,jk,jn) + zu * zslpx(ji  ,jj,jk)
147                  zwx(ji,jj,jk) = pun(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
148                  !
149                  z0v = SIGN( 0.5, pvn(ji,jj,jk) )
150                  zalpha = 0.5 - z0v
151                  zv  = z0v - 0.5 * pvn(ji,jj,jk) * zdt / ( e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk) )
152                  zzwx = ptb(ji,jj+1,jk,jn) + zv * zslpy(ji,jj+1,jk)
153                  zzwy = ptb(ji,jj  ,jk,jn) + zv * zslpy(ji,jj  ,jk) 
154                  zwy(ji,jj,jk) = pvn(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
155               END DO
156            END DO
157         END DO
158         !                                                    ! lateral boundary conditions on zwx, zwy   (changed sign)
159         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )
160         !
161         ! Tracer flux divergence at t-point added to the general trend
162         DO jk = 1, jpkm1
163            DO jj = 2, jpjm1     
164               DO ji = fs_2, fs_jpim1   ! vector opt.
165                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
166                  ! horizontal advective trends
167                  ztra = - zbtr * ( zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
168                  &               + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  ) )
169                  ! add it to the general tracer trends
170                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
171               END DO
172           END DO
173         END DO       
174         !                                 ! trend diagnostics (contribution of upstream fluxes)
175         IF( l_trd )  THEN
176            CALL trd_tra( kt, cdtype, jn, jptra_trd_xad, zwx, pun, ptb(:,:,:,jn) )
177            CALL trd_tra( kt, cdtype, jn, jptra_trd_yad, zwy, pvn, ptb(:,:,:,jn) )
178         END IF
179         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
180         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN 
181            IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) )
182            IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) )
183         ENDIF
184
185         ! II. Vertical advective fluxes
186         ! -----------------------------
187         !                                             !-- first guess of the slopes
188         zwx (:,:, 1 ) = 0.e0    ;    zwx (:,:,jpk) = 0.e0    ! surface & bottom boundary conditions
189         DO jk = 2, jpkm1                                     ! interior values
190            zwx(:,:,jk) = tmask(:,:,jk) * ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) )
191         END DO
192
193         !                                             !-- Slopes of tracer
194         zslpx(:,:,1) = 0.e0                                  ! surface values
195         DO jk = 2, jpkm1                                     ! interior value
196            DO jj = 1, jpj
197               DO ji = 1, jpi
198                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji,jj,jk+1) )   &
199                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji,jj,jk+1) ) )
200               END DO
201            END DO
202         END DO
203         !                                             !-- Slopes limitation
204         DO jk = 2, jpkm1                                     ! interior values
205            DO jj = 1, jpj
206               DO ji = 1, jpi
207                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji,jj,jk  ) ),   &
208                     &                                                 2.*ABS( zwx  (ji,jj,jk+1) ),   &
209                     &                                                 2.*ABS( zwx  (ji,jj,jk  ) )  )
210               END DO
211            END DO
212         END DO
213         !                                             !-- vertical advective flux
214         !                                                    ! surface values  (bottom already set to zero)
215         IF( lk_vvl ) THEN    ;   zwx(:,:, 1 ) = 0.e0                      !  variable volume
216         ELSE                 ;   zwx(:,:, 1 ) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
217         ENDIF 
218         !
219         DO jk = 1, jpkm1                                     ! interior values
220            zdt  = p2dt(jk)
221            DO jj = 2, jpjm1     
222               DO ji = fs_2, fs_jpim1   ! vector opt.
223                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3w(ji,jj,jk+1) )
224                  z0w = SIGN( 0.5, pwn(ji,jj,jk+1) )
225                  zalpha = 0.5 + z0w
226                  zw  = z0w - 0.5 * pwn(ji,jj,jk+1) * zdt * zbtr 
227                  zzwx = ptb(ji,jj,jk+1,jn) + zw * zslpx(ji,jj,jk+1)
228                  zzwy = ptb(ji,jj,jk  ,jn) + zw * zslpx(ji,jj,jk  )
229                  zwx(ji,jj,jk+1) = pwn(ji,jj,jk+1) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
230               END DO
231            END DO
232         END DO
233
234         ! Compute & add the vertical advective trend
235         DO jk = 1, jpkm1
236            DO jj = 2, jpjm1     
237               DO ji = fs_2, fs_jpim1   ! vector opt.
238                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
239                  ! vertical advective trends
240                  ztra = - zbtr * ( zwx(ji,jj,jk) - zwx(ji,jj,jk+1) )
241                  ! add it to the general tracer trends
242                  pta(ji,jj,jk,jn) =  pta(ji,jj,jk,jn) + ztra
243               END DO
244            END DO
245         END DO
246         !                                 ! Save the vertical advective trends for diagnostic
247         IF( l_trd ) CALL trd_tra( kt, cdtype, jn, jptra_trd_zad, zwx, pwn, ptb(:,:,:,jn) )
248         !
249      ENDDO
250      !
251   END SUBROUTINE tra_adv_muscl
252
253   !!======================================================================
254END MODULE traadv_muscl
Note: See TracBrowser for help on using the repository browser.