New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_muscl2.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_muscl2.F90 @ 3558

Last change on this file since 3558 was 3558, checked in by rblod, 11 years ago

Fix issues when using key_nosignedzeo, see ticket #996

  • Property svn:keywords set to Id
File size: 15.2 KB
Line 
1MODULE traadv_muscl2
2   !!======================================================================
3   !!                       ***  MODULE  traadv_muscl2  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!======================================================================
6   !! History :  1.0  !  2002-06  (G. Madec) from traadv_muscl
7   !!            3.2  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   tra_adv_muscl2 : update the tracer trend with the horizontal
12   !!                    and vertical advection trends using MUSCL2 scheme
13   !!----------------------------------------------------------------------
14   USE oce             ! ocean dynamics and active tracers
15   USE dom_oce         ! ocean space and time domain
16   USE trdmod_oce      ! tracers trends
17   USE trdtra          ! tracers trends
18   USE in_out_manager  ! I/O manager
19   USE dynspg_oce      ! choice/control of key cpp for surface pressure gradient
20   USE trabbl          ! tracers: bottom boundary layer
21   USE lib_mpp         ! distribued memory computing
22   USE lbclnk          ! ocean lateral boundary condition (or mpp link)
23   USE diaptr          ! poleward transport diagnostics
24   USE trc_oce         ! share passive tracers/Ocean variables
25   USE wrk_nemo        ! Memory Allocation
26   USE timing          ! Timing
27   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
28
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   tra_adv_muscl2        ! routine called by step.F90
34
35   LOGICAL  :: l_trd       ! flag to compute trends
36
37   !! * Substitutions
38#  include "domzgr_substitute.h90"
39#  include "vectopt_loop_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
42   !! $Id$
43   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE tra_adv_muscl2( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
48      &                                         ptb, ptn, pta, kjpt )
49      !!----------------------------------------------------------------------
50      !!                   ***  ROUTINE tra_adv_muscl2  ***
51      !!
52      !! ** Purpose :   Compute the now trend due to total advection of T and
53      !!      S using a MUSCL scheme (Monotone Upstream-centered Scheme for
54      !!      Conservation Laws) and add it to the general tracer trend.
55      !!
56      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
57      !!
58      !! ** Action  : - update (pta) with the now advective tracer trends
59      !!              - save trends
60      !!
61      !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
62      !!              IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
63      !!----------------------------------------------------------------------
64      USE oce     , ONLY:   zwx   => ua    , zwy   => va         ! (ua,va) used as 3D workspace
65      !!
66      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
67      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
68      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
69      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
70      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
71      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
72      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before & now tracer fields
73      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
74      !!
75      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
76      REAL(wp) ::   zu, z0u, zzwx, zw         ! local scalars
77      REAL(wp) ::   zv, z0v, zzwy, z0w        !   -      -
78      REAL(wp) ::   ztra, zbtr, zdt, zalpha   !   -      -
79      REAL(wp), POINTER, DIMENSION(:,:,:) :: zslpx, zslpy
80      !!----------------------------------------------------------------------
81      !
82      IF( nn_timing == 1 )  CALL timing_start('tra_adv_muscl2')
83      !
84      CALL wrk_alloc( jpi, jpj, jpk, zslpx, zslpy )
85      !
86
87      IF( kt == kit000 )  THEN
88         IF(lwp) WRITE(numout,*)
89         IF(lwp) WRITE(numout,*) 'tra_adv_muscl2 : MUSCL2 advection scheme on ', cdtype
90         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~'
91         !
92         l_trd = .FALSE.
93         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )   l_trd = .TRUE.
94      ENDIF
95
96      !                                                          ! ===========
97      DO jn = 1, kjpt                                            ! tracer loop
98         !                                                       ! ===========
99         ! I. Horizontal advective fluxes
100         ! ------------------------------
101         ! first guess of the slopes
102         zwx(:,:,jpk) = 0.e0   ;   zwy(:,:,jpk) = 0.e0        ! bottom values
103         ! interior values
104         DO jk = 1, jpkm1
105            DO jj = 1, jpjm1     
106               DO ji = 1, fs_jpim1   ! vector opt.
107                  zwx(ji,jj,jk) = umask(ji,jj,jk) * ( ptb(ji+1,jj,jk,jn) - ptb(ji,jj,jk,jn) )
108                  zwy(ji,jj,jk) = vmask(ji,jj,jk) * ( ptb(ji,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
109               END DO
110           END DO
111         END DO
112         !
113         CALL lbc_lnk( zwx, 'U', -1. )                        ! lateral boundary conditions on zwx, zwy   (changed sign)
114         CALL lbc_lnk( zwy, 'V', -1. )
115         !                                             !-- Slopes of tracer
116         zslpx(:,:,jpk) = 0.e0   ;   zslpy(:,:,jpk) = 0.e0    ! bottom values
117         DO jk = 1, jpkm1                                     ! interior values
118            DO jj = 2, jpj
119               DO ji = fs_2, jpi   ! vector opt.
120                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji-1,jj  ,jk) )   &
121                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji-1,jj  ,jk) ) )
122                  zslpy(ji,jj,jk) =                    ( zwy(ji,jj,jk) + zwy(ji  ,jj-1,jk) )   &
123                     &            * ( 0.25 + SIGN( 0.25, zwy(ji,jj,jk) * zwy(ji  ,jj-1,jk) ) )
124               END DO
125            END DO
126         END DO
127         !
128         DO jk = 1, jpkm1                                     ! Slopes limitation
129            DO jj = 2, jpj
130               DO ji = fs_2, jpi   ! vector opt.
131                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji  ,jj,jk) ),   &
132                     &                                                 2.*ABS( zwx  (ji-1,jj,jk) ),   &
133                     &                                                 2.*ABS( zwx  (ji  ,jj,jk) ) )
134                  zslpy(ji,jj,jk) = SIGN( 1., zslpy(ji,jj,jk) ) * MIN(    ABS( zslpy(ji,jj  ,jk) ),   &
135                     &                                                 2.*ABS( zwy  (ji,jj-1,jk) ),   &
136                     &                                                 2.*ABS( zwy  (ji,jj  ,jk) ) )
137               END DO
138           END DO
139         END DO             ! interior values
140
141        !                                             !-- MUSCL horizontal advective fluxes
142         DO jk = 1, jpkm1                                     ! interior values
143            zdt  = p2dt(jk)
144            DO jj = 2, jpjm1
145               DO ji = fs_2, fs_jpim1   ! vector opt.
146                  ! MUSCL fluxes
147                  z0u = SIGN( 0.5, pun(ji,jj,jk) )
148                  zalpha = 0.5 - z0u
149                  zu  = z0u - 0.5 * pun(ji,jj,jk) * zdt / ( e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk) )
150                  zzwx = ptb(ji+1,jj,jk,jn) + zu * zslpx(ji+1,jj,jk)
151                  zzwy = ptb(ji  ,jj,jk,jn) + zu * zslpx(ji  ,jj,jk)
152                  zwx(ji,jj,jk) = pun(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
153                  !
154                  z0v = SIGN( 0.5, pvn(ji,jj,jk) )
155                  zalpha = 0.5 - z0v
156                  zv  = z0v - 0.5 * pvn(ji,jj,jk) * zdt / ( e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk) )
157                  zzwx = ptb(ji,jj+1,jk,jn) + zv * zslpy(ji,jj+1,jk)
158                  zzwy = ptb(ji,jj  ,jk,jn) + zv * zslpy(ji,jj  ,jk)
159                  zwy(ji,jj,jk) = pvn(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
160               END DO
161            END DO
162         END DO
163
164         !!  centered scheme at lateral b.C. if off-shore velocity
165         DO jk = 1, jpkm1
166            DO jj = 2, jpjm1
167               DO ji = fs_2, fs_jpim1   ! vector opt.
168                  IF( umask(ji,jj,jk) == 0. ) THEN
169                     IF( pun(ji+1,jj,jk) > 0. .AND. ji /= jpi ) THEN
170                        zwx(ji+1,jj,jk) = 0.5 * pun(ji+1,jj,jk) * ( ptn(ji+1,jj,jk,jn) + ptn(ji+2,jj,jk,jn) )
171                     ENDIF
172                     IF( pun(ji-1,jj,jk) < 0. ) THEN
173                        zwx(ji-1,jj,jk) = 0.5 * pun(ji-1,jj,jk) * ( ptn(ji-1,jj,jk,jn) + ptn(ji,jj,jk,jn) ) 
174                     ENDIF
175                  ENDIF
176                  IF( vmask(ji,jj,jk) == 0. ) THEN
177                     IF( pvn(ji,jj+1,jk) > 0. .AND. jj /= jpj ) THEN
178                        zwy(ji,jj+1,jk) = 0.5 * pvn(ji,jj+1,jk) * ( ptn(ji,jj+1,jk,jn) + ptn(ji,jj+2,jk,jn) )
179                     ENDIF
180                     IF( pvn(ji,jj-1,jk) < 0. ) THEN
181                        zwy(ji,jj-1,jk) = 0.5 * pvn(ji,jj-1,jk) * ( ptn(ji,jj-1,jk,jn) + ptn(ji,jj,jk,jn) ) 
182                     ENDIF
183                  ENDIF
184               END DO
185            END DO
186         END DO
187         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )   ! lateral boundary condition (changed sign)
188
189         ! Tracer flux divergence at t-point added to the general trend
190         DO jk = 1, jpkm1
191            DO jj = 2, jpjm1
192               DO ji = fs_2, fs_jpim1   ! vector opt.
193                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
194                  ! horizontal advective trends
195                  ztra = - zbtr * ( zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
196                  &               + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  ) )
197                  ! added to the general tracer trends
198                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
199               END DO
200           END DO
201         END DO
202         !                                 ! trend diagnostics (contribution of upstream fluxes)
203         IF( l_trd ) THEN
204            CALL trd_tra( kt, cdtype, jn, jptra_trd_xad, zwx, pun, ptb(:,:,:,jn) )
205            CALL trd_tra( kt, cdtype, jn, jptra_trd_yad, zwy, pvn, ptb(:,:,:,jn) )
206         END IF
207
208         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
209         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN
210            IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) )
211            IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) )
212         ENDIF
213
214         ! II. Vertical advective fluxes
215         ! -----------------------------
216         !                                             !-- first guess of the slopes
217         zwx (:,:, 1 ) = 0.e0    ;    zwx (:,:,jpk) = 0.e0    ! surface & bottom boundary conditions
218         DO jk = 2, jpkm1                                     ! interior values
219            zwx(:,:,jk) = tmask(:,:,jk) * ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) )
220         END DO
221
222         !                                             !-- Slopes of tracer
223         zslpx(:,:,1) = 0.e0                                  ! surface values
224         DO jk = 2, jpkm1                                     ! interior value
225            DO jj = 1, jpj
226               DO ji = 1, jpi
227                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji,jj,jk+1) )   &
228                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji,jj,jk+1) ) )
229               END DO
230            END DO
231         END DO
232         !                                             !-- Slopes limitation
233         DO jk = 2, jpkm1                                     ! interior values
234            DO jj = 1, jpj
235               DO ji = 1, jpi
236                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji,jj,jk  ) ),   &
237                     &                                                 2.*ABS( zwx  (ji,jj,jk+1) ),   &
238                     &                                                 2.*ABS( zwx  (ji,jj,jk  ) )  )
239               END DO
240            END DO
241         END DO
242         !                                             !-- vertical advective flux
243         !                                                    ! surface values  (bottom already set to zero)
244         IF( lk_vvl ) THEN    ;   zwx(:,:, 1 ) = 0.e0                      !  variable volume
245         ELSE                 ;   zwx(:,:, 1 ) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
246         ENDIF
247         !
248         DO jk = 1, jpkm1                                     ! interior values
249            zdt  = p2dt(jk)
250            DO jj = 2, jpjm1
251               DO ji = fs_2, fs_jpim1   ! vector opt.
252                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3w(ji,jj,jk+1) )
253                  z0w = SIGN( 0.5, pwn(ji,jj,jk+1) )
254                  zalpha = 0.5 + z0w
255                  zw  = z0w - 0.5 * pwn(ji,jj,jk+1) * zdt * zbtr
256                  zzwx = ptb(ji,jj,jk+1,jn) + zw * zslpx(ji,jj,jk+1)
257                  zzwy = ptb(ji,jj,jk  ,jn) + zw * zslpx(ji,jj,jk  )
258                  zwx(ji,jj,jk+1) = pwn(ji,jj,jk+1) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
259               END DO
260            END DO
261         END DO
262         !
263         DO jk = 2, jpkm1        ! centered near the bottom
264            DO jj = 2, jpjm1
265               DO ji = fs_2, fs_jpim1   ! vector opt.
266                  IF( tmask(ji,jj,jk+1) == 0. ) THEN
267                     IF( pwn(ji,jj,jk) > 0. ) THEN
268                        zwx(ji,jj,jk) = 0.5 * pwn(ji,jj,jk) * ( ptn(ji,jj,jk-1,jn) + ptn(ji,jj,jk,jn) ) 
269                     ENDIF
270                  ENDIF
271               END DO
272            END DO
273         END DO
274         !
275         DO jk = 1, jpkm1        ! Compute & add the vertical advective trend
276            DO jj = 2, jpjm1     
277               DO ji = fs_2, fs_jpim1   ! vector opt.
278                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
279                  ! vertical advective trends
280                  ztra = - zbtr * ( zwx(ji,jj,jk) - zwx(ji,jj,jk+1) )
281                  ! added to the general tracer trends
282                  pta(ji,jj,jk,jn) =  pta(ji,jj,jk,jn) + ztra
283               END DO
284            END DO
285         END DO
286         !                       ! trend diagnostics (contribution of upstream fluxes)
287         IF( l_trd )  CALL trd_tra( kt, cdtype, jn, jptra_trd_zad, zwx, pwn, ptb(:,:,:,jn) )
288         !
289      END DO
290      !
291      CALL wrk_dealloc( jpi, jpj, jpk, zslpx, zslpy )
292      !
293      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_muscl2')
294      !
295   END SUBROUTINE tra_adv_muscl2
296
297   !!======================================================================
298END MODULE traadv_muscl2
Note: See TracBrowser for help on using the repository browser.